lib/DBIx/Class/Storage/DBI/Sybase/NoBindVars.pm

   1 package DBIx::Class::Storage::DBI::Sybase::NoBindVars;
   2
   3 use base qw/
   4   DBIx::Class::Storage::DBI::NoBindVars
   5   DBIx::Class::Storage::DBI::Sybase
   6 /;
   7 use mro 'c3';
   8 use List::Util ();
   9 use Scalar::Util ();
  10
  11 sub _init {
  12   my $self = shift;
  13   $self->disable_sth_caching(1);
  14   $self->_identity_method('@@IDENTITY');
  15   $self->next::method (@_);
  16 }
  17
  18 sub _fetch_identity_sql { 'SELECT ' . $_[0]->_identity_method }
  19
  20 my $number = sub { Scalar::Util::looks_like_number($_[0]) };
  21
  22 my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
  23
  24 my %noquote = (
  25     int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
  26     bit => => sub { $_[0] =~ /^[01]\z/ },
  27     money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
  28     float => $number,
  29     real => $number,
  30     double => $number,
  31     decimal => $decimal,
  32     numeric => $decimal,
  33 );
  34
  35 sub interpolate_unquoted {
  36   my $self = shift;
  37   my ($type, $value) = @_;
  38
  39   return $self->next::method(@_) if not defined $value or not defined $type;
  40
  41   if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
  42     return 1 if $noquote{$key}->($value);
  43   }
  44   elsif ($self->is_datatype_numeric($type) && $number->($value)) {
  45     return 1;
  46   }
  47
  48   return $self->next::method(@_);
  49 }
  50
  51 sub _prep_interpolated_value {
  52   my ($self, $type, $value) = @_;
  53
  54   if ($type =~ /money/i && defined $value) {
  55     # change a ^ not followed by \$ to a \$
  56     $value =~ s/^ (?! \$) /\$/x;
  57   }
  58
  59   return $value;
  60 }
  61
  62 # for tests
  63 sub _can_insert_bulk { 0 }
  64
  65 1;
  66
  67 =head1 NAME
  68
  69 DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
  70 without placeholder support
  71
  72 =head1 DESCRIPTION
  73
  74 If you're using this driver than your version of Sybase, or the libraries you
  75 use to connect to it, do not support placeholders.
  76
  77 You can also enable this driver explicitly using:
  78
  79   my $schema = SchemaClass->clone;
  80   $schema->storage_type('::DBI::Sybase::NoBindVars');
  81   $schema->connect($dsn, $user, $pass, \%opts);
  82
  83 See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
  84 $sth->execute >> for details on the pros and cons of using placeholders.
  85
  86 One advantage of not using placeholders is that C<select @@identity> will work
  87 for obtainging the last insert id of an C<IDENTITY> column, instead of having to
  88 do C<select max(col)> in a transaction as the base Sybase driver does.
  89
  90 When using this driver, bind variables will be interpolated (properly quoted of
  91 course) into the SQL query itself, without using placeholders.
  92
  93 The caching of prepared statements is also explicitly disabled, as the
  94 interpolation renders it useless.
  95
  96 =head1 AUTHORS
  97
  98 See L<DBIx::Class/CONTRIBUTORS>.
  99
 100 =head1 LICENSE
 101
 102 You may distribute this code under the same terms as Perl itself.
 103
 104 =cut
 105 # vim:sts=2 sw=2: