lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use strict;
   4
   5 use Fcntl qw( :DEFAULT :flock :seek );
   6
   7 sub precalc_sizes {
   8     ##
   9     # Precalculate index, bucket and bucket list sizes
  10     ##
  11     my $self = shift;
  12
  13     $self->{index_size}       = (2**8) * $self->{long_size};
  14     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size};
  15     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
  16
  17     return 1;
  18 }
  19
  20 sub set_pack {
  21     ##
  22     # Set pack/unpack modes (see file header for more)
  23     ##
  24     my $self = shift;
  25     my ($long_s, $long_p, $data_s, $data_p) = @_;
  26
  27     ##
  28     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  29     #    (Perl must be compiled with largefile support for files > 2 GB)
  30     #
  31     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  32     #    (Perl must be compiled with largefile and 64-bit long support)
  33     ##
  34     $self->{long_size} = $long_s ? $long_s : 4;
  35     $self->{long_pack} = $long_p ? $long_p : 'N';
  36
  37     ##
  38     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  39     # Upgrading this is possible (see above) but probably not necessary.  If you need
  40     # more than 4 GB for a single key or value, this module is really not for you :-)
  41     ##
  42     $self->{data_size} = $data_s ? $data_s : 4;
  43     $self->{data_pack} = $data_p ? $data_p : 'N';
  44
  45     return $self->precalc_sizes();
  46 }
  47
  48 sub set_digest {
  49     ##
  50     # Set key digest function (default is MD5)
  51     ##
  52     my $self = shift;
  53     my ($digest_func, $hash_size) = @_;
  54
  55     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
  56     $self->{hash_size} = $hash_size ? $hash_size : 16;
  57
  58     return $self->precalc_sizes();
  59 }
  60
  61 sub new {
  62     my $class = shift;
  63     my ($args) = @_;
  64
  65     my $self = bless {
  66         long_size   => 4,
  67         long_pack   => 'N',
  68         data_size   => 4,
  69         data_pack   => 'N',
  70
  71         digest      => \&Digest::MD5::md5,
  72         hash_size   => 16,
  73
  74         ##
  75         # Maximum number of buckets per list before another level of indexing is done.
  76         # Increase this value for slightly greater speed, but larger database files.
  77         # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  78         ##
  79         max_buckets => 16,
  80     }, $class;
  81
  82     $self->precalc_sizes;
  83
  84     return $self;
  85 }
  86
  87 sub setup_fh {
  88     my $self = shift;
  89     my ($obj) = @_;
  90
  91     $self->open( $obj ) if !defined $obj->_fh;
  92
  93     #XXX Is {end} busted? Can't we just seek( $fh, 0, SEEK_END ) ?
  94     unless ( $obj->_root->{inode} ) {
  95         my @stats = stat($obj->_fh);
  96         $obj->_root->{inode} = $stats[1];
  97         $obj->_root->{end} = $stats[7];
  98     }
  99
 100     return 1;
 101 }
 102
 103 sub open {
 104     ##
 105     # Open a fh to the database, create if nonexistent.
 106     # Make sure file signature matches DBM::Deep spec.
 107     ##
 108     my $self = shift;
 109     my ($obj) = @_;
 110
 111     if (defined($obj->_fh)) { $self->close_fh( $obj ); }
 112
 113     eval {
 114         local $SIG{'__DIE__'};
 115         # Theoretically, adding O_BINARY should remove the need for the binmode
 116         # Of course, testing it is going to be ... interesting.
 117         my $flags = O_RDWR | O_CREAT | O_BINARY;
 118
 119         my $fh;
 120         sysopen( $fh, $obj->_root->{file}, $flags )
 121             or $fh = undef;
 122         $obj->_root->{fh} = $fh;
 123     }; if ($@ ) { $obj->_throw_error( "Received error: $@\n" ); }
 124     if (! defined($obj->_fh)) {
 125         return $obj->_throw_error("Cannot sysopen file: " . $obj->_root->{file} . ": $!");
 126     }
 127
 128     my $fh = $obj->_fh;
 129
 130     #XXX Can we remove this by using the right sysopen() flags?
 131     # Maybe ... q.v. above
 132     binmode $fh; # for win32
 133
 134     if ($obj->_root->{autoflush}) {
 135         my $old = select $fh;
 136         $|=1;
 137         select $old;
 138     }
 139
 140     seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 141
 142     my $signature;
 143     my $bytes_read = read( $fh, $signature, length(DBM::Deep->SIG_FILE));
 144
 145     ##
 146     # File is empty -- write signature and master index
 147     ##
 148     if (!$bytes_read) {
 149         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 150         print( $fh DBM::Deep->SIG_FILE);
 151
 152         $self->create_tag($obj, $obj->_base_offset, $obj->_type, chr(0) x $self->{index_size});
 153
 154         my $plain_key = "[base]";
 155         print( $fh pack($self->{data_pack}, length($plain_key)) . $plain_key );
 156
 157         # Flush the filehandle
 158         my $old_fh = select $fh;
 159         my $old_af = $|; $| = 1; $| = $old_af;
 160         select $old_fh;
 161
 162         return 1;
 163     }
 164
 165     ##
 166     # Check signature was valid
 167     ##
 168     unless ($signature eq DBM::Deep->SIG_FILE) {
 169         $self->close_fh( $obj );
 170         return $obj->_throw_error("Signature not found -- file is not a Deep DB");
 171     }
 172
 173     ##
 174     # Get our type from master index signature
 175     ##
 176     my $tag = $self->load_tag($obj, $obj->_base_offset);
 177     if (!$tag) {
 178         return $obj->_throw_error("Corrupted file, no master index record");
 179     }
 180
 181     if ($obj->{type} ne $tag->{signature}) {
 182         return $obj->_throw_error("File type mismatch");
 183     }
 184
 185 #XXX We probably also want to store the hash algorithm name and not assume anything
 186 #XXX The cool thing would be to allow a different hashing algorithm at every level
 187
 188     return 1;
 189 }
 190
 191 sub close_fh {
 192     my $self = shift;
 193     my ($obj) = @_;
 194
 195     if ( my $fh = $obj->_root->{fh} ) {
 196         close $fh;
 197     }
 198     $obj->_root->{fh} = undef;
 199
 200     return 1;
 201 }
 202
 203 sub create_tag {
 204     ##
 205     # Given offset, signature and content, create tag and write to disk
 206     ##
 207     my $self = shift;
 208     my ($obj, $offset, $sig, $content) = @_;
 209     my $size = length($content);
 210
 211     my $fh = $obj->_fh;
 212
 213     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 214     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
 215
 216     if ($offset == $obj->_root->{end}) {
 217         $obj->_root->{end} += DBM::Deep->SIG_SIZE + $self->{data_size} + $size;
 218     }
 219
 220     return {
 221         signature => $sig,
 222         size => $size,
 223         offset => $offset + DBM::Deep->SIG_SIZE + $self->{data_size},
 224         content => $content
 225     };
 226 }
 227
 228 sub load_tag {
 229     ##
 230     # Given offset, load single tag and return signature, size and data
 231     ##
 232     my $self = shift;
 233     my ($obj, $offset) = @_;
 234
 235     my $fh = $obj->_fh;
 236
 237     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 238     if (eof $fh) { return undef; }
 239
 240     my $b;
 241     read( $fh, $b, DBM::Deep->SIG_SIZE + $self->{data_size} );
 242     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
 243
 244     my $buffer;
 245     read( $fh, $buffer, $size);
 246
 247     return {
 248         signature => $sig,
 249         size => $size,
 250         offset => $offset + DBM::Deep->SIG_SIZE + $self->{data_size},
 251         content => $buffer
 252     };
 253 }
 254
 255 sub add_bucket {
 256     ##
 257     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 258     # plain (undigested) key and value.
 259     ##
 260     my $self = shift;
 261     my ($obj, $tag, $md5, $plain_key, $value) = @_;
 262     my $keys = $tag->{content};
 263     my $location = 0;
 264     my $result = 2;
 265
 266     my $root = $obj->_root;
 267
 268     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 269     my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 270
 271     my $fh = $obj->_fh;
 272
 273     ##
 274     # Iterate through buckets, seeing if this is a new entry or a replace.
 275     ##
 276     for (my $i = 0; $i < $self->{max_buckets}; $i++) {
 277         my $subloc = unpack($self->{long_pack}, substr($keys, ($i * $self->{bucket_size}) + $self->{hash_size}, $self->{long_size}));
 278         if (!$subloc) {
 279             ##
 280             # Found empty bucket (end of list).  Populate and exit loop.
 281             ##
 282             $result = 2;
 283
 284             $location = $internal_ref
 285                 ? $value->_base_offset
 286                 : $root->{end};
 287
 288             seek($fh, $tag->{offset} + ($i * $self->{bucket_size}) + $root->{file_offset}, SEEK_SET);
 289             print( $fh $md5 . pack($self->{long_pack}, $location) );
 290             last;
 291         }
 292
 293         my $key = substr($keys, $i * $self->{bucket_size}, $self->{hash_size});
 294         if ($md5 eq $key) {
 295             ##
 296             # Found existing bucket with same key.  Replace with new value.
 297             ##
 298             $result = 1;
 299
 300             if ($internal_ref) {
 301                 $location = $value->_base_offset;
 302                 seek($fh, $tag->{offset} + ($i * $self->{bucket_size}) + $root->{file_offset}, SEEK_SET);
 303                 print( $fh $md5 . pack($self->{long_pack}, $location) );
 304                 return $result;
 305             }
 306
 307             seek($fh, $subloc + DBM::Deep->SIG_SIZE + $root->{file_offset}, SEEK_SET);
 308             my $size;
 309             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 310
 311             ##
 312             # If value is a hash, array, or raw value with equal or less size, we can
 313             # reuse the same content area of the database.  Otherwise, we have to create
 314             # a new content area at the EOF.
 315             ##
 316             my $actual_length;
 317             my $r = Scalar::Util::reftype( $value ) || '';
 318             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 319                 $actual_length = $self->{index_size};
 320
 321                 # if autobless is enabled, must also take into consideration
 322                 # the class name, as it is stored along with key/value.
 323                 if ( $root->{autobless} ) {
 324                     my $value_class = Scalar::Util::blessed($value);
 325                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 326                         $actual_length += length($value_class);
 327                     }
 328                 }
 329             }
 330             else { $actual_length = length($value); }
 331
 332             if ($actual_length <= $size) {
 333                 $location = $subloc;
 334             }
 335             else {
 336                 $location = $root->{end};
 337                 seek($fh, $tag->{offset} + ($i * $self->{bucket_size}) + $self->{hash_size} + $root->{file_offset}, SEEK_SET);
 338                 print( $fh pack($self->{long_pack}, $location) );
 339             }
 340
 341             last;
 342         }
 343     }
 344
 345     ##
 346     # If this is an internal reference, return now.
 347     # No need to write value or plain key
 348     ##
 349     if ($internal_ref) {
 350         return $result;
 351     }
 352
 353     ##
 354     # If bucket didn't fit into list, split into a new index level
 355     ##
 356     if (!$location) {
 357         seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 358         print( $fh pack($self->{long_pack}, $root->{end}) );
 359
 360         my $index_tag = $self->create_tag($obj, $root->{end}, DBM::Deep->SIG_INDEX, chr(0) x $self->{index_size});
 361         my @offsets = ();
 362
 363         $keys .= $md5 . pack($self->{long_pack}, 0);
 364
 365         for (my $i=0; $i<=$self->{max_buckets}; $i++) {
 366             my $key = substr($keys, $i * $self->{bucket_size}, $self->{hash_size});
 367             if ($key) {
 368                 my $old_subloc = unpack($self->{long_pack}, substr($keys, ($i * $self->{bucket_size}) +
 369                         $self->{hash_size}, $self->{long_size}));
 370                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 371
 372                 if ($offsets[$num]) {
 373                     my $offset = $offsets[$num] + DBM::Deep->SIG_SIZE + $self->{data_size};
 374                     seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 375                     my $subkeys;
 376                     read( $fh, $subkeys, $self->{bucket_list_size});
 377
 378                     for (my $k=0; $k<$self->{max_buckets}; $k++) {
 379                         my $subloc = unpack($self->{long_pack}, substr($subkeys, ($k * $self->{bucket_size}) +
 380                                 $self->{hash_size}, $self->{long_size}));
 381                         if (!$subloc) {
 382                             seek($fh, $offset + ($k * $self->{bucket_size}) + $root->{file_offset}, SEEK_SET);
 383                             print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
 384                             last;
 385                         }
 386                     } # k loop
 387                 }
 388                 else {
 389                     $offsets[$num] = $root->{end};
 390                     seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
 391                     print( $fh pack($self->{long_pack}, $root->{end}) );
 392
 393                     my $blist_tag = $self->create_tag($obj, $root->{end}, DBM::Deep->SIG_BLIST, chr(0) x $self->{bucket_list_size});
 394
 395                     seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 396                     print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
 397                 }
 398             } # key is real
 399         } # i loop
 400
 401         $location ||= $root->{end};
 402     } # re-index bucket list
 403
 404     ##
 405     # Seek to content area and store signature, value and plaintext key
 406     ##
 407     if ($location) {
 408         my $content_length;
 409         seek($fh, $location + $root->{file_offset}, SEEK_SET);
 410
 411         ##
 412         # Write signature based on content type, set content length and write actual value.
 413         ##
 414         my $r = Scalar::Util::reftype($value) || '';
 415         if ($r eq 'HASH') {
 416             print( $fh DBM::Deep->TYPE_HASH );
 417             print( $fh pack($self->{data_pack}, $self->{index_size}) . chr(0) x $self->{index_size} );
 418             $content_length = $self->{index_size};
 419         }
 420         elsif ($r eq 'ARRAY') {
 421             print( $fh DBM::Deep->TYPE_ARRAY );
 422             print( $fh pack($self->{data_pack}, $self->{index_size}) . chr(0) x $self->{index_size} );
 423             $content_length = $self->{index_size};
 424         }
 425         elsif (!defined($value)) {
 426             print( $fh DBM::Deep->SIG_NULL );
 427             print( $fh pack($self->{data_pack}, 0) );
 428             $content_length = 0;
 429         }
 430         else {
 431             print( $fh DBM::Deep->SIG_DATA );
 432             print( $fh pack($self->{data_pack}, length($value)) . $value );
 433             $content_length = length($value);
 434         }
 435
 436         ##
 437         # Plain key is stored AFTER value, as keys are typically fetched less often.
 438         ##
 439         print( $fh pack($self->{data_pack}, length($plain_key)) . $plain_key );
 440
 441         ##
 442         # If value is blessed, preserve class name
 443         ##
 444         if ( $root->{autobless} ) {
 445             my $value_class = Scalar::Util::blessed($value);
 446             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 447                 ##
 448                 # Blessed ref -- will restore later
 449                 ##
 450                 print( $fh chr(1) );
 451                 print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
 452                 $content_length += 1;
 453                 $content_length += $self->{data_size} + length($value_class);
 454             }
 455             else {
 456                 print( $fh chr(0) );
 457                 $content_length += 1;
 458             }
 459         }
 460
 461         ##
 462         # If this is a new content area, advance EOF counter
 463         ##
 464         if ($location == $root->{end}) {
 465             $root->{end} += DBM::Deep->SIG_SIZE;
 466             $root->{end} += $self->{data_size} + $content_length;
 467             $root->{end} += $self->{data_size} + length($plain_key);
 468         }
 469
 470         ##
 471         # If content is a hash or array, create new child DBM::Deep object and
 472         # pass each key or element to it.
 473         ##
 474         if ($r eq 'HASH') {
 475             my $branch = DBM::Deep->new(
 476                 type => DBM::Deep->TYPE_HASH,
 477                 base_offset => $location,
 478                 root => $root,
 479             );
 480             foreach my $key (keys %{$value}) {
 481                 $branch->STORE( $key, $value->{$key} );
 482             }
 483         }
 484         elsif ($r eq 'ARRAY') {
 485             my $branch = DBM::Deep->new(
 486                 type => DBM::Deep->TYPE_ARRAY,
 487                 base_offset => $location,
 488                 root => $root,
 489             );
 490             my $index = 0;
 491             foreach my $element (@{$value}) {
 492                 $branch->STORE( $index, $element );
 493                 $index++;
 494             }
 495         }
 496
 497         return $result;
 498     }
 499
 500     return $obj->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 501 }
 502
 503 sub get_bucket_value {
 504     ##
 505     # Fetch single value given tag and MD5 digested key.
 506     ##
 507     my $self = shift;
 508     my ($obj, $tag, $md5) = @_;
 509     my $keys = $tag->{content};
 510
 511     my $fh = $obj->_fh;
 512
 513     ##
 514     # Iterate through buckets, looking for a key match
 515     ##
 516     BUCKET:
 517     for (my $i=0; $i<$self->{max_buckets}; $i++) {
 518         my $key = substr($keys, $i * $self->{bucket_size}, $self->{hash_size});
 519         my $subloc = unpack($self->{long_pack}, substr($keys, ($i * $self->{bucket_size}) + $self->{hash_size}, $self->{long_size}));
 520
 521         if (!$subloc) {
 522             ##
 523             # Hit end of list, no match
 524             ##
 525             return;
 526         }
 527
 528         if ( $md5 ne $key ) {
 529             next BUCKET;
 530         }
 531
 532         ##
 533         # Found match -- seek to offset and read signature
 534         ##
 535         my $signature;
 536         seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 537         read( $fh, $signature, DBM::Deep->SIG_SIZE);
 538
 539         ##
 540         # If value is a hash or array, return new DBM::Deep object with correct offset
 541         ##
 542         if (($signature eq DBM::Deep->TYPE_HASH) || ($signature eq DBM::Deep->TYPE_ARRAY)) {
 543             my $obj = DBM::Deep->new(
 544                 type => $signature,
 545                 base_offset => $subloc,
 546                 root => $obj->_root,
 547             );
 548
 549             if ($obj->_root->{autobless}) {
 550                 ##
 551                 # Skip over value and plain key to see if object needs
 552                 # to be re-blessed
 553                 ##
 554                 seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
 555
 556                 my $size;
 557                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 558                 if ($size) { seek($fh, $size, SEEK_CUR); }
 559
 560                 my $bless_bit;
 561                 read( $fh, $bless_bit, 1);
 562                 if (ord($bless_bit)) {
 563                     ##
 564                     # Yes, object needs to be re-blessed
 565                     ##
 566                     my $class_name;
 567                     read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 568                     if ($size) { read( $fh, $class_name, $size); }
 569                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 570                 }
 571             }
 572
 573             return $obj;
 574         }
 575
 576         ##
 577         # Otherwise return actual value
 578         ##
 579         elsif ($signature eq DBM::Deep->SIG_DATA) {
 580             my $size;
 581             my $value = '';
 582             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 583             if ($size) { read( $fh, $value, $size); }
 584             return $value;
 585         }
 586
 587         ##
 588         # Key exists, but content is null
 589         ##
 590         else { return; }
 591     } # i loop
 592
 593     return;
 594 }
 595
 596 sub delete_bucket {
 597     ##
 598     # Delete single key/value pair given tag and MD5 digested key.
 599     ##
 600     my $self = shift;
 601     my ($obj, $tag, $md5) = @_;
 602     my $keys = $tag->{content};
 603
 604     my $fh = $obj->_fh;
 605
 606     ##
 607     # Iterate through buckets, looking for a key match
 608     ##
 609     BUCKET:
 610     for (my $i=0; $i<$self->{max_buckets}; $i++) {
 611         my $key = substr($keys, $i * $self->{bucket_size}, $self->{hash_size});
 612         my $subloc = unpack($self->{long_pack}, substr($keys, ($i * $self->{bucket_size}) + $self->{hash_size}, $self->{long_size}));
 613
 614         if (!$subloc) {
 615             ##
 616             # Hit end of list, no match
 617             ##
 618             return;
 619         }
 620
 621         if ( $md5 ne $key ) {
 622             next BUCKET;
 623         }
 624
 625         ##
 626         # Matched key -- delete bucket and return
 627         ##
 628         seek($fh, $tag->{offset} + ($i * $self->{bucket_size}) + $obj->_root->{file_offset}, SEEK_SET);
 629         print( $fh substr($keys, ($i+1) * $self->{bucket_size} ) );
 630         print( $fh chr(0) x $self->{bucket_size} );
 631
 632         return 1;
 633     } # i loop
 634
 635     return;
 636 }
 637
 638 sub bucket_exists {
 639     ##
 640     # Check existence of single key given tag and MD5 digested key.
 641     ##
 642     my $self = shift;
 643     my ($obj, $tag, $md5) = @_;
 644     my $keys = $tag->{content};
 645
 646     ##
 647     # Iterate through buckets, looking for a key match
 648     ##
 649     BUCKET:
 650     for (my $i=0; $i<$self->{max_buckets}; $i++) {
 651         my $key = substr($keys, $i * $self->{bucket_size}, $self->{hash_size});
 652         my $subloc = unpack($self->{long_pack}, substr($keys, ($i * $self->{bucket_size}) + $self->{hash_size}, $self->{long_size}));
 653
 654         if (!$subloc) {
 655             ##
 656             # Hit end of list, no match
 657             ##
 658             return;
 659         }
 660
 661         if ( $md5 ne $key ) {
 662             next BUCKET;
 663         }
 664
 665         ##
 666         # Matched key -- return true
 667         ##
 668         return 1;
 669     } # i loop
 670
 671     return;
 672 }
 673
 674 sub find_bucket_list {
 675     ##
 676     # Locate offset for bucket list, given digested key
 677     ##
 678     my $self = shift;
 679     my ($obj, $md5, $args) = @_;
 680     $args = {} unless $args;
 681
 682     ##
 683     # Locate offset for bucket list using digest index system
 684     ##
 685     my $ch = 0;
 686     my $tag = $self->load_tag($obj, $obj->_base_offset);
 687     if (!$tag) {
 688         return $self->_throw_error( "INTERNAL ERROR - Cannot find tag" );
 689     }
 690
 691     while ($tag->{signature} ne DBM::Deep->SIG_BLIST) {
 692         my $num = ord substr($md5, $ch, 1);
 693
 694         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
 695         $tag = $self->index_lookup( $obj, $tag, $num );
 696
 697         if (!$tag) {
 698             if ( $args->{create} ) {
 699                 my $fh = $obj->_fh;
 700                 seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
 701                 print( $fh pack($self->{long_pack}, $obj->_root->{end}) );
 702
 703                 $tag = $self->create_tag(
 704                     $obj, $obj->_root->{end},
 705                     DBM::Deep->SIG_BLIST,
 706                     chr(0) x $self->{bucket_list_size},
 707                 );
 708
 709                 $tag->{ref_loc} = $ref_loc;
 710                 $tag->{ch} = $ch;
 711
 712                 last;
 713             }
 714             else {
 715                 return;
 716             }
 717         }
 718
 719         $tag->{ch} = $ch;
 720         $tag->{ref_loc} = $ref_loc;
 721
 722         $ch++;
 723     }
 724
 725     return $tag;
 726 }
 727
 728 sub index_lookup {
 729     ##
 730     # Given index tag, lookup single entry in index and return .
 731     ##
 732     my $self = shift;
 733     my ($obj, $tag, $index) = @_;
 734
 735     my $location = unpack(
 736         $self->{long_pack},
 737         substr(
 738             $tag->{content},
 739             $index * $self->{long_size},
 740             $self->{long_size},
 741         ),
 742     );
 743
 744     if (!$location) { return; }
 745
 746     return $self->load_tag( $obj, $location );
 747 }
 748
 749 sub traverse_index {
 750     ##
 751     # Scan index and recursively step into deeper levels, looking for next key.
 752     ##
 753     my $self = shift;
 754     my ($obj, $offset, $ch, $force_return_next) = @_;
 755     $force_return_next = undef unless $force_return_next;
 756
 757     my $tag = $self->load_tag($obj, $offset );
 758
 759     my $fh = $obj->_fh;
 760
 761     if ($tag->{signature} ne DBM::Deep->SIG_BLIST) {
 762         my $content = $tag->{content};
 763         my $start;
 764         if ($obj->{return_next}) { $start = 0; }
 765         else { $start = ord(substr($obj->{prev_md5}, $ch, 1)); }
 766
 767         for (my $index = $start; $index < 256; $index++) {
 768             my $subloc = unpack($self->{long_pack}, substr($content, $index * $self->{long_size}, $self->{long_size}) );
 769             if ($subloc) {
 770                 my $result = $self->traverse_index( $obj, $subloc, $ch + 1, $force_return_next );
 771                 if (defined($result)) { return $result; }
 772             }
 773         } # index loop
 774
 775         $obj->{return_next} = 1;
 776     } # tag is an index
 777
 778     elsif ($tag->{signature} eq DBM::Deep->SIG_BLIST) {
 779         my $keys = $tag->{content};
 780         if ($force_return_next) { $obj->{return_next} = 1; }
 781
 782         ##
 783         # Iterate through buckets, looking for a key match
 784         ##
 785         for (my $i=0; $i<$self->{max_buckets}; $i++) {
 786             my $key = substr($keys, $i * $self->{bucket_size}, $self->{hash_size});
 787             my $subloc = unpack($self->{long_pack}, substr($keys, ($i * $self->{bucket_size}) + $self->{hash_size}, $self->{long_size}));
 788
 789             if (!$subloc) {
 790                 ##
 791                 # End of bucket list -- return to outer loop
 792                 ##
 793                 $obj->{return_next} = 1;
 794                 last;
 795             }
 796             elsif ($key eq $obj->{prev_md5}) {
 797                 ##
 798                 # Located previous key -- return next one found
 799                 ##
 800                 $obj->{return_next} = 1;
 801                 next;
 802             }
 803             elsif ($obj->{return_next}) {
 804                 ##
 805                 # Seek to bucket location and skip over signature
 806                 ##
 807                 seek($fh, $subloc + DBM::Deep->SIG_SIZE + $obj->_root->{file_offset}, SEEK_SET);
 808
 809                 ##
 810                 # Skip over value to get to plain key
 811                 ##
 812                 my $size;
 813                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 814                 if ($size) { seek($fh, $size, SEEK_CUR); }
 815
 816                 ##
 817                 # Read in plain key and return as scalar
 818                 ##
 819                 my $plain_key;
 820                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 821                 if ($size) { read( $fh, $plain_key, $size); }
 822
 823                 return $plain_key;
 824             }
 825         } # bucket loop
 826
 827         $obj->{return_next} = 1;
 828     } # tag is a bucket list
 829
 830     return;
 831 }
 832
 833 sub get_next_key {
 834     ##
 835     # Locate next key, given digested previous one
 836     ##
 837     my $self = shift;
 838     my ($obj) = @_;
 839
 840     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
 841     $obj->{return_next} = 0;
 842
 843     ##
 844     # If the previous key was not specifed, start at the top and
 845     # return the first one found.
 846     ##
 847     if (!$obj->{prev_md5}) {
 848         $obj->{prev_md5} = chr(0) x $self->{hash_size};
 849         $obj->{return_next} = 1;
 850     }
 851
 852     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
 853 }
 854
 855 1;
 856 __END__