lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching on_connect_do
  18        on_disconnect_do transaction_depth unsafe _dbh_autocommit
  19        auto_savepoint savepoints/
  20 );
  21
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  25 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  26
  27 BEGIN {
  28
  29 package # Hide from PAUSE
  30   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  31
  32 use base qw/SQL::Abstract::Limit/;
  33
  34 # This prevents the caching of $dbh in S::A::L, I believe
  35 sub new {
  36   my $self = shift->SUPER::new(@_);
  37
  38   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  39   #   it with what it resolves to:
  40   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  41     if ref $self->{limit_dialect};
  42
  43   $self;
  44 }
  45
  46 sub _RowNumberOver {
  47   my ($self, $sql, $order, $rows, $offset ) = @_;
  48
  49   $offset += 1;
  50   my $last = $rows + $offset;
  51   my ( $order_by ) = $self->_order_by( $order );
  52
  53   $sql = <<"";
  54 SELECT * FROM
  55 (
  56    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  57       $sql
  58       $order_by
  59    ) Q1
  60 ) Q2
  61 WHERE ROW_NUM BETWEEN $offset AND $last
  62
  63   return $sql;
  64 }
  65
  66
  67 # While we're at it, this should make LIMIT queries more efficient,
  68 #  without digging into things too deeply
  69 use Scalar::Util 'blessed';
  70 sub _find_syntax {
  71   my ($self, $syntax) = @_;
  72   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  73   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  74     return 'RowNumberOver';
  75   }
  76
  77   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  78 }
  79
  80 sub select {
  81   my ($self, $table, $fields, $where, $order, @rest) = @_;
  82   $table = $self->_quote($table) unless ref($table);
  83   local $self->{rownum_hack_count} = 1
  84     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  85   @rest = (-1) unless defined $rest[0];
  86   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  87     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  88   local $self->{having_bind} = [];
  89   my ($sql, @ret) = $self->SUPER::select(
  90     $table, $self->_recurse_fields($fields), $where, $order, @rest
  91   );
  92   $sql .=
  93     $self->{for} ?
  94     (
  95       $self->{for} eq 'update' ? ' FOR UPDATE' :
  96       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  97       ''
  98     ) :
  99     ''
 100   ;
 101   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 102 }
 103
 104 sub insert {
 105   my $self = shift;
 106   my $table = shift;
 107   $table = $self->_quote($table) unless ref($table);
 108   $self->SUPER::insert($table, @_);
 109 }
 110
 111 sub update {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::update($table, @_);
 116 }
 117
 118 sub delete {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::delete($table, @_);
 123 }
 124
 125 sub _emulate_limit {
 126   my $self = shift;
 127   if ($_[3] == -1) {
 128     return $_[1].$self->_order_by($_[2]);
 129   } else {
 130     return $self->SUPER::_emulate_limit(@_);
 131   }
 132 }
 133
 134 sub _recurse_fields {
 135   my ($self, $fields, $params) = @_;
 136   my $ref = ref $fields;
 137   return $self->_quote($fields) unless $ref;
 138   return $$fields if $ref eq 'SCALAR';
 139
 140   if ($ref eq 'ARRAY') {
 141     return join(', ', map {
 142       $self->_recurse_fields($_)
 143         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 144           ? ' AS col'.$self->{rownum_hack_count}++
 145           : '')
 146       } @$fields);
 147   } elsif ($ref eq 'HASH') {
 148     foreach my $func (keys %$fields) {
 149       return $self->_sqlcase($func)
 150         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 151     }
 152   }
 153 }
 154
 155 sub _order_by {
 156   my $self = shift;
 157   my $ret = '';
 158   my @extra;
 159   if (ref $_[0] eq 'HASH') {
 160     if (defined $_[0]->{group_by}) {
 161       $ret = $self->_sqlcase(' group by ')
 162         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 163     }
 164     if (defined $_[0]->{having}) {
 165       my $frag;
 166       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 167       push(@{$self->{having_bind}}, @extra);
 168       $ret .= $self->_sqlcase(' having ').$frag;
 169     }
 170     if (defined $_[0]->{order_by}) {
 171       $ret .= $self->_order_by($_[0]->{order_by});
 172     }
 173   } elsif (ref $_[0] eq 'SCALAR') {
 174     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 175   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 176     my @order = @{+shift};
 177     $ret = $self->_sqlcase(' order by ')
 178           .join(', ', map {
 179                         my $r = $self->_order_by($_, @_);
 180                         $r =~ s/^ ?ORDER BY //i;
 181                         $r;
 182                       } @order);
 183   } else {
 184     $ret = $self->SUPER::_order_by(@_);
 185   }
 186   return $ret;
 187 }
 188
 189 sub _order_directions {
 190   my ($self, $order) = @_;
 191   $order = $order->{order_by} if ref $order eq 'HASH';
 192   return $self->SUPER::_order_directions($order);
 193 }
 194
 195 sub _table {
 196   my ($self, $from) = @_;
 197   if (ref $from eq 'ARRAY') {
 198     return $self->_recurse_from(@$from);
 199   } elsif (ref $from eq 'HASH') {
 200     return $self->_make_as($from);
 201   } else {
 202     return $from; # would love to quote here but _table ends up getting called
 203                   # twice during an ->select without a limit clause due to
 204                   # the way S::A::Limit->select works. should maybe consider
 205                   # bypassing this and doing S::A::select($self, ...) in
 206                   # our select method above. meantime, quoting shims have
 207                   # been added to select/insert/update/delete here
 208   }
 209 }
 210
 211 sub _recurse_from {
 212   my ($self, $from, @join) = @_;
 213   my @sqlf;
 214   push(@sqlf, $self->_make_as($from));
 215   foreach my $j (@join) {
 216     my ($to, $on) = @$j;
 217
 218     # check whether a join type exists
 219     my $join_clause = '';
 220     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 221     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 222       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 223     } else {
 224       $join_clause = ' JOIN ';
 225     }
 226     push(@sqlf, $join_clause);
 227
 228     if (ref $to eq 'ARRAY') {
 229       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 230     } else {
 231       push(@sqlf, $self->_make_as($to));
 232     }
 233     push(@sqlf, ' ON ', $self->_join_condition($on));
 234   }
 235   return join('', @sqlf);
 236 }
 237
 238 sub _make_as {
 239   my ($self, $from) = @_;
 240   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 241                      reverse each %{$self->_skip_options($from)});
 242 }
 243
 244 sub _skip_options {
 245   my ($self, $hash) = @_;
 246   my $clean_hash = {};
 247   $clean_hash->{$_} = $hash->{$_}
 248     for grep {!/^-/} keys %$hash;
 249   return $clean_hash;
 250 }
 251
 252 sub _join_condition {
 253   my ($self, $cond) = @_;
 254   if (ref $cond eq 'HASH') {
 255     my %j;
 256     for (keys %$cond) {
 257       my $v = $cond->{$_};
 258       if (ref $v) {
 259         # XXX no throw_exception() in this package and croak() fails with strange results
 260         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 261             if ref($v) ne 'SCALAR';
 262         $j{$_} = $v;
 263       }
 264       else {
 265         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 266       }
 267     };
 268     return scalar($self->_recurse_where(\%j));
 269   } elsif (ref $cond eq 'ARRAY') {
 270     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 271   } else {
 272     die "Can't handle this yet!";
 273   }
 274 }
 275
 276 sub _quote {
 277   my ($self, $label) = @_;
 278   return '' unless defined $label;
 279   return "*" if $label eq '*';
 280   return $label unless $self->{quote_char};
 281   if(ref $self->{quote_char} eq "ARRAY"){
 282     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 283       if !defined $self->{name_sep};
 284     my $sep = $self->{name_sep};
 285     return join($self->{name_sep},
 286         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 287        split(/\Q$sep\E/,$label));
 288   }
 289   return $self->SUPER::_quote($label);
 290 }
 291
 292 sub limit_dialect {
 293     my $self = shift;
 294     $self->{limit_dialect} = shift if @_;
 295     return $self->{limit_dialect};
 296 }
 297
 298 sub quote_char {
 299     my $self = shift;
 300     $self->{quote_char} = shift if @_;
 301     return $self->{quote_char};
 302 }
 303
 304 sub name_sep {
 305     my $self = shift;
 306     $self->{name_sep} = shift if @_;
 307     return $self->{name_sep};
 308 }
 309
 310 } # End of BEGIN block
 311
 312 =head1 NAME
 313
 314 DBIx::Class::Storage::DBI - DBI storage handler
 315
 316 =head1 SYNOPSIS
 317
 318 =head1 DESCRIPTION
 319
 320 This class represents the connection to an RDBMS via L<DBI>.  See
 321 L<DBIx::Class::Storage> for general information.  This pod only
 322 documents DBI-specific methods and behaviors.
 323
 324 =head1 METHODS
 325
 326 =cut
 327
 328 sub new {
 329   my $new = shift->next::method(@_);
 330
 331   $new->transaction_depth(0);
 332   $new->_sql_maker_opts({});
 333   $new->{savepoints} = [];
 334   $new->{_in_dbh_do} = 0;
 335   $new->{_dbh_gen} = 0;
 336
 337   $new;
 338 }
 339
 340 =head2 connect_info
 341
 342 The arguments of C<connect_info> are always a single array reference.
 343
 344 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 345 encapsulates its argument list in an arrayref before calling
 346 C<connect_info> here.
 347
 348 The arrayref can either contain the same set of arguments one would
 349 normally pass to L<DBI/connect>, or a lone code reference which returns
 350 a connected database handle.  Please note that the L<DBI> docs
 351 recommend that you always explicitly set C<AutoCommit> to either
 352 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 353 to C<1>, and that you perform transactions via our L</txn_do>
 354 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 355 set it to zero.  This is the default for most DBDs.  See below for more
 356 details.
 357
 358 In either case, if the final argument in your connect_info happens
 359 to be a hashref, C<connect_info> will look there for several
 360 connection-specific options:
 361
 362 =over 4
 363
 364 =item on_connect_do
 365
 366 Specifies things to do immediately after connecting or re-connecting to
 367 the database.  Its value may contain:
 368
 369 =over
 370
 371 =item an array reference
 372
 373 This contains SQL statements to execute in order.  Each element contains
 374 a string or a code reference that returns a string.
 375
 376 =item a code reference
 377
 378 This contains some code to execute.  Unlike code references within an
 379 array reference, its return value is ignored.
 380
 381 =back
 382
 383 =item on_disconnect_do
 384
 385 Takes arguments in the same form as L<on_connect_do> and executes them
 386 immediately before disconnecting from the database.
 387
 388 Note, this only runs if you explicitly call L<disconnect> on the
 389 storage object.
 390
 391 =item disable_sth_caching
 392
 393 If set to a true value, this option will disable the caching of
 394 statement handles via L<DBI/prepare_cached>.
 395
 396 =item limit_dialect
 397
 398 Sets the limit dialect. This is useful for JDBC-bridge among others
 399 where the remote SQL-dialect cannot be determined by the name of the
 400 driver alone.
 401
 402 =item quote_char
 403
 404 Specifies what characters to use to quote table and column names. If
 405 you use this you will want to specify L<name_sep> as well.
 406
 407 quote_char expects either a single character, in which case is it is placed
 408 on either side of the table/column, or an arrayref of length 2 in which case the
 409 table/column name is placed between the elements.
 410
 411 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 412 use C<quote_char =E<gt> [qw/[ ]/]>.
 413
 414 =item name_sep
 415
 416 This only needs to be used in conjunction with L<quote_char>, and is used to
 417 specify the charecter that seperates elements (schemas, tables, columns) from
 418 each other. In most cases this is simply a C<.>.
 419
 420 =item unsafe
 421
 422 This Storage driver normally installs its own C<HandleError>, sets
 423 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 424 all database handles, including those supplied by a coderef.  It does this
 425 so that it can have consistent and useful error behavior.
 426
 427 If you set this option to a true value, Storage will not do its usual
 428 modifications to the database handle's attributes, and instead relies on
 429 the settings in your connect_info DBI options (or the values you set in
 430 your connection coderef, in the case that you are connecting via coderef).
 431
 432 Note that your custom settings can cause Storage to malfunction,
 433 especially if you set a C<HandleError> handler that suppresses exceptions
 434 and/or disable C<RaiseError>.
 435
 436 =item auto_savepoint
 437
 438 If this option is true, L<DBIx::Class> will use savepoints when nesting
 439 transactions, making it possible to recover from failure in the inner
 440 transaction without having to abort all outer transactions.
 441
 442 =back
 443
 444 These options can be mixed in with your other L<DBI> connection attributes,
 445 or placed in a seperate hashref after all other normal L<DBI> connection
 446 arguments.
 447
 448 Every time C<connect_info> is invoked, any previous settings for
 449 these options will be cleared before setting the new ones, regardless of
 450 whether any options are specified in the new C<connect_info>.
 451
 452 Another Important Note:
 453
 454 DBIC can do some wonderful magic with handling exceptions,
 455 disconnections, and transactions when you use C<< AutoCommit => 1 >>
 456 combined with C<txn_do> for transaction support.
 457
 458 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
 459 in an assumed transaction between commits, and you're telling us you'd
 460 like to manage that manually.  A lot of DBIC's magic protections
 461 go away.  We can't protect you from exceptions due to database
 462 disconnects because we don't know anything about how to restart your
 463 transactions.  You're on your own for handling all sorts of exceptional
 464 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
 465 be with raw DBI.
 466
 467 Examples:
 468
 469   # Simple SQLite connection
 470   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 471
 472   # Connect via subref
 473   ->connect_info([ sub { DBI->connect(...) } ]);
 474
 475   # A bit more complicated
 476   ->connect_info(
 477     [
 478       'dbi:Pg:dbname=foo',
 479       'postgres',
 480       'my_pg_password',
 481       { AutoCommit => 1 },
 482       { quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Equivalent to the previous example
 487   ->connect_info(
 488     [
 489       'dbi:Pg:dbname=foo',
 490       'postgres',
 491       'my_pg_password',
 492       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 493     ]
 494   );
 495
 496   # Subref + DBIC-specific connection options
 497   ->connect_info(
 498     [
 499       sub { DBI->connect(...) },
 500       {
 501           quote_char => q{`},
 502           name_sep => q{@},
 503           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 504           disable_sth_caching => 1,
 505       },
 506     ]
 507   );
 508
 509 =cut
 510
 511 sub connect_info {
 512   my ($self, $info_arg) = @_;
 513
 514   return $self->_connect_info if !$info_arg;
 515
 516   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 517   #  the new set of options
 518   $self->_sql_maker(undef);
 519   $self->_sql_maker_opts({});
 520   $self->_connect_info([@$info_arg]); # copy for _connect_info
 521
 522   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 523
 524   my $last_info = $dbi_info->[-1];
 525   if(ref $last_info eq 'HASH') {
 526     $last_info = { %$last_info }; # so delete is non-destructive
 527     my @storage_option = qw(
 528       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 529       auto_savepoint
 530     );
 531     for my $storage_opt (@storage_option) {
 532       if(my $value = delete $last_info->{$storage_opt}) {
 533         $self->$storage_opt($value);
 534       }
 535     }
 536     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 537       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 538         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 539       }
 540     }
 541     # re-insert modified hashref
 542     $dbi_info->[-1] = $last_info;
 543
 544     # Get rid of any trailing empty hashref
 545     pop(@$dbi_info) if !keys %$last_info;
 546   }
 547   $self->_dbi_connect_info($dbi_info);
 548
 549   $self->_connect_info;
 550 }
 551
 552 =head2 on_connect_do
 553
 554 This method is deprecated in favor of setting via L</connect_info>.
 555
 556 =head2 dbh_do
 557
 558 Arguments: ($subref | $method_name), @extra_coderef_args?
 559
 560 Execute the given $subref or $method_name using the new exception-based
 561 connection management.
 562
 563 The first two arguments will be the storage object that C<dbh_do> was called
 564 on and a database handle to use.  Any additional arguments will be passed
 565 verbatim to the called subref as arguments 2 and onwards.
 566
 567 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 568 exception handling and reconnection (or failover in future subclasses).
 569
 570 Your subref should have no side-effects outside of the database, as
 571 there is the potential for your subref to be partially double-executed
 572 if the database connection was stale/dysfunctional.
 573
 574 Example:
 575
 576   my @stuff = $schema->storage->dbh_do(
 577     sub {
 578       my ($storage, $dbh, @cols) = @_;
 579       my $cols = join(q{, }, @cols);
 580       $dbh->selectrow_array("SELECT $cols FROM foo");
 581     },
 582     @column_list
 583   );
 584
 585 =cut
 586
 587 sub dbh_do {
 588   my $self = shift;
 589   my $code = shift;
 590
 591   my $dbh = $self->_dbh;
 592
 593   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 594       || $self->{transaction_depth};
 595
 596   local $self->{_in_dbh_do} = 1;
 597
 598   my @result;
 599   my $want_array = wantarray;
 600
 601   eval {
 602     $self->_verify_pid if $dbh;
 603     if( !$dbh ) {
 604         $self->_populate_dbh;
 605         $dbh = $self->_dbh;
 606     }
 607
 608     if($want_array) {
 609         @result = $self->$code($dbh, @_);
 610     }
 611     elsif(defined $want_array) {
 612         $result[0] = $self->$code($dbh, @_);
 613     }
 614     else {
 615         $self->$code($dbh, @_);
 616     }
 617   };
 618
 619   my $exception = $@;
 620   if(!$exception) { return $want_array ? @result : $result[0] }
 621
 622   $self->throw_exception($exception) if $self->connected;
 623
 624   # We were not connected - reconnect and retry, but let any
 625   #  exception fall right through this time
 626   $self->_populate_dbh;
 627   $self->$code($self->_dbh, @_);
 628 }
 629
 630 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 631 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 632 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 633 sub txn_do {
 634   my $self = shift;
 635   my $coderef = shift;
 636
 637   ref $coderef eq 'CODE' or $self->throw_exception
 638     ('$coderef must be a CODE reference');
 639
 640   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 641
 642   local $self->{_in_dbh_do} = 1;
 643
 644   my @result;
 645   my $want_array = wantarray;
 646
 647   my $tried = 0;
 648   while(1) {
 649     eval {
 650       $self->_verify_pid if $self->_dbh;
 651       $self->_populate_dbh if !$self->_dbh;
 652
 653       $self->txn_begin;
 654       if($want_array) {
 655           @result = $coderef->(@_);
 656       }
 657       elsif(defined $want_array) {
 658           $result[0] = $coderef->(@_);
 659       }
 660       else {
 661           $coderef->(@_);
 662       }
 663       $self->txn_commit;
 664     };
 665
 666     my $exception = $@;
 667     if(!$exception) { return $want_array ? @result : $result[0] }
 668
 669     if($tried++ > 0 || $self->connected) {
 670       eval { $self->txn_rollback };
 671       my $rollback_exception = $@;
 672       if($rollback_exception) {
 673         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 674         $self->throw_exception($exception)  # propagate nested rollback
 675           if $rollback_exception =~ /$exception_class/;
 676
 677         $self->throw_exception(
 678           "Transaction aborted: ${exception}. "
 679           . "Rollback failed: ${rollback_exception}"
 680         );
 681       }
 682       $self->throw_exception($exception)
 683     }
 684
 685     # We were not connected, and was first try - reconnect and retry
 686     # via the while loop
 687     $self->_populate_dbh;
 688   }
 689 }
 690
 691 =head2 disconnect
 692
 693 Our C<disconnect> method also performs a rollback first if the
 694 database is not in C<AutoCommit> mode.
 695
 696 =cut
 697
 698 sub disconnect {
 699   my ($self) = @_;
 700
 701   if( $self->connected ) {
 702     my $connection_do = $self->on_disconnect_do;
 703     $self->_do_connection_actions($connection_do) if ref($connection_do);
 704
 705     $self->_dbh->rollback unless $self->_dbh_autocommit;
 706     $self->_dbh->disconnect;
 707     $self->_dbh(undef);
 708     $self->{_dbh_gen}++;
 709   }
 710 }
 711
 712 sub connected {
 713   my ($self) = @_;
 714
 715   if(my $dbh = $self->_dbh) {
 716       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 717           $self->_dbh(undef);
 718           $self->{_dbh_gen}++;
 719           return;
 720       }
 721       else {
 722           $self->_verify_pid;
 723           return 0 if !$self->_dbh;
 724       }
 725       return ($dbh->FETCH('Active') && $dbh->ping);
 726   }
 727
 728   return 0;
 729 }
 730
 731 # handle pid changes correctly
 732 #  NOTE: assumes $self->_dbh is a valid $dbh
 733 sub _verify_pid {
 734   my ($self) = @_;
 735
 736   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 737
 738   $self->_dbh->{InactiveDestroy} = 1;
 739   $self->_dbh(undef);
 740   $self->{_dbh_gen}++;
 741
 742   return;
 743 }
 744
 745 sub ensure_connected {
 746   my ($self) = @_;
 747
 748   unless ($self->connected) {
 749     $self->_populate_dbh;
 750   }
 751 }
 752
 753 =head2 dbh
 754
 755 Returns the dbh - a data base handle of class L<DBI>.
 756
 757 =cut
 758
 759 sub dbh {
 760   my ($self) = @_;
 761
 762   $self->ensure_connected;
 763   return $self->_dbh;
 764 }
 765
 766 sub _sql_maker_args {
 767     my ($self) = @_;
 768
 769     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 770 }
 771
 772 sub sql_maker {
 773   my ($self) = @_;
 774   unless ($self->_sql_maker) {
 775     my $sql_maker_class = $self->sql_maker_class;
 776     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 777   }
 778   return $self->_sql_maker;
 779 }
 780
 781 sub _rebless {}
 782
 783 sub _populate_dbh {
 784   my ($self) = @_;
 785   my @info = @{$self->_dbi_connect_info || []};
 786   $self->_dbh($self->_connect(@info));
 787
 788   # Always set the transaction depth on connect, since
 789   #  there is no transaction in progress by definition
 790   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 791
 792   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 793     my $driver = $self->_dbh->{Driver}->{Name};
 794     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 795       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 796       $self->_rebless();
 797     }
 798   }
 799
 800   my $connection_do = $self->on_connect_do;
 801   $self->_do_connection_actions($connection_do) if ref($connection_do);
 802
 803   $self->_conn_pid($$);
 804   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 805 }
 806
 807 sub _do_connection_actions {
 808   my $self = shift;
 809   my $connection_do = shift;
 810
 811   if (ref $connection_do eq 'ARRAY') {
 812     $self->_do_query($_) foreach @$connection_do;
 813   }
 814   elsif (ref $connection_do eq 'CODE') {
 815     $connection_do->();
 816   }
 817
 818   return $self;
 819 }
 820
 821 sub _do_query {
 822   my ($self, $action) = @_;
 823
 824   if (ref $action eq 'CODE') {
 825     $action = $action->($self);
 826     $self->_do_query($_) foreach @$action;
 827   }
 828   else {
 829     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 830     $self->_query_start(@to_run);
 831     $self->_dbh->do(@to_run);
 832     $self->_query_end(@to_run);
 833   }
 834
 835   return $self;
 836 }
 837
 838 sub _connect {
 839   my ($self, @info) = @_;
 840
 841   $self->throw_exception("You failed to provide any connection info")
 842     if !@info;
 843
 844   my ($old_connect_via, $dbh);
 845
 846   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 847     $old_connect_via = $DBI::connect_via;
 848     $DBI::connect_via = 'connect';
 849   }
 850
 851   eval {
 852     if(ref $info[0] eq 'CODE') {
 853        $dbh = &{$info[0]}
 854     }
 855     else {
 856        $dbh = DBI->connect(@info);
 857     }
 858
 859     if($dbh && !$self->unsafe) {
 860       my $weak_self = $self;
 861       weaken($weak_self);
 862       $dbh->{HandleError} = sub {
 863           $weak_self->throw_exception("DBI Exception: $_[0]")
 864       };
 865       $dbh->{ShowErrorStatement} = 1;
 866       $dbh->{RaiseError} = 1;
 867       $dbh->{PrintError} = 0;
 868     }
 869   };
 870
 871   $DBI::connect_via = $old_connect_via if $old_connect_via;
 872
 873   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 874     if !$dbh || $@;
 875
 876   $self->_dbh_autocommit($dbh->{AutoCommit});
 877
 878   $dbh;
 879 }
 880
 881 sub svp_begin {
 882   my ($self, $name) = @_;
 883
 884   $name = $self->_svp_generate_name
 885     unless defined $name;
 886
 887   $self->throw_exception ("You can't use savepoints outside a transaction")
 888     if $self->{transaction_depth} == 0;
 889
 890   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 891     unless $self->can('_svp_begin');
 892
 893   push @{ $self->{savepoints} }, $name;
 894
 895   $self->debugobj->svp_begin($name) if $self->debug;
 896
 897   return $self->_svp_begin($name);
 898 }
 899
 900 sub svp_release {
 901   my ($self, $name) = @_;
 902
 903   $self->throw_exception ("You can't use savepoints outside a transaction")
 904     if $self->{transaction_depth} == 0;
 905
 906   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 907     unless $self->can('_svp_release');
 908
 909   if (defined $name) {
 910     $self->throw_exception ("Savepoint '$name' does not exist")
 911       unless grep { $_ eq $name } @{ $self->{savepoints} };
 912
 913     # Dig through the stack until we find the one we are releasing.  This keeps
 914     # the stack up to date.
 915     my $svp;
 916
 917     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 918   } else {
 919     $name = pop @{ $self->{savepoints} };
 920   }
 921
 922   $self->debugobj->svp_release($name) if $self->debug;
 923
 924   return $self->_svp_release($name);
 925 }
 926
 927 sub svp_rollback {
 928   my ($self, $name) = @_;
 929
 930   $self->throw_exception ("You can't use savepoints outside a transaction")
 931     if $self->{transaction_depth} == 0;
 932
 933   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 934     unless $self->can('_svp_rollback');
 935
 936   if (defined $name) {
 937       # If they passed us a name, verify that it exists in the stack
 938       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 939           $self->throw_exception("Savepoint '$name' does not exist!");
 940       }
 941
 942       # Dig through the stack until we find the one we are releasing.  This keeps
 943       # the stack up to date.
 944       while(my $s = pop(@{ $self->{savepoints} })) {
 945           last if($s eq $name);
 946       }
 947       # Add the savepoint back to the stack, as a rollback doesn't remove the
 948       # named savepoint, only everything after it.
 949       push(@{ $self->{savepoints} }, $name);
 950   } else {
 951       # We'll assume they want to rollback to the last savepoint
 952       $name = $self->{savepoints}->[-1];
 953   }
 954
 955   $self->debugobj->svp_rollback($name) if $self->debug;
 956
 957   return $self->_svp_rollback($name);
 958 }
 959
 960 sub _svp_generate_name {
 961     my ($self) = @_;
 962
 963     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 964 }
 965
 966 sub txn_begin {
 967   my $self = shift;
 968   $self->ensure_connected();
 969   if($self->{transaction_depth} == 0) {
 970     $self->debugobj->txn_begin()
 971       if $self->debug;
 972     # this isn't ->_dbh-> because
 973     #  we should reconnect on begin_work
 974     #  for AutoCommit users
 975     $self->dbh->begin_work;
 976   } elsif ($self->auto_savepoint) {
 977     $self->svp_begin;
 978   }
 979   $self->{transaction_depth}++;
 980 }
 981
 982 sub txn_commit {
 983   my $self = shift;
 984   if ($self->{transaction_depth} == 1) {
 985     my $dbh = $self->_dbh;
 986     $self->debugobj->txn_commit()
 987       if ($self->debug);
 988     $dbh->commit;
 989     $self->{transaction_depth} = 0
 990       if $self->_dbh_autocommit;
 991   }
 992   elsif($self->{transaction_depth} > 1) {
 993     $self->{transaction_depth}--;
 994     $self->svp_release
 995       if $self->auto_savepoint;
 996   }
 997 }
 998
 999 sub txn_rollback {
1000   my $self = shift;
1001   my $dbh = $self->_dbh;
1002   eval {
1003     if ($self->{transaction_depth} == 1) {
1004       $self->debugobj->txn_rollback()
1005         if ($self->debug);
1006       $self->{transaction_depth} = 0
1007         if $self->_dbh_autocommit;
1008       $dbh->rollback;
1009     }
1010     elsif($self->{transaction_depth} > 1) {
1011       $self->{transaction_depth}--;
1012       if ($self->auto_savepoint) {
1013         $self->svp_rollback;
1014         $self->svp_release;
1015       }
1016     }
1017     else {
1018       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1019     }
1020   };
1021   if ($@) {
1022     my $error = $@;
1023     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1024     $error =~ /$exception_class/ and $self->throw_exception($error);
1025     # ensure that a failed rollback resets the transaction depth
1026     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1027     $self->throw_exception($error);
1028   }
1029 }
1030
1031 # This used to be the top-half of _execute.  It was split out to make it
1032 #  easier to override in NoBindVars without duping the rest.  It takes up
1033 #  all of _execute's args, and emits $sql, @bind.
1034 sub _prep_for_execute {
1035   my ($self, $op, $extra_bind, $ident, $args) = @_;
1036
1037   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1038   unshift(@bind,
1039     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1040       if $extra_bind;
1041
1042   return ($sql, \@bind);
1043 }
1044
1045 sub _fix_bind_params {
1046     my ($self, @bind) = @_;
1047
1048     ### Turn @bind from something like this:
1049     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1050     ### to this:
1051     ###   ( "'1'", "'1'", "'3'" )
1052     return
1053         map {
1054             if ( defined( $_ && $_->[1] ) ) {
1055                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1056             }
1057             else { q{'NULL'}; }
1058         } @bind;
1059 }
1060
1061 sub _query_start {
1062     my ( $self, $sql, @bind ) = @_;
1063
1064     if ( $self->debug ) {
1065         @bind = $self->_fix_bind_params(@bind);
1066
1067         $self->debugobj->query_start( $sql, @bind );
1068     }
1069 }
1070
1071 sub _query_end {
1072     my ( $self, $sql, @bind ) = @_;
1073
1074     if ( $self->debug ) {
1075         @bind = $self->_fix_bind_params(@bind);
1076         $self->debugobj->query_end( $sql, @bind );
1077     }
1078 }
1079
1080 sub _dbh_execute {
1081   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1082
1083   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1084     $ident = $ident->from();
1085   }
1086
1087   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1088
1089   $self->_query_start( $sql, @$bind );
1090
1091   my $sth = $self->sth($sql,$op);
1092
1093   my $placeholder_index = 1;
1094
1095   foreach my $bound (@$bind) {
1096     my $attributes = {};
1097     my($column_name, @data) = @$bound;
1098
1099     if ($bind_attributes) {
1100       $attributes = $bind_attributes->{$column_name}
1101       if defined $bind_attributes->{$column_name};
1102     }
1103
1104     foreach my $data (@data) {
1105       $data = ref $data ? ''.$data : $data; # stringify args
1106
1107       $sth->bind_param($placeholder_index, $data, $attributes);
1108       $placeholder_index++;
1109     }
1110   }
1111
1112   # Can this fail without throwing an exception anyways???
1113   my $rv = $sth->execute();
1114   $self->throw_exception($sth->errstr) if !$rv;
1115
1116   $self->_query_end( $sql, @$bind );
1117
1118   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1119 }
1120
1121 sub _execute {
1122     my $self = shift;
1123     $self->dbh_do('_dbh_execute', @_)
1124 }
1125
1126 sub insert {
1127   my ($self, $source, $to_insert) = @_;
1128
1129   my $ident = $source->from;
1130   my $bind_attributes = $self->source_bind_attributes($source);
1131
1132   foreach my $col ( $source->columns ) {
1133     if ( !defined $to_insert->{$col} ) {
1134       my $col_info = $source->column_info($col);
1135
1136       if ( $col_info->{auto_nextval} ) {
1137         $self->ensure_connected;
1138         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1139       }
1140     }
1141   }
1142
1143   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1144
1145   return $to_insert;
1146 }
1147
1148 ## Still not quite perfect, and EXPERIMENTAL
1149 ## Currently it is assumed that all values passed will be "normal", i.e. not
1150 ## scalar refs, or at least, all the same type as the first set, the statement is
1151 ## only prepped once.
1152 sub insert_bulk {
1153   my ($self, $source, $cols, $data) = @_;
1154   my %colvalues;
1155   my $table = $source->from;
1156   @colvalues{@$cols} = (0..$#$cols);
1157   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1158
1159   $self->_query_start( $sql, @bind );
1160   my $sth = $self->sth($sql);
1161
1162 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1163
1164   ## This must be an arrayref, else nothing works!
1165
1166   my $tuple_status = [];
1167
1168   ##use Data::Dumper;
1169   ##print STDERR Dumper( $data, $sql, [@bind] );
1170
1171   my $time = time();
1172
1173   ## Get the bind_attributes, if any exist
1174   my $bind_attributes = $self->source_bind_attributes($source);
1175
1176   ## Bind the values and execute
1177   my $placeholder_index = 1;
1178
1179   foreach my $bound (@bind) {
1180
1181     my $attributes = {};
1182     my ($column_name, $data_index) = @$bound;
1183
1184     if( $bind_attributes ) {
1185       $attributes = $bind_attributes->{$column_name}
1186       if defined $bind_attributes->{$column_name};
1187     }
1188
1189     my @data = map { $_->[$data_index] } @$data;
1190
1191     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1192     $placeholder_index++;
1193   }
1194   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1195   $self->throw_exception($sth->errstr) if !$rv;
1196
1197   $self->_query_end( $sql, @bind );
1198   return (wantarray ? ($rv, $sth, @bind) : $rv);
1199 }
1200
1201 sub update {
1202   my $self = shift @_;
1203   my $source = shift @_;
1204   my $bind_attributes = $self->source_bind_attributes($source);
1205
1206   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1207 }
1208
1209
1210 sub delete {
1211   my $self = shift @_;
1212   my $source = shift @_;
1213
1214   my $bind_attrs = {}; ## If ever it's needed...
1215
1216   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1217 }
1218
1219 sub _select {
1220   my ($self, $ident, $select, $condition, $attrs) = @_;
1221   my $order = $attrs->{order_by};
1222
1223   if (ref $condition eq 'SCALAR') {
1224     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1225   }
1226
1227   my $for = delete $attrs->{for};
1228   my $sql_maker = $self->sql_maker;
1229   local $sql_maker->{for} = $for;
1230
1231   if (exists $attrs->{group_by} || $attrs->{having}) {
1232     $order = {
1233       group_by => $attrs->{group_by},
1234       having => $attrs->{having},
1235       ($order ? (order_by => $order) : ())
1236     };
1237   }
1238   my $bind_attrs = {}; ## Future support
1239   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1240   if ($attrs->{software_limit} ||
1241       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1242         $attrs->{software_limit} = 1;
1243   } else {
1244     $self->throw_exception("rows attribute must be positive if present")
1245       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1246
1247     # MySQL actually recommends this approach.  I cringe.
1248     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1249     push @args, $attrs->{rows}, $attrs->{offset};
1250   }
1251
1252   return $self->_execute(@args);
1253 }
1254
1255 sub source_bind_attributes {
1256   my ($self, $source) = @_;
1257
1258   my $bind_attributes;
1259   foreach my $column ($source->columns) {
1260
1261     my $data_type = $source->column_info($column)->{data_type} || '';
1262     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1263      if $data_type;
1264   }
1265
1266   return $bind_attributes;
1267 }
1268
1269 =head2 select
1270
1271 =over 4
1272
1273 =item Arguments: $ident, $select, $condition, $attrs
1274
1275 =back
1276
1277 Handle a SQL select statement.
1278
1279 =cut
1280
1281 sub select {
1282   my $self = shift;
1283   my ($ident, $select, $condition, $attrs) = @_;
1284   return $self->cursor_class->new($self, \@_, $attrs);
1285 }
1286
1287 sub select_single {
1288   my $self = shift;
1289   my ($rv, $sth, @bind) = $self->_select(@_);
1290   my @row = $sth->fetchrow_array;
1291   if(@row && $sth->fetchrow_array) {
1292     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1293   }
1294   # Need to call finish() to work round broken DBDs
1295   $sth->finish();
1296   return @row;
1297 }
1298
1299 sub reload_row {
1300         my ($self, $row) = @_;
1301
1302     my $reload = $row->result_source->resultset->find(
1303         map { $row->$_ } $row->primary_columns
1304     );
1305
1306     return $reload;
1307 }
1308
1309 =head2 sth
1310
1311 =over 4
1312
1313 =item Arguments: $sql
1314
1315 =back
1316
1317 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1318
1319 =cut
1320
1321 sub _dbh_sth {
1322   my ($self, $dbh, $sql) = @_;
1323
1324   # 3 is the if_active parameter which avoids active sth re-use
1325   my $sth = $self->disable_sth_caching
1326     ? $dbh->prepare($sql)
1327     : $dbh->prepare_cached($sql, {}, 3);
1328
1329   # XXX You would think RaiseError would make this impossible,
1330   #  but apparently that's not true :(
1331   $self->throw_exception($dbh->errstr) if !$sth;
1332
1333   $sth;
1334 }
1335
1336 sub sth {
1337   my ($self, $sql) = @_;
1338   $self->dbh_do('_dbh_sth', $sql);
1339 }
1340
1341 sub _dbh_columns_info_for {
1342   my ($self, $dbh, $table) = @_;
1343
1344   if ($dbh->can('column_info')) {
1345     my %result;
1346     eval {
1347       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1348       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1349       $sth->execute();
1350       while ( my $info = $sth->fetchrow_hashref() ){
1351         my %column_info;
1352         $column_info{data_type}   = $info->{TYPE_NAME};
1353         $column_info{size}      = $info->{COLUMN_SIZE};
1354         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1355         $column_info{default_value} = $info->{COLUMN_DEF};
1356         my $col_name = $info->{COLUMN_NAME};
1357         $col_name =~ s/^\"(.*)\"$/$1/;
1358
1359         $result{$col_name} = \%column_info;
1360       }
1361     };
1362     return \%result if !$@ && scalar keys %result;
1363   }
1364
1365   my %result;
1366   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1367   $sth->execute;
1368   my @columns = @{$sth->{NAME_lc}};
1369   for my $i ( 0 .. $#columns ){
1370     my %column_info;
1371     $column_info{data_type} = $sth->{TYPE}->[$i];
1372     $column_info{size} = $sth->{PRECISION}->[$i];
1373     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1374
1375     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1376       $column_info{data_type} = $1;
1377       $column_info{size}    = $2;
1378     }
1379
1380     $result{$columns[$i]} = \%column_info;
1381   }
1382   $sth->finish;
1383
1384   foreach my $col (keys %result) {
1385     my $colinfo = $result{$col};
1386     my $type_num = $colinfo->{data_type};
1387     my $type_name;
1388     if(defined $type_num && $dbh->can('type_info')) {
1389       my $type_info = $dbh->type_info($type_num);
1390       $type_name = $type_info->{TYPE_NAME} if $type_info;
1391       $colinfo->{data_type} = $type_name if $type_name;
1392     }
1393   }
1394
1395   return \%result;
1396 }
1397
1398 sub columns_info_for {
1399   my ($self, $table) = @_;
1400   $self->dbh_do('_dbh_columns_info_for', $table);
1401 }
1402
1403 =head2 last_insert_id
1404
1405 Return the row id of the last insert.
1406
1407 =cut
1408
1409 sub _dbh_last_insert_id {
1410     my ($self, $dbh, $source, $col) = @_;
1411     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1412     $dbh->func('last_insert_rowid');
1413 }
1414
1415 sub last_insert_id {
1416   my $self = shift;
1417   $self->dbh_do('_dbh_last_insert_id', @_);
1418 }
1419
1420 =head2 sqlt_type
1421
1422 Returns the database driver name.
1423
1424 =cut
1425
1426 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1427
1428 =head2 bind_attribute_by_data_type
1429
1430 Given a datatype from column info, returns a database specific bind attribute for
1431 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1432 just handle it.
1433
1434 Generally only needed for special case column types, like bytea in postgres.
1435
1436 =cut
1437
1438 sub bind_attribute_by_data_type {
1439     return;
1440 }
1441
1442 =head2 create_ddl_dir
1443
1444 =over 4
1445
1446 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1447
1448 =back
1449
1450 Creates a SQL file based on the Schema, for each of the specified
1451 database types, in the given directory.
1452
1453 By default, C<\%sqlt_args> will have
1454
1455  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1456
1457 merged with the hash passed in. To disable any of those features, pass in a
1458 hashref like the following
1459
1460  { ignore_constraint_names => 0, # ... other options }
1461
1462 =cut
1463
1464 sub create_ddl_dir
1465 {
1466   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1467
1468   if(!$dir || !-d $dir)
1469   {
1470     warn "No directory given, using ./\n";
1471     $dir = "./";
1472   }
1473   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1474   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1475   $version ||= $schema->VERSION || '1.x';
1476   $sqltargs = {
1477     add_drop_table => 1,
1478     ignore_constraint_names => 1,
1479     ignore_index_names => 1,
1480     %{$sqltargs || {}}
1481   };
1482
1483   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1484       . $self->_check_sqlt_message . q{'})
1485           if !$self->_check_sqlt_version;
1486
1487   my $sqlt = SQL::Translator->new( $sqltargs );
1488
1489   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1490   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1491
1492   foreach my $db (@$databases)
1493   {
1494     $sqlt->reset();
1495     $sqlt = $self->configure_sqlt($sqlt, $db);
1496     $sqlt->{schema} = $sqlt_schema;
1497     $sqlt->producer($db);
1498
1499     my $file;
1500     my $filename = $schema->ddl_filename($db, $dir, $version);
1501     if(-e $filename)
1502     {
1503       warn("$filename already exists, skipping $db");
1504       next unless ($preversion);
1505     } else {
1506       my $output = $sqlt->translate;
1507       if(!$output)
1508       {
1509         warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1510         next;
1511       }
1512       if(!open($file, ">$filename"))
1513       {
1514           $self->throw_exception("Can't open $filename for writing ($!)");
1515           next;
1516       }
1517       print $file $output;
1518       close($file);
1519     }
1520     if($preversion)
1521     {
1522       require SQL::Translator::Diff;
1523
1524       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1525 #      print "Previous version $prefilename\n";
1526       if(!-e $prefilename)
1527       {
1528         warn("No previous schema file found ($prefilename)");
1529         next;
1530       }
1531
1532       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1533       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1534       if(-e $difffile)
1535       {
1536         warn("$difffile already exists, skipping");
1537         next;
1538       }
1539
1540       my $source_schema;
1541       {
1542         my $t = SQL::Translator->new($sqltargs);
1543         $t->debug( 0 );
1544         $t->trace( 0 );
1545         $t->parser( $db )                       or die $t->error;
1546         $t = $self->configure_sqlt($t, $db);
1547         my $out = $t->translate( $prefilename ) or die $t->error;
1548         $source_schema = $t->schema;
1549         unless ( $source_schema->name ) {
1550           $source_schema->name( $prefilename );
1551         }
1552       }
1553
1554       # The "new" style of producers have sane normalization and can support
1555       # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1556       # And we have to diff parsed SQL against parsed SQL.
1557       my $dest_schema = $sqlt_schema;
1558
1559       unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1560         my $t = SQL::Translator->new($sqltargs);
1561         $t->debug( 0 );
1562         $t->trace( 0 );
1563         $t->parser( $db )                    or die $t->error;
1564         $t = $self->configure_sqlt($t, $db);
1565         my $out = $t->translate( $filename ) or die $t->error;
1566         $dest_schema = $t->schema;
1567         $dest_schema->name( $filename )
1568           unless $dest_schema->name;
1569       }
1570
1571       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1572                                                     $dest_schema,   $db,
1573                                                     $sqltargs
1574                                                    );
1575       if(!open $file, ">$difffile")
1576       {
1577         $self->throw_exception("Can't write to $difffile ($!)");
1578         next;
1579       }
1580       print $file $diff;
1581       close($file);
1582     }
1583   }
1584 }
1585
1586 sub configure_sqlt() {
1587   my $self = shift;
1588   my $tr = shift;
1589   my $db = shift || $self->sqlt_type;
1590   if ($db eq 'PostgreSQL') {
1591     $tr->quote_table_names(0);
1592     $tr->quote_field_names(0);
1593   }
1594   return $tr;
1595 }
1596
1597 =head2 deployment_statements
1598
1599 =over 4
1600
1601 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1602
1603 =back
1604
1605 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1606 The database driver name is given by C<$type>, though the value from
1607 L</sqlt_type> is used if it is not specified.
1608
1609 C<$directory> is used to return statements from files in a previously created
1610 L</create_ddl_dir> directory and is optional. The filenames are constructed
1611 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1612
1613 If no C<$directory> is specified then the statements are constructed on the
1614 fly using L<SQL::Translator> and C<$version> is ignored.
1615
1616 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1617
1618 =cut
1619
1620 sub deployment_statements {
1621   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1622   # Need to be connected to get the correct sqlt_type
1623   $self->ensure_connected() unless $type;
1624   $type ||= $self->sqlt_type;
1625   $version ||= $schema->VERSION || '1.x';
1626   $dir ||= './';
1627   my $filename = $schema->ddl_filename($type, $dir, $version);
1628   if(-f $filename)
1629   {
1630       my $file;
1631       open($file, "<$filename")
1632         or $self->throw_exception("Can't open $filename ($!)");
1633       my @rows = <$file>;
1634       close($file);
1635       return join('', @rows);
1636   }
1637
1638   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1639       . $self->_check_sqlt_message . q{'})
1640           if !$self->_check_sqlt_version;
1641
1642   require SQL::Translator::Parser::DBIx::Class;
1643   eval qq{use SQL::Translator::Producer::${type}};
1644   $self->throw_exception($@) if $@;
1645
1646   # sources needs to be a parser arg, but for simplicty allow at top level
1647   # coming in
1648   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1649       if exists $sqltargs->{sources};
1650
1651   my $tr = SQL::Translator->new(%$sqltargs);
1652   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1653   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1654
1655   return;
1656
1657 }
1658
1659 sub deploy {
1660   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1661   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1662     foreach my $line ( split(";\n", $statement)) {
1663       next if($line =~ /^--/);
1664       next if(!$line);
1665 #      next if($line =~ /^DROP/m);
1666       next if($line =~ /^BEGIN TRANSACTION/m);
1667       next if($line =~ /^COMMIT/m);
1668       next if $line =~ /^\s+$/; # skip whitespace only
1669       $self->_query_start($line);
1670       eval {
1671         $self->dbh->do($line); # shouldn't be using ->dbh ?
1672       };
1673       if ($@) {
1674         warn qq{$@ (running "${line}")};
1675       }
1676       $self->_query_end($line);
1677     }
1678   }
1679 }
1680
1681 =head2 datetime_parser
1682
1683 Returns the datetime parser class
1684
1685 =cut
1686
1687 sub datetime_parser {
1688   my $self = shift;
1689   return $self->{datetime_parser} ||= do {
1690     $self->ensure_connected;
1691     $self->build_datetime_parser(@_);
1692   };
1693 }
1694
1695 =head2 datetime_parser_type
1696
1697 Defines (returns) the datetime parser class - currently hardwired to
1698 L<DateTime::Format::MySQL>
1699
1700 =cut
1701
1702 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1703
1704 =head2 build_datetime_parser
1705
1706 See L</datetime_parser>
1707
1708 =cut
1709
1710 sub build_datetime_parser {
1711   my $self = shift;
1712   my $type = $self->datetime_parser_type(@_);
1713   eval "use ${type}";
1714   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1715   return $type;
1716 }
1717
1718 {
1719     my $_check_sqlt_version; # private
1720     my $_check_sqlt_message; # private
1721     sub _check_sqlt_version {
1722         return $_check_sqlt_version if defined $_check_sqlt_version;
1723         eval 'use SQL::Translator "0.09"';
1724         $_check_sqlt_message = $@ || '';
1725         $_check_sqlt_version = !$@;
1726     }
1727
1728     sub _check_sqlt_message {
1729         _check_sqlt_version if !defined $_check_sqlt_message;
1730         $_check_sqlt_message;
1731     }
1732 }
1733
1734 =head2 is_replicating
1735
1736 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1737 replicate from a master database.  Default is undef, which is the result
1738 returned by databases that don't support replication.
1739
1740 =cut
1741
1742 sub is_replicating {
1743     return;
1744
1745 }
1746
1747 =head2 lag_behind_master
1748
1749 Returns a number that represents a certain amount of lag behind a master db
1750 when a given storage is replicating.  The number is database dependent, but
1751 starts at zero and increases with the amount of lag. Default in undef
1752
1753 =cut
1754
1755 sub lag_behind_master {
1756     return;
1757 }
1758
1759 sub DESTROY {
1760   my $self = shift;
1761   return if !$self->_dbh;
1762   $self->_verify_pid;
1763   $self->_dbh(undef);
1764 }
1765
1766 1;
1767
1768 =head1 SQL METHODS
1769
1770 The module defines a set of methods within the DBIC::SQL::Abstract
1771 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1772 SQL query functions.
1773
1774 The following methods are extended:-
1775
1776 =over 4
1777
1778 =item delete
1779
1780 =item insert
1781
1782 =item select
1783
1784 =item update
1785
1786 =item limit_dialect
1787
1788 See L</connect_info> for details.
1789 For setting, this method is deprecated in favor of L</connect_info>.
1790
1791 =item quote_char
1792
1793 See L</connect_info> for details.
1794 For setting, this method is deprecated in favor of L</connect_info>.
1795
1796 =item name_sep
1797
1798 See L</connect_info> for details.
1799 For setting, this method is deprecated in favor of L</connect_info>.
1800
1801 =back
1802
1803 =head1 AUTHORS
1804
1805 Matt S. Trout <mst@shadowcatsystems.co.uk>
1806
1807 Andy Grundman <andy@hybridized.org>
1808
1809 =head1 LICENSE
1810
1811 You may distribute this code under the same terms as Perl itself.
1812
1813 =cut