1 package DBIx::Class::Storage::DBI::Replicated;
5 die('The following modules are required for Replication ' . DBIx::Class::Optional::Dependencies->req_missing_for ('replicated') . "\n" )
6 unless DBIx::Class::Optional::Dependencies->req_ok_for ('replicated');
10 use DBIx::Class::Storage::DBI;
11 use DBIx::Class::Storage::DBI::Replicated::Pool;
12 use DBIx::Class::Storage::DBI::Replicated::Balancer;
13 use DBIx::Class::Storage::DBI::Replicated::Types qw/BalancerClassNamePart DBICSchema DBICStorageDBI/;
14 use MooseX::Types::Moose qw/ClassName HashRef Object/;
15 use Scalar::Util 'reftype';
17 use List::Util qw/min max reduce/;
18 use Context::Preserve 'preserve_context';
21 use namespace::clean -except => 'meta';
27 DBIx::Class::Storage::DBI::Replicated - BETA Replicated database support
31 The Following example shows how to change an existing $schema to a replicated
32 storage type, add some replicated (read-only) databases, and perform reporting
35 You should set the 'storage_type attribute to a replicated type. You should
36 also define your arguments, such as which balancer you want and any arguments
37 that the Pool object should get.
39 my $schema = Schema::Class->clone;
40 $schema->storage_type( ['::DBI::Replicated', {balancer=>'::Random'}] );
41 $schema->connection(...);
43 Next, you need to add in the Replicants. Basically this is an array of
44 arrayrefs, where each arrayref is database connect information. Think of these
45 arguments as what you'd pass to the 'normal' $schema->connect method.
47 $schema->storage->connect_replicants(
48 [$dsn1, $user, $pass, \%opts],
49 [$dsn2, $user, $pass, \%opts],
50 [$dsn3, $user, $pass, \%opts],
53 Now, just use the $schema as you normally would. Automatically all reads will
54 be delegated to the replicants, while writes to the master.
56 $schema->resultset('Source')->search({name=>'etc'});
58 You can force a given query to use a particular storage using the search
59 attribute 'force_pool'. For example:
61 my $rs = $schema->resultset('Source')->search(undef, {force_pool=>'master'});
63 Now $rs will force everything (both reads and writes) to use whatever was setup
64 as the master storage. 'master' is hardcoded to always point to the Master,
65 but you can also use any Replicant name. Please see:
66 L<DBIx::Class::Storage::DBI::Replicated::Pool> and the replicants attribute for more.
68 Also see transactions and L</execute_reliably> for alternative ways to
69 force read traffic to the master. In general, you should wrap your statements
70 in a transaction when you are reading and writing to the same tables at the
71 same time, since your replicants will often lag a bit behind the master.
73 If you have a multi-statement read only transaction you can force it to select
74 a random server in the pool by:
76 my $rs = $schema->resultset('Source')->search( undef,
77 { force_pool => $db->storage->read_handler->next_storage }
82 Warning: This class is marked BETA. This has been running a production
83 website using MySQL native replication as its backend and we have some decent
84 test coverage but the code hasn't yet been stressed by a variety of databases.
85 Individual DBs may have quirks we are not aware of. Please use this in first
86 development and pass along your experiences/bug fixes.
88 This class implements replicated data store for DBI. Currently you can define
89 one master and numerous slave database connections. All write-type queries
90 (INSERT, UPDATE, DELETE and even LAST_INSERT_ID) are routed to master
91 database, all read-type queries (SELECTs) go to the slave database.
93 Basically, any method request that L<DBIx::Class::Storage::DBI> would normally
94 handle gets delegated to one of the two attributes: L</read_handler> or to
95 L</write_handler>. Additionally, some methods need to be distributed
96 to all existing storages. This way our storage class is a drop in replacement
97 for L<DBIx::Class::Storage::DBI>.
99 Read traffic is spread across the replicants (slaves) occurring to a user
100 selected algorithm. The default algorithm is random weighted.
104 The consistency between master and replicants is database specific. The Pool
105 gives you a method to validate its replicants, removing and replacing them
106 when they fail/pass predefined criteria. Please make careful use of the ways
107 to force a query to run against Master when needed.
111 Replicated Storage has additional requirements not currently part of
112 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
116 This class defines the following attributes.
120 The underlying L<DBIx::Class::Schema> object this storage is attaching
133 Contains the classname which will instantiate the L</pool> object. Defaults
134 to: L<DBIx::Class::Storage::DBI::Replicated::Pool>.
141 default=>'DBIx::Class::Storage::DBI::Replicated::Pool',
143 'create_pool' => 'new',
149 Contains a hashref of initialized information to pass to the Balancer object.
150 See L<DBIx::Class::Storage::DBI::Replicated::Pool> for available arguments.
164 The replication pool requires a balance class to provider the methods for
165 choose how to spread the query load across each replicant in the pool.
169 has 'balancer_type' => (
171 isa=>BalancerClassNamePart,
174 default=> 'DBIx::Class::Storage::DBI::Replicated::Balancer::First',
176 'create_balancer' => 'new',
182 Contains a hashref of initialized information to pass to the Balancer object.
183 See L<DBIx::Class::Storage::DBI::Replicated::Balancer> for available arguments.
187 has 'balancer_args' => (
197 Is a L<DBIx::Class::Storage::DBI::Replicated::Pool> or derived class. This is a
198 container class for one or more replicated databases.
204 isa=>'DBIx::Class::Storage::DBI::Replicated::Pool',
215 Is a L<DBIx::Class::Storage::DBI::Replicated::Balancer> or derived class. This
216 is a class that takes a pool (L<DBIx::Class::Storage::DBI::Replicated::Pool>)
222 isa=>'DBIx::Class::Storage::DBI::Replicated::Balancer',
224 handles=>[qw/auto_validate_every/],
229 The master defines the canonical state for a pool of connected databases. All
230 the replicants are expected to match this databases state. Thus, in a classic
231 Master / Slaves distributed system, all the slaves are expected to replicate
232 the Master's state as quick as possible. This is the only database in the
233 pool of databases that is allowed to handle write traffic.
243 =head1 ATTRIBUTES IMPLEMENTING THE DBIx::Storage::DBI INTERFACE
245 The following methods are delegated all the methods required for the
246 L<DBIx::Class::Storage::DBI> interface.
250 my $method_dispatch = {
262 deployment_statements
265 build_datetime_parser
281 with_deferred_fk_checks
289 relname_to_table_alias
291 _default_dbi_connect_attributes
293 _dbic_connect_attributes
299 bind_attribute_by_data_type
303 _dbh_execute_for_fetch
305 _dbh_execute_inserts_with_no_binds
306 _select_args_to_query
309 _normalize_connect_info
323 /, Class::MOP::Class->initialize('DBIx::Class::Storage::DBIHacks')->get_method_list ],
328 _dbh_columns_info_for
331 unimplemented => [qw/
332 _arm_global_destructor
335 source_bind_attributes
337 get_use_dbms_capability
338 set_use_dbms_capability
349 _perform_autoinc_retrieval
350 _autoinc_supplied_for_op
361 # the capability framework
362 # not sure if CMOP->initialize does evil things to DBIC::S::DBI, fix if a problem
364 { $_ =~ /^ _ (?: use | supports | determine_supports ) _ /x }
365 ( Class::MOP::Class->initialize('DBIx::Class::Storage::DBI')->get_all_method_names )
369 if (DBIx::Class::_ENV_::DBICTEST) {
372 for my $type (keys %$method_dispatch) {
373 for (@{$method_dispatch->{$type}}) {
374 push @{$seen->{$_}}, $type;
378 if (my @dupes = grep { @{$seen->{$_}} > 1 } keys %$seen) {
380 'The following methods show up multiple times in ::Storage::DBI::Replicated handlers:',
381 (map { "$_: " . (join ', ', @{$seen->{$_}}) } sort @dupes),
386 if (my @cant = grep { ! DBIx::Class::Storage::DBI->can($_) } keys %$seen) {
388 '::Storage::DBI::Replicated specifies handling of the following *NON EXISTING* ::Storage::DBI methods:',
395 for my $method (@{$method_dispatch->{unimplemented}}) {
396 __PACKAGE__->meta->add_method($method, sub {
398 $self->throw_exception("$method must not be called on ".(blessed $self).' objects');
404 Defines an object that implements the read side of L<BIx::Class::Storage::DBI>.
408 has 'read_handler' => (
412 handles=>$method_dispatch->{reader},
417 Defines an object that implements the write side of L<BIx::Class::Storage::DBI>,
418 as well as methods that don't write or read that can be called on only one
419 storage, methods that return a C<$dbh>, and any methods that don't make sense to
424 has 'write_handler' => (
428 handles=>$method_dispatch->{writer},
433 has _master_connect_info_opts =>
434 (is => 'rw', isa => HashRef, default => sub { {} });
436 =head2 around: connect_info
438 Preserves master's C<connect_info> options (for merging with replicants.)
439 Also sets any Replicated-related options from connect_info, such as
440 C<pool_type>, C<pool_args>, C<balancer_type> and C<balancer_args>.
444 around connect_info => sub {
445 my ($next, $self, $info, @extra) = @_;
447 my $merge = Hash::Merge->new('LEFT_PRECEDENT');
450 for my $arg (@$info) {
451 next unless (reftype($arg)||'') eq 'HASH';
452 %opts = %{ $merge->merge($arg, \%opts) };
456 if (@opts{qw/pool_type pool_args/}) {
457 $self->pool_type(delete $opts{pool_type})
461 $merge->merge((delete $opts{pool_args} || {}), $self->pool_args)
464 ## Since we possibly changed the pool_args, we need to clear the current
465 ## pool object so that next time it is used it will be rebuilt.
469 if (@opts{qw/balancer_type balancer_args/}) {
470 $self->balancer_type(delete $opts{balancer_type})
471 if $opts{balancer_type};
473 $self->balancer_args(
474 $merge->merge((delete $opts{balancer_args} || {}), $self->balancer_args)
477 $self->balancer($self->_build_balancer)
481 $self->_master_connect_info_opts(\%opts);
483 return preserve_context {
484 $self->$next($info, @extra);
486 # Make sure master is blessed into the correct class and apply role to it.
487 my $master = $self->master;
488 $master->_determine_driver;
489 Moose::Meta::Class->initialize(ref $master);
491 DBIx::Class::Storage::DBI::Replicated::WithDSN->meta->apply($master);
493 # link pool back to master
494 $self->pool->master($master);
500 This class defines the following methods.
504 L<DBIx::Class::Schema> when instantiating its storage passed itself as the
505 first argument. So we need to massage the arguments a bit so that all the
506 bits get put into the correct places.
511 my ($class, $schema, $storage_type_args, @args) = @_;
522 Lazy builder for the L</master> attribute.
528 my $master = DBIx::Class::Storage::DBI->new($self->schema);
534 Lazy builder for the L</pool> attribute.
540 $self->create_pool(%{$self->pool_args});
543 =head2 _build_balancer
545 Lazy builder for the L</balancer> attribute. This takes a Pool object so that
546 the balancer knows which pool it's balancing.
550 sub _build_balancer {
552 $self->create_balancer(
554 master=>$self->master,
555 %{$self->balancer_args},
559 =head2 _build_write_handler
561 Lazy builder for the L</write_handler> attribute. The default is to set this to
566 sub _build_write_handler {
567 return shift->master;
570 =head2 _build_read_handler
572 Lazy builder for the L</read_handler> attribute. The default is to set this to
577 sub _build_read_handler {
578 return shift->balancer;
581 =head2 around: connect_replicants
583 All calls to connect_replicants needs to have an existing $schema tacked onto
584 top of the args, since L<DBIx::Storage::DBI> needs it, and any C<connect_info>
585 options merged with the master, with replicant opts having higher priority.
589 around connect_replicants => sub {
590 my ($next, $self, @args) = @_;
593 $r = [ $r ] unless reftype $r eq 'ARRAY';
595 $self->throw_exception('coderef replicant connect_info not supported')
596 if ref $r->[0] && reftype $r->[0] eq 'CODE';
598 # any connect_info options?
600 $i++ while $i < @$r && (reftype($r->[$i])||'') ne 'HASH';
603 $r->[$i] = {} unless $r->[$i];
605 # merge if two hashes
606 my @hashes = @$r[$i .. $#{$r}];
608 $self->throw_exception('invalid connect_info options')
609 if (grep { reftype($_) eq 'HASH' } @hashes) != @hashes;
611 $self->throw_exception('too many hashrefs in connect_info')
614 my $merge = Hash::Merge->new('LEFT_PRECEDENT');
615 my %opts = %{ $merge->merge(reverse @hashes) };
618 splice @$r, $i+1, ($#{$r} - $i), ();
620 # make sure master/replicants opts don't clash
621 my %master_opts = %{ $self->_master_connect_info_opts };
622 if (exists $opts{dbh_maker}) {
623 delete @master_opts{qw/dsn user password/};
625 delete $master_opts{dbh_maker};
628 %opts = %{ $merge->merge(\%opts, \%master_opts) };
634 $self->$next($self->schema, @args);
639 Returns an array of of all the connected storage backends. The first element
640 in the returned array is the master, and the remainings are each of the
647 return grep {defined $_ && blessed $_} (
649 values %{ $self->replicants },
653 =head2 execute_reliably ($coderef, ?@args)
655 Given a coderef, saves the current state of the L</read_handler>, forces it to
656 use reliable storage (e.g. sets it to the master), executes a coderef and then
657 restores the original state.
663 $schema->resultset('User')->create({name=>$name});
664 my $user_rs = $schema->resultset('User')->find({name=>$name});
668 my $user_rs = $schema->storage->execute_reliably($reliably, 'John');
670 Use this when you must be certain of your database state, such as when you just
671 inserted something and need to get a resultset including it, etc.
675 sub execute_reliably {
679 unless( ref $coderef eq 'CODE') {
680 $self->throw_exception('Second argument must be a coderef');
683 ## replace the current read handler for the remainder of the scope
684 local $self->{read_handler} = $self->master;
690 $self->throw_exception("coderef returned an error: $_");
694 =head2 set_reliable_storage
696 Sets the current $schema to be 'reliable', that is all queries, both read and
697 write are sent to the master
701 sub set_reliable_storage {
703 my $schema = $self->schema;
704 my $write_handler = $self->schema->storage->write_handler;
706 $schema->storage->read_handler($write_handler);
709 =head2 set_balanced_storage
711 Sets the current $schema to be use the </balancer> for all reads, while all
712 writes are sent to the master only
716 sub set_balanced_storage {
718 my $schema = $self->schema;
719 my $balanced_handler = $self->schema->storage->balancer;
721 $schema->storage->read_handler($balanced_handler);
726 Check that the master and at least one of the replicants is connected.
733 $self->master->connected &&
734 $self->pool->connected_replicants;
737 =head2 ensure_connected
739 Make sure all the storages are connected.
743 sub ensure_connected {
745 foreach my $source ($self->all_storages) {
746 $source->ensure_connected(@_);
752 Set the limit_dialect for all existing storages
758 foreach my $source ($self->all_storages) {
759 $source->limit_dialect(@_);
761 return $self->master->limit_dialect;
766 Set the quote_char for all existing storages
772 foreach my $source ($self->all_storages) {
773 $source->quote_char(@_);
775 return $self->master->quote_char;
780 Set the name_sep for all existing storages
786 foreach my $source ($self->all_storages) {
787 $source->name_sep(@_);
789 return $self->master->name_sep;
794 Set the schema object for all existing storages
800 foreach my $source ($self->all_storages) {
801 $source->set_schema(@_);
807 set a debug flag across all storages
814 foreach my $source ($self->all_storages) {
818 return $self->master->debug;
829 return $self->master->debugobj(@_);
840 return $self->master->debugfh(@_);
851 return $self->master->debugcb(@_);
856 disconnect everything
862 foreach my $source ($self->all_storages) {
863 $source->disconnect(@_);
869 set cursor class on all storages, or return master's
874 my ($self, $cursor_class) = @_;
877 $_->cursor_class($cursor_class) for $self->all_storages;
879 $self->master->cursor_class;
884 set cursor class on all storages, or return master's, alias for L</cursor_class>
890 my ($self, $cursor_class) = @_;
893 $_->cursor($cursor_class) for $self->all_storages;
895 $self->master->cursor;
900 sets the L<DBIx::Class::Storage::DBI/unsafe> option on all storages or returns
901 master's current setting
909 $_->unsafe(@_) for $self->all_storages;
912 return $self->master->unsafe;
915 =head2 disable_sth_caching
917 sets the L<DBIx::Class::Storage::DBI/disable_sth_caching> option on all storages
918 or returns master's current setting
922 sub disable_sth_caching {
926 $_->disable_sth_caching(@_) for $self->all_storages;
929 return $self->master->disable_sth_caching;
932 =head2 lag_behind_master
934 returns the highest Replicant L<DBIx::Class::Storage::DBI/lag_behind_master>
939 sub lag_behind_master {
942 return max map $_->lag_behind_master, $self->replicants;
945 =head2 is_replicating
947 returns true if all replicants return true for
948 L<DBIx::Class::Storage::DBI/is_replicating>
955 return (grep $_->is_replicating, $self->replicants) == ($self->replicants);
958 =head2 connect_call_datetime_setup
960 calls L<DBIx::Class::Storage::DBI/connect_call_datetime_setup> for all storages
964 sub connect_call_datetime_setup {
966 $_->connect_call_datetime_setup for $self->all_storages;
971 $_->_populate_dbh for $self->all_storages;
976 $_->_connect for $self->all_storages;
981 $_->_rebless for $self->all_storages;
984 sub _determine_driver {
986 $_->_determine_driver for $self->all_storages;
989 sub _driver_determined {
993 $_->_driver_determined(@_) for $self->all_storages;
996 return $self->master->_driver_determined;
1002 $_->_init for $self->all_storages;
1005 sub _run_connection_actions {
1008 $_->_run_connection_actions for $self->all_storages;
1011 sub _do_connection_actions {
1015 $_->_do_connection_actions(@_) for $self->all_storages;
1019 sub connect_call_do_sql {
1021 $_->connect_call_do_sql(@_) for $self->all_storages;
1024 sub disconnect_call_do_sql {
1026 $_->disconnect_call_do_sql(@_) for $self->all_storages;
1029 sub _seems_connected {
1032 return min map $_->_seems_connected, $self->all_storages;
1038 return min map $_->_ping, $self->all_storages;
1041 # not using the normalized_version, because we want to preserve
1042 # version numbers much longer than the conventional xxx.yyyzzz
1043 my $numify_ver = sub {
1045 my @numparts = split /\D+/, $ver;
1046 my $format = '%d.' . (join '', ('%06d') x (@numparts - 1));
1048 return sprintf $format, @numparts;
1053 if (not $self->_dbh_details->{info}) {
1054 $self->_dbh_details->{info} = (
1055 reduce { $a->[0] < $b->[0] ? $a : $b }
1056 map [ $numify_ver->($_->{dbms_version}), $_ ],
1057 map $_->_server_info, $self->all_storages
1061 return $self->next::method;
1064 sub _get_server_version {
1067 return $self->_server_info->{dbms_version};
1072 Due to the fact that replicants can lag behind a master, you must take care to
1073 make sure you use one of the methods to force read queries to a master should
1074 you need realtime data integrity. For example, if you insert a row, and then
1075 immediately re-read it from the database (say, by doing $row->discard_changes)
1076 or you insert a row and then immediately build a query that expects that row
1077 to be an item, you should force the master to handle reads. Otherwise, due to
1078 the lag, there is no certainty your data will be in the expected state.
1080 For data integrity, all transactions automatically use the master storage for
1081 all read and write queries. Using a transaction is the preferred and recommended
1082 method to force the master to handle all read queries.
1084 Otherwise, you can force a single query to use the master with the 'force_pool'
1087 my $row = $resultset->search(undef, {force_pool=>'master'})->find($pk);
1089 This attribute will safely be ignore by non replicated storages, so you can use
1090 the same code for both types of systems.
1092 Lastly, you can use the L</execute_reliably> method, which works very much like
1095 For debugging, you can turn replication on/off with the methods L</set_reliable_storage>
1096 and L</set_balanced_storage>, however this operates at a global level and is not
1097 suitable if you have a shared Schema object being used by multiple processes,
1098 such as on a web application server. You can get around this limitation by
1099 using the Schema clone method.
1101 my $new_schema = $schema->clone;
1102 $new_schema->set_reliable_storage;
1104 ## $new_schema will use only the Master storage for all reads/writes while
1105 ## the $schema object will use replicated storage.
1109 John Napiorkowski <john.napiorkowski@takkle.com>
1111 Based on code originated by:
1113 Norbert Csongrádi <bert@cpan.org>
1114 Peter Siklósi <einon@einon.hu>
1118 You may distribute this code under the same terms as Perl itself.
1122 __PACKAGE__->meta->make_immutable;