lib/DBIx/Class/Storage/DBI/Sybase/NoBindVars.pm

   1 package DBIx::Class::Storage::DBI::Sybase::NoBindVars;
   2
   3 use Class::C3;
   4 use base qw/
   5   DBIx::Class::Storage::DBI::NoBindVars
   6   DBIx::Class::Storage::DBI::Sybase
   7 /;
   8 use List::Util ();
   9 use Scalar::Util ();
  10
  11 sub _rebless {
  12   my $self = shift;
  13   $self->disable_sth_caching(1);
  14 }
  15
  16 sub _dbh_last_insert_id {
  17   my ($self, $dbh, $source, $col) = @_;
  18
  19   # @@identity works only if not using placeholders
  20   # Should this query be cached?
  21   return ($dbh->selectrow_array('select @@identity'))[0];
  22 }
  23
  24 my $number = sub { Scalar::Util::looks_like_number($_[0]) };
  25
  26 my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
  27
  28 my %noquote = (
  29     int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
  30     bit => => sub { $_[0] =~ /^[01]\z/ },
  31     money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
  32     float => $number,
  33     real => $number,
  34     double => $number,
  35     decimal => $decimal,
  36     numeric => $decimal,
  37 );
  38
  39 sub should_quote_value {
  40   my $self = shift;
  41   my ($type, $value) = @_;
  42
  43   return $self->next::method(@_) if not defined $value or not defined $type;
  44
  45   if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
  46     return 0 if $noquote{$key}->($value);
  47   } elsif($self->is_datatype_numeric($type) && $number->($value)) {
  48     return 0;
  49   }
  50
  51 ## try to guess based on value
  52 #  elsif (not $type) {
  53 #    return 0 if $number->($value) || $noquote->{money}->($value);
  54 #  }
  55
  56   return $self->next::method(@_);
  57 }
  58
  59 1;
  60
  61 =head1 NAME
  62
  63 DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
  64 without placeholder support
  65
  66 =head1 DESCRIPTION
  67
  68 If you're using this driver than your version of Sybase does not support
  69 placeholders, or your version of L<DBD::Sybase> was compiled with FreeTDS rather
  70 than the Sybase OpenClient libraries. You can check with:
  71
  72   $dbh->{syb_dynamic_supported}
  73
  74 To see if you are using FreeTDS, run:
  75
  76   perl -MDBD::Sybase -le 'print grep /Sybase\./, @DynaLoader::dl_shared_objects' | xargs ldd
  77
  78 If you see C<libct.so> or similar, rather than C<libsybct.so> then you are using
  79 FreeTDS.
  80
  81 You can also enable this driver explicitly using:
  82
  83   my $schema = SchemaClass->clone;
  84   $schema->storage_type('::DBI::Sybase::NoBindVars');
  85   $schema->connect($dsn, $user, $pass, \%opts);
  86
  87 See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
  88 $sth->execute >> for details on the pros and cons of using placeholders.
  89
  90 One advantage of not using placeholders is that C<select @@identity> will work
  91 for obtainging the last insert id of an C<IDENTITY> column, instead of having to
  92 do C<select max(col)> as the base Sybase driver does.
  93
  94 When using this driver, bind variables will be interpolated (properly quoted of
  95 course) into the SQL query itself, without using placeholders.
  96
  97 The caching of prepared statements is also explicitly disabled, as the
  98 interpolation renders it useless.
  99
 100 =head1 AUTHORS
 101
 102 See L<DBIx::Class/CONTRIBUTORS>.
 103
 104 =head1 LICENSE
 105
 106 You may distribute this code under the same terms as Perl itself.
 107
 108 =cut
 109 # vim:sts=2 sw=2: