lib/DBIx/Class/Storage/DBI/Sybase/NoBindVars.pm

   1 package DBIx::Class::Storage::DBI::Sybase::NoBindVars;
   2
   3 use Class::C3;
   4 use base qw/
   5   DBIx::Class::Storage::DBI::NoBindVars
   6   DBIx::Class::Storage::DBI::Sybase
   7 /;
   8 use List::Util ();
   9 use Scalar::Util ();
  10
  11 sub _rebless {
  12   my $self = shift;
  13   $self->disable_sth_caching(1);
  14   $self->_insert_txn(0);
  15 }
  16
  17 # this works when NOT using placeholders
  18 sub _fetch_identity_sql { 'SELECT @@IDENTITY' }
  19
  20 my $number = sub { Scalar::Util::looks_like_number($_[0]) };
  21
  22 my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
  23
  24 my %noquote = (
  25     int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
  26     bit => => sub { $_[0] =~ /^[01]\z/ },
  27     money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
  28     float => $number,
  29     real => $number,
  30     double => $number,
  31     decimal => $decimal,
  32     numeric => $decimal,
  33 );
  34
  35 sub should_quote_value {
  36   my $self = shift;
  37   my ($type, $value) = @_;
  38
  39   return $self->next::method(@_) if not defined $value or not defined $type;
  40
  41   if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
  42     return 0 if $noquote{$key}->($value);
  43   } elsif ($self->is_datatype_numeric($type) && $number->($value)) {
  44     return 0;
  45   }
  46
  47 ## try to guess based on value
  48 #  elsif (not $type) {
  49 #    return 0 if $number->($value) || $noquote->{money}->($value);
  50 #  }
  51
  52   return $self->next::method(@_);
  53 }
  54
  55 sub transform_unbound_value {
  56   my ($self, $type, $value) = @_;
  57
  58   if ($type =~ /money/i && defined $value) {
  59     $value =~ s/^\$//;
  60     $value = '$' . $value;
  61   }
  62
  63   return $value;
  64 }
  65
  66 1;
  67
  68 =head1 NAME
  69
  70 DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
  71 without placeholder support
  72
  73 =head1 DESCRIPTION
  74
  75 If you're using this driver than your version of Sybase does not support
  76 placeholders, or your version of L<DBD::Sybase> was compiled with FreeTDS rather
  77 than the Sybase OpenClient libraries. You can check with:
  78
  79   $dbh->{syb_dynamic_supported}
  80
  81 To see if you are using FreeTDS, run:
  82
  83   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
  84
  85 You will get a warning on startup if you're using FreeTDS in any case.
  86
  87 You can also enable this driver explicitly using:
  88
  89   my $schema = SchemaClass->clone;
  90   $schema->storage_type('::DBI::Sybase::NoBindVars');
  91   $schema->connect($dsn, $user, $pass, \%opts);
  92
  93 See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
  94 $sth->execute >> for details on the pros and cons of using placeholders.
  95
  96 One advantage of not using placeholders is that C<select @@identity> will work
  97 for obtainging the last insert id of an C<IDENTITY> column, instead of having to
  98 do C<select max(col)> as the base Sybase driver does.
  99
 100 When using this driver, bind variables will be interpolated (properly quoted of
 101 course) into the SQL query itself, without using placeholders.
 102
 103 The caching of prepared statements is also explicitly disabled, as the
 104 interpolation renders it useless.
 105
 106 =head1 AUTHORS
 107
 108 See L<DBIx::Class/CONTRIBUTORS>.
 109
 110 =head1 LICENSE
 111
 112 You may distribute this code under the same terms as Perl itself.
 113
 114 =cut
 115 # vim:sts=2 sw=2: