lib/DBIx/Class/Storage/DBI.pm

   1 package DBIx::Class::Storage::DBI;
   2 # -*- mode: cperl; cperl-indent-level: 2 -*-
   3
   4 use base 'DBIx::Class::Storage';
   5
   6 use strict;
   7 use warnings;
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use DBI;
  10 use SQL::Abstract::Limit;
  11 use DBIx::Class::Storage::DBI::Cursor;
  12 use DBIx::Class::Storage::Statistics;
  13 use Scalar::Util qw/blessed weaken/;
  14
  15 __PACKAGE__->mk_group_accessors('simple' =>
  16     qw/_connect_info _dbi_connect_info _dbh _sql_maker _sql_maker_opts
  17        _conn_pid _conn_tid transaction_depth _dbh_autocommit savepoints/
  18 );
  19
  20 # the values for these accessors are picked out (and deleted) from
  21 # the attribute hashref passed to connect_info
  22 my @storage_options = qw/
  23   on_connect_do on_disconnect_do disable_sth_caching unsafe auto_savepoint
  24 /;
  25 __PACKAGE__->mk_group_accessors('simple' => @storage_options);
  26
  27
  28 # default cursor class, overridable in connect_info attributes
  29 __PACKAGE__->cursor_class('DBIx::Class::Storage::DBI::Cursor');
  30
  31 __PACKAGE__->mk_group_accessors('inherited' => qw/sql_maker_class/);
  32 __PACKAGE__->sql_maker_class('DBIC::SQL::Abstract');
  33
  34 BEGIN {
  35
  36 package # Hide from PAUSE
  37   DBIC::SQL::Abstract; # Would merge upstream, but nate doesn't reply :(
  38
  39 use base qw/SQL::Abstract::Limit/;
  40
  41 # This prevents the caching of $dbh in S::A::L, I believe
  42 sub new {
  43   my $self = shift->SUPER::new(@_);
  44
  45   # If limit_dialect is a ref (like a $dbh), go ahead and replace
  46   #   it with what it resolves to:
  47   $self->{limit_dialect} = $self->_find_syntax($self->{limit_dialect})
  48     if ref $self->{limit_dialect};
  49
  50   $self;
  51 }
  52
  53 sub _RowNumberOver {
  54   my ($self, $sql, $order, $rows, $offset ) = @_;
  55
  56   $offset += 1;
  57   my $last = $rows + $offset;
  58   my ( $order_by ) = $self->_order_by( $order );
  59
  60   $sql = <<"";
  61 SELECT * FROM
  62 (
  63    SELECT Q1.*, ROW_NUMBER() OVER( ) AS ROW_NUM FROM (
  64       $sql
  65       $order_by
  66    ) Q1
  67 ) Q2
  68 WHERE ROW_NUM BETWEEN $offset AND $last
  69
  70   return $sql;
  71 }
  72
  73
  74 # While we're at it, this should make LIMIT queries more efficient,
  75 #  without digging into things too deeply
  76 use Scalar::Util 'blessed';
  77 sub _find_syntax {
  78   my ($self, $syntax) = @_;
  79   my $dbhname = blessed($syntax) ?  $syntax->{Driver}{Name} : $syntax;
  80   if(ref($self) && $dbhname && $dbhname eq 'DB2') {
  81     return 'RowNumberOver';
  82   }
  83
  84   $self->{_cached_syntax} ||= $self->SUPER::_find_syntax($syntax);
  85 }
  86
  87 sub select {
  88   my ($self, $table, $fields, $where, $order, @rest) = @_;
  89   $table = $self->_quote($table) unless ref($table);
  90   local $self->{rownum_hack_count} = 1
  91     if (defined $rest[0] && $self->{limit_dialect} eq 'RowNum');
  92   @rest = (-1) unless defined $rest[0];
  93   die "LIMIT 0 Does Not Compute" if $rest[0] == 0;
  94     # and anyway, SQL::Abstract::Limit will cause a barf if we don't first
  95   local $self->{having_bind} = [];
  96   my ($sql, @ret) = $self->SUPER::select(
  97     $table, $self->_recurse_fields($fields), $where, $order, @rest
  98   );
  99   $sql .=
 100     $self->{for} ?
 101     (
 102       $self->{for} eq 'update' ? ' FOR UPDATE' :
 103       $self->{for} eq 'shared' ? ' FOR SHARE'  :
 104       ''
 105     ) :
 106     ''
 107   ;
 108   return wantarray ? ($sql, @ret, @{$self->{having_bind}}) : $sql;
 109 }
 110
 111 sub insert {
 112   my $self = shift;
 113   my $table = shift;
 114   $table = $self->_quote($table) unless ref($table);
 115   $self->SUPER::insert($table, @_);
 116 }
 117
 118 sub update {
 119   my $self = shift;
 120   my $table = shift;
 121   $table = $self->_quote($table) unless ref($table);
 122   $self->SUPER::update($table, @_);
 123 }
 124
 125 sub delete {
 126   my $self = shift;
 127   my $table = shift;
 128   $table = $self->_quote($table) unless ref($table);
 129   $self->SUPER::delete($table, @_);
 130 }
 131
 132 sub _emulate_limit {
 133   my $self = shift;
 134   if ($_[3] == -1) {
 135     return $_[1].$self->_order_by($_[2]);
 136   } else {
 137     return $self->SUPER::_emulate_limit(@_);
 138   }
 139 }
 140
 141 sub _recurse_fields {
 142   my ($self, $fields, $params) = @_;
 143   my $ref = ref $fields;
 144   return $self->_quote($fields) unless $ref;
 145   return $$fields if $ref eq 'SCALAR';
 146
 147   if ($ref eq 'ARRAY') {
 148     return join(', ', map {
 149       $self->_recurse_fields($_)
 150         .(exists $self->{rownum_hack_count} && !($params && $params->{no_rownum_hack})
 151           ? ' AS col'.$self->{rownum_hack_count}++
 152           : '')
 153       } @$fields);
 154   } elsif ($ref eq 'HASH') {
 155     foreach my $func (keys %$fields) {
 156       return $self->_sqlcase($func)
 157         .'( '.$self->_recurse_fields($fields->{$func}).' )';
 158     }
 159   }
 160 }
 161
 162 sub _order_by {
 163   my $self = shift;
 164   my $ret = '';
 165   my @extra;
 166   if (ref $_[0] eq 'HASH') {
 167     if (defined $_[0]->{group_by}) {
 168       $ret = $self->_sqlcase(' group by ')
 169         .$self->_recurse_fields($_[0]->{group_by}, { no_rownum_hack => 1 });
 170     }
 171     if (defined $_[0]->{having}) {
 172       my $frag;
 173       ($frag, @extra) = $self->_recurse_where($_[0]->{having});
 174       push(@{$self->{having_bind}}, @extra);
 175       $ret .= $self->_sqlcase(' having ').$frag;
 176     }
 177     if (defined $_[0]->{order_by}) {
 178       $ret .= $self->_order_by($_[0]->{order_by});
 179     }
 180   } elsif (ref $_[0] eq 'SCALAR') {
 181     $ret = $self->_sqlcase(' order by ').${ $_[0] };
 182   } elsif (ref $_[0] eq 'ARRAY' && @{$_[0]}) {
 183     my @order = @{+shift};
 184     $ret = $self->_sqlcase(' order by ')
 185           .join(', ', map {
 186                         my $r = $self->_order_by($_, @_);
 187                         $r =~ s/^ ?ORDER BY //i;
 188                         $r;
 189                       } @order);
 190   } else {
 191     $ret = $self->SUPER::_order_by(@_);
 192   }
 193   return $ret;
 194 }
 195
 196 sub _order_directions {
 197   my ($self, $order) = @_;
 198   $order = $order->{order_by} if ref $order eq 'HASH';
 199   return $self->SUPER::_order_directions($order);
 200 }
 201
 202 sub _table {
 203   my ($self, $from) = @_;
 204   if (ref $from eq 'ARRAY') {
 205     return $self->_recurse_from(@$from);
 206   } elsif (ref $from eq 'HASH') {
 207     return $self->_make_as($from);
 208   } else {
 209     return $from; # would love to quote here but _table ends up getting called
 210                   # twice during an ->select without a limit clause due to
 211                   # the way S::A::Limit->select works. should maybe consider
 212                   # bypassing this and doing S::A::select($self, ...) in
 213                   # our select method above. meantime, quoting shims have
 214                   # been added to select/insert/update/delete here
 215   }
 216 }
 217
 218 sub _recurse_from {
 219   my ($self, $from, @join) = @_;
 220   my @sqlf;
 221   push(@sqlf, $self->_make_as($from));
 222   foreach my $j (@join) {
 223     my ($to, $on) = @$j;
 224
 225     # check whether a join type exists
 226     my $join_clause = '';
 227     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 228     if (ref($to_jt) eq 'HASH' and exists($to_jt->{-join_type})) {
 229       $join_clause = ' '.uc($to_jt->{-join_type}).' JOIN ';
 230     } else {
 231       $join_clause = ' JOIN ';
 232     }
 233     push(@sqlf, $join_clause);
 234
 235     if (ref $to eq 'ARRAY') {
 236       push(@sqlf, '(', $self->_recurse_from(@$to), ')');
 237     } else {
 238       push(@sqlf, $self->_make_as($to));
 239     }
 240     push(@sqlf, ' ON ', $self->_join_condition($on));
 241   }
 242   return join('', @sqlf);
 243 }
 244
 245 sub _make_as {
 246   my ($self, $from) = @_;
 247   return join(' ', map { (ref $_ eq 'SCALAR' ? $$_ : $self->_quote($_)) }
 248                      reverse each %{$self->_skip_options($from)});
 249 }
 250
 251 sub _skip_options {
 252   my ($self, $hash) = @_;
 253   my $clean_hash = {};
 254   $clean_hash->{$_} = $hash->{$_}
 255     for grep {!/^-/} keys %$hash;
 256   return $clean_hash;
 257 }
 258
 259 sub _join_condition {
 260   my ($self, $cond) = @_;
 261   if (ref $cond eq 'HASH') {
 262     my %j;
 263     for (keys %$cond) {
 264       my $v = $cond->{$_};
 265       if (ref $v) {
 266         # XXX no throw_exception() in this package and croak() fails with strange results
 267         Carp::croak(ref($v) . qq{ reference arguments are not supported in JOINS - try using \"..." instead'})
 268             if ref($v) ne 'SCALAR';
 269         $j{$_} = $v;
 270       }
 271       else {
 272         my $x = '= '.$self->_quote($v); $j{$_} = \$x;
 273       }
 274     };
 275     return scalar($self->_recurse_where(\%j));
 276   } elsif (ref $cond eq 'ARRAY') {
 277     return join(' OR ', map { $self->_join_condition($_) } @$cond);
 278   } else {
 279     die "Can't handle this yet!";
 280   }
 281 }
 282
 283 sub _quote {
 284   my ($self, $label) = @_;
 285   return '' unless defined $label;
 286   return "*" if $label eq '*';
 287   return $label unless $self->{quote_char};
 288   if(ref $self->{quote_char} eq "ARRAY"){
 289     return $self->{quote_char}->[0] . $label . $self->{quote_char}->[1]
 290       if !defined $self->{name_sep};
 291     my $sep = $self->{name_sep};
 292     return join($self->{name_sep},
 293         map { $self->{quote_char}->[0] . $_ . $self->{quote_char}->[1]  }
 294        split(/\Q$sep\E/,$label));
 295   }
 296   return $self->SUPER::_quote($label);
 297 }
 298
 299 sub limit_dialect {
 300     my $self = shift;
 301     $self->{limit_dialect} = shift if @_;
 302     return $self->{limit_dialect};
 303 }
 304
 305 sub quote_char {
 306     my $self = shift;
 307     $self->{quote_char} = shift if @_;
 308     return $self->{quote_char};
 309 }
 310
 311 sub name_sep {
 312     my $self = shift;
 313     $self->{name_sep} = shift if @_;
 314     return $self->{name_sep};
 315 }
 316
 317 } # End of BEGIN block
 318
 319 =head1 NAME
 320
 321 DBIx::Class::Storage::DBI - DBI storage handler
 322
 323 =head1 SYNOPSIS
 324
 325   my $schema = MySchema->connect('dbi:SQLite:my.db');
 326
 327   $schema->storage->debug(1);
 328   $schema->dbh_do("DROP TABLE authors");
 329
 330   $schema->resultset('Book')->search({
 331      written_on => $schema->storage->datetime_parser(DateTime->now)
 332   });
 333
 334 =head1 DESCRIPTION
 335
 336 This class represents the connection to an RDBMS via L<DBI>.  See
 337 L<DBIx::Class::Storage> for general information.  This pod only
 338 documents DBI-specific methods and behaviors.
 339
 340 =head1 METHODS
 341
 342 =cut
 343
 344 sub new {
 345   my $new = shift->next::method(@_);
 346
 347   $new->transaction_depth(0);
 348   $new->_sql_maker_opts({});
 349   $new->{savepoints} = [];
 350   $new->{_in_dbh_do} = 0;
 351   $new->{_dbh_gen} = 0;
 352
 353   $new;
 354 }
 355
 356 =head2 connect_info
 357
 358 This method is normally called by L<DBIx::Class::Schema/connection>, which
 359 encapsulates its argument list in an arrayref before passing them here.
 360
 361 The argument list may contain:
 362
 363 =over
 364
 365 =item *
 366
 367 The same 4-element argument set one would normally pass to
 368 L<DBI/connect>, optionally followed by
 369 L<extra attributes|/DBIx::Class specific connection attributes>
 370 recognized by DBIx::Class:
 371
 372   $connect_info_args = [ $dsn, $user, $password, \%dbi_attributes?, \%extra_attributes? ];
 373
 374 =item *
 375
 376 A single code reference which returns a connected
 377 L<DBI database handle|DBI/connect> optionally followed by
 378 L<extra attributes|/DBIx::Class specific connection attributes> recognized
 379 by DBIx::Class:
 380
 381   $connect_info_args = [ sub { DBI->connect (...) }, \%extra_attributes? ];
 382
 383 =item *
 384
 385 A single hashref with all the attributes and the dsn/user/password
 386 mixed together:
 387
 388   $connect_info_args = [{
 389     dsn => $dsn,
 390     user => $user,
 391     password => $pass,
 392     %dbi_attributes,
 393     %extra_attributes,
 394   }];
 395
 396 This is particularly useful for L<Catalyst> based applications, allowing the
 397 following config (L<Config::General> style):
 398
 399   <Model::DB>
 400     schema_class   App::DB
 401     <connect_info>
 402       dsn          dbi:mysql:database=test
 403       user         testuser
 404       password     TestPass
 405       AutoCommit   1
 406     </connect_info>
 407   </Model::DB>
 408
 409 =back
 410
 411 Please note that the L<DBI> docs recommend that you always explicitly
 412 set C<AutoCommit> to either I<0> or I<1>.  L<DBIx::Class> further
 413 recommends that it be set to I<1>, and that you perform transactions
 414 via our L<DBIx::Class::Schema/txn_do> method.  L<DBIx::Class> will set it
 415 to I<1> if you do not do explicitly set it to zero.  This is the default
 416 for most DBDs. See L</DBIx::Class and AutoCommit> for details.
 417
 418 =head3 DBIx::Class specific connection attributes
 419
 420 In addition to the standard L<DBI|DBI/ATTRIBUTES_COMMON_TO_ALL_HANDLES>
 421 L<connection|DBI/Database_Handle_Attributes> attributes, DBIx::Class recognizes
 422 the following connection options. These options can be mixed in with your other
 423 L<DBI> connection attributes, or placed in a seperate hashref
 424 (C<\%extra_attributes>) as shown above.
 425
 426 Every time C<connect_info> is invoked, any previous settings for
 427 these options will be cleared before setting the new ones, regardless of
 428 whether any options are specified in the new C<connect_info>.
 429
 430
 431 =over
 432
 433 =item on_connect_do
 434
 435 Specifies things to do immediately after connecting or re-connecting to
 436 the database.  Its value may contain:
 437
 438 =over
 439
 440 =item an array reference
 441
 442 This contains SQL statements to execute in order.  Each element contains
 443 a string or a code reference that returns a string.
 444
 445 =item a code reference
 446
 447 This contains some code to execute.  Unlike code references within an
 448 array reference, its return value is ignored.
 449
 450 =back
 451
 452 =item on_disconnect_do
 453
 454 Takes arguments in the same form as L</on_connect_do> and executes them
 455 immediately before disconnecting from the database.
 456
 457 Note, this only runs if you explicitly call L</disconnect> on the
 458 storage object.
 459
 460 =item disable_sth_caching
 461
 462 If set to a true value, this option will disable the caching of
 463 statement handles via L<DBI/prepare_cached>.
 464
 465 =item limit_dialect
 466
 467 Sets the limit dialect. This is useful for JDBC-bridge among others
 468 where the remote SQL-dialect cannot be determined by the name of the
 469 driver alone. See also L<SQL::Abstract::Limit>.
 470
 471 =item quote_char
 472
 473 Specifies what characters to use to quote table and column names. If
 474 you use this you will want to specify L</name_sep> as well.
 475
 476 C<quote_char> expects either a single character, in which case is it
 477 is placed on either side of the table/column name, or an arrayref of length
 478 2 in which case the table/column name is placed between the elements.
 479
 480 For example under MySQL you should use C<< quote_char => '`' >>, and for
 481 SQL Server you should use C<< quote_char => [qw/[ ]/] >>.
 482
 483 =item name_sep
 484
 485 This only needs to be used in conjunction with C<quote_char>, and is used to
 486 specify the charecter that seperates elements (schemas, tables, columns) from
 487 each other. In most cases this is simply a C<.>.
 488
 489 The consequences of not supplying this value is that L<SQL::Abstract>
 490 will assume DBIx::Class' uses of aliases to be complete column
 491 names. The output will look like I<"me.name"> when it should actually
 492 be I<"me"."name">.
 493
 494 =item unsafe
 495
 496 This Storage driver normally installs its own C<HandleError>, sets
 497 C<RaiseError> and C<ShowErrorStatement> on, and sets C<PrintError> off on
 498 all database handles, including those supplied by a coderef.  It does this
 499 so that it can have consistent and useful error behavior.
 500
 501 If you set this option to a true value, Storage will not do its usual
 502 modifications to the database handle's attributes, and instead relies on
 503 the settings in your connect_info DBI options (or the values you set in
 504 your connection coderef, in the case that you are connecting via coderef).
 505
 506 Note that your custom settings can cause Storage to malfunction,
 507 especially if you set a C<HandleError> handler that suppresses exceptions
 508 and/or disable C<RaiseError>.
 509
 510 =item auto_savepoint
 511
 512 If this option is true, L<DBIx::Class> will use savepoints when nesting
 513 transactions, making it possible to recover from failure in the inner
 514 transaction without having to abort all outer transactions.
 515
 516 =item cursor_class
 517
 518 Use this argument to supply a cursor class other than the default
 519 L<DBIx::Class::Storage::DBI::Cursor>.
 520
 521 =back
 522
 523 Some real-life examples of arguments to L</connect_info> and
 524 L<DBIx::Class::Schema/connect>
 525
 526   # Simple SQLite connection
 527   ->connect_info([ 'dbi:SQLite:./foo.db' ]);
 528
 529   # Connect via subref
 530   ->connect_info([ sub { DBI->connect(...) } ]);
 531
 532   # A bit more complicated
 533   ->connect_info(
 534     [
 535       'dbi:Pg:dbname=foo',
 536       'postgres',
 537       'my_pg_password',
 538       { AutoCommit => 1 },
 539       { quote_char => q{"}, name_sep => q{.} },
 540     ]
 541   );
 542
 543   # Equivalent to the previous example
 544   ->connect_info(
 545     [
 546       'dbi:Pg:dbname=foo',
 547       'postgres',
 548       'my_pg_password',
 549       { AutoCommit => 1, quote_char => q{"}, name_sep => q{.} },
 550     ]
 551   );
 552
 553   # Same, but with hashref as argument
 554   # See parse_connect_info for explanation
 555   ->connect_info(
 556     [{
 557       dsn         => 'dbi:Pg:dbname=foo',
 558       user        => 'postgres',
 559       password    => 'my_pg_password',
 560       AutoCommit  => 1,
 561       quote_char  => q{"},
 562       name_sep    => q{.},
 563     }]
 564   );
 565
 566   # Subref + DBIx::Class-specific connection options
 567   ->connect_info(
 568     [
 569       sub { DBI->connect(...) },
 570       {
 571           quote_char => q{`},
 572           name_sep => q{@},
 573           on_connect_do => ['SET search_path TO myschema,otherschema,public'],
 574           disable_sth_caching => 1,
 575       },
 576     ]
 577   );
 578
 579
 580
 581 =cut
 582
 583 sub connect_info {
 584   my ($self, $info_arg) = @_;
 585
 586   return $self->_connect_info if !$info_arg;
 587
 588   my @args = @$info_arg;  # take a shallow copy for further mutilation
 589   $self->_connect_info([@args]); # copy for _connect_info
 590
 591
 592   # combine/pre-parse arguments depending on invocation style
 593
 594   my %attrs;
 595   if (ref $args[0] eq 'CODE') {     # coderef with optional \%extra_attributes
 596     %attrs = %{ $args[1] || {} };
 597     @args = $args[0];
 598   }
 599   elsif (ref $args[0] eq 'HASH') { # single hashref (i.e. Catalyst config)
 600     %attrs = %{$args[0]};
 601     @args = ();
 602     for (qw/password user dsn/) {
 603       unshift @args, delete $attrs{$_};
 604     }
 605   }
 606   else {                # otherwise assume dsn/user/password + \%attrs + \%extra_attrs
 607     %attrs = (
 608       % { $args[3] || {} },
 609       % { $args[4] || {} },
 610     );
 611     @args = @args[0,1,2];
 612   }
 613
 614   # Kill sql_maker/_sql_maker_opts, so we get a fresh one with only
 615   #  the new set of options
 616   $self->_sql_maker(undef);
 617   $self->_sql_maker_opts({});
 618
 619   if(keys %attrs) {
 620     for my $storage_opt (@storage_options, 'cursor_class') {    # @storage_options is declared at the top of the module
 621       if(my $value = delete $attrs{$storage_opt}) {
 622         $self->$storage_opt($value);
 623       }
 624     }
 625     for my $sql_maker_opt (qw/limit_dialect quote_char name_sep/) {
 626       if(my $opt_val = delete $attrs{$sql_maker_opt}) {
 627         $self->_sql_maker_opts->{$sql_maker_opt} = $opt_val;
 628       }
 629     }
 630   }
 631
 632   %attrs = () if (ref $args[0] eq 'CODE');  # _connect() never looks past $args[0] in this case
 633
 634   $self->_dbi_connect_info([@args, keys %attrs ? \%attrs : ()]);
 635   $self->_connect_info;
 636 }
 637
 638 =head2 on_connect_do
 639
 640 This method is deprecated in favour of setting via L</connect_info>.
 641
 642
 643 =head2 dbh_do
 644
 645 Arguments: ($subref | $method_name), @extra_coderef_args?
 646
 647 Execute the given $subref or $method_name using the new exception-based
 648 connection management.
 649
 650 The first two arguments will be the storage object that C<dbh_do> was called
 651 on and a database handle to use.  Any additional arguments will be passed
 652 verbatim to the called subref as arguments 2 and onwards.
 653
 654 Using this (instead of $self->_dbh or $self->dbh) ensures correct
 655 exception handling and reconnection (or failover in future subclasses).
 656
 657 Your subref should have no side-effects outside of the database, as
 658 there is the potential for your subref to be partially double-executed
 659 if the database connection was stale/dysfunctional.
 660
 661 Example:
 662
 663   my @stuff = $schema->storage->dbh_do(
 664     sub {
 665       my ($storage, $dbh, @cols) = @_;
 666       my $cols = join(q{, }, @cols);
 667       $dbh->selectrow_array("SELECT $cols FROM foo");
 668     },
 669     @column_list
 670   );
 671
 672 =cut
 673
 674 sub dbh_do {
 675   my $self = shift;
 676   my $code = shift;
 677
 678   my $dbh = $self->_dbh;
 679
 680   return $self->$code($dbh, @_) if $self->{_in_dbh_do}
 681       || $self->{transaction_depth};
 682
 683   local $self->{_in_dbh_do} = 1;
 684
 685   my @result;
 686   my $want_array = wantarray;
 687
 688   eval {
 689     $self->_verify_pid if $dbh;
 690     if(!$self->_dbh) {
 691         $self->_populate_dbh;
 692         $dbh = $self->_dbh;
 693     }
 694
 695     if($want_array) {
 696         @result = $self->$code($dbh, @_);
 697     }
 698     elsif(defined $want_array) {
 699         $result[0] = $self->$code($dbh, @_);
 700     }
 701     else {
 702         $self->$code($dbh, @_);
 703     }
 704   };
 705
 706   my $exception = $@;
 707   if(!$exception) { return $want_array ? @result : $result[0] }
 708
 709   $self->throw_exception($exception) if $self->connected;
 710
 711   # We were not connected - reconnect and retry, but let any
 712   #  exception fall right through this time
 713   $self->_populate_dbh;
 714   $self->$code($self->_dbh, @_);
 715 }
 716
 717 # This is basically a blend of dbh_do above and DBIx::Class::Storage::txn_do.
 718 # It also informs dbh_do to bypass itself while under the direction of txn_do,
 719 #  via $self->{_in_dbh_do} (this saves some redundant eval and errorcheck, etc)
 720 sub txn_do {
 721   my $self = shift;
 722   my $coderef = shift;
 723
 724   ref $coderef eq 'CODE' or $self->throw_exception
 725     ('$coderef must be a CODE reference');
 726
 727   return $coderef->(@_) if $self->{transaction_depth} && ! $self->auto_savepoint;
 728
 729   local $self->{_in_dbh_do} = 1;
 730
 731   my @result;
 732   my $want_array = wantarray;
 733
 734   my $tried = 0;
 735   while(1) {
 736     eval {
 737       $self->_verify_pid if $self->_dbh;
 738       $self->_populate_dbh if !$self->_dbh;
 739
 740       $self->txn_begin;
 741       if($want_array) {
 742           @result = $coderef->(@_);
 743       }
 744       elsif(defined $want_array) {
 745           $result[0] = $coderef->(@_);
 746       }
 747       else {
 748           $coderef->(@_);
 749       }
 750       $self->txn_commit;
 751     };
 752
 753     my $exception = $@;
 754     if(!$exception) { return $want_array ? @result : $result[0] }
 755
 756     if($tried++ > 0 || $self->connected) {
 757       eval { $self->txn_rollback };
 758       my $rollback_exception = $@;
 759       if($rollback_exception) {
 760         my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
 761         $self->throw_exception($exception)  # propagate nested rollback
 762           if $rollback_exception =~ /$exception_class/;
 763
 764         $self->throw_exception(
 765           "Transaction aborted: ${exception}. "
 766           . "Rollback failed: ${rollback_exception}"
 767         );
 768       }
 769       $self->throw_exception($exception)
 770     }
 771
 772     # We were not connected, and was first try - reconnect and retry
 773     # via the while loop
 774     $self->_populate_dbh;
 775   }
 776 }
 777
 778 =head2 disconnect
 779
 780 Our C<disconnect> method also performs a rollback first if the
 781 database is not in C<AutoCommit> mode.
 782
 783 =cut
 784
 785 sub disconnect {
 786   my ($self) = @_;
 787
 788   if( $self->connected ) {
 789     my $connection_do = $self->on_disconnect_do;
 790     $self->_do_connection_actions($connection_do) if ref($connection_do);
 791
 792     $self->_dbh->rollback unless $self->_dbh_autocommit;
 793     $self->_dbh->disconnect;
 794     $self->_dbh(undef);
 795     $self->{_dbh_gen}++;
 796   }
 797 }
 798
 799 =head2 with_deferred_fk_checks
 800
 801 =over 4
 802
 803 =item Arguments: C<$coderef>
 804
 805 =item Return Value: The return value of $coderef
 806
 807 =back
 808
 809 Storage specific method to run the code ref with FK checks deferred or
 810 in MySQL's case disabled entirely.
 811
 812 =cut
 813
 814 # Storage subclasses should override this
 815 sub with_deferred_fk_checks {
 816   my ($self, $sub) = @_;
 817
 818   $sub->();
 819 }
 820
 821 sub connected {
 822   my ($self) = @_;
 823
 824   if(my $dbh = $self->_dbh) {
 825       if(defined $self->_conn_tid && $self->_conn_tid != threads->tid) {
 826           $self->_dbh(undef);
 827           $self->{_dbh_gen}++;
 828           return;
 829       }
 830       else {
 831           $self->_verify_pid;
 832           return 0 if !$self->_dbh;
 833       }
 834       return ($dbh->FETCH('Active') && $dbh->ping);
 835   }
 836
 837   return 0;
 838 }
 839
 840 # handle pid changes correctly
 841 #  NOTE: assumes $self->_dbh is a valid $dbh
 842 sub _verify_pid {
 843   my ($self) = @_;
 844
 845   return if defined $self->_conn_pid && $self->_conn_pid == $$;
 846
 847   $self->_dbh->{InactiveDestroy} = 1;
 848   $self->_dbh(undef);
 849   $self->{_dbh_gen}++;
 850
 851   return;
 852 }
 853
 854 sub ensure_connected {
 855   my ($self) = @_;
 856
 857   unless ($self->connected) {
 858     $self->_populate_dbh;
 859   }
 860 }
 861
 862 =head2 dbh
 863
 864 Returns the dbh - a data base handle of class L<DBI>.
 865
 866 =cut
 867
 868 sub dbh {
 869   my ($self) = @_;
 870
 871   $self->ensure_connected;
 872   return $self->_dbh;
 873 }
 874
 875 sub _sql_maker_args {
 876     my ($self) = @_;
 877
 878     return ( bindtype=>'columns', limit_dialect => $self->dbh, %{$self->_sql_maker_opts} );
 879 }
 880
 881 sub sql_maker {
 882   my ($self) = @_;
 883   unless ($self->_sql_maker) {
 884     my $sql_maker_class = $self->sql_maker_class;
 885     $self->_sql_maker($sql_maker_class->new( $self->_sql_maker_args ));
 886   }
 887   return $self->_sql_maker;
 888 }
 889
 890 sub _rebless {}
 891
 892 sub _populate_dbh {
 893   my ($self) = @_;
 894   my @info = @{$self->_dbi_connect_info || []};
 895   $self->_dbh($self->_connect(@info));
 896
 897   # Always set the transaction depth on connect, since
 898   #  there is no transaction in progress by definition
 899   $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
 900
 901   if(ref $self eq 'DBIx::Class::Storage::DBI') {
 902     my $driver = $self->_dbh->{Driver}->{Name};
 903     if ($self->load_optional_class("DBIx::Class::Storage::DBI::${driver}")) {
 904       bless $self, "DBIx::Class::Storage::DBI::${driver}";
 905       $self->_rebless();
 906     }
 907   }
 908
 909   my $connection_do = $self->on_connect_do;
 910   $self->_do_connection_actions($connection_do) if ref($connection_do);
 911
 912   $self->_conn_pid($$);
 913   $self->_conn_tid(threads->tid) if $INC{'threads.pm'};
 914 }
 915
 916 sub _do_connection_actions {
 917   my $self = shift;
 918   my $connection_do = shift;
 919
 920   if (ref $connection_do eq 'ARRAY') {
 921     $self->_do_query($_) foreach @$connection_do;
 922   }
 923   elsif (ref $connection_do eq 'CODE') {
 924     $connection_do->();
 925   }
 926
 927   return $self;
 928 }
 929
 930 sub _do_query {
 931   my ($self, $action) = @_;
 932
 933   if (ref $action eq 'CODE') {
 934     $action = $action->($self);
 935     $self->_do_query($_) foreach @$action;
 936   }
 937   else {
 938     my @to_run = (ref $action eq 'ARRAY') ? (@$action) : ($action);
 939     $self->_query_start(@to_run);
 940     $self->_dbh->do(@to_run);
 941     $self->_query_end(@to_run);
 942   }
 943
 944   return $self;
 945 }
 946
 947 sub _connect {
 948   my ($self, @info) = @_;
 949
 950   $self->throw_exception("You failed to provide any connection info")
 951     if !@info;
 952
 953   my ($old_connect_via, $dbh);
 954
 955   if ($INC{'Apache/DBI.pm'} && $ENV{MOD_PERL}) {
 956     $old_connect_via = $DBI::connect_via;
 957     $DBI::connect_via = 'connect';
 958   }
 959
 960   eval {
 961     if(ref $info[0] eq 'CODE') {
 962        $dbh = &{$info[0]}
 963     }
 964     else {
 965        $dbh = DBI->connect(@info);
 966     }
 967
 968     if($dbh && !$self->unsafe) {
 969       my $weak_self = $self;
 970       weaken($weak_self);
 971       $dbh->{HandleError} = sub {
 972           if ($weak_self) {
 973             $weak_self->throw_exception("DBI Exception: $_[0]");
 974           }
 975           else {
 976             croak ("DBI Exception: $_[0]");
 977           }
 978       };
 979       $dbh->{ShowErrorStatement} = 1;
 980       $dbh->{RaiseError} = 1;
 981       $dbh->{PrintError} = 0;
 982     }
 983   };
 984
 985   $DBI::connect_via = $old_connect_via if $old_connect_via;
 986
 987   $self->throw_exception("DBI Connection failed: " . ($@||$DBI::errstr))
 988     if !$dbh || $@;
 989
 990   $self->_dbh_autocommit($dbh->{AutoCommit});
 991
 992   $dbh;
 993 }
 994
 995 sub svp_begin {
 996   my ($self, $name) = @_;
 997
 998   $name = $self->_svp_generate_name
 999     unless defined $name;
1000
1001   $self->throw_exception ("You can't use savepoints outside a transaction")
1002     if $self->{transaction_depth} == 0;
1003
1004   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1005     unless $self->can('_svp_begin');
1006
1007   push @{ $self->{savepoints} }, $name;
1008
1009   $self->debugobj->svp_begin($name) if $self->debug;
1010
1011   return $self->_svp_begin($name);
1012 }
1013
1014 sub svp_release {
1015   my ($self, $name) = @_;
1016
1017   $self->throw_exception ("You can't use savepoints outside a transaction")
1018     if $self->{transaction_depth} == 0;
1019
1020   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1021     unless $self->can('_svp_release');
1022
1023   if (defined $name) {
1024     $self->throw_exception ("Savepoint '$name' does not exist")
1025       unless grep { $_ eq $name } @{ $self->{savepoints} };
1026
1027     # Dig through the stack until we find the one we are releasing.  This keeps
1028     # the stack up to date.
1029     my $svp;
1030
1031     do { $svp = pop @{ $self->{savepoints} } } while $svp ne $name;
1032   } else {
1033     $name = pop @{ $self->{savepoints} };
1034   }
1035
1036   $self->debugobj->svp_release($name) if $self->debug;
1037
1038   return $self->_svp_release($name);
1039 }
1040
1041 sub svp_rollback {
1042   my ($self, $name) = @_;
1043
1044   $self->throw_exception ("You can't use savepoints outside a transaction")
1045     if $self->{transaction_depth} == 0;
1046
1047   $self->throw_exception ("Your Storage implementation doesn't support savepoints")
1048     unless $self->can('_svp_rollback');
1049
1050   if (defined $name) {
1051       # If they passed us a name, verify that it exists in the stack
1052       unless(grep({ $_ eq $name } @{ $self->{savepoints} })) {
1053           $self->throw_exception("Savepoint '$name' does not exist!");
1054       }
1055
1056       # Dig through the stack until we find the one we are releasing.  This keeps
1057       # the stack up to date.
1058       while(my $s = pop(@{ $self->{savepoints} })) {
1059           last if($s eq $name);
1060       }
1061       # Add the savepoint back to the stack, as a rollback doesn't remove the
1062       # named savepoint, only everything after it.
1063       push(@{ $self->{savepoints} }, $name);
1064   } else {
1065       # We'll assume they want to rollback to the last savepoint
1066       $name = $self->{savepoints}->[-1];
1067   }
1068
1069   $self->debugobj->svp_rollback($name) if $self->debug;
1070
1071   return $self->_svp_rollback($name);
1072 }
1073
1074 sub _svp_generate_name {
1075     my ($self) = @_;
1076
1077     return 'savepoint_'.scalar(@{ $self->{'savepoints'} });
1078 }
1079
1080 sub txn_begin {
1081   my $self = shift;
1082   $self->ensure_connected();
1083   if($self->{transaction_depth} == 0) {
1084     $self->debugobj->txn_begin()
1085       if $self->debug;
1086     # this isn't ->_dbh-> because
1087     #  we should reconnect on begin_work
1088     #  for AutoCommit users
1089     $self->dbh->begin_work;
1090   } elsif ($self->auto_savepoint) {
1091     $self->svp_begin;
1092   }
1093   $self->{transaction_depth}++;
1094 }
1095
1096 sub txn_commit {
1097   my $self = shift;
1098   if ($self->{transaction_depth} == 1) {
1099     my $dbh = $self->_dbh;
1100     $self->debugobj->txn_commit()
1101       if ($self->debug);
1102     $dbh->commit;
1103     $self->{transaction_depth} = 0
1104       if $self->_dbh_autocommit;
1105   }
1106   elsif($self->{transaction_depth} > 1) {
1107     $self->{transaction_depth}--;
1108     $self->svp_release
1109       if $self->auto_savepoint;
1110   }
1111 }
1112
1113 sub txn_rollback {
1114   my $self = shift;
1115   my $dbh = $self->_dbh;
1116   eval {
1117     if ($self->{transaction_depth} == 1) {
1118       $self->debugobj->txn_rollback()
1119         if ($self->debug);
1120       $self->{transaction_depth} = 0
1121         if $self->_dbh_autocommit;
1122       $dbh->rollback;
1123     }
1124     elsif($self->{transaction_depth} > 1) {
1125       $self->{transaction_depth}--;
1126       if ($self->auto_savepoint) {
1127         $self->svp_rollback;
1128         $self->svp_release;
1129       }
1130     }
1131     else {
1132       die DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION->new;
1133     }
1134   };
1135   if ($@) {
1136     my $error = $@;
1137     my $exception_class = "DBIx::Class::Storage::NESTED_ROLLBACK_EXCEPTION";
1138     $error =~ /$exception_class/ and $self->throw_exception($error);
1139     # ensure that a failed rollback resets the transaction depth
1140     $self->{transaction_depth} = $self->_dbh_autocommit ? 0 : 1;
1141     $self->throw_exception($error);
1142   }
1143 }
1144
1145 # This used to be the top-half of _execute.  It was split out to make it
1146 #  easier to override in NoBindVars without duping the rest.  It takes up
1147 #  all of _execute's args, and emits $sql, @bind.
1148 sub _prep_for_execute {
1149   my ($self, $op, $extra_bind, $ident, $args) = @_;
1150
1151   my ($sql, @bind) = $self->sql_maker->$op($ident, @$args);
1152   unshift(@bind,
1153     map { ref $_ eq 'ARRAY' ? $_ : [ '!!dummy', $_ ] } @$extra_bind)
1154       if $extra_bind;
1155
1156   return ($sql, \@bind);
1157 }
1158
1159 sub _fix_bind_params {
1160     my ($self, @bind) = @_;
1161
1162     ### Turn @bind from something like this:
1163     ###   ( [ "artist", 1 ], [ "cdid", 1, 3 ] )
1164     ### to this:
1165     ###   ( "'1'", "'1'", "'3'" )
1166     return
1167         map {
1168             if ( defined( $_ && $_->[1] ) ) {
1169                 map { qq{'$_'}; } @{$_}[ 1 .. $#$_ ];
1170             }
1171             else { q{'NULL'}; }
1172         } @bind;
1173 }
1174
1175 sub _query_start {
1176     my ( $self, $sql, @bind ) = @_;
1177
1178     if ( $self->debug ) {
1179         @bind = $self->_fix_bind_params(@bind);
1180
1181         $self->debugobj->query_start( $sql, @bind );
1182     }
1183 }
1184
1185 sub _query_end {
1186     my ( $self, $sql, @bind ) = @_;
1187
1188     if ( $self->debug ) {
1189         @bind = $self->_fix_bind_params(@bind);
1190         $self->debugobj->query_end( $sql, @bind );
1191     }
1192 }
1193
1194 sub _dbh_execute {
1195   my ($self, $dbh, $op, $extra_bind, $ident, $bind_attributes, @args) = @_;
1196
1197   if( blessed($ident) && $ident->isa("DBIx::Class::ResultSource") ) {
1198     $ident = $ident->from();
1199   }
1200
1201   my ($sql, $bind) = $self->_prep_for_execute($op, $extra_bind, $ident, \@args);
1202
1203   $self->_query_start( $sql, @$bind );
1204
1205   my $sth = $self->sth($sql,$op);
1206
1207   my $placeholder_index = 1;
1208
1209   foreach my $bound (@$bind) {
1210     my $attributes = {};
1211     my($column_name, @data) = @$bound;
1212
1213     if ($bind_attributes) {
1214       $attributes = $bind_attributes->{$column_name}
1215       if defined $bind_attributes->{$column_name};
1216     }
1217
1218     foreach my $data (@data) {
1219       $data = ref $data ? ''.$data : $data; # stringify args
1220
1221       $sth->bind_param($placeholder_index, $data, $attributes);
1222       $placeholder_index++;
1223     }
1224   }
1225
1226   # Can this fail without throwing an exception anyways???
1227   my $rv = $sth->execute();
1228   $self->throw_exception($sth->errstr) if !$rv;
1229
1230   $self->_query_end( $sql, @$bind );
1231
1232   return (wantarray ? ($rv, $sth, @$bind) : $rv);
1233 }
1234
1235 sub _execute {
1236     my $self = shift;
1237     $self->dbh_do('_dbh_execute', @_)
1238 }
1239
1240 sub insert {
1241   my ($self, $source, $to_insert) = @_;
1242
1243   my $ident = $source->from;
1244   my $bind_attributes = $self->source_bind_attributes($source);
1245
1246   $self->ensure_connected;
1247   foreach my $col ( $source->columns ) {
1248     if ( !defined $to_insert->{$col} ) {
1249       my $col_info = $source->column_info($col);
1250
1251       if ( $col_info->{auto_nextval} ) {
1252         $to_insert->{$col} = $self->_sequence_fetch( 'nextval', $col_info->{sequence} || $self->_dbh_get_autoinc_seq($self->dbh, $source) );
1253       }
1254     }
1255   }
1256
1257   $self->_execute('insert' => [], $source, $bind_attributes, $to_insert);
1258
1259   return $to_insert;
1260 }
1261
1262 ## Still not quite perfect, and EXPERIMENTAL
1263 ## Currently it is assumed that all values passed will be "normal", i.e. not
1264 ## scalar refs, or at least, all the same type as the first set, the statement is
1265 ## only prepped once.
1266 sub insert_bulk {
1267   my ($self, $source, $cols, $data) = @_;
1268   my %colvalues;
1269   my $table = $source->from;
1270   @colvalues{@$cols} = (0..$#$cols);
1271   my ($sql, @bind) = $self->sql_maker->insert($table, \%colvalues);
1272
1273   $self->_query_start( $sql, @bind );
1274   my $sth = $self->sth($sql);
1275
1276 #  @bind = map { ref $_ ? ''.$_ : $_ } @bind; # stringify args
1277
1278   ## This must be an arrayref, else nothing works!
1279
1280   my $tuple_status = [];
1281
1282   ##use Data::Dumper;
1283   ##print STDERR Dumper( $data, $sql, [@bind] );
1284
1285   my $time = time();
1286
1287   ## Get the bind_attributes, if any exist
1288   my $bind_attributes = $self->source_bind_attributes($source);
1289
1290   ## Bind the values and execute
1291   my $placeholder_index = 1;
1292
1293   foreach my $bound (@bind) {
1294
1295     my $attributes = {};
1296     my ($column_name, $data_index) = @$bound;
1297
1298     if( $bind_attributes ) {
1299       $attributes = $bind_attributes->{$column_name}
1300       if defined $bind_attributes->{$column_name};
1301     }
1302
1303     my @data = map { $_->[$data_index] } @$data;
1304
1305     $sth->bind_param_array( $placeholder_index, [@data], $attributes );
1306     $placeholder_index++;
1307   }
1308   my $rv = $sth->execute_array({ArrayTupleStatus => $tuple_status});
1309   $self->throw_exception($sth->errstr) if !$rv;
1310
1311   $self->_query_end( $sql, @bind );
1312   return (wantarray ? ($rv, $sth, @bind) : $rv);
1313 }
1314
1315 sub update {
1316   my $self = shift @_;
1317   my $source = shift @_;
1318   my $bind_attributes = $self->source_bind_attributes($source);
1319
1320   return $self->_execute('update' => [], $source, $bind_attributes, @_);
1321 }
1322
1323
1324 sub delete {
1325   my $self = shift @_;
1326   my $source = shift @_;
1327
1328   my $bind_attrs = {}; ## If ever it's needed...
1329
1330   return $self->_execute('delete' => [], $source, $bind_attrs, @_);
1331 }
1332
1333 sub _select {
1334   my ($self, $ident, $select, $condition, $attrs) = @_;
1335   my $order = $attrs->{order_by};
1336
1337   if (ref $condition eq 'SCALAR') {
1338     my $unwrap = ${$condition};
1339     if ($unwrap =~ s/ORDER BY (.*)$//i) {
1340       $order = $1;
1341       $condition = \$unwrap;
1342     }
1343   }
1344
1345   my $for = delete $attrs->{for};
1346   my $sql_maker = $self->sql_maker;
1347   local $sql_maker->{for} = $for;
1348
1349   if (exists $attrs->{group_by} || $attrs->{having}) {
1350     $order = {
1351       group_by => $attrs->{group_by},
1352       having => $attrs->{having},
1353       ($order ? (order_by => $order) : ())
1354     };
1355   }
1356   my $bind_attrs = {}; ## Future support
1357   my @args = ('select', $attrs->{bind}, $ident, $bind_attrs, $select, $condition, $order);
1358   if ($attrs->{software_limit} ||
1359       $self->sql_maker->_default_limit_syntax eq "GenericSubQ") {
1360         $attrs->{software_limit} = 1;
1361   } else {
1362     $self->throw_exception("rows attribute must be positive if present")
1363       if (defined($attrs->{rows}) && !($attrs->{rows} > 0));
1364
1365     # MySQL actually recommends this approach.  I cringe.
1366     $attrs->{rows} = 2**48 if not defined $attrs->{rows} and defined $attrs->{offset};
1367     push @args, $attrs->{rows}, $attrs->{offset};
1368   }
1369
1370   return $self->_execute(@args);
1371 }
1372
1373 sub source_bind_attributes {
1374   my ($self, $source) = @_;
1375
1376   my $bind_attributes;
1377   foreach my $column ($source->columns) {
1378
1379     my $data_type = $source->column_info($column)->{data_type} || '';
1380     $bind_attributes->{$column} = $self->bind_attribute_by_data_type($data_type)
1381      if $data_type;
1382   }
1383
1384   return $bind_attributes;
1385 }
1386
1387 =head2 select
1388
1389 =over 4
1390
1391 =item Arguments: $ident, $select, $condition, $attrs
1392
1393 =back
1394
1395 Handle a SQL select statement.
1396
1397 =cut
1398
1399 sub select {
1400   my $self = shift;
1401   my ($ident, $select, $condition, $attrs) = @_;
1402   return $self->cursor_class->new($self, \@_, $attrs);
1403 }
1404
1405 sub select_single {
1406   my $self = shift;
1407   my ($rv, $sth, @bind) = $self->_select(@_);
1408   my @row = $sth->fetchrow_array;
1409   if(@row && $sth->fetchrow_array) {
1410     carp "Query returned more than one row.  SQL that returns multiple rows is DEPRECATED for ->find and ->single";
1411   }
1412   # Need to call finish() to work round broken DBDs
1413   $sth->finish();
1414   return @row;
1415 }
1416
1417 =head2 sth
1418
1419 =over 4
1420
1421 =item Arguments: $sql
1422
1423 =back
1424
1425 Returns a L<DBI> sth (statement handle) for the supplied SQL.
1426
1427 =cut
1428
1429 sub _dbh_sth {
1430   my ($self, $dbh, $sql) = @_;
1431
1432   # 3 is the if_active parameter which avoids active sth re-use
1433   my $sth = $self->disable_sth_caching
1434     ? $dbh->prepare($sql)
1435     : $dbh->prepare_cached($sql, {}, 3);
1436
1437   # XXX You would think RaiseError would make this impossible,
1438   #  but apparently that's not true :(
1439   $self->throw_exception($dbh->errstr) if !$sth;
1440
1441   $sth;
1442 }
1443
1444 sub sth {
1445   my ($self, $sql) = @_;
1446   $self->dbh_do('_dbh_sth', $sql);
1447 }
1448
1449 sub _dbh_columns_info_for {
1450   my ($self, $dbh, $table) = @_;
1451
1452   if ($dbh->can('column_info')) {
1453     my %result;
1454     eval {
1455       my ($schema,$tab) = $table =~ /^(.+?)\.(.+)$/ ? ($1,$2) : (undef,$table);
1456       my $sth = $dbh->column_info( undef,$schema, $tab, '%' );
1457       $sth->execute();
1458       while ( my $info = $sth->fetchrow_hashref() ){
1459         my %column_info;
1460         $column_info{data_type}   = $info->{TYPE_NAME};
1461         $column_info{size}      = $info->{COLUMN_SIZE};
1462         $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
1463         $column_info{default_value} = $info->{COLUMN_DEF};
1464         my $col_name = $info->{COLUMN_NAME};
1465         $col_name =~ s/^\"(.*)\"$/$1/;
1466
1467         $result{$col_name} = \%column_info;
1468       }
1469     };
1470     return \%result if !$@ && scalar keys %result;
1471   }
1472
1473   my %result;
1474   my $sth = $dbh->prepare($self->sql_maker->select($table, undef, \'1 = 0'));
1475   $sth->execute;
1476   my @columns = @{$sth->{NAME_lc}};
1477   for my $i ( 0 .. $#columns ){
1478     my %column_info;
1479     $column_info{data_type} = $sth->{TYPE}->[$i];
1480     $column_info{size} = $sth->{PRECISION}->[$i];
1481     $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
1482
1483     if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
1484       $column_info{data_type} = $1;
1485       $column_info{size}    = $2;
1486     }
1487
1488     $result{$columns[$i]} = \%column_info;
1489   }
1490   $sth->finish;
1491
1492   foreach my $col (keys %result) {
1493     my $colinfo = $result{$col};
1494     my $type_num = $colinfo->{data_type};
1495     my $type_name;
1496     if(defined $type_num && $dbh->can('type_info')) {
1497       my $type_info = $dbh->type_info($type_num);
1498       $type_name = $type_info->{TYPE_NAME} if $type_info;
1499       $colinfo->{data_type} = $type_name if $type_name;
1500     }
1501   }
1502
1503   return \%result;
1504 }
1505
1506 sub columns_info_for {
1507   my ($self, $table) = @_;
1508   $self->dbh_do('_dbh_columns_info_for', $table);
1509 }
1510
1511 =head2 last_insert_id
1512
1513 Return the row id of the last insert.
1514
1515 =cut
1516
1517 sub _dbh_last_insert_id {
1518     my ($self, $dbh, $source, $col) = @_;
1519     # XXX This is a SQLite-ism as a default... is there a DBI-generic way?
1520     $dbh->func('last_insert_rowid');
1521 }
1522
1523 sub last_insert_id {
1524   my $self = shift;
1525   $self->dbh_do('_dbh_last_insert_id', @_);
1526 }
1527
1528 =head2 sqlt_type
1529
1530 Returns the database driver name.
1531
1532 =cut
1533
1534 sub sqlt_type { shift->dbh->{Driver}->{Name} }
1535
1536 =head2 bind_attribute_by_data_type
1537
1538 Given a datatype from column info, returns a database specific bind
1539 attribute for C<< $dbh->bind_param($val,$attribute) >> or nothing if we will
1540 let the database planner just handle it.
1541
1542 Generally only needed for special case column types, like bytea in postgres.
1543
1544 =cut
1545
1546 sub bind_attribute_by_data_type {
1547     return;
1548 }
1549
1550 =head2 create_ddl_dir
1551
1552 =over 4
1553
1554 =item Arguments: $schema \@databases, $version, $directory, $preversion, \%sqlt_args
1555
1556 =back
1557
1558 Creates a SQL file based on the Schema, for each of the specified
1559 database types, in the given directory.
1560
1561 By default, C<\%sqlt_args> will have
1562
1563  { add_drop_table => 1, ignore_constraint_names => 1, ignore_index_names => 1 }
1564
1565 merged with the hash passed in. To disable any of those features, pass in a
1566 hashref like the following
1567
1568  { ignore_constraint_names => 0, # ... other options }
1569
1570 =cut
1571
1572 sub create_ddl_dir {
1573   my ($self, $schema, $databases, $version, $dir, $preversion, $sqltargs) = @_;
1574
1575   if(!$dir || !-d $dir) {
1576     warn "No directory given, using ./\n";
1577     $dir = "./";
1578   }
1579   $databases ||= ['MySQL', 'SQLite', 'PostgreSQL'];
1580   $databases = [ $databases ] if(ref($databases) ne 'ARRAY');
1581   $version ||= $schema->VERSION || '1.x';
1582   $sqltargs = {
1583     add_drop_table => 1,
1584     ignore_constraint_names => 1,
1585     ignore_index_names => 1,
1586     %{$sqltargs || {}}
1587   };
1588
1589   $self->throw_exception(q{Can't create a ddl file without SQL::Translator 0.09: '}
1590       . $self->_check_sqlt_message . q{'})
1591           if !$self->_check_sqlt_version;
1592
1593   my $sqlt = SQL::Translator->new( $sqltargs );
1594
1595   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
1596   my $sqlt_schema = $sqlt->translate({ data => $schema }) or die $sqlt->error;
1597
1598   foreach my $db (@$databases) {
1599     $sqlt->reset();
1600     $sqlt = $self->configure_sqlt($sqlt, $db);
1601     $sqlt->{schema} = $sqlt_schema;
1602     $sqlt->producer($db);
1603
1604     my $file;
1605     my $filename = $schema->ddl_filename($db, $version, $dir);
1606     if (-e $filename && (!$version || ($version == $schema->schema_version()))) {
1607       # if we are dumping the current version, overwrite the DDL
1608       warn "Overwriting existing DDL file - $filename";
1609       unlink($filename);
1610     }
1611
1612     my $output = $sqlt->translate;
1613     if(!$output) {
1614       warn("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
1615       next;
1616     }
1617     if(!open($file, ">$filename")) {
1618       $self->throw_exception("Can't open $filename for writing ($!)");
1619       next;
1620     }
1621     print $file $output;
1622     close($file);
1623
1624     next unless ($preversion);
1625
1626     require SQL::Translator::Diff;
1627
1628     my $prefilename = $schema->ddl_filename($db, $preversion, $dir);
1629     if(!-e $prefilename) {
1630       warn("No previous schema file found ($prefilename)");
1631       next;
1632     }
1633
1634     my $difffile = $schema->ddl_filename($db, $version, $dir, $preversion);
1635     if(-e $difffile) {
1636       warn("Overwriting existing diff file - $difffile");
1637       unlink($difffile);
1638     }
1639
1640     my $source_schema;
1641     {
1642       my $t = SQL::Translator->new($sqltargs);
1643       $t->debug( 0 );
1644       $t->trace( 0 );
1645       $t->parser( $db )                       or die $t->error;
1646       $t = $self->configure_sqlt($t, $db);
1647       my $out = $t->translate( $prefilename ) or die $t->error;
1648       $source_schema = $t->schema;
1649       unless ( $source_schema->name ) {
1650         $source_schema->name( $prefilename );
1651       }
1652     }
1653
1654     # The "new" style of producers have sane normalization and can support
1655     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
1656     # And we have to diff parsed SQL against parsed SQL.
1657     my $dest_schema = $sqlt_schema;
1658
1659     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
1660       my $t = SQL::Translator->new($sqltargs);
1661       $t->debug( 0 );
1662       $t->trace( 0 );
1663       $t->parser( $db )                    or die $t->error;
1664       $t = $self->configure_sqlt($t, $db);
1665       my $out = $t->translate( $filename ) or die $t->error;
1666       $dest_schema = $t->schema;
1667       $dest_schema->name( $filename )
1668         unless $dest_schema->name;
1669     }
1670
1671     my $diff = SQL::Translator::Diff::schema_diff($source_schema, $db,
1672                                                   $dest_schema,   $db,
1673                                                   $sqltargs
1674                                                  );
1675     if(!open $file, ">$difffile") {
1676       $self->throw_exception("Can't write to $difffile ($!)");
1677       next;
1678     }
1679     print $file $diff;
1680     close($file);
1681   }
1682 }
1683
1684 sub configure_sqlt() {
1685   my $self = shift;
1686   my $tr = shift;
1687   my $db = shift || $self->sqlt_type;
1688   if ($db eq 'PostgreSQL') {
1689     $tr->quote_table_names(0);
1690     $tr->quote_field_names(0);
1691   }
1692   return $tr;
1693 }
1694
1695 =head2 deployment_statements
1696
1697 =over 4
1698
1699 =item Arguments: $schema, $type, $version, $directory, $sqlt_args
1700
1701 =back
1702
1703 Returns the statements used by L</deploy> and L<DBIx::Class::Schema/deploy>.
1704 The database driver name is given by C<$type>, though the value from
1705 L</sqlt_type> is used if it is not specified.
1706
1707 C<$directory> is used to return statements from files in a previously created
1708 L</create_ddl_dir> directory and is optional. The filenames are constructed
1709 from L<DBIx::Class::Schema/ddl_filename>, the schema name and the C<$version>.
1710
1711 If no C<$directory> is specified then the statements are constructed on the
1712 fly using L<SQL::Translator> and C<$version> is ignored.
1713
1714 See L<SQL::Translator/METHODS> for a list of values for C<$sqlt_args>.
1715
1716 =cut
1717
1718 sub deployment_statements {
1719   my ($self, $schema, $type, $version, $dir, $sqltargs) = @_;
1720   # Need to be connected to get the correct sqlt_type
1721   $self->ensure_connected() unless $type;
1722   $type ||= $self->sqlt_type;
1723   $version ||= $schema->VERSION || '1.x';
1724   $dir ||= './';
1725   my $filename = $schema->ddl_filename($type, $dir, $version);
1726   if(-f $filename)
1727   {
1728       my $file;
1729       open($file, "<$filename")
1730         or $self->throw_exception("Can't open $filename ($!)");
1731       my @rows = <$file>;
1732       close($file);
1733       return join('', @rows);
1734   }
1735
1736   $self->throw_exception(q{Can't deploy without SQL::Translator 0.09: '}
1737       . $self->_check_sqlt_message . q{'})
1738           if !$self->_check_sqlt_version;
1739
1740   require SQL::Translator::Parser::DBIx::Class;
1741   eval qq{use SQL::Translator::Producer::${type}};
1742   $self->throw_exception($@) if $@;
1743
1744   # sources needs to be a parser arg, but for simplicty allow at top level
1745   # coming in
1746   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
1747       if exists $sqltargs->{sources};
1748
1749   my $tr = SQL::Translator->new(%$sqltargs);
1750   SQL::Translator::Parser::DBIx::Class::parse( $tr, $schema );
1751   return "SQL::Translator::Producer::${type}"->can('produce')->($tr);
1752 }
1753
1754 sub deploy {
1755   my ($self, $schema, $type, $sqltargs, $dir) = @_;
1756   my @statements = $self->deployment_statements($schema, $type, undef, $dir, { no_comments => 1, %{ $sqltargs || {} } } );
1757   foreach my $statement ( @statements ) {
1758     my $deploy = sub {
1759       my $line = shift;
1760       return if($line =~ /^--/);
1761       return if(!$line);
1762 #      next if($line =~ /^DROP/m);
1763       return if($line =~ /^BEGIN TRANSACTION/m);
1764       return if($line =~ /^COMMIT/m);
1765       return if $line =~ /^\s+$/; # skip whitespace only
1766       $self->_query_start($line);
1767       eval {
1768         $self->dbh->do($line); # shouldn't be using ->dbh ?
1769       };
1770       if ($@) {
1771         warn qq{$@ (running "${line}")};
1772       }
1773       $self->_query_end($line);
1774     };
1775     if (@statements > 1) {
1776         $deploy->( $statement );
1777     }
1778     else {
1779         foreach my $line ( split(";\n", $statement)) {
1780             $deploy->( $line );
1781         }
1782     }
1783   }
1784 }
1785
1786 =head2 datetime_parser
1787
1788 Returns the datetime parser class
1789
1790 =cut
1791
1792 sub datetime_parser {
1793   my $self = shift;
1794   return $self->{datetime_parser} ||= do {
1795     $self->ensure_connected;
1796     $self->build_datetime_parser(@_);
1797   };
1798 }
1799
1800 =head2 datetime_parser_type
1801
1802 Defines (returns) the datetime parser class - currently hardwired to
1803 L<DateTime::Format::MySQL>
1804
1805 =cut
1806
1807 sub datetime_parser_type { "DateTime::Format::MySQL"; }
1808
1809 =head2 build_datetime_parser
1810
1811 See L</datetime_parser>
1812
1813 =cut
1814
1815 sub build_datetime_parser {
1816   my $self = shift;
1817   my $type = $self->datetime_parser_type(@_);
1818   eval "use ${type}";
1819   $self->throw_exception("Couldn't load ${type}: $@") if $@;
1820   return $type;
1821 }
1822
1823 {
1824     my $_check_sqlt_version; # private
1825     my $_check_sqlt_message; # private
1826     sub _check_sqlt_version {
1827         return $_check_sqlt_version if defined $_check_sqlt_version;
1828         eval 'use SQL::Translator "0.09"';
1829         $_check_sqlt_message = $@ || '';
1830         $_check_sqlt_version = !$@;
1831     }
1832
1833     sub _check_sqlt_message {
1834         _check_sqlt_version if !defined $_check_sqlt_message;
1835         $_check_sqlt_message;
1836     }
1837 }
1838
1839 =head2 is_replicating
1840
1841 A boolean that reports if a particular L<DBIx::Class::Storage::DBI> is set to
1842 replicate from a master database.  Default is undef, which is the result
1843 returned by databases that don't support replication.
1844
1845 =cut
1846
1847 sub is_replicating {
1848     return;
1849
1850 }
1851
1852 =head2 lag_behind_master
1853
1854 Returns a number that represents a certain amount of lag behind a master db
1855 when a given storage is replicating.  The number is database dependent, but
1856 starts at zero and increases with the amount of lag. Default in undef
1857
1858 =cut
1859
1860 sub lag_behind_master {
1861     return;
1862 }
1863
1864 sub DESTROY {
1865   my $self = shift;
1866   return if !$self->_dbh;
1867   $self->_verify_pid;
1868   $self->_dbh(undef);
1869 }
1870
1871 1;
1872
1873 =head1 USAGE NOTES
1874
1875 =head2 DBIx::Class and AutoCommit
1876
1877 DBIx::Class can do some wonderful magic with handling exceptions,
1878 disconnections, and transactions when you use C<< AutoCommit => 1 >>
1879 combined with C<txn_do> for transaction support.
1880
1881 If you set C<< AutoCommit => 0 >> in your connect info, then you are always
1882 in an assumed transaction between commits, and you're telling us you'd
1883 like to manage that manually.  A lot of the magic protections offered by
1884 this module will go away.  We can't protect you from exceptions due to database
1885 disconnects because we don't know anything about how to restart your
1886 transactions.  You're on your own for handling all sorts of exceptional
1887 cases if you choose the C<< AutoCommit => 0 >> path, just as you would
1888 be with raw DBI.
1889
1890
1891 =head1 SQL METHODS
1892
1893 The module defines a set of methods within the DBIC::SQL::Abstract
1894 namespace.  These build on L<SQL::Abstract::Limit> to provide the
1895 SQL query functions.
1896
1897 The following methods are extended:-
1898
1899 =over 4
1900
1901 =item delete
1902
1903 =item insert
1904
1905 =item select
1906
1907 =item update
1908
1909 =item limit_dialect
1910
1911 See L</connect_info> for details.
1912
1913 =item quote_char
1914
1915 See L</connect_info> for details.
1916
1917 =item name_sep
1918
1919 See L</connect_info> for details.
1920
1921 =back
1922
1923 =head1 AUTHORS
1924
1925 Matt S. Trout <mst@shadowcatsystems.co.uk>
1926
1927 Andy Grundman <andy@hybridized.org>
1928
1929 =head1 LICENSE
1930
1931 You may distribute this code under the same terms as Perl itself.
1932
1933 =cut