lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid disable_sth_caching on_connect_do
  18        on_disconnect_do transaction_depth unsafe _dbh_autocommit
  19        auto_savepoint savepoints/
  20 );
  21
  22 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  23
  24 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  25 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  26
  27 BEGIN {
  28
  29 package # Hide from PAUSE
  30   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  31
  32 use base qw/SQL::Abstract::Limit/;
  33
  34 # This prevents the caching of $dbh in S::A::L, I believe
  35 sub new {
  36   my $self = shift->SUPER::new(@_);
  37
  38   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  39   #   it with what it resolves to:
  40   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  41     if ref $self->{limit_dialect};
  42
  43   $self;
  44 }
  45
  46 sub _RowNumberOver {
  47   my ($self, $sql, $order, $rows, $offset ) = @_;
  48
  49   $offset += 1;
  50   my $last = $rows + $offset;
  51   my ( $order_by ) = $self->_order_by( $order );
  52
  53   $sql = <<"";
  54 SELECT * FROM
  55 (
  56    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  57       $sql
  58       $order_by
  59    ) Q1
  60 ) Q2
  61 WHERE ROW_NUM BETWEEN $offset AND $last
  62
  63   return $sql;
  64 }
  65
  66
  67 # While we're at it, this should make LIMIT queries more efficient,
  68 #  without digging into things too deeply
  69 use Scalar::Util 'blessed';
  70 sub _find_syntax {
  71   my ($self, $syntax) = @_;
  72   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  73   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  74     return 'RowNumberOver';
  75   }
  76
  77   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  78 }
  79
  80 sub select {
  81   my ($self, $table, $fields, $where, $order, @rest) = @_;
  82   $table = $self->_quote($table) unless ref($table);
  83   local $self->{rownum_hack_count} = 1
  84     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  85   @rest = (-1) unless defined $rest[0];
  86   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  87     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  88   local $self->{having_bind} = [];
  89   my ($sql, @ret) = $self->SUPER::select(
  90     $table, $self->_recurse_fields($fields), $where, $order, @rest
  91   );
  92   $sql .=
  93     $self->{for} ?
  94     (
  95       $self->{for} eq 'update' ? ' FOR UPDATE' :
  96       $self->{for} eq 'shared' ? ' FOR SHARE'  :
  97       ''
  98     ) :
  99     ''
 100   ;
 101   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 102 }
 103
 104 sub insert {
 105   my $self = shift;
 106   my $table = shift;
 107   $table = $self->_quote($table) unless ref($table);
 108   $self->SUPER::insert($table, @_);
 109 }
 110
 111 sub update {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::update($table, @_);
 116 }
 117
 118 sub delete {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::delete($table, @_);
 123 }
 124
 125 sub _emulate_limit {
 126   my $self = shift;
 127   if ($_[3] == -1) {
 128     return $_[1].$self->_order_by($_[2]);
 129   } else {
 130     return $self->SUPER::_emulate_limit(@_);
 131   }
 132 }
 133
 134 sub _recurse_fields {
 135   my ($self, $fields, $params) = @_;
 136   my $ref = ref $fields;
 137   return $self->_quote($fields) unless $ref;
 138   return $$fields if $ref eq 'SCALAR';
 139
 140   if ($ref eq 'ARRAY') {
 141     return join(', ', map {
 142       $self->_recurse_fields($_)
 143         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 144           ? ' AS col'.$self->{rownum_hack_count}++
 145           : '')
 146       } @$fields);
 147   } elsif ($ref eq 'HASH') {
 148     foreach my $func (keys %$fields) {
 149       return $self->_sqlcase($func)
 150         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 151     }
 152   }
 153 }
 154
 155 sub _order_by {
 156   my $self = shift;
 157   my $ret = '';
 158   my @extra;
 159   if (ref $_[0] eq 'HASH') {
 160     if (defined $_[0]->{group_by}) {
 161       $ret = $self->_sqlcase(' group by ')
 162         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 163     }
 164     if (defined $_[0]->{having}) {
 165       my $frag;
 166       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 167       push(@{$self->{having_bind}}, @extra);
 168       $ret .= $self->_sqlcase(' having ').$frag;
 169     }
 170     if (defined $_[0]->{order_by}) {
 171       $ret .= $self->_order_by($_[0]->{order_by});
 172     }
 173   } elsif (ref $_[0] eq 'SCALAR') {
 174     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 175   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 176     my @order = @{+shift};
 177     $ret = $self->_sqlcase(' order by ')
 178           .join(', ', map {
 179                         my $r = $self->_order_by($_, @_);
 180                         $r =~ s/^ ?ORDER BY //i;
 181                         $r;
 182                       } @order);
 183   } else {
 184     $ret = $self->SUPER::_order_by(@_);
 185   }
 186   return $ret;
 187 }
 188
 189 sub _order_directions {
 190   my ($self, $order) = @_;
 191   $order = $order->{order_by} if ref $order eq 'HASH';
 192   return $self->SUPER::_order_directions($order);
 193 }
 194
 195 sub _table {
 196   my ($self, $from) = @_;
 197   if (ref $from eq 'ARRAY') {
 198     return $self->_recurse_from(@$from);
 199   } elsif (ref $from eq 'HASH') {
 200     return $self->_make_as($from);
 201   } else {
 202     return $from; # would love to quote here but _table ends up getting called
 203                   # twice during an ->select without a limit clause due to
 204                   # the way S::A::Limit->select works. should maybe consider
 205                   # bypassing this and doing S::A::select($self, ...) in
 206                   # our select method above. meantime, quoting shims have
 207                   # been added to select/insert/update/delete here
 208   }
 209 }
 210
 211 sub _recurse_from {
 212   my ($self, $from, @join) = @_;
 213   my @sqlf;
 214   push(@sqlf, $self->_make_as($from));
 215   foreach my $j (@join) {
 216     my ($to, $on) = @$j;
 217
 218     # check whether a join type exists
 219     my $join_clause = '';
 220     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 221     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 222       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 223     } else {
 224       $join_clause = ' JOIN ';
 225     }
 226     push(@sqlf, $join_clause);
 227
 228     if (ref $to eq 'ARRAY') {
 229       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 230     } else {
 231       push(@sqlf, $self->_make_as($to));
 232     }
 233     push(@sqlf, ' ON ', $self->_join_condition($on));
 234   }
 235   return join('', @sqlf);
 236 }
 237
 238 sub _make_as {
 239   my ($self, $from) = @_;
 240   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 241                      reverse each %{$self->_skip_options($from)});
 242 }
 243
 244 sub _skip_options {
 245   my ($self, $hash) = @_;
 246   my $clean_hash = {};
 247   $clean_hash->{$_} = $hash->{$_}
 248     for grep {!/^-/} keys %$hash;
 249   return $clean_hash;
 250 }
 251
 252 sub _join_condition {
 253   my ($self, $cond) = @_;
 254   if (ref $cond eq 'HASH') {
 255     my %j;
 256     for (keys %$cond) {
 257       my $v = $cond->{$_};
 258       if (ref $v) {
 259         # XXX no throw_exception() in this package and croak() fails with strange results
 260         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 261             if ref($v) ne 'SCALAR';
 262         $j{$_} = $v;
 263       }
 264       else {
 265         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 266       }
 267     };
 268     return scalar($self->_recurse_where(\%j));
 269   } elsif (ref $cond eq 'ARRAY') {
 270     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 271   } else {
 272     die "Can't handle this yet!";
 273   }
 274 }
 275
 276 sub _quote {
 277   my ($self, $label) = @_;
 278   return '' unless defined $label;
 279   return "*" if $label eq '*';
 280   return $label unless $self->{quote_char};
 281   if(ref $self->{quote_char} eq "ARRAY"){
 282     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 283       if !defined $self->{name_sep};
 284     my $sep = $self->{name_sep};
 285     return join($self->{name_sep},
 286         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 287        split(/\Q$sep\E/,$label));
 288   }
 289   return $self->SUPER::_quote($label);
 290 }
 291
 292 sub limit_dialect {
 293     my $self = shift;
 294     $self->{limit_dialect} = shift if @_;
 295     return $self->{limit_dialect};
 296 }
 297
 298 sub quote_char {
 299     my $self = shift;
 300     $self->{quote_char} = shift if @_;
 301     return $self->{quote_char};
 302 }
 303
 304 sub name_sep {
 305     my $self = shift;
 306     $self->{name_sep} = shift if @_;
 307     return $self->{name_sep};
 308 }
 309
 310 } # End of BEGIN block
 311
 312 =head1 NAME
 313
 314 DBIx::Class::Storage::DBI - DBI storage handler
 315
 316 =head1 SYNOPSIS
 317
 318 =head1 DESCRIPTION
 319
 320 This class represents the connection to an RDBMS via L<DBI>.  See
 321 L<DBIx::Class::Storage> for general information.  This pod only
 322 documents DBI-specific methods and behaviors.
 323
 324 =head1 METHODS
 325
 326 =cut
 327
 328 sub new {
 329   my $new = shift->next::method(@_);
 330
 331   $new->transaction_depth(0);
 332   $new->_sql_maker_opts({});
 333   $new->{savepoints} = [];
 334   $new->{_in_dbh_do} = 0;
 335   $new->{_dbh_gen} = 0;
 336
 337   $new;
 338 }
 339
 340 =head2 connect_info
 341
 342 The arguments of C<connect_info> are always a single array reference.
 343
 344 This is normally accessed via L<DBIx::Class::Schema/connection>, which
 345 encapsulates its argument list in an arrayref before calling
 346 C<connect_info> here.
 347
 348 The arrayref can either contain the same set of arguments one would
 349 normally pass to L<DBI/connect>, or a lone code reference which returns
 350 a connected database handle.  Please note that the L<DBI> docs
 351 recommend that you always explicitly set C<AutoCommit> to either
 352 C<0> or C<1>.   L<DBIx::Class> further recommends that it be set
 353 to C<1>, and that you perform transactions via our L</txn_do>
 354 method.  L<DBIx::Class> will set it to C<1> if you do not do explicitly
 355 set it to zero.  This is the default for most DBDs.  See below for more
 356 details.
 357
 358 In either case, if the final argument in your connect_info happens
 359 to be a hashref, C<connect_info> will look there for several
 360 connection-specific options:
 361
 362 =over 4
 363
 364 =item on_connect_do
 365
 366 Specifies things to do immediately after connecting or re-connecting to
 367 the database.  Its value may contain:
 368
 369 =over
 370
 371 =item an array reference
 372
 373 This contains SQL statements to execute in order.  Each element contains
 374 a string or a code reference that returns a string.
 375
 376 =item a code reference
 377
 378 This contains some code to execute.  Unlike code references within an
 379 array reference, its return value is ignored.
 380
 381 =back
 382
 383 =item on_disconnect_do
 384
 385 Takes arguments in the same form as L<on_connect_do> and executes them
 386 immediately before disconnecting from the database.
 387
 388 Note, this only runs if you explicitly call L<disconnect> on the
 389 storage object.
 390
 391 =item disable_sth_caching
 392
 393 If set to a true value, this option will disable the caching of
 394 statement handles via L<DBI/prepare_cached>.
 395
 396 =item limit_dialect
 397
 398 Sets the limit dialect. This is useful for JDBC-bridge among others
 399 where the remote SQL-dialect cannot be determined by the name of the
 400 driver alone.
 401
 402 =item quote_char
 403
 404 Specifies what characters to use to quote table and column names. If
 405 you use this you will want to specify L<name_sep> as well.
 406
 407 quote_char expects either a single character, in which case is it is placed
 408 on either side of the table/column, or an arrayref of length 2 in which case the
 409 table/column name is placed between the elements.
 410
 411 For example under MySQL you'd use C<quote_char =E<gt> '`'>, and user SQL Server you'd
 412 use C<quote_char =E<gt> [qw/[ ]/]>.
 413
 414 =item name_sep
 415
 416 This only needs to be used in conjunction with L<quote_char>, and is used to
 417 specify the charecter that seperates elements (schemas, tables, columns) from
 418 each other. In most cases this is simply a C<.>.
 419
 420 =item unsafe
 421
 422 This Storage driver normally installs its own C<HandleError>, sets
 423 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 424 all database handles, including those supplied by a coderef.  It does this
 425 so that it can have consistent and useful error behavior.
 426
 427 If you set this option to a true value, Storage will not do its usual
 428 modifications to the database handle's attributes, and instead relies on
 429 the settings in your connect_info DBI options (or the values you set in
 430 your connection coderef, in the case that you are connecting via coderef).
 431
 432 Note that your custom settings can cause Storage to malfunction,
 433 especially if you set a C<HandleError> handler that suppresses exceptions
 434 and/or disable C<RaiseError>.
 435
 436 =item auto_savepoint
 437
 438 If this option is true, L<DBIx::Class> will use savepoints when nesting
 439 transactions, making it possible to recover from failure in the inner
 440 transaction without having to abort all outer transactions.
 441
 442 =back
 443
 444 These options can be mixed in with your other L<DBI> connection attributes,
 445 or placed in a seperate hashref after all other normal L<DBI> connection
 446 arguments.
 447
 448 Every time C<connect_info> is invoked, any previous settings for
 449 these options will be cleared before setting the new ones, regardless of
 450 whether any options are specified in the new C<connect_info>.
 451
 452 Another Important Note:
 453
 454 DBIC can do some wonderful magic with handling exceptions,
 455 disconnections, and transactions when you use C<< AutoCommit => 1 >>
 456 combined with C<txn_do> for transaction support.
 457
 458 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
 459 in an assumed transaction between commits, and you're telling us you'd
 460 like to manage that manually.  A lot of DBIC's magic protections
 461 go away.  We can't protect you from exceptions due to database
 462 disconnects because we don't know anything about how to restart your
 463 transactions.  You're on your own for handling all sorts of exceptional
 464 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
 465 be with raw DBI.
 466
 467 Examples:
 468
 469   # Simple SQLite connection
 470   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 471
 472   # Connect via subref
 473   ->connect_info([ sub { DBI->connect(...) } ]);
 474
 475   # A bit more complicated
 476   ->connect_info(
 477     [
 478       'dbi:Pg:dbname=foo',
 479       'postgres',
 480       'my_pg_password',
 481       { AutoCommit => 1 },
 482       { quote_char => q{"}, name_sep => q{.} },
 483     ]
 484   );
 485
 486   # Equivalent to the previous example
 487   ->connect_info(
 488     [
 489       'dbi:Pg:dbname=foo',
 490       'postgres',
 491       'my_pg_password',
 492       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 493     ]
 494   );
 495
 496   # Subref + DBIC-specific connection options
 497   ->connect_info(
 498     [
 499       sub { DBI->connect(...) },
 500       {
 501           quote_char => q{`},
 502           name_sep => q{@},
 503           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 504           disable_sth_caching => 1,
 505       },
 506     ]
 507   );
 508
 509 =cut
 510
 511 sub connect_info {
 512   my ($self, $info_arg) = @_;
 513
 514   return $self->_connect_info if !$info_arg;
 515
 516   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 517   #  the new set of options
 518   $self->_sql_maker(undef);
 519   $self->_sql_maker_opts({});
 520   $self->_connect_info([@$info_arg]); # copy for _connect_info
 521
 522   my $dbi_info = [@$info_arg]; # copy for _dbi_connect_info
 523
 524   my $last_info = $dbi_info->[-1];
 525   if(ref $last_info eq 'HASH') {
 526     $last_info = { %$last_info }; # so delete is non-destructive
 527     my @storage_option = qw(
 528       on_connect_do on_disconnect_do disable_sth_caching unsafe cursor_class
 529       auto_savepoint
 530     );
 531     for my $storage_opt (@storage_option) {
 532       if(my $value = delete $last_info->{$storage_opt}) {
 533         $self->$storage_opt($value);
 534       }
 535     }
 536     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 537       if(my $opt_val = delete $last_info->{$sql_maker_opt}) {
 538         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 539       }
 540     }
 541     # re-insert modified hashref
 542     $dbi_info->[-1] = $last_info;
 543
 544     # Get rid of any trailing empty hashref
 545     pop(@$dbi_info) if !keys %$last_info;
 546   }
 547   $self->_dbi_connect_info($dbi_info);
 548
 549   $self->_connect_info;
 550 }
 551
 552 =head2 on_connect_do
 553
 554 This method is deprecated in favor of setting via L</connect_info>.
 555
 556 =head2 dbh_do
 557
 558 Arguments: ($subref | $method_name), @extra_coderef_args?
 559
 560 Execute the given $subref or $method_name using the new exception-based
 561 connection management.
 562
 563 The first two arguments will be the storage object that C<dbh_do> was called
 564 on and a database handle to use.  Any additional arguments will be passed
 565 verbatim to the called subref as arguments 2 and onwards.
 566
 567 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 568 exception handling and reconnection (or failover in future subclasses).
 569
 570 Your subref should have no side-effects outside of the database, as
 571 there is the potential for your subref to be partially double-executed
 572 if the database connection was stale/dysfunctional.
 573
 574 Example:
 575
 576   my @stuff = $schema->storage->dbh_do(
 577     sub {
 578       my ($storage, $dbh, @cols) = @_;
 579       my $cols = join(q{, }, @cols);
 580       $dbh->selectrow_array("SELECT $cols FROM foo");
 581     },
 582     @column_list
 583   );
 584
 585 =cut
 586
 587 sub dbh_do {
 588   my $self = shift;
 589   my $code = shift;
 590
 591   my $dbh = $self->_dbh;
 592
 593   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 594       || $self->{transaction_depth};
 595
 596   local $self->{_in_dbh_do} = 1;
 597
 598   my @result;
 599   my $want_array = wantarray;
 600
 601   eval {
 602     $self->_verify_pid if $dbh;
 603     if(!$self->_dbh) {
 604         $self->_populate_dbh;
 605         $dbh = $self->_dbh;
 606     }
 607
 608     if($want_array) {
 609         @result = $self->$code($dbh, @_);
 610     }
 611     elsif(defined $want_array) {
 612         $result[0] = $self->$code($dbh, @_);
 613     }
 614     else {
 615         $self->$code($dbh, @_);
 616     }
 617   };
 618
 619   my $exception = $@;
 620   if(!$exception) { return $want_array ? @result : $result[0] }
 621
 622   $self->throw_exception($exception) if $self->connected;
 623
 624   # We were not connected - reconnect and retry, but let any
 625   #  exception fall right through this time
 626   $self->_populate_dbh;
 627   $self->$code($self->_dbh, @_);
 628 }
 629
 630 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 631 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 632 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 633 sub txn_do {
 634   my $self = shift;
 635   my $coderef = shift;
 636
 637   ref $coderef eq 'CODE' or $self->throw_exception
 638     ('$coderef must be a CODE reference');
 639
 640   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 641
 642   local $self->{_in_dbh_do} = 1;
 643
 644   my @result;
 645   my $want_array = wantarray;
 646
 647   my $tried = 0;
 648   while(1) {
 649     eval {
 650       $self->_verify_pid if $self->_dbh;
 651       $self->_populate_dbh if !$self->_dbh;
 652
 653       $self->txn_begin;
 654       if($want_array) {
 655           @result = $coderef->(@_);
 656       }
 657       elsif(defined $want_array) {
 658           $result[0] = $coderef->(@_);
 659       }
 660       else {
 661           $coderef->(@_);
 662       }
 663       $self->txn_commit;
 664     };
 665
 666     my $exception = $@;
 667     if(!$exception) { return $want_array ? @result : $result[0] }
 668
 669     if($tried++ > 0 || $self->connected) {
 670       eval { $self->txn_rollback };
 671       my $rollback_exception = $@;
 672       if($rollback_exception) {
 673         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 674         $self->throw_exception($exception)  # propagate nested rollback
 675           if $rollback_exception =~ /$exception_class/;
 676
 677         $self->throw_exception(
 678           "Transaction aborted: ${exception}. "
 679           . "Rollback failed: ${rollback_exception}"
 680         );
 681       }
 682       $self->throw_exception($exception)
 683     }
 684
 685     # We were not connected, and was first try - reconnect and retry
 686     # via the while loop
 687     $self->_populate_dbh;
 688   }
 689 }
 690
 691 =head2 disconnect
 692
 693 Our C<disconnect> method also performs a rollback first if the
 694 database is not in C<AutoCommit> mode.
 695
 696 =cut
 697
 698 sub disconnect {
 699   my ($self) = @_;
 700
 701   if( $self->connected ) {
 702     my $connection_do = $self->on_disconnect_do;
 703     $self->_do_connection_actions($connection_do) if ref($connection_do);
 704
 705     $self->_dbh->rollback unless $self->_dbh_autocommit;
 706     $self->_dbh->disconnect;
 707     $self->_dbh(undef);
 708     $self->{_dbh_gen}++;
 709   }
 710 }
 711
 712 sub connected {
 713   my ($self) = @_;
 714
 715   if(my $dbh = $self->_dbh) {
 716       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 717           $self->_dbh(undef);
 718           $self->{_dbh_gen}++;
 719           return;
 720       }
 721       else {
 722           $self->_verify_pid;
 723           return 0 if !$self->_dbh;
 724       }
 725       return ($dbh->FETCH('Active') && $dbh->ping);
 726   }
 727
 728   return 0;
 729 }
 730
 731 # handle pid changes correctly
 732 #  NOTE: assumes $self->_dbh is a valid $dbh
 733 sub _verify_pid {
 734   my ($self) = @_;
 735
 736   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 737
 738   $self->_dbh->{InactiveDestroy} = 1;
 739   $self->_dbh(undef);
 740   $self->{_dbh_gen}++;
 741
 742   return;
 743 }
 744
 745 sub ensure_connected {
 746   my ($self) = @_;
 747
 748   unless ($self->connected) {
 749     $self->_populate_dbh;
 750   }
 751 }
 752
 753 =head2 dbh
 754
 755 Returns the dbh - a data base handle of class L<DBI>.
 756
 757 =cut
 758
 759 sub dbh {
 760   my ($self) = @_;
 761
 762   $self->ensure_connected;
 763   return $self->_dbh;
 764 }
 765
 766 sub _sql_maker_args {
 767     my ($self) = @_;
 768
 769     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 770 }
 771
 772 sub sql_maker {
 773   my ($self) = @_;
 774   unless ($self->_sql_maker) {
 775     my $sql_maker_class = $self->sql_maker_class;
 776     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 777   }
 778   return $self->_sql_maker;
 779 }
 780
 781 sub _rebless {}
 782
 783 sub _populate_dbh {
 784   my ($self) = @_;
 785   my @info = @{$self->_dbi_connect_info || []};
 786   $self->_dbh($self->_connect(@info));
 787
 788   # Always set the transaction depth on connect, since
 789   #  there is no transaction in progress by definition
 790   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 791
 792   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 793     my $driver = $self->_dbh->{Driver}->{Name};
 794     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 795       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 796       $self->_rebless();
 797     }
 798   }
 799
 800   my $connection_do = $self->on_connect_do;
 801   $self->_do_connection_actions($connection_do) if ref($connection_do);
 802
 803   $self->_conn_pid($$);
 804   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 805 }
 806
 807 sub _do_connection_actions {
 808   my $self = shift;
 809   my $connection_do = shift;
 810
 811   if (ref $connection_do eq 'ARRAY') {
 812     $self->_do_query($_) foreach @$connection_do;
 813   }
 814   elsif (ref $connection_do eq 'CODE') {
 815     $connection_do->();
 816   }
 817
 818   return $self;
 819 }
 820
 821 sub _do_query {
 822   my ($self, $action) = @_;
 823
 824   if (ref $action eq 'CODE') {
 825     $action = $action->($self);
 826     $self->_do_query($_) foreach @$action;
 827   }
 828   else {
 829     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 830     $self->_query_start(@to_run);
 831     $self->_dbh->do(@to_run);
 832     $self->_query_end(@to_run);
 833   }
 834
 835   return $self;
 836 }
 837
 838 sub _connect {
 839   my ($self, @info) = @_;
 840
 841   $self->throw_exception("You failed to provide any connection info")
 842     if !@info;
 843
 844   my ($old_connect_via, $dbh);
 845
 846   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 847     $old_connect_via = $DBI::connect_via;
 848     $DBI::connect_via = 'connect';
 849   }
 850
 851   eval {
 852     if(ref $info[0] eq 'CODE') {
 853        $dbh = &{$info[0]}
 854     }
 855     else {
 856        $dbh = DBI->connect(@info);
 857     }
 858
 859     if($dbh && !$self->unsafe) {
 860       my $weak_self = $self;
 861       weaken($weak_self);
 862       $dbh->{HandleError} = sub {
 863           $weak_self->throw_exception("DBI Exception: $_[0]")
 864       };
 865       $dbh->{ShowErrorStatement} = 1;
 866       $dbh->{RaiseError} = 1;
 867       $dbh->{PrintError} = 0;
 868     }
 869   };
 870
 871   $DBI::connect_via = $old_connect_via if $old_connect_via;
 872
 873   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 874     if !$dbh || $@;
 875
 876   $self->_dbh_autocommit($dbh->{AutoCommit});
 877
 878   $dbh;
 879 }
 880
 881 sub svp_begin {
 882   my ($self, $name) = @_;
 883
 884   $name = $self->_svp_generate_name
 885     unless defined $name;
 886
 887   $self->throw_exception ("You can't use savepoints outside a transaction")
 888     if $self->{transaction_depth} == 0;
 889
 890   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 891     unless $self->can('_svp_begin');
 892
 893   push @{ $self->{savepoints} }, $name;
 894
 895   $self->debugobj->svp_begin($name) if $self->debug;
 896
 897   return $self->_svp_begin($name);
 898 }
 899
 900 sub svp_release {
 901   my ($self, $name) = @_;
 902
 903   $self->throw_exception ("You can't use savepoints outside a transaction")
 904     if $self->{transaction_depth} == 0;
 905
 906   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 907     unless $self->can('_svp_release');
 908
 909   if (defined $name) {
 910     $self->throw_exception ("Savepoint '$name' does not exist")
 911       unless grep { $_ eq $name } @{ $self->{savepoints} };
 912
 913     # Dig through the stack until we find the one we are releasing.  This keeps
 914     # the stack up to date.
 915     my $svp;
 916
 917     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
 918   } else {
 919     $name = pop @{ $self->{savepoints} };
 920   }
 921
 922   $self->debugobj->svp_release($name) if $self->debug;
 923
 924   return $self->_svp_release($name);
 925 }
 926
 927 sub svp_rollback {
 928   my ($self, $name) = @_;
 929
 930   $self->throw_exception ("You can't use savepoints outside a transaction")
 931     if $self->{transaction_depth} == 0;
 932
 933   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
 934     unless $self->can('_svp_rollback');
 935
 936   if (defined $name) {
 937       # If they passed us a name, verify that it exists in the stack
 938       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
 939           $self->throw_exception("Savepoint '$name' does not exist!");
 940       }
 941
 942       # Dig through the stack until we find the one we are releasing.  This keeps
 943       # the stack up to date.
 944       while(my $s = pop(@{ $self->{savepoints} })) {
 945           last if($s eq $name);
 946       }
 947       # Add the savepoint back to the stack, as a rollback doesn't remove the
 948       # named savepoint, only everything after it.
 949       push(@{ $self->{savepoints} }, $name);
 950   } else {
 951       # We'll assume they want to rollback to the last savepoint
 952       $name = $self->{savepoints}->[-1];
 953   }
 954
 955   $self->debugobj->svp_rollback($name) if $self->debug;
 956
 957   return $self->_svp_rollback($name);
 958 }
 959
 960 sub _svp_generate_name {
 961     my ($self) = @_;
 962
 963     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
 964 }
 965
 966 sub txn_begin {
 967   my $self = shift;
 968   $self->ensure_connected();
 969   if($self->{transaction_depth} == 0) {
 970     $self->debugobj->txn_begin()
 971       if $self->debug;
 972     # this isn't ->_dbh-> because
 973     #  we should reconnect on begin_work
 974     #  for AutoCommit users
 975     $self->dbh->begin_work;
 976   } elsif ($self->auto_savepoint) {
 977     $self->svp_begin;
 978   }
 979   $self->{transaction_depth}++;
 980 }
 981
 982 sub txn_commit {
 983   my $self = shift;
 984   if ($self->{transaction_depth} == 1) {
 985     my $dbh = $self->_dbh;
 986     $self->debugobj->txn_commit()
 987       if ($self->debug);
 988     $dbh->commit;
 989     $self->{transaction_depth} = 0
 990       if $self->_dbh_autocommit;
 991   }
 992   elsif($self->{transaction_depth} > 1) {
 993     $self->{transaction_depth}--;
 994     $self->svp_release
 995       if $self->auto_savepoint;
 996   }
 997 }
 998
 999 sub txn_rollback {
1000   my $self = shift;
1001   my $dbh = $self->_dbh;
1002   eval {
1003     if ($self->{transaction_depth} == 1) {
1004       $self->debugobj->txn_rollback()
1005         if ($self->debug);
1006       $self->{transaction_depth} = 0
1007         if $self->_dbh_autocommit;
1008       $dbh->rollback;
1009     }
1010     elsif($self->{transaction_depth} > 1) {
1011       $self->{transaction_depth}--;
1012       if ($self->auto_savepoint) {
1013         $self->svp_rollback;
1014         $self->svp_release;
1015       }
1016     }
1017     else {
1018       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1019     }
1020   };
1021   if ($@) {
1022     my $error = $@;
1023     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1024     $error =~ /$exception_class/ and $self->throw_exception($error);
1025     # ensure that a failed rollback resets the transaction depth
1026     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1027     $self->throw_exception($error);
1028   }
1029 }
1030
1031 # This used to be the top-half of _execute.  It was split out to make it
1032 #  easier to override in NoBindVars without duping the rest.  It takes up
1033 #  all of _execute's args, and emits $sql, @bind.
1034 sub _prep_for_execute {
1035   my ($self, $op, $extra_bind, $ident, $args) = @_;
1036
1037   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1038   unshift(@bind,
1039     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1040       if $extra_bind;
1041
1042   return ($sql, \@bind);
1043 }
1044
1045 sub _fix_bind_params {
1046     my ($self, @bind) = @_;
1047
1048     ### Turn @bind from something like this:
1049     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1050     ### to this:
1051     ###   ( "'1'", "'1'", "'3'" )
1052     return
1053         map {
1054             if ( defined( $_ && $_->[1] ) ) {
1055                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1056             }
1057             else { q{'NULL'}; }
1058         } @bind;
1059 }
1060
1061 sub _query_start {
1062     my ( $self, $sql, @bind ) = @_;
1063
1064     if ( $self->debug ) {
1065         @bind = $self->_fix_bind_params(@bind);
1066         $self->debugobj->query_start( $sql, @bind );
1067     }
1068 }
1069
1070 sub _query_end {
1071     my ( $self, $sql, @bind ) = @_;
1072
1073     if ( $self->debug ) {
1074         @bind = $self->_fix_bind_params(@bind);
1075         $self->debugobj->query_end( $sql, @bind );
1076     }
1077 }
1078
1079 sub _dbh_execute {
1080   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1081
1082   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1083     $ident = $ident->from();
1084   }
1085
1086   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1087
1088   $self->_query_start( $sql, @$bind );
1089
1090   my $sth = $self->sth($sql,$op);
1091
1092   my $placeholder_index = 1;
1093
1094   foreach my $bound (@$bind) {
1095     my $attributes = {};
1096     my($column_name, @data) = @$bound;
1097
1098     if ($bind_attributes) {
1099       $attributes = $bind_attributes->{$column_name}
1100       if defined $bind_attributes->{$column_name};
1101     }
1102
1103     foreach my $data (@data) {
1104       $data = ref $data ? ''.$data : $data; # stringify args
1105
1106       $sth->bind_param($placeholder_index, $data, $attributes);
1107       $placeholder_index++;
1108     }
1109   }
1110
1111   # Can this fail without throwing an exception anyways???
1112   my $rv = $sth->execute();
1113   $self->throw_exception($sth->errstr) if !$rv;
1114
1115   $self->_query_end( $sql, @$bind );
1116
1117   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1118 }
1119
1120 sub _execute {
1121     my $self = shift;
1122     $self->dbh_do('_dbh_execute', @_)
1123 }
1124
1125 sub insert {
1126   my ($self, $source, $to_insert) = @_;
1127
1128   my $ident = $source->from;
1129   my $bind_attributes = $self->source_bind_attributes($source);
1130
1131   foreach my $col ( $source->columns ) {
1132     if ( !defined $to_insert->{$col} ) {
1133       my $col_info = $source->column_info($col);
1134
1135       if ( $col_info->{auto_nextval} ) {
1136         $self->ensure_connected;
1137         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1138       }
1139     }
1140   }
1141
1142   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1143
1144   return $to_insert;
1145 }
1146
1147 ## Still not quite perfect, and EXPERIMENTAL
1148 ## Currently it is assumed that all values passed will be "normal", i.e. not
1149 ## scalar refs, or at least, all the same type as the first set, the statement is
1150 ## only prepped once.
1151 sub insert_bulk {
1152   my ($self, $source, $cols, $data) = @_;
1153   my %colvalues;
1154   my $table = $source->from;
1155   @colvalues{@$cols} = (0..$#$cols);
1156   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1157
1158   $self->_query_start( $sql, @bind );
1159   my $sth = $self->sth($sql);
1160
1161 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1162
1163   ## This must be an arrayref, else nothing works!
1164
1165   my $tuple_status = [];
1166
1167   ##use Data::Dumper;
1168   ##print STDERR Dumper( $data, $sql, [@bind] );
1169
1170   my $time = time();
1171
1172   ## Get the bind_attributes, if any exist
1173   my $bind_attributes = $self->source_bind_attributes($source);
1174
1175   ## Bind the values and execute
1176   my $placeholder_index = 1;
1177
1178   foreach my $bound (@bind) {
1179
1180     my $attributes = {};
1181     my ($column_name, $data_index) = @$bound;
1182
1183     if( $bind_attributes ) {
1184       $attributes = $bind_attributes->{$column_name}
1185       if defined $bind_attributes->{$column_name};
1186     }
1187
1188     my @data = map { $_->[$data_index] } @$data;
1189
1190     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1191     $placeholder_index++;
1192   }
1193   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1194   $self->throw_exception($sth->errstr) if !$rv;
1195
1196   $self->_query_end( $sql, @bind );
1197   return (wantarray ? ($rv, $sth, @bind) : $rv);
1198 }
1199
1200 sub update {
1201   my $self = shift @_;
1202   my $source = shift @_;
1203   my $bind_attributes = $self->source_bind_attributes($source);
1204
1205   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1206 }
1207
1208
1209 sub delete {
1210   my $self = shift @_;
1211   my $source = shift @_;
1212
1213   my $bind_attrs = {}; ## If ever it's needed...
1214
1215   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1216 }
1217
1218 sub _select {
1219   my ($self, $ident, $select, $condition, $attrs) = @_;
1220   my $order = $attrs->{order_by};
1221
1222   if (ref $condition eq 'SCALAR') {
1223     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
1224   }
1225
1226   my $for = delete $attrs->{for};
1227   my $sql_maker = $self->sql_maker;
1228   local $sql_maker->{for} = $for;
1229
1230   if (exists $attrs->{group_by} || $attrs->{having}) {
1231     $order = {
1232       group_by => $attrs->{group_by},
1233       having => $attrs->{having},
1234       ($order ? (order_by => $order) : ())
1235     };
1236   }
1237   my $bind_attrs = {}; ## Future support
1238   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1239   if ($attrs->{software_limit} ||
1240       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1241         $attrs->{software_limit} = 1;
1242   } else {
1243     $self->throw_exception("rows attribute must be positive if present")
1244       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1245
1246     # MySQL actually recommends this approach.  I cringe.
1247     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1248     push @args, $attrs->{rows}, $attrs->{offset};
1249   }
1250
1251   return $self->_execute(@args);
1252 }
1253
1254 sub source_bind_attributes {
1255   my ($self, $source) = @_;
1256
1257   my $bind_attributes;
1258   foreach my $column ($source->columns) {
1259
1260     my $data_type = $source->column_info($column)->{data_type} || '';
1261     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1262      if $data_type;
1263   }
1264
1265   return $bind_attributes;
1266 }
1267
1268 =head2 select
1269
1270 =over 4
1271
1272 =item Arguments: $ident, $select, $condition, $attrs
1273
1274 =back
1275
1276 Handle a SQL select statement.
1277
1278 =cut
1279
1280 sub select {
1281   my $self = shift;
1282   my ($ident, $select, $condition, $attrs) = @_;
1283   return $self->cursor_class->new($self, \@_, $attrs);
1284 }
1285
1286 sub select_single {
1287   my $self = shift;
1288   my ($rv, $sth, @bind) = $self->_select(@_);
1289   my @row = $sth->fetchrow_array;
1290   if(@row && $sth->fetchrow_array) {
1291     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1292   }
1293   # Need to call finish() to work round broken DBDs
1294   $sth->finish();
1295   return @row;
1296 }
1297
1298 =head2 sth
1299
1300 =over 4
1301
1302 =item Arguments: $sql
1303
1304 =back
1305
1306 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1307
1308 =cut
1309
1310 sub _dbh_sth {
1311   my ($self, $dbh, $sql) = @_;
1312
1313   # 3 is the if_active parameter which avoids active sth re-use
1314   my $sth = $self->disable_sth_caching
1315     ? $dbh->prepare($sql)
1316     : $dbh->prepare_cached($sql, {}, 3);
1317
1318   # XXX You would think RaiseError would make this impossible,
1319   #  but apparently that's not true :(
1320   $self->throw_exception($dbh->errstr) if !$sth;
1321
1322   $sth;
1323 }
1324
1325 sub sth {
1326   my ($self, $sql) = @_;
1327   $self->dbh_do('_dbh_sth', $sql);
1328 }
1329
1330 sub _dbh_columns_info_for {
1331   my ($self, $dbh, $table) = @_;
1332
1333   if ($dbh->can('column_info')) {
1334     my %result;
1335     eval {
1336       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1337       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1338       $sth->execute();
1339       while ( my $info = $sth->fetchrow_hashref() ){
1340         my %column_info;
1341         $column_info{data_type}   = $info->{TYPE_NAME};
1342         $column_info{size}      = $info->{COLUMN_SIZE};
1343         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1344         $column_info{default_value} = $info->{COLUMN_DEF};
1345         my $col_name = $info->{COLUMN_NAME};
1346         $col_name =~ s/^\"(.*)\"$/$1/;
1347
1348         $result{$col_name} = \%column_info;
1349       }
1350     };
1351     return \%result if !$@ && scalar keys %result;
1352   }
1353
1354   my %result;
1355   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1356   $sth->execute;
1357   my @columns = @{$sth->{NAME_lc}};
1358   for my $i ( 0 .. $#columns ){
1359     my %column_info;
1360     $column_info{data_type} = $sth->{TYPE}->[$i];
1361     $column_info{size} = $sth->{PRECISION}->[$i];
1362     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1363
1364     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1365       $column_info{data_type} = $1;
1366       $column_info{size}    = $2;
1367     }
1368
1369     $result{$columns[$i]} = \%column_info;
1370   }
1371   $sth->finish;
1372
1373   foreach my $col (keys %result) {
1374     my $colinfo = $result{$col};
1375     my $type_num = $colinfo->{data_type};
1376     my $type_name;
1377     if(defined $type_num && $dbh->can('type_info')) {
1378       my $type_info = $dbh->type_info($type_num);
1379       $type_name = $type_info->{TYPE_NAME} if $type_info;
1380       $colinfo->{data_type} = $type_name if $type_name;
1381     }
1382   }
1383
1384   return \%result;
1385 }
1386
1387 sub columns_info_for {
1388   my ($self, $table) = @_;
1389   $self->dbh_do('_dbh_columns_info_for', $table);
1390 }
1391
1392 =head2 last_insert_id
1393
1394 Return the row id of the last insert.
1395
1396 =cut
1397
1398 sub _dbh_last_insert_id {
1399     my ($self, $dbh, $source, $col) = @_;
1400     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1401     $dbh->func('last_insert_rowid');
1402 }
1403
1404 sub last_insert_id {
1405   my $self = shift;
1406   $self->dbh_do('_dbh_last_insert_id', @_);
1407 }
1408
1409 =head2 sqlt_type
1410
1411 Returns the database driver name.
1412
1413 =cut
1414
1415 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1416
1417 =head2 bind_attribute_by_data_type
1418
1419 Given a datatype from column info, returns a database specific bind attribute for
1420 $dbh->bind_param($val,$attribute) or nothing if we will let the database planner
1421 just handle it.
1422
1423 Generally only needed for special case column types, like bytea in postgres.
1424
1425 =cut
1426
1427 sub bind_attribute_by_data_type {
1428     return;
1429 }
1430
1431 =head2 create_ddl_dir
1432
1433 =over 4
1434
1435 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1436
1437 =back
1438
1439 Creates a SQL file based on the Schema, for each of the specified
1440 database types, in the given directory.
1441
1442 By default, C<\%sqlt_args> will have
1443
1444  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1445
1446 merged with the hash passed in. To disable any of those features, pass in a
1447 hashref like the following
1448
1449  { ignore_constraint_names => 0, # ... other options }
1450
1451 =cut
1452
1453 sub create_ddl_dir
1454 {
1455   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1456
1457   if(!$dir || !-d $dir)
1458   {
1459     warn "No directory given, using ./\n";
1460     $dir = "./";
1461   }
1462   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1463   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1464   $version ||= $schema->VERSION || '1.x';
1465   $sqltargs = {
1466     add_drop_table => 1,
1467     ignore_constraint_names => 1,
1468     ignore_index_names => 1,
1469     %{$sqltargs || {}}
1470   };
1471
1472   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1473       . $self->_check_sqlt_message . q{'})
1474           if !$self->_check_sqlt_version;
1475
1476   my $sqlt = SQL::Translator->new( $sqltargs );
1477
1478   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1479   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1480
1481   foreach my $db (@$databases)
1482   {
1483     $sqlt->reset();
1484     $sqlt = $self->configure_sqlt($sqlt, $db);
1485     $sqlt->{schema} = $sqlt_schema;
1486     $sqlt->producer($db);
1487
1488     my $file;
1489     my $filename = $schema->ddl_filename($db, $dir, $version);
1490     if(-e $filename)
1491     {
1492       warn("$filename already exists, skipping $db");
1493       next unless ($preversion);
1494     } else {
1495       my $output = $sqlt->translate;
1496       if(!$output)
1497       {
1498         warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1499         next;
1500       }
1501       if(!open($file, ">$filename"))
1502       {
1503           $self->throw_exception("Can't open $filename for writing ($!)");
1504           next;
1505       }
1506       print $file $output;
1507       close($file);
1508     }
1509     if($preversion)
1510     {
1511       require SQL::Translator::Diff;
1512
1513       my $prefilename = $schema->ddl_filename($db, $dir, $preversion);
1514 #      print "Previous version $prefilename\n";
1515       if(!-e $prefilename)
1516       {
1517         warn("No previous schema file found ($prefilename)");
1518         next;
1519       }
1520
1521       my $difffile = $schema->ddl_filename($db, $dir, $version, $preversion);
1522       print STDERR "Diff: $difffile: $db, $dir, $version, $preversion \n";
1523       if(-e $difffile)
1524       {
1525         warn("$difffile already exists, skipping");
1526         next;
1527       }
1528
1529       my $source_schema;
1530       {
1531         my $t = SQL::Translator->new($sqltargs);
1532         $t->debug( 0 );
1533         $t->trace( 0 );
1534         $t->parser( $db )                       or die $t->error;
1535         $t = $self->configure_sqlt($t, $db);
1536         my $out = $t->translate( $prefilename ) or die $t->error;
1537         $source_schema = $t->schema;
1538         unless ( $source_schema->name ) {
1539           $source_schema->name( $prefilename );
1540         }
1541       }
1542
1543       # The "new" style of producers have sane normalization and can support
1544       # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1545       # And we have to diff parsed SQL against parsed SQL.
1546       my $dest_schema = $sqlt_schema;
1547
1548       unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1549         my $t = SQL::Translator->new($sqltargs);
1550         $t->debug( 0 );
1551         $t->trace( 0 );
1552         $t->parser( $db )                    or die $t->error;
1553         $t = $self->configure_sqlt($t, $db);
1554         my $out = $t->translate( $filename ) or die $t->error;
1555         $dest_schema = $t->schema;
1556         $dest_schema->name( $filename )
1557           unless $dest_schema->name;
1558       }
1559
1560       my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1561                                                     $dest_schema,   $db,
1562                                                     $sqltargs
1563                                                    );
1564       if(!open $file, ">$difffile")
1565       {
1566         $self->throw_exception("Can't write to $difffile ($!)");
1567         next;
1568       }
1569       print $file $diff;
1570       close($file);
1571     }
1572   }
1573 }
1574
1575 sub configure_sqlt() {
1576   my $self = shift;
1577   my $tr = shift;
1578   my $db = shift || $self->sqlt_type;
1579   if ($db eq 'PostgreSQL') {
1580     $tr->quote_table_names(0);
1581     $tr->quote_field_names(0);
1582   }
1583   return $tr;
1584 }
1585
1586 =head2 deployment_statements
1587
1588 =over 4
1589
1590 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1591
1592 =back
1593
1594 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1595 The database driver name is given by C<$type>, though the value from
1596 L</sqlt_type> is used if it is not specified.
1597
1598 C<$directory> is used to return statements from files in a previously created
1599 L</create_ddl_dir> directory and is optional. The filenames are constructed
1600 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1601
1602 If no C<$directory> is specified then the statements are constructed on the
1603 fly using L<SQL::Translator> and C<$version> is ignored.
1604
1605 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1606
1607 =cut
1608
1609 sub deployment_statements {
1610   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1611   # Need to be connected to get the correct sqlt_type
1612   $self->ensure_connected() unless $type;
1613   $type ||= $self->sqlt_type;
1614   $version ||= $schema->VERSION || '1.x';
1615   $dir ||= './';
1616   my $filename = $schema->ddl_filename($type, $dir, $version);
1617   if(-f $filename)
1618   {
1619       my $file;
1620       open($file, "<$filename")
1621         or $self->throw_exception("Can't open $filename ($!)");
1622       my @rows = <$file>;
1623       close($file);
1624       return join('', @rows);
1625   }
1626
1627   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1628       . $self->_check_sqlt_message . q{'})
1629           if !$self->_check_sqlt_version;
1630
1631   require SQL::Translator::Parser::DBIx::Class;
1632   eval qq{use SQL::Translator::Producer::${type}};
1633   $self->throw_exception($@) if $@;
1634
1635   # sources needs to be a parser arg, but for simplicty allow at top level
1636   # coming in
1637   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1638       if exists $sqltargs->{sources};
1639
1640   my $tr = SQL::Translator->new(%$sqltargs);
1641   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1642   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1643
1644   return;
1645
1646 }
1647
1648 sub deploy {
1649   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1650   foreach my $statement ( $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } ) ) {
1651     foreach my $line ( split(";\n", $statement)) {
1652       next if($line =~ /^--/);
1653       next if(!$line);
1654 #      next if($line =~ /^DROP/m);
1655       next if($line =~ /^BEGIN TRANSACTION/m);
1656       next if($line =~ /^COMMIT/m);
1657       next if $line =~ /^\s+$/; # skip whitespace only
1658       $self->_query_start($line);
1659       eval {
1660         $self->dbh->do($line); # shouldn't be using ->dbh ?
1661       };
1662       if ($@) {
1663         warn qq{$@ (running "${line}")};
1664       }
1665       $self->_query_end($line);
1666     }
1667   }
1668 }
1669
1670 =head2 datetime_parser
1671
1672 Returns the datetime parser class
1673
1674 =cut
1675
1676 sub datetime_parser {
1677   my $self = shift;
1678   return $self->{datetime_parser} ||= do {
1679     $self->ensure_connected;
1680     $self->build_datetime_parser(@_);
1681   };
1682 }
1683
1684 =head2 datetime_parser_type
1685
1686 Defines (returns) the datetime parser class - currently hardwired to
1687 L<DateTime::Format::MySQL>
1688
1689 =cut
1690
1691 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1692
1693 =head2 build_datetime_parser
1694
1695 See L</datetime_parser>
1696
1697 =cut
1698
1699 sub build_datetime_parser {
1700   my $self = shift;
1701   my $type = $self->datetime_parser_type(@_);
1702   eval "use ${type}";
1703   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1704   return $type;
1705 }
1706
1707 {
1708     my $_check_sqlt_version; # private
1709     my $_check_sqlt_message; # private
1710     sub _check_sqlt_version {
1711         return $_check_sqlt_version if defined $_check_sqlt_version;
1712         eval 'use SQL::Translator "0.09"';
1713         $_check_sqlt_message = $@ || '';
1714         $_check_sqlt_version = !$@;
1715     }
1716
1717     sub _check_sqlt_message {
1718         _check_sqlt_version if !defined $_check_sqlt_message;
1719         $_check_sqlt_message;
1720     }
1721 }
1722
1723 sub DESTROY {
1724   my $self = shift;
1725   return if !$self->_dbh;
1726   $self->_verify_pid;
1727   $self->_dbh(undef);
1728 }
1729
1730 1;
1731
1732 =head1 SQL METHODS
1733
1734 The module defines a set of methods within the DBIC::SQL::Abstract
1735 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1736 SQL query functions.
1737
1738 The following methods are extended:-
1739
1740 =over 4
1741
1742 =item delete
1743
1744 =item insert
1745
1746 =item select
1747
1748 =item update
1749
1750 =item limit_dialect
1751
1752 See L</connect_info> for details.
1753 For setting, this method is deprecated in favor of L</connect_info>.
1754
1755 =item quote_char
1756
1757 See L</connect_info> for details.
1758 For setting, this method is deprecated in favor of L</connect_info>.
1759
1760 =item name_sep
1761
1762 See L</connect_info> for details.
1763 For setting, this method is deprecated in favor of L</connect_info>.
1764
1765 =back
1766
1767 =head1 AUTHORS
1768
1769 Matt S. Trout <mst@shadowcatsystems.co.uk>
1770
1771 Andy Grundman <andy@hybridized.org>
1772
1773 =head1 LICENSE
1774
1775 You may distribute this code under the same terms as Perl itself.
1776
1777 =cut