lib/DBIx/Class/Storage/DBI/Sybase/NoBindVars.pm

   1 package DBIx::Class::Storage::DBI::Sybase::NoBindVars;
   2
   3 use Class::C3;
   4 use base qw/
   5   DBIx::Class::Storage::DBI::NoBindVars
   6   DBIx::Class::Storage::DBI::Sybase
   7 /;
   8 use List::Util ();
   9 use Scalar::Util ();
  10
  11 sub _rebless {
  12   my $self = shift;
  13   $self->disable_sth_caching(1);
  14   $self->unsafe_insert(1);  # there is nothing unsafe as the
  15                             # last_insert_id mechanism is different
  16                             # without bindvars
  17 }
  18
  19 # this works when NOT using placeholders
  20 sub _fetch_identity_sql { 'SELECT @@IDENTITY' }
  21
  22 my $number = sub { Scalar::Util::looks_like_number($_[0]) };
  23
  24 my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
  25
  26 my %noquote = (
  27     int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
  28     bit => => sub { $_[0] =~ /^[01]\z/ },
  29     money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
  30     float => $number,
  31     real => $number,
  32     double => $number,
  33     decimal => $decimal,
  34     numeric => $decimal,
  35 );
  36
  37 sub interpolate_unquoted {
  38   my $self = shift;
  39   my ($type, $value) = @_;
  40
  41   return $self->next::method(@_) if not defined $value or not defined $type;
  42
  43   if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
  44     return 1 if $noquote{$key}->($value);
  45   }
  46   elsif ($self->is_datatype_numeric($type) && $number->($value)) {
  47     return 1;
  48   }
  49
  50   return $self->next::method(@_);
  51 }
  52
  53 sub _prep_interpolated_value {
  54   my ($self, $type, $value) = @_;
  55
  56   if ($type =~ /money/i && defined $value) {
  57     # change a ^ not followed by \$ to a \$
  58     $value =~ s/^ (?! \$) /\$/x;
  59   }
  60
  61   return $value;
  62 }
  63
  64 1;
  65
  66 =head1 NAME
  67
  68 DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
  69 without placeholder support
  70
  71 =head1 DESCRIPTION
  72
  73 If you're using this driver than your version of Sybase, or the libraries you
  74 use to connect to it, do not support placeholders.
  75
  76 You can also enable this driver explicitly using:
  77
  78   my $schema = SchemaClass->clone;
  79   $schema->storage_type('::DBI::Sybase::NoBindVars');
  80   $schema->connect($dsn, $user, $pass, \%opts);
  81
  82 See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
  83 $sth->execute >> for details on the pros and cons of using placeholders.
  84
  85 One advantage of not using placeholders is that C<select @@identity> will work
  86 for obtainging the last insert id of an C<IDENTITY> column, instead of having to
  87 do C<select max(col)> in a transaction as the base Sybase driver does.
  88
  89 When using this driver, bind variables will be interpolated (properly quoted of
  90 course) into the SQL query itself, without using placeholders.
  91
  92 The caching of prepared statements is also explicitly disabled, as the
  93 interpolation renders it useless.
  94
  95 =head1 AUTHORS
  96
  97 See L<DBIx::Class/CONTRIBUTORS>.
  98
  99 =head1 LICENSE
 100
 101 You may distribute this code under the same terms as Perl itself.
 102
 103 =cut
 104 # vim:sts=2 sw=2: