lib/DBM/Deep/Array.pm

   1 package DBM::Deep::Array;
   2
   3 use 5.006_000;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = q(1.0008);
   9
  10 # This is to allow DBM::Deep::Array to handle negative indices on
  11 # its own. Otherwise, Perl would intercept the call to negative
  12 # indices for us. This was causing bugs for negative index handling.
  13 our $NEGATIVE_INDICES = 1;
  14
  15 use base 'DBM::Deep';
  16
  17 use Scalar::Util ();
  18
  19 sub _get_self {
  20     eval { local $SIG{'__DIE__'}; tied( @{$_[0]} ) } || $_[0]
  21 }
  22
  23 sub _repr { [] }
  24
  25 sub TIEARRAY {
  26     my $class = shift;
  27     my $args = $class->_get_args( @_ );
  28
  29     $args->{type} = $class->TYPE_ARRAY;
  30
  31     return $class->_init($args);
  32 }
  33
  34 sub FETCH {
  35     my $self = shift->_get_self;
  36     my ($key) = @_;
  37
  38     $self->lock( $self->LOCK_SH );
  39
  40     if ( !defined $key ) {
  41         $self->unlock;
  42         DBM::Deep->_throw_error( "Cannot use an undefined array index." );
  43     }
  44     elsif ( $key =~ /^-?\d+$/ ) {
  45         if ( $key < 0 ) {
  46             $key += $self->FETCHSIZE;
  47             unless ( $key >= 0 ) {
  48                 $self->unlock;
  49                 return;
  50             }
  51         }
  52     }
  53     elsif ( $key ne 'length' ) {
  54         $self->unlock;
  55         DBM::Deep->_throw_error( "Cannot use '$key' as an array index." );
  56     }
  57
  58     my $rv = $self->SUPER::FETCH( $key );
  59
  60     $self->unlock;
  61
  62     return $rv;
  63 }
  64
  65 sub STORE {
  66     my $self = shift->_get_self;
  67     my ($key, $value) = @_;
  68
  69     $self->lock( $self->LOCK_EX );
  70
  71     my $size;
  72     my $idx_is_numeric;
  73     if ( !defined $key ) {
  74         $self->unlock;
  75         DBM::Deep->_throw_error( "Cannot use an undefined array index." );
  76     }
  77     elsif ( $key =~ /^-?\d+$/ ) {
  78         $idx_is_numeric = 1;
  79         if ( $key < 0 ) {
  80             $size = $self->FETCHSIZE;
  81             if ( $key + $size < 0 ) {
  82                 die( "Modification of non-creatable array value attempted, subscript $key" );
  83             }
  84             $key += $size
  85         }
  86     }
  87     elsif ( $key ne 'length' ) {
  88         $self->unlock;
  89         DBM::Deep->_throw_error( "Cannot use '$key' as an array index." );
  90     }
  91
  92     my $rv = $self->SUPER::STORE( $key, $value );
  93
  94     if ( $idx_is_numeric ) {
  95         $size = $self->FETCHSIZE unless defined $size;
  96         if ( $key >= $size ) {
  97             $self->STORESIZE( $key + 1 );
  98         }
  99     }
 100
 101     $self->unlock;
 102
 103     return $rv;
 104 }
 105
 106 sub EXISTS {
 107     my $self = shift->_get_self;
 108     my ($key) = @_;
 109
 110     $self->lock( $self->LOCK_SH );
 111
 112     if ( !defined $key ) {
 113         $self->unlock;
 114         DBM::Deep->_throw_error( "Cannot use an undefined array index." );
 115     }
 116     elsif ( $key =~ /^-?\d+$/ ) {
 117         if ( $key < 0 ) {
 118             $key += $self->FETCHSIZE;
 119             unless ( $key >= 0 ) {
 120                 $self->unlock;
 121                 return;
 122             }
 123         }
 124     }
 125     elsif ( $key ne 'length' ) {
 126         $self->unlock;
 127         DBM::Deep->_throw_error( "Cannot use '$key' as an array index." );
 128     }
 129
 130     my $rv = $self->SUPER::EXISTS( $key );
 131
 132     $self->unlock;
 133
 134     return $rv;
 135 }
 136
 137 sub DELETE {
 138     my $self = shift->_get_self;
 139     my ($key) = @_;
 140
 141     $self->lock( $self->LOCK_EX );
 142
 143     my $size = $self->FETCHSIZE;
 144     if ( !defined $key ) {
 145         $self->unlock;
 146         DBM::Deep->_throw_error( "Cannot use an undefined array index." );
 147     }
 148     elsif ( $key =~ /^-?\d+$/ ) {
 149         if ( $key < 0 ) {
 150             $key += $size;
 151             unless ( $key >= 0 ) {
 152                 $self->unlock;
 153                 return;
 154             }
 155         }
 156     }
 157     elsif ( $key ne 'length' ) {
 158         $self->unlock;
 159         DBM::Deep->_throw_error( "Cannot use '$key' as an array index." );
 160     }
 161
 162     my $rv = $self->SUPER::DELETE( $key );
 163
 164     if ($rv && $key == $size - 1) {
 165         $self->STORESIZE( $key );
 166     }
 167
 168     $self->unlock;
 169
 170     return $rv;
 171 }
 172
 173 # Now that we have a real Reference sector, we should store arrayzize there. However,
 174 # arraysize needs to be transactionally-aware, so a simple location to store it isn't
 175 # going to work.
 176 sub FETCHSIZE {
 177     my $self = shift->_get_self;
 178
 179     $self->lock( $self->LOCK_SH );
 180
 181     my $SAVE_FILTER = $self->_storage->{filter_fetch_value};
 182     $self->_storage->{filter_fetch_value} = undef;
 183
 184     my $size = $self->FETCH('length') || 0;
 185
 186     $self->_storage->{filter_fetch_value} = $SAVE_FILTER;
 187
 188     $self->unlock;
 189
 190     return $size;
 191 }
 192
 193 sub STORESIZE {
 194     my $self = shift->_get_self;
 195     my ($new_length) = @_;
 196
 197     $self->lock( $self->LOCK_EX );
 198
 199     my $SAVE_FILTER = $self->_storage->{filter_store_value};
 200     $self->_storage->{filter_store_value} = undef;
 201
 202     my $result = $self->STORE('length', $new_length, 'length');
 203
 204     $self->_storage->{filter_store_value} = $SAVE_FILTER;
 205
 206     $self->unlock;
 207
 208     return $result;
 209 }
 210
 211 sub POP {
 212     my $self = shift->_get_self;
 213
 214     $self->lock( $self->LOCK_EX );
 215
 216     my $length = $self->FETCHSIZE();
 217
 218     if ($length) {
 219         my $content = $self->FETCH( $length - 1 );
 220         $self->DELETE( $length - 1 );
 221
 222         $self->unlock;
 223
 224         return $content;
 225     }
 226     else {
 227         $self->unlock;
 228         return;
 229     }
 230 }
 231
 232 sub PUSH {
 233     my $self = shift->_get_self;
 234
 235     $self->lock( $self->LOCK_EX );
 236
 237     my $length = $self->FETCHSIZE();
 238
 239     while (my $content = shift @_) {
 240         $self->STORE( $length, $content );
 241         $length++;
 242     }
 243
 244     $self->unlock;
 245
 246     return $length;
 247 }
 248
 249 # XXX This really needs to be something more direct within the file, not a
 250 # fetch and re-store. -RobK, 2007-09-20
 251 sub _move_value {
 252     my $self = shift;
 253     my ($old_key, $new_key) = @_;
 254
 255     return $self->_engine->make_reference( $self, $old_key, $new_key );
 256 }
 257
 258 sub SHIFT {
 259     my $self = shift->_get_self;
 260
 261     $self->lock( $self->LOCK_EX );
 262
 263     my $length = $self->FETCHSIZE();
 264
 265     if ( !$length ) {
 266         $self->unlock;
 267         return;
 268     }
 269
 270     my $content = $self->FETCH( 0 );
 271
 272     for (my $i = 0; $i < $length - 1; $i++) {
 273         $self->_move_value( $i+1, $i );
 274     }
 275     $self->DELETE( $length - 1 );
 276
 277     $self->unlock;
 278
 279     return $content;
 280 }
 281
 282 sub UNSHIFT {
 283     my $self = shift->_get_self;
 284     my @new_elements = @_;
 285
 286     $self->lock( $self->LOCK_EX );
 287
 288     my $length = $self->FETCHSIZE();
 289     my $new_size = scalar @new_elements;
 290
 291     if ($length) {
 292         for (my $i = $length - 1; $i >= 0; $i--) {
 293             $self->_move_value( $i, $i+$new_size );
 294         }
 295
 296         $self->STORESIZE( $length + $new_size );
 297     }
 298
 299     for (my $i = 0; $i < $new_size; $i++) {
 300         $self->STORE( $i, $new_elements[$i] );
 301     }
 302
 303     $self->unlock;
 304
 305     return $length + $new_size;
 306 }
 307
 308 sub SPLICE {
 309     my $self = shift->_get_self;
 310
 311     $self->lock( $self->LOCK_EX );
 312
 313     my $length = $self->FETCHSIZE();
 314
 315     ##
 316     # Calculate offset and length of splice
 317     ##
 318     my $offset = shift;
 319     $offset = 0 unless defined $offset;
 320     if ($offset < 0) { $offset += $length; }
 321
 322     my $splice_length;
 323     if (scalar @_) { $splice_length = shift; }
 324     else { $splice_length = $length - $offset; }
 325     if ($splice_length < 0) { $splice_length += ($length - $offset); }
 326
 327     ##
 328     # Setup array with new elements, and copy out old elements for return
 329     ##
 330     my @new_elements = @_;
 331     my $new_size = scalar @new_elements;
 332
 333     my @old_elements = map {
 334         $self->FETCH( $_ )
 335     } $offset .. ($offset + $splice_length - 1);
 336
 337     ##
 338     # Adjust array length, and shift elements to accomodate new section.
 339     ##
 340     if ( $new_size != $splice_length ) {
 341         if ($new_size > $splice_length) {
 342             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
 343                 $self->_move_value( $i, $i + ($new_size - $splice_length) );
 344             }
 345             $self->STORESIZE( $length + $new_size - $splice_length );
 346         }
 347         else {
 348             for (my $i = $offset + $splice_length; $i < $length; $i++) {
 349                 $self->_move_value( $i, $i + ($new_size - $splice_length) );
 350             }
 351             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
 352                 $self->DELETE( $length - 1 );
 353                 $length--;
 354             }
 355         }
 356     }
 357
 358     ##
 359     # Insert new elements into array
 360     ##
 361     for (my $i = $offset; $i < $offset + $new_size; $i++) {
 362         $self->STORE( $i, shift @new_elements );
 363     }
 364
 365     $self->unlock;
 366
 367     ##
 368     # Return deleted section, or last element in scalar context.
 369     ##
 370     return wantarray ? @old_elements : $old_elements[-1];
 371 }
 372
 373 # We don't need to populate it, yet.
 374 # It will be useful, though, when we split out HASH and ARRAY
 375 sub EXTEND {
 376     ##
 377     # Perl will call EXTEND() when the array is likely to grow.
 378     # We don't care, but include it because it gets called at times.
 379     ##
 380 }
 381
 382 sub _copy_node {
 383     my $self = shift;
 384     my ($db_temp) = @_;
 385
 386     my $length = $self->length();
 387     for (my $index = 0; $index < $length; $index++) {
 388         my $value = $self->get($index);
 389         $self->_copy_value( \$db_temp->[$index], $value );
 390     }
 391
 392     return 1;
 393 }
 394
 395 ##
 396 # Public method aliases
 397 ##
 398 sub length { (shift)->FETCHSIZE(@_) }
 399 sub pop { (shift)->POP(@_) }
 400 sub push { (shift)->PUSH(@_) }
 401 sub unshift { (shift)->UNSHIFT(@_) }
 402 sub splice { (shift)->SPLICE(@_) }
 403
 404 # This must be last otherwise we have to qualify all other calls to shift
 405 # as calls to CORE::shift
 406 sub shift { (CORE::shift)->SHIFT(@_) }
 407
 408 1;
 409 __END__