lib/DBIx/Class/Storage/DBI/Sybase/NoBindVars.pm

   1 package DBIx::Class::Storage::DBI::Sybase::NoBindVars;
   2
   3 use Class::C3;
   4 use base qw/
   5   DBIx::Class::Storage::DBI::NoBindVars
   6   DBIx::Class::Storage::DBI::Sybase
   7 /;
   8 use List::Util ();
   9 use Scalar::Util ();
  10
  11 sub _rebless {
  12   my $self = shift;
  13   $self->disable_sth_caching(1);
  14 }
  15
  16 # this works when NOT using placeholders
  17 sub _fetch_identity_sql { 'SELECT @@IDENTITY' }
  18
  19 my $number = sub { Scalar::Util::looks_like_number($_[0]) };
  20
  21 my $decimal = sub { $_[0] =~ /^ [-+]? \d+ (?:\.\d*)? \z/x };
  22
  23 my %noquote = (
  24     int => sub { $_[0] =~ /^ [-+]? \d+ \z/x },
  25     bit => => sub { $_[0] =~ /^[01]\z/ },
  26     money => sub { $_[0] =~ /^\$ \d+ (?:\.\d*)? \z/x },
  27     float => $number,
  28     real => $number,
  29     double => $number,
  30     decimal => $decimal,
  31     numeric => $decimal,
  32 );
  33
  34 sub should_quote_value {
  35   my $self = shift;
  36   my ($type, $value) = @_;
  37
  38   return $self->next::method(@_) if not defined $value or not defined $type;
  39
  40   if (my $key = List::Util::first { $type =~ /$_/i } keys %noquote) {
  41     return 0 if $noquote{$key}->($value);
  42   } elsif($self->is_datatype_numeric($type) && $number->($value)) {
  43     return 0;
  44   }
  45
  46 ## try to guess based on value
  47 #  elsif (not $type) {
  48 #    return 0 if $number->($value) || $noquote->{money}->($value);
  49 #  }
  50
  51   return $self->next::method(@_);
  52 }
  53
  54 1;
  55
  56 =head1 NAME
  57
  58 DBIx::Class::Storage::DBI::Sybase::NoBindVars - Storage::DBI subclass for Sybase
  59 without placeholder support
  60
  61 =head1 DESCRIPTION
  62
  63 If you're using this driver than your version of Sybase does not support
  64 placeholders, or your version of L<DBD::Sybase> was compiled with FreeTDS rather
  65 than the Sybase OpenClient libraries. You can check with:
  66
  67   $dbh->{syb_dynamic_supported}
  68
  69 To see if you are using FreeTDS, run:
  70
  71   perl -MDBI -le 'my $dbh = DBI->connect($dsn, $user, $pass); print $dbh->{syb_oc_version}'
  72
  73 You will get a warning on startup if you're using FreeTDS in any case.
  74
  75 You can also enable this driver explicitly using:
  76
  77   my $schema = SchemaClass->clone;
  78   $schema->storage_type('::DBI::Sybase::NoBindVars');
  79   $schema->connect($dsn, $user, $pass, \%opts);
  80
  81 See the discussion in L<< DBD::Sybase/Using ? Placeholders & bind parameters to
  82 $sth->execute >> for details on the pros and cons of using placeholders.
  83
  84 One advantage of not using placeholders is that C<select @@identity> will work
  85 for obtainging the last insert id of an C<IDENTITY> column, instead of having to
  86 do C<select max(col)> as the base Sybase driver does.
  87
  88 When using this driver, bind variables will be interpolated (properly quoted of
  89 course) into the SQL query itself, without using placeholders.
  90
  91 The caching of prepared statements is also explicitly disabled, as the
  92 interpolation renders it useless.
  93
  94 =head1 AUTHORS
  95
  96 See L<DBIx::Class/CONTRIBUTORS>.
  97
  98 =head1 LICENSE
  99
 100 You may distribute this code under the same terms as Perl itself.
 101
 102 =cut
 103 # vim:sts=2 sw=2: