SQL::Abstract compatability
[dbsrgits/DBIx-Class-Historic.git] / lib / DBIx / Class / Storage / DBI.pm
1 package DBIx::Class::Storage::DBI;
2
3 use base 'DBIx::Class::Storage';
4
5 use strict;
6 use warnings;
7 use DBI;
8 use SQL::Abstract::Limit;
9 use DBIx::Class::Storage::DBI::Cursor;
10 use IO::File;
11 use Carp::Clan qw/DBIx::Class/;
12
13 BEGIN {
14
15 package DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
16
17 use base qw/SQL::Abstract::Limit/;
18
19 sub select {
20   my ($self, $table, $fields, $where, $order, @rest) = @_;
21   $table = $self->_quote($table) unless ref($table);
22   @rest = (-1) unless defined $rest[0];
23   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
24     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
25   local $self->{having_bind} = [];
26   my ($sql, @ret) = $self->SUPER::select(
27     $table, $self->_recurse_fields($fields), $where, $order, @rest
28   );
29   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
30 }
31
32 sub insert {
33   my $self = shift;
34   my $table = shift;
35   $table = $self->_quote($table) unless ref($table);
36   $self->SUPER::insert($table, @_);
37 }
38
39 sub update {
40   my $self = shift;
41   my $table = shift;
42   $table = $self->_quote($table) unless ref($table);
43   $self->SUPER::update($table, @_);
44 }
45
46 sub delete {
47   my $self = shift;
48   my $table = shift;
49   $table = $self->_quote($table) unless ref($table);
50   $self->SUPER::delete($table, @_);
51 }
52
53 sub _emulate_limit {
54   my $self = shift;
55   if ($_[3] == -1) {
56     return $_[1].$self->_order_by($_[2]);
57   } else {
58     return $self->SUPER::_emulate_limit(@_);
59   }
60 }
61
62 sub _recurse_fields {
63   my ($self, $fields) = @_;
64   my $ref = ref $fields;
65   return $self->_quote($fields) unless $ref;
66   return $$fields if $ref eq 'SCALAR';
67
68   if ($ref eq 'ARRAY') {
69     return join(', ', map { $self->_recurse_fields($_) } @$fields);
70   } elsif ($ref eq 'HASH') {
71     foreach my $func (keys %$fields) {
72       return $self->_sqlcase($func)
73         .'( '.$self->_recurse_fields($fields->{$func}).' )';
74     }
75   }
76 }
77
78 sub _order_by {
79   my $self = shift;
80   my $ret = '';
81   my @extra;
82   if (ref $_[0] eq 'HASH') {
83     if (defined $_[0]->{group_by}) {
84       $ret = $self->_sqlcase(' group by ')
85                .$self->_recurse_fields($_[0]->{group_by});
86     }
87     if (defined $_[0]->{having}) {
88       my $frag;
89       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
90       push(@{$self->{having_bind}}, @extra);
91       $ret .= $self->_sqlcase(' having ').$frag;
92     }
93     if (defined $_[0]->{order_by}) {
94       $ret .= $self->SUPER::_order_by($_[0]->{order_by});
95     }
96   } elsif(ref $_[0] eq 'SCALAR') {
97     $ret = $self->_sqlcase(' order by ').${ $_[0] };
98   } else {
99     $ret = $self->SUPER::_order_by(@_);
100   }
101   return $ret;
102 }
103
104 sub _order_directions {
105   my ($self, $order) = @_;
106   $order = $order->{order_by} if ref $order eq 'HASH';
107   return $self->SUPER::_order_directions($order);
108 }
109
110 sub _table {
111   my ($self, $from) = @_;
112   if (ref $from eq 'ARRAY') {
113     return $self->_recurse_from(@$from);
114   } elsif (ref $from eq 'HASH') {
115     return $self->_make_as($from);
116   } else {
117     return $from; # would love to quote here but _table ends up getting called
118                   # twice during an ->select without a limit clause due to
119                   # the way S::A::Limit->select works. should maybe consider
120                   # bypassing this and doing S::A::select($self, ...) in
121                   # our select method above. meantime, quoting shims have
122                   # been added to select/insert/update/delete here
123   }
124 }
125
126 sub _recurse_from {
127   my ($self, $from, @join) = @_;
128   my @sqlf;
129   push(@sqlf, $self->_make_as($from));
130   foreach my $j (@join) {
131     push @sqlf, ', ' . $self->_quote($j) and next unless ref $j;
132     push @sqlf, ', ' . $$j and next if ref $j eq 'SCALAR';
133     
134     my ($to, $on) = @$j;
135
136     # check whether a join type exists
137     my $join_clause = '';
138     if (ref($to) eq 'HASH' and exists($to->{-join_type})) {
139       $join_clause = $self->_sqlcase(' ' . $to->{-join_type} . ' JOIN ');
140     } else {
141       $join_clause = $self->_sqlcase(' JOIN ');
142     }
143     push(@sqlf, $join_clause);
144
145     if (ref $to eq 'ARRAY') {
146       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
147     } else {
148       push(@sqlf, $self->_make_as($to));
149     }
150     push(@sqlf, $self->_sqlcase(' ON '), $self->_join_condition($on));
151   }
152   return join('', @sqlf);
153 }
154
155 sub _make_as {
156   my ($self, $from) = @_;
157   return $self->_quote($from) unless ref $from;
158   return $$from if ref $from eq 'SCALAR';
159   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
160                      reverse each %{$self->_skip_options($from)});
161 }
162 sub _skip_options {
163   my ($self, $hash) = @_;
164   my $clean_hash = {};
165   $clean_hash->{$_} = $hash->{$_}
166     for grep {!/^-/} keys %$hash;
167   return $clean_hash;
168 }
169
170 sub _join_condition {
171   my ($self, $cond) = @_;
172   if (ref $cond eq 'HASH') {
173     my %j;
174     for (keys %$cond) {
175       my $x = '= '.$self->_quote($cond->{$_}); $j{$_} = \$x;
176     };
177     return $self->_recurse_where(\%j);
178   } elsif (ref $cond eq 'ARRAY') {
179     return join(' OR ', map { $self->_join_condition($_) } @$cond);
180   } else {
181     die "Can't handle this yet!";
182   }
183 }
184
185 sub _quote {
186   my ($self, $label) = @_;
187   return '' unless defined $label;
188   return "*" if $label eq '*';
189   return $label unless $self->{quote_char};
190   if(ref $self->{quote_char} eq "ARRAY"){
191     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
192       if !defined $self->{name_sep};
193     my $sep = $self->{name_sep};
194     return join($self->{name_sep},
195         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
196        split(/\Q$sep\E/,$label));
197   }
198   return $self->SUPER::_quote($label);
199 }
200
201 sub _RowNum {
202    my $self = shift;
203    my $c;
204    $_[0] =~ s/SELECT (.*?) FROM/
205      'SELECT '.join(', ', map { $_.' AS col'.++$c } split(', ', $1)).' FROM'/e;
206    $self->SUPER::_RowNum(@_);
207 }
208
209 # Accessor for setting limit dialect. This is useful
210 # for JDBC-bridge among others where the remote SQL-dialect cannot
211 # be determined by the name of the driver alone.
212 #
213 sub limit_dialect {
214     my $self = shift;
215     $self->{limit_dialect} = shift if @_;
216     return $self->{limit_dialect};
217 }
218
219 sub quote_char {
220     my $self = shift;
221     $self->{quote_char} = shift if @_;
222     return $self->{quote_char};
223 }
224
225 sub name_sep {
226     my $self = shift;
227     $self->{name_sep} = shift if @_;
228     return $self->{name_sep};
229 }
230
231
232
233
234 package DBIx::Class::Storage::DBI::DebugCallback;
235
236 sub print {
237   my ($self, $string) = @_;
238   $string =~ m/^(\w+)/;
239   ${$self}->($1, $string);
240 }
241
242 } # End of BEGIN block
243
244 use base qw/DBIx::Class/;
245
246 __PACKAGE__->load_components(qw/AccessorGroup/);
247
248 __PACKAGE__->mk_group_accessors('simple' =>
249   qw/connect_info _dbh _sql_maker _conn_pid _conn_tid debug debugfh
250      cursor on_connect_do transaction_depth/);
251
252 sub new {
253   my $new = bless({}, ref $_[0] || $_[0]);
254   $new->cursor("DBIx::Class::Storage::DBI::Cursor");
255   $new->transaction_depth(0);
256   if (defined($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG}) &&
257      ($ENV{DBIX_CLASS_STORAGE_DBI_DEBUG} =~ /=(.+)$/)) {
258     $new->debugfh(IO::File->new($1, 'w'))
259       or $new->throw_exception("Cannot open trace file $1");
260   } else {
261     $new->debugfh(IO::File->new('>&STDERR'));
262   }
263   $new->debug(1) if $ENV{DBIX_CLASS_STORAGE_DBI_DEBUG};
264   return $new;
265 }
266
267 sub throw_exception {
268   my ($self, $msg) = @_;
269   croak($msg);
270 }
271
272 =head1 NAME
273
274 DBIx::Class::Storage::DBI - DBI storage handler
275
276 =head1 SYNOPSIS
277
278 =head1 DESCRIPTION
279
280 This class represents the connection to the database
281
282 =head1 METHODS
283
284 =cut
285
286 =head2 on_connect_do
287
288 Executes the sql statements given as a listref on every db connect.
289
290 =head2 quote_char
291
292 Specifies what characters to use to quote table and column names. If 
293 you use this you will want to specify L<name_sep> as well.
294
295 quote_char expectes either a single character, in which case is it is placed
296 on either side of the table/column, or an array of length 2 in which case the
297 table/column name is placed between the elements.
298
299 For example under MySQL you'd use C<quote_char('`')>, and user SQL Server you'd 
300 use C<quote_char(qw/[ ]/)>.
301
302 =head2 name_sep
303
304 This only needs to be used in conjunction with L<quote_char>, and is used to 
305 specify the charecter that seperates elements (schemas, tables, columns) from 
306 each other. In most cases this is simply a C<.>.
307
308 =head2 debug
309
310 Causes SQL trace information to be emitted on C<debugfh> filehandle
311 (or C<STDERR> if C<debugfh> has not specifically been set).
312
313 =head2 debugfh
314
315 Sets or retrieves the filehandle used for trace/debug output.  This
316 should be an IO::Handle compatible object (only the C<print> method is
317 used).  Initially set to be STDERR - although see information on the
318 L<DBIX_CLASS_STORAGE_DBI_DEBUG> environment variable.
319
320 =head2 debugcb
321
322 Sets a callback to be executed each time a statement is run; takes a sub
323 reference. Overrides debugfh. Callback is executed as $sub->($op, $info)
324 where $op is SELECT/INSERT/UPDATE/DELETE and $info is what would normally
325 be printed.
326
327 =cut
328
329 sub debugcb {
330   my ($self, $cb) = @_;
331   my $cb_obj = bless(\$cb, 'DBIx::Class::Storage::DBI::DebugCallback');
332   $self->debugfh($cb_obj);
333 }
334
335 sub disconnect {
336   my ($self) = @_;
337
338   if( $self->connected ) {
339     $self->_dbh->rollback unless $self->_dbh->{AutoCommit};
340     $self->_dbh->disconnect;
341     $self->_dbh(undef);
342   }
343 }
344
345 sub connected {
346   my ($self) = @_;
347
348   if(my $dbh = $self->_dbh) {
349       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
350           $self->_sql_maker(undef);
351           return $self->_dbh(undef);
352       }
353       elsif($self->_conn_pid != $$) {
354           $self->_dbh->{InactiveDestroy} = 1;
355           $self->_sql_maker(undef);
356           return $self->_dbh(undef)
357       }
358       return ($dbh->FETCH('Active') && $dbh->ping);
359   }
360
361   return 0;
362 }
363
364 sub ensure_connected {
365   my ($self) = @_;
366
367   unless ($self->connected) {
368     $self->_populate_dbh;
369   }
370 }
371
372 =head2 dbh
373
374 Returns the dbh - a data base handle of class L<DBI>.
375
376 =cut
377
378 sub dbh {
379   my ($self) = @_;
380
381   $self->ensure_connected;
382   return $self->_dbh;
383 }
384
385 sub sql_maker {
386   my ($self) = @_;
387   unless ($self->_sql_maker) {
388     $self->_sql_maker(new DBIC::SQL::Abstract( limit_dialect => $self->dbh ));
389   }
390   return $self->_sql_maker;
391 }
392
393 sub _populate_dbh {
394   my ($self) = @_;
395   my @info = @{$self->connect_info || []};
396   $self->_dbh($self->_connect(@info));
397   my $driver = $self->_dbh->{Driver}->{Name};
398   eval "require DBIx::Class::Storage::DBI::${driver}";
399   unless ($@) {
400     bless $self, "DBIx::Class::Storage::DBI::${driver}";
401   }
402   # if on-connect sql statements are given execute them
403   foreach my $sql_statement (@{$self->on_connect_do || []}) {
404     $self->_dbh->do($sql_statement);
405   }
406
407   $self->_conn_pid($$);
408   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
409 }
410
411 sub _connect {
412   my ($self, @info) = @_;
413
414   $self->throw_exception("You failed to provide any connection info")
415       if !@info;
416
417   my ($old_connect_via, $dbh);
418
419   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
420       $old_connect_via = $DBI::connect_via;
421       $DBI::connect_via = 'connect';
422   }
423
424   eval {
425     if(ref $info[0] eq 'CODE') {
426         $dbh = &{$info[0]};
427     }
428     else {
429         $dbh = DBI->connect(@info);
430     }
431   };
432
433   $DBI::connect_via = $old_connect_via if $old_connect_via;
434
435   if (!$dbh || $@) {
436     $self->throw_exception("DBI Connection failed: " . ($@ || $DBI::errstr));
437   }
438
439   $dbh;
440 }
441
442 =head2 txn_begin
443
444 Calls begin_work on the current dbh.
445
446 See L<DBIx::Class::Schema> for the txn_do() method, which allows for
447 an entire code block to be executed transactionally.
448
449 =cut
450
451 sub txn_begin {
452   my $self = shift;
453   if ($self->{transaction_depth}++ == 0) {
454     my $dbh = $self->dbh;
455     if ($dbh->{AutoCommit}) {
456       $self->debugfh->print("BEGIN WORK\n")
457         if ($self->debug);
458       $dbh->begin_work;
459     }
460   }
461 }
462
463 =head2 txn_commit
464
465 Issues a commit against the current dbh.
466
467 =cut
468
469 sub txn_commit {
470   my $self = shift;
471   my $dbh = $self->dbh;
472   if ($self->{transaction_depth} == 0) {
473     unless ($dbh->{AutoCommit}) {
474       $self->debugfh->print("COMMIT\n")
475         if ($self->debug);
476       $dbh->commit;
477     }
478   }
479   else {
480     if (--$self->{transaction_depth} == 0) {
481       $self->debugfh->print("COMMIT\n")
482         if ($self->debug);
483       $dbh->commit;
484     }
485   }
486 }
487
488 =head2 txn_rollback
489
490 Issues a rollback against the current dbh. A nested rollback will
491 throw a L<DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION> exception,
492 which allows the rollback to propagate to the outermost transaction.
493
494 =cut
495
496 sub txn_rollback {
497   my $self = shift;
498
499   eval {
500     my $dbh = $self->dbh;
501     if ($self->{transaction_depth} == 0) {
502       unless ($dbh->{AutoCommit}) {
503         $self->debugfh->print("ROLLBACK\n")
504           if ($self->debug);
505         $dbh->rollback;
506       }
507     }
508     else {
509       if (--$self->{transaction_depth} == 0) {
510         $self->debugfh->print("ROLLBACK\n")
511           if ($self->debug);
512         $dbh->rollback;
513       }
514       else {
515         die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
516       }
517     }
518   };
519
520   if ($@) {
521     my $error = $@;
522     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
523     $error =~ /$exception_class/ and $self->throw_exception($error);
524     $self->{transaction_depth} = 0;          # ensure that a failed rollback
525     $self->throw_exception($error);          # resets the transaction depth
526   }
527 }
528
529 sub _execute {
530   my ($self, $op, $extra_bind, $ident, @args) = @_;
531   my ($sql, @bind) = $self->sql_maker->$op($ident, @args);
532   unshift(@bind, @$extra_bind) if $extra_bind;
533   if ($self->debug) {
534     my $bind_str = join(', ', map {
535       defined $_ ? qq{`$_'} : q{`NULL'}
536     } @bind);
537     $self->debugfh->print("$sql ($bind_str)\n");
538   }
539   my $sth = eval { $self->sth($sql,$op) };
540
541   if (!$sth || $@) {
542     $self->throw_exception(
543       'no sth generated via sql (' . ($@ || $self->_dbh->errstr) . "): $sql"
544     );
545   }
546   @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
547   my $rv = eval { $sth->execute(@bind) };
548   if ($@ || !$rv) {
549     my $bind_str = join(', ', map {
550       defined $_ ? qq{`$_'} : q{`NULL'}
551     } @bind);
552     $self->throw_exception(
553       "Error executing '$sql' ($bind_str): ".($@ || $sth->errstr)
554     );
555   }
556   return (wantarray ? ($rv, $sth, @bind) : $rv);
557 }
558
559 sub insert {
560   my ($self, $ident, $to_insert) = @_;
561   $self->throw_exception(
562     "Couldn't insert ".join(', ',
563       map "$_ => $to_insert->{$_}", keys %$to_insert
564     )." into ${ident}"
565   ) unless ($self->_execute('insert' => [], $ident, $to_insert));
566   return $to_insert;
567 }
568
569 sub update {
570   return shift->_execute('update' => [], @_);
571 }
572
573 sub delete {
574   return shift->_execute('delete' => [], @_);
575 }
576
577 sub _select {
578   my ($self, $ident, $select, $condition, $attrs) = @_;
579   my $order = $attrs->{order_by};
580   if (ref $condition eq 'SCALAR') {
581     $order = $1 if $$condition =~ s/ORDER BY (.*)$//i;
582   }
583   if (exists $attrs->{group_by} || $attrs->{having}) {
584     $order = {
585       group_by => $attrs->{group_by},
586       having => $attrs->{having},
587       ($order ? (order_by => $order) : ())
588     };
589   }
590   my @args = ('select', $attrs->{bind}, $ident, $select, $condition, $order);
591   if ($attrs->{software_limit} ||
592       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
593         $attrs->{software_limit} = 1;
594   } else {
595     $self->throw_exception("rows attribute must be positive if present")
596       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
597     push @args, $attrs->{rows}, $attrs->{offset};
598   }
599   return $self->_execute(@args);
600 }
601
602 sub select {
603   my $self = shift;
604   my ($ident, $select, $condition, $attrs) = @_;
605   return $self->cursor->new($self, \@_, $attrs);
606 }
607
608 # Need to call finish() to work round broken DBDs
609
610 sub select_single {
611   my $self = shift;
612   my ($rv, $sth, @bind) = $self->_select(@_);
613   my @row = $sth->fetchrow_array;
614   $sth->finish();
615   return @row;
616 }
617
618 sub sth {
619   my ($self, $sql) = @_;
620   # 3 is the if_active parameter which avoids active sth re-use
621   return $self->dbh->prepare_cached($sql, {}, 3);
622 }
623
624 =head2 columns_info_for
625
626 Returns database type info for a given table columns.
627
628 =cut
629
630 sub columns_info_for {
631   my ($self, $table) = @_;
632
633   my $dbh = $self->dbh;
634
635   if ($dbh->can('column_info')) {
636     my %result;
637     my $old_raise_err = $dbh->{RaiseError};
638     my $old_print_err = $dbh->{PrintError};
639     $dbh->{RaiseError} = 1;
640     $dbh->{PrintError} = 0;
641     eval {
642       my $sth = $dbh->column_info( undef, undef, $table, '%' );
643       $sth->execute();
644       while ( my $info = $sth->fetchrow_hashref() ){
645         my %column_info;
646         $column_info{data_type}   = $info->{TYPE_NAME};
647         $column_info{size}      = $info->{COLUMN_SIZE};
648         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
649         $column_info{default_value} = $info->{COLUMN_DEF};
650
651         $result{$info->{COLUMN_NAME}} = \%column_info;
652       }
653     };
654     $dbh->{RaiseError} = $old_raise_err;
655     $dbh->{PrintError} = $old_print_err;
656     return \%result if !$@;
657   }
658
659   my %result;
660   my $sth = $dbh->prepare("SELECT * FROM $table WHERE 1=0");
661   $sth->execute;
662   my @columns = @{$sth->{NAME_lc}};
663   for my $i ( 0 .. $#columns ){
664     my %column_info;
665     my $type_num = $sth->{TYPE}->[$i];
666     my $type_name;
667     if(defined $type_num && $dbh->can('type_info')) {
668       my $type_info = $dbh->type_info($type_num);
669       $type_name = $type_info->{TYPE_NAME} if $type_info;
670     }
671     $column_info{data_type} = $type_name ? $type_name : $type_num;
672     $column_info{size} = $sth->{PRECISION}->[$i];
673     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
674
675     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
676       $column_info{data_type} = $1;
677       $column_info{size}    = $2;
678     }
679
680     $result{$columns[$i]} = \%column_info;
681   }
682
683   return \%result;
684 }
685
686 sub last_insert_id {
687   my ($self, $row) = @_;
688     
689   return $self->dbh->func('last_insert_rowid');
690
691 }
692
693 sub sqlt_type { shift->dbh->{Driver}->{Name} }
694
695 sub deployment_statements {
696   my ($self, $schema, $type, $sqltargs) = @_;
697   $type ||= $self->sqlt_type;
698   eval "use SQL::Translator";
699   $self->throw_exception("Can't deploy without SQL::Translator: $@") if $@;
700   eval "use SQL::Translator::Parser::DBIx::Class;";
701   $self->throw_exception($@) if $@;
702   eval "use SQL::Translator::Producer::${type};";
703   $self->throw_exception($@) if $@;
704   my $tr = SQL::Translator->new(%$sqltargs);
705   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
706   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
707 }
708
709 sub deploy {
710   my ($self, $schema, $type, $sqltargs) = @_;
711   foreach my $statement ( $self->deployment_statements($schema, $type, $sqltargs) ) {
712     for ( split(";\n", $statement)) {
713       $self->debugfh->print("$_\n") if $self->debug;
714       $self->dbh->do($_) or warn "SQL was:\n $_";
715     }
716   }
717 }
718
719 sub DESTROY { shift->disconnect }
720
721 1;
722
723 =head1 ENVIRONMENT VARIABLES
724
725 =head2 DBIX_CLASS_STORAGE_DBI_DEBUG
726
727 If C<DBIX_CLASS_STORAGE_DBI_DEBUG> is set then SQL trace information
728 is produced (as when the L<debug> method is set).
729
730 If the value is of the form C<1=/path/name> then the trace output is
731 written to the file C</path/name>.
732
733 This environment variable is checked when the storage object is first
734 created (when you call connect on your schema).  So, run-time changes 
735 to this environment variable will not take effect unless you also 
736 re-connect on your schema.
737
738 =head1 AUTHORS
739
740 Matt S. Trout <mst@shadowcatsystems.co.uk>
741
742 Andy Grundman <andy@hybridized.org>
743
744 =head1 LICENSE
745
746 You may distribute this code under the same terms as Perl itself.
747
748 =cut
749