lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use DBIx::Class::SQLAHacks;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIx::Class::SQLAHacks');
  33
  34
  35 =head1 NAME
  36
  37 DBIx::Class::Storage::DBI - DBI storage handler
  38
  39 =head1 SYNOPSIS
  40
  41   my $schema = MySchema->connect('dbi:SQLite:my.db');
  42
  43   $schema->storage->debug(1);
  44   $schema->dbh_do("DROP TABLE authors");
  45
  46   $schema->resultset('Book')->search({
  47      written_on => $schema->storage->datetime_parser(DateTime->now)
  48   });
  49
  50 =head1 DESCRIPTION
  51
  52 This class represents the connection to an RDBMS via L<DBI>.  See
  53 L<DBIx::Class::Storage> for general information.  This pod only
  54 documents DBI-specific methods and behaviors.
  55
  56 =head1 METHODS
  57
  58 =cut
  59
  60 sub new {
  61   my $new = shift->next::method(@_);
  62
  63   $new->transaction_depth(0);
  64   $new->_sql_maker_opts({});
  65   $new->{savepoints} = [];
  66   $new->{_in_dbh_do} = 0;
  67   $new->{_dbh_gen} = 0;
  68
  69   $new;
  70 }
  71
  72 =head2 connect_info
  73
  74 This method is normally called by L<DBIx::Class::Schema/connection>, which
  75 encapsulates its argument list in an arrayref before passing them here.
  76
  77 The argument list may contain:
  78
  79 =over
  80
  81 =item *
  82
  83 The same 4-element argument set one would normally pass to
  84 L<DBI/connect>, optionally followed by
  85 L<extra attributes|/DBIx::Class specific connection attributes>
  86 recognized by DBIx::Class:
  87
  88   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
  89
  90 =item *
  91
  92 A single code reference which returns a connected
  93 L<DBI database handle|DBI/connect> optionally followed by
  94 L<extra attributes|/DBIx::Class specific connection attributes> recognized
  95 by DBIx::Class:
  96
  97   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
  98
  99 =item *
 100
 101 A single hashref with all the attributes and the dsn/user/password
 102 mixed together:
 103
 104   $connect_info_args = [{
 105     dsn => $dsn,
 106     user => $user,
 107     password => $pass,
 108     %dbi_attributes,
 109     %extra_attributes,
 110   }];
 111
 112 This is particularly useful for L<Catalyst> based applications, allowing the
 113 following config (L<Config::General> style):
 114
 115   <Model::DB>
 116     schema_class   App::DB
 117     <connect_info>
 118       dsn          dbi:mysql:database=test
 119       user         testuser
 120       password     TestPass
 121       AutoCommit   1
 122     </connect_info>
 123   </Model::DB>
 124
 125 =back
 126
 127 Please note that the L<DBI> docs recommend that you always explicitly
 128 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 129 recommends that it be set to I<1>, and that you perform transactions
 130 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 131 to I<1> if you do not do explicitly set it to zero.  This is the default
 132 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 133
 134 =head3 DBIx::Class specific connection attributes
 135
 136 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 137 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 138 the following connection options. These options can be mixed in with your other
 139 L<DBI> connection attributes, or placed in a seperate hashref
 140 (C<\%extra_attributes>) as shown above.
 141
 142 Every time C<connect_info> is invoked, any previous settings for
 143 these options will be cleared before setting the new ones, regardless of
 144 whether any options are specified in the new C<connect_info>.
 145
 146
 147 =over
 148
 149 =item on_connect_do
 150
 151 Specifies things to do immediately after connecting or re-connecting to
 152 the database.  Its value may contain:
 153
 154 =over
 155
 156 =item an array reference
 157
 158 This contains SQL statements to execute in order.  Each element contains
 159 a string or a code reference that returns a string.
 160
 161 =item a code reference
 162
 163 This contains some code to execute.  Unlike code references within an
 164 array reference, its return value is ignored.
 165
 166 =back
 167
 168 =item on_disconnect_do
 169
 170 Takes arguments in the same form as L</on_connect_do> and executes them
 171 immediately before disconnecting from the database.
 172
 173 Note, this only runs if you explicitly call L</disconnect> on the
 174 storage object.
 175
 176 =item disable_sth_caching
 177
 178 If set to a true value, this option will disable the caching of
 179 statement handles via L<DBI/prepare_cached>.
 180
 181 =item limit_dialect
 182
 183 Sets the limit dialect. This is useful for JDBC-bridge among others
 184 where the remote SQL-dialect cannot be determined by the name of the
 185 driver alone. See also L<SQL::Abstract::Limit>.
 186
 187 =item quote_char
 188
 189 Specifies what characters to use to quote table and column names. If
 190 you use this you will want to specify L</name_sep> as well.
 191
 192 C<quote_char> expects either a single character, in which case is it
 193 is placed on either side of the table/column name, or an arrayref of length
 194 2 in which case the table/column name is placed between the elements.
 195
 196 For example under MySQL you should use C<< quote_char => '`' >>, and for
 197 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 198
 199 =item name_sep
 200
 201 This only needs to be used in conjunction with C<quote_char>, and is used to
 202 specify the charecter that seperates elements (schemas, tables, columns) from
 203 each other. In most cases this is simply a C<.>.
 204
 205 The consequences of not supplying this value is that L<SQL::Abstract>
 206 will assume DBIx::Class' uses of aliases to be complete column
 207 names. The output will look like I<"me.name"> when it should actually
 208 be I<"me"."name">.
 209
 210 =item unsafe
 211
 212 This Storage driver normally installs its own C<HandleError>, sets
 213 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 214 all database handles, including those supplied by a coderef.  It does this
 215 so that it can have consistent and useful error behavior.
 216
 217 If you set this option to a true value, Storage will not do its usual
 218 modifications to the database handle's attributes, and instead relies on
 219 the settings in your connect_info DBI options (or the values you set in
 220 your connection coderef, in the case that you are connecting via coderef).
 221
 222 Note that your custom settings can cause Storage to malfunction,
 223 especially if you set a C<HandleError> handler that suppresses exceptions
 224 and/or disable C<RaiseError>.
 225
 226 =item auto_savepoint
 227
 228 If this option is true, L<DBIx::Class> will use savepoints when nesting
 229 transactions, making it possible to recover from failure in the inner
 230 transaction without having to abort all outer transactions.
 231
 232 =item cursor_class
 233
 234 Use this argument to supply a cursor class other than the default
 235 L<DBIx::Class::Storage::DBI::Cursor>.
 236
 237 =back
 238
 239 Some real-life examples of arguments to L</connect_info> and
 240 L<DBIx::Class::Schema/connect>
 241
 242   # Simple SQLite connection
 243   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 244
 245   # Connect via subref
 246   ->connect_info([ sub { DBI->connect(...) } ]);
 247
 248   # A bit more complicated
 249   ->connect_info(
 250     [
 251       'dbi:Pg:dbname=foo',
 252       'postgres',
 253       'my_pg_password',
 254       { AutoCommit => 1 },
 255       { quote_char => q{"}, name_sep => q{.} },
 256     ]
 257   );
 258
 259   # Equivalent to the previous example
 260   ->connect_info(
 261     [
 262       'dbi:Pg:dbname=foo',
 263       'postgres',
 264       'my_pg_password',
 265       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 266     ]
 267   );
 268
 269   # Same, but with hashref as argument
 270   # See parse_connect_info for explanation
 271   ->connect_info(
 272     [{
 273       dsn         => 'dbi:Pg:dbname=foo',
 274       user        => 'postgres',
 275       password    => 'my_pg_password',
 276       AutoCommit  => 1,
 277       quote_char  => q{"},
 278       name_sep    => q{.},
 279     }]
 280   );
 281
 282   # Subref + DBIx::Class-specific connection options
 283   ->connect_info(
 284     [
 285       sub { DBI->connect(...) },
 286       {
 287           quote_char => q{`},
 288           name_sep => q{@},
 289           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 290           disable_sth_caching => 1,
 291       },
 292     ]
 293   );
 294
 295
 296
 297 =cut
 298
 299 sub connect_info {
 300   my ($self, $info_arg) = @_;
 301
 302   return $self->_connect_info if !$info_arg;
 303
 304   my @args = @$info_arg;  # take a shallow copy for further mutilation
 305   $self->_connect_info([@args]); # copy for _connect_info
 306
 307
 308   # combine/pre-parse arguments depending on invocation style
 309
 310   my %attrs;
 311   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 312     %attrs = %{ $args[1] || {} };
 313     @args = $args[0];
 314   }
 315   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 316     %attrs = %{$args[0]};
 317     @args = ();
 318     for (qw/password user dsn/) {
 319       unshift @args, delete $attrs{$_};
 320     }
 321   }
 322   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 323     %attrs = (
 324       % { $args[3] || {} },
 325       % { $args[4] || {} },
 326     );
 327     @args = @args[0,1,2];
 328   }
 329
 330   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 331   #  the new set of options
 332   $self->_sql_maker(undef);
 333   $self->_sql_maker_opts({});
 334
 335   if(keys %attrs) {
 336     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 337       if(my $value = delete $attrs{$storage_opt}) {
 338         $self->$storage_opt($value);
 339       }
 340     }
 341     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 342       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 343         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 344       }
 345     }
 346   }
 347
 348   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 349
 350   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 351   $self->_connect_info;
 352 }
 353
 354 =head2 on_connect_do
 355
 356 This method is deprecated in favour of setting via L</connect_info>.
 357
 358
 359 =head2 dbh_do
 360
 361 Arguments: ($subref | $method_name), @extra_coderef_args?
 362
 363 Execute the given $subref or $method_name using the new exception-based
 364 connection management.
 365
 366 The first two arguments will be the storage object that C<dbh_do> was called
 367 on and a database handle to use.  Any additional arguments will be passed
 368 verbatim to the called subref as arguments 2 and onwards.
 369
 370 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 371 exception handling and reconnection (or failover in future subclasses).
 372
 373 Your subref should have no side-effects outside of the database, as
 374 there is the potential for your subref to be partially double-executed
 375 if the database connection was stale/dysfunctional.
 376
 377 Example:
 378
 379   my @stuff = $schema->storage->dbh_do(
 380     sub {
 381       my ($storage, $dbh, @cols) = @_;
 382       my $cols = join(q{, }, @cols);
 383       $dbh->selectrow_array("SELECT $cols FROM foo");
 384     },
 385     @column_list
 386   );
 387
 388 =cut
 389
 390 sub dbh_do {
 391   my $self = shift;
 392   my $code = shift;
 393
 394   my $dbh = $self->_dbh;
 395
 396   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 397       || $self->{transaction_depth};
 398
 399   local $self->{_in_dbh_do} = 1;
 400
 401   my @result;
 402   my $want_array = wantarray;
 403
 404   eval {
 405     $self->_verify_pid if $dbh;
 406     if(!$self->_dbh) {
 407         $self->_populate_dbh;
 408         $dbh = $self->_dbh;
 409     }
 410
 411     if($want_array) {
 412         @result = $self->$code($dbh, @_);
 413     }
 414     elsif(defined $want_array) {
 415         $result[0] = $self->$code($dbh, @_);
 416     }
 417     else {
 418         $self->$code($dbh, @_);
 419     }
 420   };
 421
 422   my $exception = $@;
 423   if(!$exception) { return $want_array ? @result : $result[0] }
 424
 425   $self->throw_exception($exception) if $self->connected;
 426
 427   # We were not connected - reconnect and retry, but let any
 428   #  exception fall right through this time
 429   $self->_populate_dbh;
 430   $self->$code($self->_dbh, @_);
 431 }
 432
 433 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 434 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 435 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 436 sub txn_do {
 437   my $self = shift;
 438   my $coderef = shift;
 439
 440   ref $coderef eq 'CODE' or $self->throw_exception
 441     ('$coderef must be a CODE reference');
 442
 443   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 444
 445   local $self->{_in_dbh_do} = 1;
 446
 447   my @result;
 448   my $want_array = wantarray;
 449
 450   my $tried = 0;
 451   while(1) {
 452     eval {
 453       $self->_verify_pid if $self->_dbh;
 454       $self->_populate_dbh if !$self->_dbh;
 455
 456       $self->txn_begin;
 457       if($want_array) {
 458           @result = $coderef->(@_);
 459       }
 460       elsif(defined $want_array) {
 461           $result[0] = $coderef->(@_);
 462       }
 463       else {
 464           $coderef->(@_);
 465       }
 466       $self->txn_commit;
 467     };
 468
 469     my $exception = $@;
 470     if(!$exception) { return $want_array ? @result : $result[0] }
 471
 472     if($tried++ > 0 || $self->connected) {
 473       eval { $self->txn_rollback };
 474       my $rollback_exception = $@;
 475       if($rollback_exception) {
 476         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 477         $self->throw_exception($exception)  # propagate nested rollback
 478           if $rollback_exception =~ /$exception_class/;
 479
 480         $self->throw_exception(
 481           "Transaction aborted: ${exception}. "
 482           . "Rollback failed: ${rollback_exception}"
 483         );
 484       }
 485       $self->throw_exception($exception)
 486     }
 487
 488     # We were not connected, and was first try - reconnect and retry
 489     # via the while loop
 490     $self->_populate_dbh;
 491   }
 492 }
 493
 494 =head2 disconnect
 495
 496 Our C<disconnect> method also performs a rollback first if the
 497 database is not in C<AutoCommit> mode.
 498
 499 =cut
 500
 501 sub disconnect {
 502   my ($self) = @_;
 503
 504   if( $self->connected ) {
 505     my $connection_do = $self->on_disconnect_do;
 506     $self->_do_connection_actions($connection_do) if ref($connection_do);
 507
 508     $self->_dbh->rollback unless $self->_dbh_autocommit;
 509     $self->_dbh->disconnect;
 510     $self->_dbh(undef);
 511     $self->{_dbh_gen}++;
 512   }
 513 }
 514
 515 =head2 with_deferred_fk_checks
 516
 517 =over 4
 518
 519 =item Arguments: C<$coderef>
 520
 521 =item Return Value: The return value of $coderef
 522
 523 =back
 524
 525 Storage specific method to run the code ref with FK checks deferred or
 526 in MySQL's case disabled entirely.
 527
 528 =cut
 529
 530 # Storage subclasses should override this
 531 sub with_deferred_fk_checks {
 532   my ($self, $sub) = @_;
 533
 534   $sub->();
 535 }
 536
 537 sub connected {
 538   my ($self) = @_;
 539
 540   if(my $dbh = $self->_dbh) {
 541       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 542           $self->_dbh(undef);
 543           $self->{_dbh_gen}++;
 544           return;
 545       }
 546       else {
 547           $self->_verify_pid;
 548           return 0 if !$self->_dbh;
 549       }
 550       return ($dbh->FETCH('Active') && $dbh->ping);
 551   }
 552
 553   return 0;
 554 }
 555
 556 # handle pid changes correctly
 557 #  NOTE: assumes $self->_dbh is a valid $dbh
 558 sub _verify_pid {
 559   my ($self) = @_;
 560
 561   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 562
 563   $self->_dbh->{InactiveDestroy} = 1;
 564   $self->_dbh(undef);
 565   $self->{_dbh_gen}++;
 566
 567   return;
 568 }
 569
 570 sub ensure_connected {
 571   my ($self) = @_;
 572
 573   unless ($self->connected) {
 574     $self->_populate_dbh;
 575   }
 576 }
 577
 578 =head2 dbh
 579
 580 Returns the dbh - a data base handle of class L<DBI>.
 581
 582 =cut
 583
 584 sub dbh {
 585   my ($self) = @_;
 586
 587   $self->ensure_connected;
 588   return $self->_dbh;
 589 }
 590
 591 sub _sql_maker_args {
 592     my ($self) = @_;
 593
 594     return ( bindtype=>'columns', array_datatypes => 1, limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 595 }
 596
 597 sub sql_maker {
 598   my ($self) = @_;
 599   unless ($self->_sql_maker) {
 600     my $sql_maker_class = $self->sql_maker_class;
 601     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 602   }
 603   return $self->_sql_maker;
 604 }
 605
 606 sub _rebless {}
 607
 608 sub _populate_dbh {
 609   my ($self) = @_;
 610   my @info = @{$self->_dbi_connect_info || []};
 611   $self->_dbh($self->_connect(@info));
 612
 613   # Always set the transaction depth on connect, since
 614   #  there is no transaction in progress by definition
 615   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 616
 617   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 618     my $driver = $self->_dbh->{Driver}->{Name};
 619     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 620       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 621       $self->_rebless();
 622     }
 623   }
 624
 625   $self->_conn_pid($$);
 626   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 627
 628   my $connection_do = $self->on_connect_do;
 629   $self->_do_connection_actions($connection_do) if ref($connection_do);
 630 }
 631
 632 sub _do_connection_actions {
 633   my $self = shift;
 634   my $connection_do = shift;
 635
 636   if (ref $connection_do eq 'ARRAY') {
 637     $self->_do_query($_) foreach @$connection_do;
 638   }
 639   elsif (ref $connection_do eq 'CODE') {
 640     $connection_do->($self);
 641   }
 642
 643   return $self;
 644 }
 645
 646 sub _do_query {
 647   my ($self, $action) = @_;
 648
 649   if (ref $action eq 'CODE') {
 650     $action = $action->($self);
 651     $self->_do_query($_) foreach @$action;
 652   }
 653   else {
 654     # Most debuggers expect ($sql, @bind), so we need to exclude
 655     # the attribute hash which is the second argument to $dbh->do
 656     # furthermore the bind values are usually to be presented
 657     # as named arrayref pairs, so wrap those here too
 658     my @do_args = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 659     my $sql = shift @do_args;
 660     my $attrs = shift @do_args;
 661     my @bind = map { [ undef, $_ ] } @do_args;
 662
 663     $self->_query_start($sql, @bind);
 664     $self->_dbh->do($sql, $attrs, @do_args);
 665     $self->_query_end($sql, @bind);
 666   }
 667
 668   return $self;
 669 }
 670
 671 sub _connect {
 672   my ($self, @info) = @_;
 673
 674   $self->throw_exception("You failed to provide any connection info")
 675     if !@info;
 676
 677   my ($old_connect_via, $dbh);
 678
 679   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 680     $old_connect_via = $DBI::connect_via;
 681     $DBI::connect_via = 'connect';
 682   }
 683
 684   eval {
 685     if(ref $info[0] eq 'CODE') {
 686        $dbh = &{$info[0]}
 687     }
 688     else {
 689        $dbh = DBI->connect(@info);
 690     }
 691
 692     if($dbh && !$self->unsafe) {
 693       my $weak_self = $self;
 694       weaken($weak_self);
 695       $dbh->{HandleError} = sub {
 696           if ($weak_self) {
 697             $weak_self->throw_exception("DBI Exception: $_[0]");
 698           }
 699           else {
 700             croak ("DBI Exception: $_[0]");
 701           }
 702       };
 703       $dbh->{ShowErrorStatement} = 1;
 704       $dbh->{RaiseError} = 1;
 705       $dbh->{PrintError} = 0;
 706     }
 707   };
 708
 709   $DBI::connect_via = $old_connect_via if $old_connect_via;
 710
 711   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 712     if !$dbh || $@;
 713
 714   $self->_dbh_autocommit($dbh->{AutoCommit});
 715
 716   $dbh;
 717 }
 718
 719 sub svp_begin {
 720   my ($self, $name) = @_;
 721
 722   $name = $self->_svp_generate_name
 723     unless defined $name;
 724
 725   $self->throw_exception ("You can't use savepoints outside a transaction")
 726     if $self->{transaction_depth} == 0;
 727
 728   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 729     unless $self->can('_svp_begin');
 730
 731   push @{ $self->{savepoints} }, $name;
 732
 733   $self->debugobj->svp_begin($name) if $self->debug;
 734
 735   return $self->_svp_begin($name);
 736 }
 737
 738 sub svp_release {
 739   my ($self, $name) = @_;
 740
 741   $self->throw_exception ("You can't use savepoints outside a transaction")
 742     if $self->{transaction_depth} == 0;
 743
 744   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 745     unless $self->can('_svp_release');
 746
 747   if (defined $name) {
 748     $self->throw_exception ("Savepoint '$name' does not exist")
 749       unless grep { $_ eq $name } @{ $self->{savepoints} };
 750
 751     # Dig through the stack until we find the one we are releasing.  This keeps
 752     # the stack up to date.
 753     my $svp;
 754
 755     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 756   } else {
 757     $name = pop @{ $self->{savepoints} };
 758   }
 759
 760   $self->debugobj->svp_release($name) if $self->debug;
 761
 762   return $self->_svp_release($name);
 763 }
 764
 765 sub svp_rollback {
 766   my ($self, $name) = @_;
 767
 768   $self->throw_exception ("You can't use savepoints outside a transaction")
 769     if $self->{transaction_depth} == 0;
 770
 771   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 772     unless $self->can('_svp_rollback');
 773
 774   if (defined $name) {
 775       # If they passed us a name, verify that it exists in the stack
 776       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 777           $self->throw_exception("Savepoint '$name' does not exist!");
 778       }
 779
 780       # Dig through the stack until we find the one we are releasing.  This keeps
 781       # the stack up to date.
 782       while(my $s = pop(@{ $self->{savepoints} })) {
 783           last if($s eq $name);
 784       }
 785       # Add the savepoint back to the stack, as a rollback doesn't remove the
 786       # named savepoint, only everything after it.
 787       push(@{ $self->{savepoints} }, $name);
 788   } else {
 789       # We'll assume they want to rollback to the last savepoint
 790       $name = $self->{savepoints}->[-1];
 791   }
 792
 793   $self->debugobj->svp_rollback($name) if $self->debug;
 794
 795   return $self->_svp_rollback($name);
 796 }
 797
 798 sub _svp_generate_name {
 799     my ($self) = @_;
 800
 801     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 802 }
 803
 804 sub txn_begin {
 805   my $self = shift;
 806   $self->ensure_connected();
 807   if($self->{transaction_depth} == 0) {
 808     $self->debugobj->txn_begin()
 809       if $self->debug;
 810     # this isn't ->_dbh-> because
 811     #  we should reconnect on begin_work
 812     #  for AutoCommit users
 813     $self->dbh->begin_work;
 814   } elsif ($self->auto_savepoint) {
 815     $self->svp_begin;
 816   }
 817   $self->{transaction_depth}++;
 818 }
 819
 820 sub txn_commit {
 821   my $self = shift;
 822   if ($self->{transaction_depth} == 1) {
 823     my $dbh = $self->_dbh;
 824     $self->debugobj->txn_commit()
 825       if ($self->debug);
 826     $dbh->commit;
 827     $self->{transaction_depth} = 0
 828       if $self->_dbh_autocommit;
 829   }
 830   elsif($self->{transaction_depth} > 1) {
 831     $self->{transaction_depth}--;
 832     $self->svp_release
 833       if $self->auto_savepoint;
 834   }
 835 }
 836
 837 sub txn_rollback {
 838   my $self = shift;
 839   my $dbh = $self->_dbh;
 840   eval {
 841     if ($self->{transaction_depth} == 1) {
 842       $self->debugobj->txn_rollback()
 843         if ($self->debug);
 844       $self->{transaction_depth} = 0
 845         if $self->_dbh_autocommit;
 846       $dbh->rollback;
 847     }
 848     elsif($self->{transaction_depth} > 1) {
 849       $self->{transaction_depth}--;
 850       if ($self->auto_savepoint) {
 851         $self->svp_rollback;
 852         $self->svp_release;
 853       }
 854     }
 855     else {
 856       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
 857     }
 858   };
 859   if ($@) {
 860     my $error = $@;
 861     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 862     $error =~ /$exception_class/ and $self->throw_exception($error);
 863     # ensure that a failed rollback resets the transaction depth
 864     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 865     $self->throw_exception($error);
 866   }
 867 }
 868
 869 # This used to be the top-half of _execute.  It was split out to make it
 870 #  easier to override in NoBindVars without duping the rest.  It takes up
 871 #  all of _execute's args, and emits $sql, @bind.
 872 sub _prep_for_execute {
 873   my ($self, $op, $extra_bind, $ident, $args) = @_;
 874
 875   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
 876     $ident = $ident->from();
 877   }
 878
 879   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
 880
 881   unshift(@bind,
 882     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
 883       if $extra_bind;
 884   return ($sql, \@bind);
 885 }
 886
 887 sub _fix_bind_params {
 888     my ($self, @bind) = @_;
 889
 890     ### Turn @bind from something like this:
 891     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
 892     ### to this:
 893     ###   ( "'1'", "'1'", "'3'" )
 894     return
 895         map {
 896             if ( defined( $_ && $_->[1] ) ) {
 897                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
 898             }
 899             else { q{'NULL'}; }
 900         } @bind;
 901 }
 902
 903 sub _query_start {
 904     my ( $self, $sql, @bind ) = @_;
 905
 906     if ( $self->debug ) {
 907         @bind = $self->_fix_bind_params(@bind);
 908
 909         $self->debugobj->query_start( $sql, @bind );
 910     }
 911 }
 912
 913 sub _query_end {
 914     my ( $self, $sql, @bind ) = @_;
 915
 916     if ( $self->debug ) {
 917         @bind = $self->_fix_bind_params(@bind);
 918         $self->debugobj->query_end( $sql, @bind );
 919     }
 920 }
 921
 922 sub _dbh_execute {
 923   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
 924
 925   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
 926
 927   $self->_query_start( $sql, @$bind );
 928
 929   my $sth = $self->sth($sql,$op);
 930
 931   my $placeholder_index = 1;
 932
 933   foreach my $bound (@$bind) {
 934     my $attributes = {};
 935     my($column_name, @data) = @$bound;
 936
 937     if ($bind_attributes) {
 938       $attributes = $bind_attributes->{$column_name}
 939       if defined $bind_attributes->{$column_name};
 940     }
 941
 942     foreach my $data (@data) {
 943       my $ref = ref $data;
 944       $data = $ref && $ref ne 'ARRAY' ? ''.$data : $data; # stringify args (except arrayrefs)
 945
 946       $sth->bind_param($placeholder_index, $data, $attributes);
 947       $placeholder_index++;
 948     }
 949   }
 950
 951   # Can this fail without throwing an exception anyways???
 952   my $rv = $sth->execute();
 953   $self->throw_exception($sth->errstr) if !$rv;
 954
 955   $self->_query_end( $sql, @$bind );
 956
 957   return (wantarray ? ($rv, $sth, @$bind) : $rv);
 958 }
 959
 960 sub _execute {
 961     my $self = shift;
 962     $self->dbh_do('_dbh_execute', @_)
 963 }
 964
 965 sub insert {
 966   my ($self, $source, $to_insert) = @_;
 967
 968   my $ident = $source->from;
 969   my $bind_attributes = $self->source_bind_attributes($source);
 970
 971   my $updated_cols = {};
 972
 973   $self->ensure_connected;
 974   foreach my $col ( $source->columns ) {
 975     if ( !defined $to_insert->{$col} ) {
 976       my $col_info = $source->column_info($col);
 977
 978       if ( $col_info->{auto_nextval} ) {
 979         $updated_cols->{$col} = $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
 980       }
 981     }
 982   }
 983
 984   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
 985
 986   return $updated_cols;
 987 }
 988
 989 ## Still not quite perfect, and EXPERIMENTAL
 990 ## Currently it is assumed that all values passed will be "normal", i.e. not
 991 ## scalar refs, or at least, all the same type as the first set, the statement is
 992 ## only prepped once.
 993 sub insert_bulk {
 994   my ($self, $source, $cols, $data) = @_;
 995   my %colvalues;
 996   my $table = $source->from;
 997   @colvalues{@$cols} = (0..$#$cols);
 998   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
 999
1000   $self->_query_start( $sql, @bind );
1001   my $sth = $self->sth($sql);
1002
1003 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1004
1005   ## This must be an arrayref, else nothing works!
1006   my $tuple_status = [];
1007
1008   ## Get the bind_attributes, if any exist
1009   my $bind_attributes = $self->source_bind_attributes($source);
1010
1011   ## Bind the values and execute
1012   my $placeholder_index = 1;
1013
1014   foreach my $bound (@bind) {
1015
1016     my $attributes = {};
1017     my ($column_name, $data_index) = @$bound;
1018
1019     if( $bind_attributes ) {
1020       $attributes = $bind_attributes->{$column_name}
1021       if defined $bind_attributes->{$column_name};
1022     }
1023
1024     my @data = map { $_->[$data_index] } @$data;
1025
1026     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1027     $placeholder_index++;
1028   }
1029   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1030   $self->throw_exception($sth->errstr) if !$rv;
1031
1032   $self->_query_end( $sql, @bind );
1033   return (wantarray ? ($rv, $sth, @bind) : $rv);
1034 }
1035
1036 sub update {
1037   my $self = shift @_;
1038   my $source = shift @_;
1039   my $bind_attributes = $self->source_bind_attributes($source);
1040
1041   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1042 }
1043
1044
1045 sub delete {
1046   my $self = shift @_;
1047   my $source = shift @_;
1048
1049   my $bind_attrs = {}; ## If ever it's needed...
1050
1051   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1052 }
1053
1054 # We were sent here because the $rs contains a complex search
1055 # which will require a subquery to select the correct rows
1056 # (i.e. joined or limited resultsets)
1057 #
1058 # Genarating a single PK column subquery is trivial and supported
1059 # by all RDBMS. However if we have a multicolumn PK, things get ugly.
1060 # Look at multipk_update_delete()
1061 sub subq_update_delete {
1062   my $self = shift;
1063   my ($rs, $op, $values) = @_;
1064
1065   if ($rs->result_source->primary_columns == 1) {
1066     return $self->_onepk_update_delete (@_);
1067   }
1068   else {
1069     return $self->_multipk_update_delete (@_);
1070   }
1071 }
1072
1073 # Generally a single PK resultset operation is trivially expressed
1074 # with PK IN (subquery). However some databases (mysql) do not support
1075 # modification of a table mentioned in the subselect. This method
1076 # should be overriden in the appropriate storage class to be smarter
1077 # in such situations
1078 sub _onepk_update_delete {
1079
1080   my $self = shift;
1081   my ($rs, $op, $values) = @_;
1082
1083   my $rsrc = $rs->result_source;
1084   my @pcols = $rsrc->primary_columns;
1085
1086   return $self->$op (
1087     $rsrc,
1088     $op eq 'update' ? $values : (),
1089     { $pcols[0] => { -in => $rs->get_column ($pcols[0])->as_query } },
1090   );
1091 }
1092
1093 # ANSI SQL does not provide a reliable way to perform a multicol-PK
1094 # resultset update/delete involving subqueries. So resort to simple
1095 # (and inefficient) delete_all style per-row opearations, while allowing
1096 # specific storages to override this with a faster implementation.
1097 #
1098 # We do not use $row->$op style queries, because resultset update/delete
1099 # is not expected to cascade (this is what delete_all/update_all is for).
1100 #
1101 # There should be no race conditions as the entire operation is rolled
1102 # in a transaction.
1103 sub _multipk_update_delete {
1104   my $self = shift;
1105   my ($rs, $op, $values) = @_;
1106
1107   my $rsrc = $rs->result_source;
1108   my @pcols = $rsrc->primary_columns;
1109
1110   my $guard = $self->txn_scope_guard;
1111
1112   my $subrs_cur = $rs->search ({}, { columns => \@pcols })->cursor;
1113   while (my @pks = $subrs_cur->next) {
1114
1115     my $cond;
1116     for my $i (0.. $#pcols) {
1117       $cond->{$pcols[$i]} = $pks[$i];
1118     }
1119
1120     $self->$op (
1121       $rsrc,
1122       $op eq 'update' ? $values : (),
1123       $cond,
1124     );
1125   }
1126
1127   $guard->commit;
1128
1129   return 1;
1130 }
1131
1132
1133 sub _select {
1134   my $self = shift;
1135   my $sql_maker = $self->sql_maker;
1136   local $sql_maker->{for};
1137   return $self->_execute($self->_select_args(@_));
1138 }
1139
1140 sub _select_args {
1141   my ($self, $ident, $select, $condition, $attrs) = @_;
1142   my $order = $attrs->{order_by};
1143
1144   my $for = delete $attrs->{for};
1145   my $sql_maker = $self->sql_maker;
1146   $sql_maker->{for} = $for;
1147
1148   if (exists $attrs->{group_by} || $attrs->{having}) {
1149     $order = {
1150       group_by => $attrs->{group_by},
1151       having => $attrs->{having},
1152       ($order ? (order_by => $order) : ())
1153     };
1154   }
1155   my $bind_attrs = {}; ## Future support
1156   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1157   if ($attrs->{software_limit} ||
1158       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1159         $attrs->{software_limit} = 1;
1160   } else {
1161     $self->throw_exception("rows attribute must be positive if present")
1162       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1163
1164     # MySQL actually recommends this approach.  I cringe.
1165     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1166     push @args, $attrs->{rows}, $attrs->{offset};
1167   }
1168   return @args;
1169 }
1170
1171 sub source_bind_attributes {
1172   my ($self, $source) = @_;
1173
1174   my $bind_attributes;
1175   foreach my $column ($source->columns) {
1176
1177     my $data_type = $source->column_info($column)->{data_type} || '';
1178     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1179      if $data_type;
1180   }
1181
1182   return $bind_attributes;
1183 }
1184
1185 =head2 select
1186
1187 =over 4
1188
1189 =item Arguments: $ident, $select, $condition, $attrs
1190
1191 =back
1192
1193 Handle a SQL select statement.
1194
1195 =cut
1196
1197 sub select {
1198   my $self = shift;
1199   my ($ident, $select, $condition, $attrs) = @_;
1200   return $self->cursor_class->new($self, \@_, $attrs);
1201 }
1202
1203 sub select_single {
1204   my $self = shift;
1205   my ($rv, $sth, @bind) = $self->_select(@_);
1206   my @row = $sth->fetchrow_array;
1207   my @nextrow = $sth->fetchrow_array if @row;
1208   if(@row && @nextrow) {
1209     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1210   }
1211   # Need to call finish() to work round broken DBDs
1212   $sth->finish();
1213   return @row;
1214 }
1215
1216 =head2 sth
1217
1218 =over 4
1219
1220 =item Arguments: $sql
1221
1222 =back
1223
1224 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1225
1226 =cut
1227
1228 sub _dbh_sth {
1229   my ($self, $dbh, $sql) = @_;
1230
1231   # 3 is the if_active parameter which avoids active sth re-use
1232   my $sth = $self->disable_sth_caching
1233     ? $dbh->prepare($sql)
1234     : $dbh->prepare_cached($sql, {}, 3);
1235
1236   # XXX You would think RaiseError would make this impossible,
1237   #  but apparently that's not true :(
1238   $self->throw_exception($dbh->errstr) if !$sth;
1239
1240   $sth;
1241 }
1242
1243 sub sth {
1244   my ($self, $sql) = @_;
1245   $self->dbh_do('_dbh_sth', $sql);
1246 }
1247
1248 sub _dbh_columns_info_for {
1249   my ($self, $dbh, $table) = @_;
1250
1251   if ($dbh->can('column_info')) {
1252     my %result;
1253     eval {
1254       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1255       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1256       $sth->execute();
1257       while ( my $info = $sth->fetchrow_hashref() ){
1258         my %column_info;
1259         $column_info{data_type}   = $info->{TYPE_NAME};
1260         $column_info{size}      = $info->{COLUMN_SIZE};
1261         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1262         $column_info{default_value} = $info->{COLUMN_DEF};
1263         my $col_name = $info->{COLUMN_NAME};
1264         $col_name =~ s/^\"(.*)\"$/$1/;
1265
1266         $result{$col_name} = \%column_info;
1267       }
1268     };
1269     return \%result if !$@ && scalar keys %result;
1270   }
1271
1272   my %result;
1273   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1274   $sth->execute;
1275   my @columns = @{$sth->{NAME_lc}};
1276   for my $i ( 0 .. $#columns ){
1277     my %column_info;
1278     $column_info{data_type} = $sth->{TYPE}->[$i];
1279     $column_info{size} = $sth->{PRECISION}->[$i];
1280     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1281
1282     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1283       $column_info{data_type} = $1;
1284       $column_info{size}    = $2;
1285     }
1286
1287     $result{$columns[$i]} = \%column_info;
1288   }
1289   $sth->finish;
1290
1291   foreach my $col (keys %result) {
1292     my $colinfo = $result{$col};
1293     my $type_num = $colinfo->{data_type};
1294     my $type_name;
1295     if(defined $type_num && $dbh->can('type_info')) {
1296       my $type_info = $dbh->type_info($type_num);
1297       $type_name = $type_info->{TYPE_NAME} if $type_info;
1298       $colinfo->{data_type} = $type_name if $type_name;
1299     }
1300   }
1301
1302   return \%result;
1303 }
1304
1305 sub columns_info_for {
1306   my ($self, $table) = @_;
1307   $self->dbh_do('_dbh_columns_info_for', $table);
1308 }
1309
1310 =head2 last_insert_id
1311
1312 Return the row id of the last insert.
1313
1314 =cut
1315
1316 sub _dbh_last_insert_id {
1317     # All Storage's need to register their own _dbh_last_insert_id
1318     # the old SQLite-based method was highly inappropriate
1319
1320     my $self = shift;
1321     my $class = ref $self;
1322     $self->throw_exception (<<EOE);
1323
1324 No _dbh_last_insert_id() method found in $class.
1325 Since the method of obtaining the autoincrement id of the last insert
1326 operation varies greatly between different databases, this method must be
1327 individually implemented for every storage class.
1328 EOE
1329 }
1330
1331 sub last_insert_id {
1332   my $self = shift;
1333   $self->dbh_do('_dbh_last_insert_id', @_);
1334 }
1335
1336 =head2 sqlt_type
1337
1338 Returns the database driver name.
1339
1340 =cut
1341
1342 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1343
1344 =head2 bind_attribute_by_data_type
1345
1346 Given a datatype from column info, returns a database specific bind
1347 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1348 let the database planner just handle it.
1349
1350 Generally only needed for special case column types, like bytea in postgres.
1351
1352 =cut
1353
1354 sub bind_attribute_by_data_type {
1355     return;
1356 }
1357
1358 =head2 create_ddl_dir
1359
1360 =over 4
1361
1362 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1363
1364 =back
1365
1366 Creates a SQL file based on the Schema, for each of the specified
1367 database types, in the given directory.
1368
1369 By default, C<\%sqlt_args> will have
1370
1371  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1372
1373 merged with the hash passed in. To disable any of those features, pass in a
1374 hashref like the following
1375
1376  { ignore_constraint_names => 0, # ... other options }
1377
1378 =cut
1379
1380 sub create_ddl_dir {
1381   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1382
1383   if(!$dir || !-d $dir) {
1384     carp "No directory given, using ./\n";
1385     $dir = "./";
1386   }
1387   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1388   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1389
1390   my $schema_version = $schema->schema_version || '1.x';
1391   $version ||= $schema_version;
1392
1393   $sqltargs = {
1394     add_drop_table => 1,
1395     ignore_constraint_names => 1,
1396     ignore_index_names => 1,
1397     %{$sqltargs || {}}
1398   };
1399
1400   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09003: '}
1401       . $self->_check_sqlt_message . q{'})
1402           if !$self->_check_sqlt_version;
1403
1404   my $sqlt = SQL::Translator->new( $sqltargs );
1405
1406   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1407   my $sqlt_schema = $sqlt->translate({ data => $schema })
1408     or $self->throw_exception ($sqlt->error);
1409
1410   foreach my $db (@$databases) {
1411     $sqlt->reset();
1412     $sqlt->{schema} = $sqlt_schema;
1413     $sqlt->producer($db);
1414
1415     my $file;
1416     my $filename = $schema->ddl_filename($db, $version, $dir);
1417     if (-e $filename && ($version eq $schema_version )) {
1418       # if we are dumping the current version, overwrite the DDL
1419       carp "Overwriting existing DDL file - $filename";
1420       unlink($filename);
1421     }
1422
1423     my $output = $sqlt->translate;
1424     if(!$output) {
1425       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1426       next;
1427     }
1428     if(!open($file, ">$filename")) {
1429       $self->throw_exception("Can't open $filename for writing ($!)");
1430       next;
1431     }
1432     print $file $output;
1433     close($file);
1434
1435     next unless ($preversion);
1436
1437     require SQL::Translator::Diff;
1438
1439     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1440     if(!-e $prefilename) {
1441       carp("No previous schema file found ($prefilename)");
1442       next;
1443     }
1444
1445     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1446     if(-e $difffile) {
1447       carp("Overwriting existing diff file - $difffile");
1448       unlink($difffile);
1449     }
1450
1451     my $source_schema;
1452     {
1453       my $t = SQL::Translator->new($sqltargs);
1454       $t->debug( 0 );
1455       $t->trace( 0 );
1456
1457       $t->parser( $db )
1458         or $self->throw_exception ($t->error);
1459
1460       my $out = $t->translate( $prefilename )
1461         or $self->throw_exception ($t->error);
1462
1463       $source_schema = $t->schema;
1464
1465       $source_schema->name( $prefilename )
1466         unless ( $source_schema->name );
1467     }
1468
1469     # The "new" style of producers have sane normalization and can support
1470     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1471     # And we have to diff parsed SQL against parsed SQL.
1472     my $dest_schema = $sqlt_schema;
1473
1474     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1475       my $t = SQL::Translator->new($sqltargs);
1476       $t->debug( 0 );
1477       $t->trace( 0 );
1478
1479       $t->parser( $db )
1480         or $self->throw_exception ($t->error);
1481
1482       my $out = $t->translate( $filename )
1483         or $self->throw_exception ($t->error);
1484
1485       $dest_schema = $t->schema;
1486
1487       $dest_schema->name( $filename )
1488         unless $dest_schema->name;
1489     }
1490
1491     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1492                                                   $dest_schema,   $db,
1493                                                   $sqltargs
1494                                                  );
1495     if(!open $file, ">$difffile") {
1496       $self->throw_exception("Can't write to $difffile ($!)");
1497       next;
1498     }
1499     print $file $diff;
1500     close($file);
1501   }
1502 }
1503
1504 =head2 deployment_statements
1505
1506 =over 4
1507
1508 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1509
1510 =back
1511
1512 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1513 The database driver name is given by C<$type>, though the value from
1514 L</sqlt_type> is used if it is not specified.
1515
1516 C<$directory> is used to return statements from files in a previously created
1517 L</create_ddl_dir> directory and is optional. The filenames are constructed
1518 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1519
1520 If no C<$directory> is specified then the statements are constructed on the
1521 fly using L<SQL::Translator> and C<$version> is ignored.
1522
1523 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1524
1525 =cut
1526
1527 sub deployment_statements {
1528   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1529   # Need to be connected to get the correct sqlt_type
1530   $self->ensure_connected() unless $type;
1531   $type ||= $self->sqlt_type;
1532   $version ||= $schema->schema_version || '1.x';
1533   $dir ||= './';
1534   my $filename = $schema->ddl_filename($type, $version, $dir);
1535   if(-f $filename)
1536   {
1537       my $file;
1538       open($file, "<$filename")
1539         or $self->throw_exception("Can't open $filename ($!)");
1540       my @rows = <$file>;
1541       close($file);
1542       return join('', @rows);
1543   }
1544
1545   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09003: '}
1546       . $self->_check_sqlt_message . q{'})
1547           if !$self->_check_sqlt_version;
1548
1549   require SQL::Translator::Parser::DBIx::Class;
1550   eval qq{use SQL::Translator::Producer::${type}};
1551   $self->throw_exception($@) if $@;
1552
1553   # sources needs to be a parser arg, but for simplicty allow at top level
1554   # coming in
1555   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1556       if exists $sqltargs->{sources};
1557
1558   my $tr = SQL::Translator->new(%$sqltargs);
1559   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1560   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1561 }
1562
1563 sub deploy {
1564   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1565   my $deploy = sub {
1566     my $line = shift;
1567     return if($line =~ /^--/);
1568     return if(!$line);
1569     # next if($line =~ /^DROP/m);
1570     return if($line =~ /^BEGIN TRANSACTION/m);
1571     return if($line =~ /^COMMIT/m);
1572     return if $line =~ /^\s+$/; # skip whitespace only
1573     $self->_query_start($line);
1574     eval {
1575       $self->dbh->do($line); # shouldn't be using ->dbh ?
1576     };
1577     if ($@) {
1578       carp qq{$@ (running "${line}")};
1579     }
1580     $self->_query_end($line);
1581   };
1582   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } );
1583   if (@statements > 1) {
1584     foreach my $statement (@statements) {
1585       $deploy->( $statement );
1586     }
1587   }
1588   elsif (@statements == 1) {
1589     foreach my $line ( split(";\n", $statements[0])) {
1590       $deploy->( $line );
1591     }
1592   }
1593 }
1594
1595 =head2 datetime_parser
1596
1597 Returns the datetime parser class
1598
1599 =cut
1600
1601 sub datetime_parser {
1602   my $self = shift;
1603   return $self->{datetime_parser} ||= do {
1604     $self->ensure_connected;
1605     $self->build_datetime_parser(@_);
1606   };
1607 }
1608
1609 =head2 datetime_parser_type
1610
1611 Defines (returns) the datetime parser class - currently hardwired to
1612 L<DateTime::Format::MySQL>
1613
1614 =cut
1615
1616 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1617
1618 =head2 build_datetime_parser
1619
1620 See L</datetime_parser>
1621
1622 =cut
1623
1624 sub build_datetime_parser {
1625   my $self = shift;
1626   my $type = $self->datetime_parser_type(@_);
1627   eval "use ${type}";
1628   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1629   return $type;
1630 }
1631
1632 {
1633     my $_check_sqlt_version; # private
1634     my $_check_sqlt_message; # private
1635     sub _check_sqlt_version {
1636         return $_check_sqlt_version if defined $_check_sqlt_version;
1637         eval 'use SQL::Translator "0.09003"';
1638         $_check_sqlt_message = $@ || '';
1639         $_check_sqlt_version = !$@;
1640     }
1641
1642     sub _check_sqlt_message {
1643         _check_sqlt_version if !defined $_check_sqlt_message;
1644         $_check_sqlt_message;
1645     }
1646 }
1647
1648 =head2 is_replicating
1649
1650 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1651 replicate from a master database.  Default is undef, which is the result
1652 returned by databases that don't support replication.
1653
1654 =cut
1655
1656 sub is_replicating {
1657     return;
1658
1659 }
1660
1661 =head2 lag_behind_master
1662
1663 Returns a number that represents a certain amount of lag behind a master db
1664 when a given storage is replicating.  The number is database dependent, but
1665 starts at zero and increases with the amount of lag. Default in undef
1666
1667 =cut
1668
1669 sub lag_behind_master {
1670     return;
1671 }
1672
1673 sub DESTROY {
1674   my $self = shift;
1675   return if !$self->_dbh;
1676   $self->_verify_pid;
1677   $self->_dbh(undef);
1678 }
1679
1680 1;
1681
1682 =head1 USAGE NOTES
1683
1684 =head2 DBIx::Class and AutoCommit
1685
1686 DBIx::Class can do some wonderful magic with handling exceptions,
1687 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1688 combined with C<txn_do> for transaction support.
1689
1690 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1691 in an assumed transaction between commits, and you're telling us you'd
1692 like to manage that manually.  A lot of the magic protections offered by
1693 this module will go away.  We can't protect you from exceptions due to database
1694 disconnects because we don't know anything about how to restart your
1695 transactions.  You're on your own for handling all sorts of exceptional
1696 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1697 be with raw DBI.
1698
1699
1700
1701 =head1 AUTHORS
1702
1703 Matt S. Trout <mst@shadowcatsystems.co.uk>
1704
1705 Andy Grundman <andy@hybridized.org>
1706
1707 =head1 LICENSE
1708
1709 You may distribute this code under the same terms as Perl itself.
1710
1711 =cut