lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use strict;
   4
   5 use Fcntl qw( :DEFAULT :flock :seek );
   6
   7 ##
   8 # Setup file and tag signatures.  These should never change.
   9 ##
  10 sub SIG_FILE     () { 'DPDB' }
  11 sub SIG_INTERNAL () { 'i'    }
  12 sub SIG_HASH     () { 'H'    }
  13 sub SIG_ARRAY    () { 'A'    }
  14 sub SIG_NULL     () { 'N'    }
  15 sub SIG_DATA     () { 'D'    }
  16 sub SIG_INDEX    () { 'I'    }
  17 sub SIG_BLIST    () { 'B'    }
  18 sub SIG_FREE     () { 'F'    }
  19 sub SIG_SIZE     () {  1     }
  20
  21 sub precalc_sizes {
  22     ##
  23     # Precalculate index, bucket and bucket list sizes
  24     ##
  25     my $self = shift;
  26
  27     $self->{index_size}       = (2**8) * $self->{long_size};
  28     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size} * 2;
  29     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
  30
  31     return 1;
  32 }
  33
  34 sub set_pack {
  35     ##
  36     # Set pack/unpack modes (see file header for more)
  37     ##
  38     my $self = shift;
  39     my ($long_s, $long_p, $data_s, $data_p) = @_;
  40
  41     ##
  42     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4
  43     # GB per file.
  44     #    (Perl must be compiled with largefile support for files > 2 GB)
  45     #
  46     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47     #    (Perl must be compiled with largefile and 64-bit long support)
  48     ##
  49     $self->{long_size} = $long_s ? $long_s : 4;
  50     $self->{long_pack} = $long_p ? $long_p : 'N';
  51
  52     ##
  53     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each
  54     # key/value. Upgrading this is possible (see above) but probably not
  55     # necessary. If you need more than 4 GB for a single key or value, this
  56     # module is really not for you :-)
  57     ##
  58     $self->{data_size} = $data_s ? $data_s : 4;
  59     $self->{data_pack} = $data_p ? $data_p : 'N';
  60
  61     return $self->precalc_sizes();
  62 }
  63
  64 sub set_digest {
  65     ##
  66     # Set key digest function (default is MD5)
  67     ##
  68     my $self = shift;
  69     my ($digest_func, $hash_size) = @_;
  70
  71     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
  72     $self->{hash_size} = $hash_size ? $hash_size : 16;
  73
  74     return $self->precalc_sizes();
  75 }
  76
  77 sub new {
  78     my $class = shift;
  79     my ($args) = @_;
  80
  81     my $self = bless {
  82         long_size   => 4,
  83         long_pack   => 'N',
  84         data_size   => 4,
  85         data_pack   => 'N',
  86
  87         digest      => \&Digest::MD5::md5,
  88         hash_size   => 16,
  89
  90         ##
  91         # Maximum number of buckets per list before another level of indexing is
  92         # done.
  93         # Increase this value for slightly greater speed, but larger database
  94         # files. DO NOT decrease this value below 16, due to risk of recursive
  95         # reindex overrun.
  96         ##
  97         max_buckets => 16,
  98     }, $class;
  99
 100     $self->precalc_sizes;
 101
 102     return $self;
 103 }
 104
 105 sub setup_fh {
 106     my $self = shift;
 107     my ($obj) = @_;
 108
 109     $self->open( $obj ) if !defined $obj->_fh;
 110
 111     my $fh = $obj->_fh;
 112     print "1\n";
 113     flock $fh, LOCK_EX;
 114     print "2\n";
 115
 116     unless ( $obj->{base_offset} ) {
 117         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 118         my $signature;
 119         my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 120
 121         ##
 122         # File is empty -- write signature and master index
 123         ##
 124         if (!$bytes_read) {
 125             my $loc = $self->_request_space( $obj, length( SIG_FILE ) );
 126             seek($fh, $loc + $obj->_root->{file_offset}, SEEK_SET);
 127             print( $fh SIG_FILE);
 128
 129             $obj->{base_offset} = $self->_request_space(
 130                 $obj, $self->tag_size( $self->{index_size} ),
 131             );
 132
 133             $self->write_tag(
 134                 $obj, $obj->_base_offset, $obj->_type,
 135                 chr(0)x$self->{index_size},
 136             );
 137
 138             # Flush the filehandle
 139             my $old_fh = select $fh;
 140             my $old_af = $|; $| = 1; $| = $old_af;
 141             select $old_fh;
 142         }
 143         else {
 144             $obj->{base_offset} = $bytes_read;
 145
 146             ##
 147             # Check signature was valid
 148             ##
 149             unless ($signature eq SIG_FILE) {
 150                 $self->close_fh( $obj );
 151                 $obj->_throw_error("Signature not found -- file is not a Deep DB");
 152             }
 153
 154             ##
 155             # Get our type from master index signature
 156             ##
 157             my $tag = $self->load_tag($obj, $obj->_base_offset)
 158             or $obj->_throw_error("Corrupted file, no master index record");
 159
 160             unless ($obj->{type} eq $tag->{signature}) {
 161                 $obj->_throw_error("File type mismatch");
 162             }
 163         }
 164     }
 165
 166     #XXX We have to make sure we don't mess up when autoflush isn't turned on
 167     unless ( $obj->_root->{inode} ) {
 168         my @stats = stat($obj->_fh);
 169         $obj->_root->{inode} = $stats[1];
 170         $obj->_root->{end} = $stats[7];
 171     }
 172
 173     flock $fh, LOCK_UN;
 174
 175     return 1;
 176 }
 177
 178 sub open {
 179     ##
 180     # Open a fh to the database, create if nonexistent.
 181     # Make sure file signature matches DBM::Deep spec.
 182     ##
 183     my $self = shift;
 184     my ($obj) = @_;
 185
 186     # Theoretically, adding O_BINARY should remove the need for the binmode
 187     # Of course, testing it is going to be ... interesting.
 188     my $flags = O_RDWR | O_CREAT | O_BINARY;
 189
 190     my $fh;
 191     my $filename = $obj->_root->{file};
 192     sysopen( $fh, $filename, $flags )
 193         or $obj->_throw_error("Cannot sysopen file '$filename': $!");
 194     $obj->_root->{fh} = $fh;
 195
 196     #XXX Can we remove this by using the right sysopen() flags?
 197     # Maybe ... q.v. above
 198     binmode $fh; # for win32
 199
 200     if ($obj->_root->{autoflush}) {
 201         my $old = select $fh;
 202         $|=1;
 203         select $old;
 204     }
 205
 206     return 1;
 207 }
 208
 209 sub close_fh {
 210     my $self = shift;
 211     my ($obj) = @_;
 212
 213     if ( my $fh = $obj->_root->{fh} ) {
 214         close $fh;
 215     }
 216     $obj->_root->{fh} = undef;
 217
 218     return 1;
 219 }
 220
 221 sub tag_size {
 222     my $self = shift;
 223     my ($size) = @_;
 224     return SIG_SIZE + $self->{data_size} + $size;
 225 }
 226
 227 sub write_tag {
 228     ##
 229     # Given offset, signature and content, create tag and write to disk
 230     ##
 231     my $self = shift;
 232     my ($obj, $offset, $sig, $content) = @_;
 233     my $size = length( $content );
 234
 235     my $fh = $obj->_fh;
 236
 237     if ( defined $offset ) {
 238         seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 239     }
 240
 241     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
 242
 243     return unless defined $offset;
 244
 245     return {
 246         signature => $sig,
 247         size => $size,
 248         offset => $offset + SIG_SIZE + $self->{data_size},
 249         content => $content
 250     };
 251 }
 252
 253 sub load_tag {
 254     ##
 255     # Given offset, load single tag and return signature, size and data
 256     ##
 257     my $self = shift;
 258     my ($obj, $offset) = @_;
 259
 260 #    print join(':',map{$_||''}caller(1)), $/;
 261
 262     my $fh = $obj->_fh;
 263
 264     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 265
 266     #XXX I'm not sure this check will work if autoflush isn't enabled ...
 267     return if eof $fh;
 268
 269     my $b;
 270     read( $fh, $b, SIG_SIZE + $self->{data_size} );
 271     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
 272
 273     my $buffer;
 274     read( $fh, $buffer, $size);
 275
 276     return {
 277         signature => $sig,
 278         size => $size,
 279         offset => $offset + SIG_SIZE + $self->{data_size},
 280         content => $buffer
 281     };
 282 }
 283
 284 sub _length_needed {
 285     my $self = shift;
 286     my ($obj, $value, $key) = @_;
 287
 288     my $is_dbm_deep = eval {
 289         local $SIG{'__DIE__'};
 290         $value->isa( 'DBM::Deep' );
 291     };
 292
 293     my $len = SIG_SIZE + $self->{data_size}
 294             + $self->{data_size} + length( $key );
 295
 296     if ( $is_dbm_deep && $value->_root eq $obj->_root ) {
 297         return $len + $self->{long_size};
 298     }
 299
 300     my $r = Scalar::Util::reftype( $value ) || '';
 301     if ( $obj->_root->{autobless} ) {
 302         # This is for the bit saying whether or not this thing is blessed.
 303         $len += 1;
 304     }
 305
 306     unless ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 307         if ( defined $value ) {
 308             $len += length( $value );
 309         }
 310         return $len;
 311     }
 312
 313     $len += $self->{index_size};
 314
 315     # if autobless is enabled, must also take into consideration
 316     # the class name as it is stored after the key.
 317     if ( $obj->_root->{autobless} ) {
 318         my $value_class = Scalar::Util::blessed($value);
 319         if ( defined $value_class && !$is_dbm_deep ) {
 320             $len += $self->{data_size} + length($value_class);
 321         }
 322     }
 323
 324     return $len;
 325 }
 326
 327 sub add_bucket {
 328     ##
 329     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 330     # plain (undigested) key and value.
 331     ##
 332     my $self = shift;
 333     my ($obj, $tag, $md5, $plain_key, $value) = @_;
 334
 335     # This verifies that only supported values will be stored.
 336     {
 337         my $r = Scalar::Util::reftype( $value );
 338         last if !defined $r;
 339
 340         last if $r eq 'HASH';
 341         last if $r eq 'ARRAY';
 342
 343         $obj->_throw_error(
 344             "Storage of variables of type '$r' is not supported."
 345         );
 346     }
 347
 348     my $location = 0;
 349     my $result = 2;
 350
 351     my $root = $obj->_root;
 352     my $fh   = $obj->_fh;
 353
 354     my $actual_length = $self->_length_needed( $obj, $value, $plain_key );
 355
 356     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 357
 358 #    $self->_release_space( $obj, $size, $subloc );
 359     # Updating a known md5
 360 #XXX This needs updating to use _release_space
 361     if ( $subloc ) {
 362         $result = 1;
 363
 364         if ($actual_length <= $size) {
 365             $location = $subloc;
 366         }
 367         else {
 368             $location = $self->_request_space( $obj, $actual_length );
 369             seek(
 370                 $fh,
 371                 $tag->{offset} + $offset
 372               + $self->{hash_size} + $root->{file_offset},
 373                 SEEK_SET,
 374             );
 375             print( $fh pack($self->{long_pack}, $location ) );
 376             print( $fh pack($self->{long_pack}, $actual_length ) );
 377         }
 378     }
 379     # Adding a new md5
 380     elsif ( defined $offset ) {
 381         $location = $self->_request_space( $obj, $actual_length );
 382
 383         seek( $fh, $tag->{offset} + $offset + $root->{file_offset}, SEEK_SET );
 384         print( $fh $md5 . pack($self->{long_pack}, $location ) );
 385         print( $fh pack($self->{long_pack}, $actual_length ) );
 386     }
 387     # If bucket didn't fit into list, split into a new index level
 388     # split_index() will do the _request_space() call
 389     else {
 390         $location = $self->split_index( $obj, $md5, $tag );
 391     }
 392
 393     $self->write_value( $obj, $location, $plain_key, $value );
 394
 395     return $result;
 396 }
 397
 398 sub write_value {
 399     my $self = shift;
 400     my ($obj, $location, $key, $value) = @_;
 401
 402     my $fh = $obj->_fh;
 403     my $root = $obj->_root;
 404
 405     my $is_dbm_deep = eval {
 406         local $SIG{'__DIE__'};
 407         $value->isa( 'DBM::Deep' );
 408     };
 409
 410     my $is_internal_ref = $is_dbm_deep && ($value->_root eq $root);
 411
 412     seek($fh, $location + $root->{file_offset}, SEEK_SET);
 413
 414     ##
 415     # Write signature based on content type, set content length and write
 416     # actual value.
 417     ##
 418     my $r = Scalar::Util::reftype($value) || '';
 419     if ( $is_internal_ref ) {
 420         $self->write_tag( $obj, undef, SIG_INTERNAL,pack($self->{long_pack}, $value->_base_offset) );
 421     }
 422     elsif ($r eq 'HASH') {
 423         $self->write_tag( $obj, undef, SIG_HASH, chr(0)x$self->{index_size} );
 424     }
 425     elsif ($r eq 'ARRAY') {
 426         $self->write_tag( $obj, undef, SIG_ARRAY, chr(0)x$self->{index_size} );
 427     }
 428     elsif (!defined($value)) {
 429         $self->write_tag( $obj, undef, SIG_NULL, '' );
 430     }
 431     else {
 432         $self->write_tag( $obj, undef, SIG_DATA, $value );
 433     }
 434
 435     ##
 436     # Plain key is stored AFTER value, as keys are typically fetched less often.
 437     ##
 438     print( $fh pack($self->{data_pack}, length($key)) . $key );
 439
 440     # Internal references don't care about autobless
 441     return 1 if $is_internal_ref;
 442
 443     ##
 444     # If value is blessed, preserve class name
 445     ##
 446     if ( $root->{autobless} ) {
 447         my $value_class = Scalar::Util::blessed($value);
 448         if ( defined $value_class && !$is_dbm_deep ) {
 449             print( $fh chr(1) );
 450             print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
 451         }
 452         else {
 453             print( $fh chr(0) );
 454         }
 455     }
 456
 457     ##
 458     # If content is a hash or array, create new child DBM::Deep object and
 459     # pass each key or element to it.
 460     ##
 461     if ( !$is_internal_ref ) {
 462         if ($r eq 'HASH') {
 463             my $branch = DBM::Deep->new(
 464                 type => DBM::Deep->TYPE_HASH,
 465                 base_offset => $location,
 466                 root => $root,
 467             );
 468             foreach my $key (keys %{$value}) {
 469                 $branch->STORE( $key, $value->{$key} );
 470             }
 471         }
 472         elsif ($r eq 'ARRAY') {
 473             my $branch = DBM::Deep->new(
 474                 type => DBM::Deep->TYPE_ARRAY,
 475                 base_offset => $location,
 476                 root => $root,
 477             );
 478             my $index = 0;
 479             foreach my $element (@{$value}) {
 480                 $branch->STORE( $index, $element );
 481                 $index++;
 482             }
 483         }
 484     }
 485
 486     return 1;
 487 }
 488
 489 sub split_index {
 490     my $self = shift;
 491     my ($obj, $md5, $tag) = @_;
 492
 493     my $fh = $obj->_fh;
 494     my $root = $obj->_root;
 495
 496     my $loc = $self->_request_space(
 497         $obj, $self->tag_size( $self->{index_size} ),
 498     );
 499
 500     seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 501     print( $fh pack($self->{long_pack}, $loc) );
 502
 503     my $index_tag = $self->write_tag(
 504         $obj, $loc, SIG_INDEX,
 505         chr(0)x$self->{index_size},
 506     );
 507
 508     my $newtag_loc = $self->_request_space(
 509         $obj, $self->tag_size( $self->{bucket_list_size} ),
 510     );
 511
 512     my $keys = $tag->{content}
 513              . $md5 . pack($self->{long_pack}, $newtag_loc)
 514                     . pack($self->{long_pack}, 0);
 515
 516     my @newloc = ();
 517     BUCKET:
 518     for (my $i = 0; $i <= $self->{max_buckets}; $i++) {
 519         my ($key, $old_subloc, $size) = $self->_get_key_subloc( $keys, $i );
 520
 521         die "[INTERNAL ERROR]: No key in split_index()\n" unless $key;
 522         die "[INTERNAL ERROR]: No subloc in split_index()\n" unless $old_subloc;
 523
 524         my $num = ord(substr($key, $tag->{ch} + 1, 1));
 525
 526         if ($newloc[$num]) {
 527             seek($fh, $newloc[$num] + $root->{file_offset}, SEEK_SET);
 528             my $subkeys;
 529             read( $fh, $subkeys, $self->{bucket_list_size});
 530
 531             # This is looking for the first empty spot
 532             my ($subloc, $offset, $size) = $self->_find_in_buckets(
 533                 { content => $subkeys }, '',
 534             );
 535
 536             seek($fh, $newloc[$num] + $offset + $root->{file_offset}, SEEK_SET);
 537             print( $fh $key . pack($self->{long_pack}, $old_subloc) );
 538
 539             next;
 540         }
 541
 542         seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
 543
 544         my $loc = $self->_request_space(
 545             $obj, $self->tag_size( $self->{bucket_list_size} ),
 546         );
 547
 548         print( $fh pack($self->{long_pack}, $loc) );
 549
 550         my $blist_tag = $self->write_tag(
 551             $obj, $loc, SIG_BLIST,
 552             chr(0)x$self->{bucket_list_size},
 553         );
 554
 555         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 556         print( $fh $key . pack($self->{long_pack}, $old_subloc) );
 557
 558         $newloc[$num] = $blist_tag->{offset};
 559     }
 560
 561     $self->_release_space(
 562         $obj, $self->tag_size( $self->{bucket_list_size} ),
 563         $tag->{offset} - SIG_SIZE - $self->{data_size},
 564     );
 565
 566     return $newtag_loc;
 567 }
 568
 569 sub read_from_loc {
 570     my $self = shift;
 571     my ($obj, $subloc) = @_;
 572
 573     my $fh = $obj->_fh;
 574
 575     ##
 576     # Found match -- seek to offset and read signature
 577     ##
 578     my $signature;
 579     seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 580     read( $fh, $signature, SIG_SIZE);
 581
 582     ##
 583     # If value is a hash or array, return new DBM::Deep object with correct offset
 584     ##
 585     if (($signature eq SIG_HASH) || ($signature eq SIG_ARRAY)) {
 586         my $obj = DBM::Deep->new(
 587             type => $signature,
 588             base_offset => $subloc,
 589             root => $obj->_root,
 590         );
 591
 592         if ($obj->_root->{autobless}) {
 593             ##
 594             # Skip over value and plain key to see if object needs
 595             # to be re-blessed
 596             ##
 597             seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
 598
 599             my $size;
 600             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 601             if ($size) { seek($fh, $size, SEEK_CUR); }
 602
 603             my $bless_bit;
 604             read( $fh, $bless_bit, 1);
 605             if (ord($bless_bit)) {
 606                 ##
 607                 # Yes, object needs to be re-blessed
 608                 ##
 609                 my $class_name;
 610                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 611                 if ($size) { read( $fh, $class_name, $size); }
 612                 if ($class_name) { $obj = bless( $obj, $class_name ); }
 613             }
 614         }
 615
 616         return $obj;
 617     }
 618     elsif ( $signature eq SIG_INTERNAL ) {
 619         my $size;
 620         read( $fh, $size, $self->{data_size});
 621         $size = unpack($self->{data_pack}, $size);
 622
 623         if ( $size ) {
 624             my $new_loc;
 625             read( $fh, $new_loc, $size );
 626             $new_loc = unpack( $self->{long_pack}, $new_loc );
 627
 628             return $self->read_from_loc( $obj, $new_loc );
 629         }
 630         else {
 631             return;
 632         }
 633     }
 634     ##
 635     # Otherwise return actual value
 636     ##
 637     elsif ($signature eq SIG_DATA) {
 638         my $size;
 639         read( $fh, $size, $self->{data_size});
 640         $size = unpack($self->{data_pack}, $size);
 641
 642         my $value = '';
 643         if ($size) { read( $fh, $value, $size); }
 644         return $value;
 645     }
 646
 647     ##
 648     # Key exists, but content is null
 649     ##
 650     return;
 651 }
 652
 653 sub get_bucket_value {
 654     ##
 655     # Fetch single value given tag and MD5 digested key.
 656     ##
 657     my $self = shift;
 658     my ($obj, $tag, $md5) = @_;
 659
 660     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 661     if ( $subloc ) {
 662         return $self->read_from_loc( $obj, $subloc );
 663     }
 664     return;
 665 }
 666
 667 sub delete_bucket {
 668     ##
 669     # Delete single key/value pair given tag and MD5 digested key.
 670     ##
 671     my $self = shift;
 672     my ($obj, $tag, $md5) = @_;
 673
 674     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 675 #XXX This needs _release_space()
 676     if ( $subloc ) {
 677         my $fh = $obj->_fh;
 678         seek($fh, $tag->{offset} + $offset + $obj->_root->{file_offset}, SEEK_SET);
 679         print( $fh substr($tag->{content}, $offset + $self->{bucket_size} ) );
 680         print( $fh chr(0) x $self->{bucket_size} );
 681
 682         return 1;
 683     }
 684     return;
 685 }
 686
 687 sub bucket_exists {
 688     ##
 689     # Check existence of single key given tag and MD5 digested key.
 690     ##
 691     my $self = shift;
 692     my ($obj, $tag, $md5) = @_;
 693
 694     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 695     return $subloc && 1;
 696 }
 697
 698 sub find_bucket_list {
 699     ##
 700     # Locate offset for bucket list, given digested key
 701     ##
 702     my $self = shift;
 703     my ($obj, $md5, $args) = @_;
 704     $args = {} unless $args;
 705
 706     ##
 707     # Locate offset for bucket list using digest index system
 708     ##
 709     my $tag = $self->load_tag($obj, $obj->_base_offset)
 710         or $obj->_throw_error( "INTERNAL ERROR - Cannot find tag" );
 711
 712     my $ch = 0;
 713     while ($tag->{signature} ne SIG_BLIST) {
 714         my $num = ord substr($md5, $ch, 1);
 715
 716         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
 717         $tag = $self->index_lookup( $obj, $tag, $num );
 718
 719         if (!$tag) {
 720             return if !$args->{create};
 721
 722             my $loc = $self->_request_space(
 723                 $obj, $self->tag_size( $self->{bucket_list_size} ),
 724             );
 725
 726             my $fh = $obj->_fh;
 727             seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
 728             print( $fh pack($self->{long_pack}, $loc) );
 729
 730             $tag = $self->write_tag(
 731                 $obj, $loc, SIG_BLIST,
 732                 chr(0)x$self->{bucket_list_size},
 733             );
 734
 735             $tag->{ref_loc} = $ref_loc;
 736             $tag->{ch} = $ch;
 737
 738             last;
 739         }
 740
 741         $tag->{ch} = $ch++;
 742         $tag->{ref_loc} = $ref_loc;
 743     }
 744
 745     return $tag;
 746 }
 747
 748 sub index_lookup {
 749     ##
 750     # Given index tag, lookup single entry in index and return .
 751     ##
 752     my $self = shift;
 753     my ($obj, $tag, $index) = @_;
 754
 755     my $location = unpack(
 756         $self->{long_pack},
 757         substr(
 758             $tag->{content},
 759             $index * $self->{long_size},
 760             $self->{long_size},
 761         ),
 762     );
 763
 764     if (!$location) { return; }
 765
 766     return $self->load_tag( $obj, $location );
 767 }
 768
 769 sub traverse_index {
 770     ##
 771     # Scan index and recursively step into deeper levels, looking for next key.
 772     ##
 773     my $self = shift;
 774     my ($obj, $offset, $ch, $force_return_next) = @_;
 775
 776     my $tag = $self->load_tag($obj, $offset );
 777
 778     my $fh = $obj->_fh;
 779
 780     if ($tag->{signature} ne SIG_BLIST) {
 781         my $content = $tag->{content};
 782         my $start = $obj->{return_next} ? 0 : ord(substr($obj->{prev_md5}, $ch, 1));
 783
 784         for (my $idx = $start; $idx < (2**8); $idx++) {
 785             my $subloc = unpack(
 786                 $self->{long_pack},
 787                 substr(
 788                     $content,
 789                     $idx * $self->{long_size},
 790                     $self->{long_size},
 791                 ),
 792             );
 793
 794             if ($subloc) {
 795                 my $result = $self->traverse_index(
 796                     $obj, $subloc, $ch + 1, $force_return_next,
 797                 );
 798
 799                 if (defined($result)) { return $result; }
 800             }
 801         } # index loop
 802
 803         $obj->{return_next} = 1;
 804     } # tag is an index
 805
 806     else {
 807         my $keys = $tag->{content};
 808         if ($force_return_next) { $obj->{return_next} = 1; }
 809
 810         ##
 811         # Iterate through buckets, looking for a key match
 812         ##
 813         for (my $i = 0; $i < $self->{max_buckets}; $i++) {
 814             my ($key, $subloc) = $self->_get_key_subloc( $keys, $i );
 815
 816             # End of bucket list -- return to outer loop
 817             if (!$subloc) {
 818                 $obj->{return_next} = 1;
 819                 last;
 820             }
 821             # Located previous key -- return next one found
 822             elsif ($key eq $obj->{prev_md5}) {
 823                 $obj->{return_next} = 1;
 824                 next;
 825             }
 826             # Seek to bucket location and skip over signature
 827             elsif ($obj->{return_next}) {
 828                 seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 829
 830                 # Skip over value to get to plain key
 831                 my $sig;
 832                 read( $fh, $sig, SIG_SIZE );
 833
 834                 my $size;
 835                 read( $fh, $size, $self->{data_size});
 836                 $size = unpack($self->{data_pack}, $size);
 837                 if ($size) { seek($fh, $size, SEEK_CUR); }
 838
 839                 # Read in plain key and return as scalar
 840                 my $plain_key;
 841                 read( $fh, $size, $self->{data_size});
 842                 $size = unpack($self->{data_pack}, $size);
 843                 if ($size) { read( $fh, $plain_key, $size); }
 844
 845                 return $plain_key;
 846             }
 847         }
 848
 849         $obj->{return_next} = 1;
 850     } # tag is a bucket list
 851
 852     return;
 853 }
 854
 855 sub get_next_key {
 856     ##
 857     # Locate next key, given digested previous one
 858     ##
 859     my $self = shift;
 860     my ($obj) = @_;
 861
 862     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
 863     $obj->{return_next} = 0;
 864
 865     ##
 866     # If the previous key was not specifed, start at the top and
 867     # return the first one found.
 868     ##
 869     if (!$obj->{prev_md5}) {
 870         $obj->{prev_md5} = chr(0) x $self->{hash_size};
 871         $obj->{return_next} = 1;
 872     }
 873
 874     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
 875 }
 876
 877 # Utilities
 878
 879 sub _get_key_subloc {
 880     my $self = shift;
 881     my ($keys, $idx) = @_;
 882
 883     my ($key, $subloc, $size) = unpack(
 884         "a$self->{hash_size} $self->{long_pack} $self->{long_pack}",
 885         substr(
 886             $keys,
 887             ($idx * $self->{bucket_size}),
 888             $self->{bucket_size},
 889         ),
 890     );
 891
 892     return ($key, $subloc, $size);
 893 }
 894
 895 sub _find_in_buckets {
 896     my $self = shift;
 897     my ($tag, $md5) = @_;
 898
 899     BUCKET:
 900     for ( my $i = 0; $i < $self->{max_buckets}; $i++ ) {
 901         my ($key, $subloc, $size) = $self->_get_key_subloc(
 902             $tag->{content}, $i,
 903         );
 904
 905         return ($subloc, $i * $self->{bucket_size}, $size) unless $subloc;
 906
 907         next BUCKET if $key ne $md5;
 908
 909         return ($subloc, $i * $self->{bucket_size}, $size);
 910     }
 911
 912     return;
 913 }
 914
 915 #sub _print_at {
 916 #    my $self = shift;
 917 #    my ($obj, $spot, $data) = @_;
 918 #
 919 #    my $fh = $obj->_fh;
 920 #    seek( $fh, $spot, SEEK_SET );
 921 #    print( $fh $data );
 922 #
 923 #    return;
 924 #}
 925
 926 sub _request_space {
 927     my $self = shift;
 928     my ($obj, $size) = @_;
 929
 930     my $loc = $obj->_root->{end};
 931     $obj->_root->{end} += $size;
 932
 933     return $loc;
 934 }
 935
 936 sub _release_space {
 937     my $self = shift;
 938     my ($obj, $size, $loc) = @_;
 939
 940     my $next_loc = 0;
 941
 942     my $fh = $obj->_fh;
 943     seek( $fh, $loc + $obj->_root->{file_offset}, SEEK_SET );
 944     print( $fh SIG_FREE
 945         . pack($self->{long_pack}, $size )
 946         . pack($self->{long_pack}, $next_loc )
 947     );
 948
 949     return;
 950 }
 951
 952 1;
 953 __END__
 954
 955 # This will be added in later, after more refactoring is done. This is an early
 956 # attempt at refactoring on the physical level instead of the virtual level.
 957 sub _read_at {
 958     my $self = shift;
 959     my ($obj, $spot, $amount, $unpack) = @_;
 960
 961     my $fh = $obj->_fh;
 962     seek( $fh, $spot + $obj->_root->{file_offset}, SEEK_SET );
 963
 964     my $buffer;
 965     my $bytes_read = read( $fh, $buffer, $amount );
 966
 967     if ( $unpack ) {
 968         $buffer = unpack( $unpack, $buffer );
 969     }
 970
 971     if ( wantarray ) {
 972         return ($buffer, $bytes_read);
 973     }
 974     else {
 975         return $buffer;
 976     }
 977 }