lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 # Temporary - tempextlib
   8 use namespace::clean;
   9 BEGIN {
  10   require Module::Runtime;
  11   require File::Spec;
  12
  13   # There can be only one of these, make sure we get the bundled part and
  14   # *not* something off the site lib
  15   for (qw(
  16     DBIx::Class::SQLMaker
  17     SQL::Abstract
  18     SQL::Abstract::Test
  19   )) {
  20     if ($INC{Module::Runtime::module_notional_filename($_)}) {
  21       die "\nUnable to continue - a part of the bundled templib contents "
  22         . "was already loaded (likely an older version from CPAN). "
  23         . "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
  24       ;
  25     }
  26   }
  27
  28   our ($HERE) = File::Spec->rel2abs(
  29     File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
  30   ) =~ /^(.*)$/; # screw you, taint mode
  31
  32   unshift @INC, $HERE;
  33 }
  34
  35 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
  36
  37 BEGIN {
  38   package # hide from pause
  39     DBIx::Class::_ENV_;
  40
  41   use Config;
  42
  43   use constant {
  44
  45     # but of course
  46     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  47
  48     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  49
  50     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  51
  52     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  53     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  54
  55     # During 5.13 dev cycle HELEMs started to leak on copy
  56     # add an escape for these perls ON SMOKERS - a user will still get death
  57     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  58
  59     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  60
  61     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  62
  63     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  64
  65     IV_SIZE => $Config{ivsize},
  66
  67     OS_NAME => $^O,
  68   };
  69
  70   if ($] < 5.009_005) {
  71     require MRO::Compat;
  72     constant->import( OLD_MRO => 1 );
  73   }
  74   else {
  75     require mro;
  76     constant->import( OLD_MRO => 0 );
  77   }
  78 }
  79
  80 # FIXME - this is not supposed to be here
  81 # Carp::Skip to the rescue soon
  82 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  83
  84 use Carp 'croak';
  85 use Scalar::Util qw(weaken blessed reftype);
  86 use List::Util qw(first);
  87
  88 # DO NOT edit away without talking to riba first, he will just put it back
  89 # BEGIN pre-Moo2 import block
  90 BEGIN {
  91   my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  92   local $ENV{PERL_STRICTURES_EXTRA} = 0;
  93   require Sub::Quote; Sub::Quote->import('quote_sub');
  94   ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
  95 }
  96 sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
  97 # END pre-Moo2 import block
  98
  99 use base 'Exporter';
 100 our @EXPORT_OK = qw(
 101   sigwarn_silencer modver_gt_or_eq
 102   fail_on_internal_wantarray fail_on_internal_call
 103   refdesc refcount hrefaddr is_exception
 104   quote_sub qsub perlstring
 105   UNRESOLVABLE_CONDITION
 106 );
 107
 108 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
 109
 110 sub sigwarn_silencer ($) {
 111   my $pattern = shift;
 112
 113   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
 114
 115   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
 116
 117   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
 118 }
 119
 120 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
 121
 122 sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }
 123
 124 sub refdesc ($) {
 125   croak "Expecting a reference" if ! length ref $_[0];
 126
 127   # be careful not to trigger stringification,
 128   # reuse @_ as a scratch-pad
 129   sprintf '%s%s(0x%x)',
 130     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
 131     reftype $_[0],
 132     Scalar::Util::refaddr($_[0]),
 133   ;
 134 }
 135
 136 sub refcount ($) {
 137   croak "Expecting a reference" if ! length ref $_[0];
 138
 139   require B;
 140   # No tempvars - must operate on $_[0], otherwise the pad
 141   # will count as an extra ref
 142   B::svref_2object($_[0])->REFCNT;
 143 }
 144
 145 sub is_exception ($) {
 146   my $e = $_[0];
 147
 148   # this is not strictly correct - an eval setting $@ to undef
 149   # is *not* the same as an eval setting $@ to ''
 150   # but for the sake of simplicity assume the following for
 151   # the time being
 152   return 0 unless defined $e;
 153
 154   my ($not_blank, $suberror);
 155   {
 156     local $@;
 157     eval {
 158       $not_blank = ($e ne '') ? 1 : 0;
 159       1;
 160     } or $suberror = $@;
 161   }
 162
 163   if (defined $suberror) {
 164     if (length (my $class = blessed($e) )) {
 165       carp_unique( sprintf(
 166         'External exception class %s implements partial (broken) overloading '
 167       . 'preventing its instances from being used in simple ($x eq $y) '
 168       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 169       . 'handling this type of brokenness is extremely dangerous on '
 170       . 'exception objects, as it may (and often does) result in silent '
 171       . '"exception substitution". DBIx::Class tries to work around this '
 172       . 'as much as possible, but other parts of your software stack may '
 173       . 'not be even aware of this. Please submit a bugreport against the '
 174       . 'distribution containing %s and in the meantime apply a fix similar '
 175       . 'to the one shown at %s, in order to ensure your exception handling '
 176       . 'is saner application-wide. What follows is the actual error text '
 177       . "as generated by Perl itself:\n\n%s\n ",
 178         $class,
 179         $class,
 180         'http://v.gd/DBIC_overload_tempfix/',
 181         $suberror,
 182       ));
 183
 184       # workaround, keeps spice flowing
 185       $not_blank = ("$e" ne '') ? 1 : 0;
 186     }
 187     else {
 188       # not blessed yet failed the 'ne'... this makes 0 sense...
 189       # just throw further
 190       die $suberror
 191     }
 192   }
 193
 194   return $not_blank;
 195 }
 196
 197 sub modver_gt_or_eq ($$) {
 198   my ($mod, $ver) = @_;
 199
 200   croak "Nonsensical module name supplied"
 201     if ! defined $mod or ! length $mod;
 202
 203   croak "Nonsensical minimum version supplied"
 204     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 205
 206   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 207     if SPURIOUS_VERSION_CHECK_WARNINGS;
 208
 209   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 210     unless $mod->VERSION;
 211
 212   local $@;
 213   eval { $mod->VERSION($ver) } ? 1 : 0;
 214 }
 215
 216 {
 217   my $list_ctx_ok_stack_marker;
 218
 219   sub fail_on_internal_wantarray () {
 220     return if $list_ctx_ok_stack_marker;
 221
 222     if (! defined wantarray) {
 223       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 224     }
 225
 226     my $cf = 1;
 227     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 228
 229       # these are public API parts that alter behavior on wantarray
 230       search | search_related | slice | search_literal
 231
 232         |
 233
 234       # these are explicitly prefixed, since we only recognize them as valid
 235       # escapes when they come from the guts of CDBICompat
 236       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 237
 238     ) $/x ) {
 239       $cf++;
 240     }
 241
 242     my ($fr, $want, $argdesc);
 243     {
 244       package DB;
 245       $fr = [ caller($cf) ];
 246       $want = ( caller($cf-1) )[5];
 247       $argdesc = ref $DB::args[0]
 248         ? DBIx::Class::_Util::refdesc($DB::args[0])
 249         : 'non '
 250       ;
 251     };
 252
 253     if (
 254       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 255     ) {
 256       DBIx::Class::Exception->throw( sprintf (
 257         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 258         $argdesc, @{$fr}[1,2]
 259       ), 'with_stacktrace');
 260     }
 261
 262     my $mark = [];
 263     weaken ( $list_ctx_ok_stack_marker = $mark );
 264     $mark;
 265   }
 266 }
 267
 268 sub fail_on_internal_call {
 269   my ($fr, $argdesc);
 270   {
 271     package DB;
 272     $fr = [ caller(1) ];
 273     $argdesc = ref $DB::args[0]
 274       ? DBIx::Class::_Util::refdesc($DB::args[0])
 275       : undef
 276     ;
 277   };
 278
 279   if (
 280     $argdesc
 281       and
 282     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 283       and
 284     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 285   ) {
 286     DBIx::Class::Exception->throw( sprintf (
 287       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 288       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 289         require B::Deparse;
 290         no strict 'refs';
 291         B::Deparse->new->coderef2text(\&{$fr->[3]})
 292       }),
 293     ), 'with_stacktrace');
 294   }
 295 }
 296
 297 1;