1 package DBIx::Class::Storage::DBI::Replicated;
4 use Carp::Clan qw/^DBIx::Class/;
6 croak('The following modules are required for Replication ' . DBIx::Class::Optional::Dependencies->req_missing_for ('replicated') )
7 unless DBIx::Class::Optional::Dependencies->req_ok_for ('replicated');
11 use DBIx::Class::Storage::DBI;
12 use DBIx::Class::Storage::DBI::Replicated::Pool;
13 use DBIx::Class::Storage::DBI::Replicated::Balancer;
14 use DBIx::Class::Storage::DBI::Replicated::Types qw/BalancerClassNamePart DBICSchema DBICStorageDBI/;
15 use MooseX::Types::Moose qw/ClassName HashRef Object/;
16 use Scalar::Util 'reftype';
18 use List::Util qw/min max reduce/;
22 use namespace::clean -except => 'meta';
26 DBIx::Class::Storage::DBI::Replicated - BETA Replicated database support
30 The Following example shows how to change an existing $schema to a replicated
31 storage type, add some replicated (read-only) databases, and perform reporting
34 You should set the 'storage_type attribute to a replicated type. You should
35 also define your arguments, such as which balancer you want and any arguments
36 that the Pool object should get.
38 my $schema = Schema::Class->clone;
39 $schema->storage_type( ['::DBI::Replicated', {balancer=>'::Random'}] );
40 $schema->connection(...);
42 Next, you need to add in the Replicants. Basically this is an array of
43 arrayrefs, where each arrayref is database connect information. Think of these
44 arguments as what you'd pass to the 'normal' $schema->connect method.
46 $schema->storage->connect_replicants(
47 [$dsn1, $user, $pass, \%opts],
48 [$dsn2, $user, $pass, \%opts],
49 [$dsn3, $user, $pass, \%opts],
52 Now, just use the $schema as you normally would. Automatically all reads will
53 be delegated to the replicants, while writes to the master.
55 $schema->resultset('Source')->search({name=>'etc'});
57 You can force a given query to use a particular storage using the search
58 attribute 'force_pool'. For example:
60 my $RS = $schema->resultset('Source')->search(undef, {force_pool=>'master'});
62 Now $RS will force everything (both reads and writes) to use whatever was setup
63 as the master storage. 'master' is hardcoded to always point to the Master,
64 but you can also use any Replicant name. Please see:
65 L<DBIx::Class::Storage::DBI::Replicated::Pool> and the replicants attribute for more.
67 Also see transactions and L</execute_reliably> for alternative ways to
68 force read traffic to the master. In general, you should wrap your statements
69 in a transaction when you are reading and writing to the same tables at the
70 same time, since your replicants will often lag a bit behind the master.
72 See L<DBIx::Class::Storage::DBI::Replicated::Instructions> for more help and
77 Warning: This class is marked BETA. This has been running a production
78 website using MySQL native replication as its backend and we have some decent
79 test coverage but the code hasn't yet been stressed by a variety of databases.
80 Individual DBs may have quirks we are not aware of. Please use this in first
81 development and pass along your experiences/bug fixes.
83 This class implements replicated data store for DBI. Currently you can define
84 one master and numerous slave database connections. All write-type queries
85 (INSERT, UPDATE, DELETE and even LAST_INSERT_ID) are routed to master
86 database, all read-type queries (SELECTs) go to the slave database.
88 Basically, any method request that L<DBIx::Class::Storage::DBI> would normally
89 handle gets delegated to one of the two attributes: L</read_handler> or to
90 L</write_handler>. Additionally, some methods need to be distributed
91 to all existing storages. This way our storage class is a drop in replacement
92 for L<DBIx::Class::Storage::DBI>.
94 Read traffic is spread across the replicants (slaves) occurring to a user
95 selected algorithm. The default algorithm is random weighted.
99 The consistency between master and replicants is database specific. The Pool
100 gives you a method to validate its replicants, removing and replacing them
101 when they fail/pass predefined criteria. Please make careful use of the ways
102 to force a query to run against Master when needed.
106 Replicated Storage has additional requirements not currently part of
107 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
111 This class defines the following attributes.
115 The underlying L<DBIx::Class::Schema> object this storage is attaching
128 Contains the classname which will instantiate the L</pool> object. Defaults
129 to: L<DBIx::Class::Storage::DBI::Replicated::Pool>.
136 default=>'DBIx::Class::Storage::DBI::Replicated::Pool',
138 'create_pool' => 'new',
144 Contains a hashref of initialized information to pass to the Balancer object.
145 See L<DBIx::Class::Storage::DBI::Replicated::Pool> for available arguments.
159 The replication pool requires a balance class to provider the methods for
160 choose how to spread the query load across each replicant in the pool.
164 has 'balancer_type' => (
166 isa=>BalancerClassNamePart,
169 default=> 'DBIx::Class::Storage::DBI::Replicated::Balancer::First',
171 'create_balancer' => 'new',
177 Contains a hashref of initialized information to pass to the Balancer object.
178 See L<DBIx::Class::Storage::DBI::Replicated::Balancer> for available arguments.
182 has 'balancer_args' => (
192 Is a L<DBIx::Class::Storage::DBI::Replicated::Pool> or derived class. This is a
193 container class for one or more replicated databases.
199 isa=>'DBIx::Class::Storage::DBI::Replicated::Pool',
210 Is a L<DBIx::Class::Storage::DBI::Replicated::Balancer> or derived class. This
211 is a class that takes a pool (L<DBIx::Class::Storage::DBI::Replicated::Pool>)
217 isa=>'DBIx::Class::Storage::DBI::Replicated::Balancer',
219 handles=>[qw/auto_validate_every/],
224 The master defines the canonical state for a pool of connected databases. All
225 the replicants are expected to match this databases state. Thus, in a classic
226 Master / Slaves distributed system, all the slaves are expected to replicate
227 the Master's state as quick as possible. This is the only database in the
228 pool of databases that is allowed to handle write traffic.
238 =head1 ATTRIBUTES IMPLEMENTING THE DBIx::Storage::DBI INTERFACE
240 The following methods are delegated all the methods required for the
241 L<DBIx::Class::Storage::DBI> interface.
245 Defines an object that implements the read side of L<BIx::Class::Storage::DBI>.
249 has 'read_handler' => (
257 _dbh_columns_info_for
264 Defines an object that implements the write side of L<BIx::Class::Storage::DBI>,
265 as well as methods that don't write or read that can be called on only one
266 storage, methods that return a C<$dbh>, and any methods that don't make sense to
271 has 'write_handler' => (
286 deployment_statements
289 build_datetime_parser
303 with_deferred_fk_checks
306 with_deferred_fk_checks
316 relname_to_table_alias
319 _default_dbi_connect_attributes
321 _dbic_connect_attributes
325 bind_attribute_by_data_type
333 _per_row_update_delete
335 _dbh_execute_inserts_with_no_binds
336 _select_args_to_query
338 _multipk_update_delete
339 source_bind_attributes
340 _normalize_connect_info
345 _sqlt_minimum_version
354 _adjust_select_args_for_complex_prefetch
355 _resolve_ident_sources
358 _strip_cond_qualifiers
359 _extract_order_columns
360 _resolve_aliastypes_from_select_args
365 _prefetch_insert_auto_nextvals
369 my @unimplemented = qw(
370 _arm_global_destructor
371 _preserve_foreign_dbh
375 get_use_dbms_capability
376 set_use_dbms_capability
384 _group_over_selection
387 # the capability framework
388 # not sure if CMOP->initialize does evil things to DBIC::S::DBI, fix if a problem
389 push @unimplemented, ( grep
390 { $_ =~ /^ _ (?: use | supports | determine_supports ) _ /x }
391 ( Class::MOP::Class->initialize('DBIx::Class::Storage::DBI')->get_all_method_names )
394 for my $method (@unimplemented) {
395 __PACKAGE__->meta->add_method($method, sub {
396 croak "$method must not be called on ".(blessed shift).' objects';
400 has _master_connect_info_opts =>
401 (is => 'rw', isa => HashRef, default => sub { {} });
403 =head2 around: connect_info
405 Preserves master's C<connect_info> options (for merging with replicants.)
406 Also sets any Replicated-related options from connect_info, such as
407 C<pool_type>, C<pool_args>, C<balancer_type> and C<balancer_args>.
411 around connect_info => sub {
412 my ($next, $self, $info, @extra) = @_;
414 my $wantarray = wantarray;
416 my $merge = Hash::Merge->new('LEFT_PRECEDENT');
419 for my $arg (@$info) {
420 next unless (reftype($arg)||'') eq 'HASH';
421 %opts = %{ $merge->merge($arg, \%opts) };
425 if (@opts{qw/pool_type pool_args/}) {
426 $self->pool_type(delete $opts{pool_type})
430 $merge->merge((delete $opts{pool_args} || {}), $self->pool_args)
433 ## Since we possibly changed the pool_args, we need to clear the current
434 ## pool object so that next time it is used it will be rebuilt.
438 if (@opts{qw/balancer_type balancer_args/}) {
439 $self->balancer_type(delete $opts{balancer_type})
440 if $opts{balancer_type};
442 $self->balancer_args(
443 $merge->merge((delete $opts{balancer_args} || {}), $self->balancer_args)
446 $self->balancer($self->_build_balancer)
450 $self->_master_connect_info_opts(\%opts);
454 @res = $self->$next($info, @extra);
456 $res = $self->$next($info, @extra);
459 # Make sure master is blessed into the correct class and apply role to it.
460 my $master = $self->master;
461 $master->_determine_driver;
462 Moose::Meta::Class->initialize(ref $master);
464 DBIx::Class::Storage::DBI::Replicated::WithDSN->meta->apply($master);
466 # link pool back to master
467 $self->pool->master($master);
469 $wantarray ? @res : $res;
474 This class defines the following methods.
478 L<DBIx::Class::Schema> when instantiating its storage passed itself as the
479 first argument. So we need to massage the arguments a bit so that all the
480 bits get put into the correct places.
485 my ($class, $schema, $storage_type_args, @args) = @_;
496 Lazy builder for the L</master> attribute.
502 my $master = DBIx::Class::Storage::DBI->new($self->schema);
508 Lazy builder for the L</pool> attribute.
514 $self->create_pool(%{$self->pool_args});
517 =head2 _build_balancer
519 Lazy builder for the L</balancer> attribute. This takes a Pool object so that
520 the balancer knows which pool it's balancing.
524 sub _build_balancer {
526 $self->create_balancer(
528 master=>$self->master,
529 %{$self->balancer_args},
533 =head2 _build_write_handler
535 Lazy builder for the L</write_handler> attribute. The default is to set this to
540 sub _build_write_handler {
541 return shift->master;
544 =head2 _build_read_handler
546 Lazy builder for the L</read_handler> attribute. The default is to set this to
551 sub _build_read_handler {
552 return shift->balancer;
555 =head2 around: connect_replicants
557 All calls to connect_replicants needs to have an existing $schema tacked onto
558 top of the args, since L<DBIx::Storage::DBI> needs it, and any C<connect_info>
559 options merged with the master, with replicant opts having higher priority.
563 around connect_replicants => sub {
564 my ($next, $self, @args) = @_;
567 $r = [ $r ] unless reftype $r eq 'ARRAY';
569 $self->throw_exception('coderef replicant connect_info not supported')
570 if ref $r->[0] && reftype $r->[0] eq 'CODE';
572 # any connect_info options?
574 $i++ while $i < @$r && (reftype($r->[$i])||'') ne 'HASH';
577 $r->[$i] = {} unless $r->[$i];
579 # merge if two hashes
580 my @hashes = @$r[$i .. $#{$r}];
582 $self->throw_exception('invalid connect_info options')
583 if (grep { reftype($_) eq 'HASH' } @hashes) != @hashes;
585 $self->throw_exception('too many hashrefs in connect_info')
588 my $merge = Hash::Merge->new('LEFT_PRECEDENT');
589 my %opts = %{ $merge->merge(reverse @hashes) };
592 splice @$r, $i+1, ($#{$r} - $i), ();
594 # make sure master/replicants opts don't clash
595 my %master_opts = %{ $self->_master_connect_info_opts };
596 if (exists $opts{dbh_maker}) {
597 delete @master_opts{qw/dsn user password/};
599 delete $master_opts{dbh_maker};
602 %opts = %{ $merge->merge(\%opts, \%master_opts) };
608 $self->$next($self->schema, @args);
613 Returns an array of of all the connected storage backends. The first element
614 in the returned array is the master, and the remainings are each of the
621 return grep {defined $_ && blessed $_} (
623 values %{ $self->replicants },
627 =head2 execute_reliably ($coderef, ?@args)
629 Given a coderef, saves the current state of the L</read_handler>, forces it to
630 use reliable storage (e.g. sets it to the master), executes a coderef and then
631 restores the original state.
637 $schema->resultset('User')->create({name=>$name});
638 my $user_rs = $schema->resultset('User')->find({name=>$name});
642 my $user_rs = $schema->storage->execute_reliably($reliably, 'John');
644 Use this when you must be certain of your database state, such as when you just
645 inserted something and need to get a resultset including it, etc.
649 sub execute_reliably {
650 my ($self, $coderef, @args) = @_;
652 unless( ref $coderef eq 'CODE') {
653 $self->throw_exception('Second argument must be a coderef');
656 ##Get copy of master storage
657 my $master = $self->master;
659 ##Get whatever the current read hander is
660 my $current = $self->read_handler;
662 ##Set the read handler to master
663 $self->read_handler($master);
665 ## do whatever the caller needs
667 my $want_array = wantarray;
671 @result = $coderef->(@args);
672 } elsif(defined $want_array) {
673 ($result[0]) = ($coderef->(@args));
678 $self->throw_exception("coderef returned an error: $_");
680 ##Reset to the original state
681 $self->read_handler($current);
684 return $want_array ? @result : $result[0];
687 =head2 set_reliable_storage
689 Sets the current $schema to be 'reliable', that is all queries, both read and
690 write are sent to the master
694 sub set_reliable_storage {
696 my $schema = $self->schema;
697 my $write_handler = $self->schema->storage->write_handler;
699 $schema->storage->read_handler($write_handler);
702 =head2 set_balanced_storage
704 Sets the current $schema to be use the </balancer> for all reads, while all
705 writes are sent to the master only
709 sub set_balanced_storage {
711 my $schema = $self->schema;
712 my $balanced_handler = $self->schema->storage->balancer;
714 $schema->storage->read_handler($balanced_handler);
719 Check that the master and at least one of the replicants is connected.
726 $self->master->connected &&
727 $self->pool->connected_replicants;
730 =head2 ensure_connected
732 Make sure all the storages are connected.
736 sub ensure_connected {
738 foreach my $source ($self->all_storages) {
739 $source->ensure_connected(@_);
745 Set the limit_dialect for all existing storages
751 foreach my $source ($self->all_storages) {
752 $source->limit_dialect(@_);
754 return $self->master->limit_dialect;
759 Set the quote_char for all existing storages
765 foreach my $source ($self->all_storages) {
766 $source->quote_char(@_);
768 return $self->master->quote_char;
773 Set the name_sep for all existing storages
779 foreach my $source ($self->all_storages) {
780 $source->name_sep(@_);
782 return $self->master->name_sep;
787 Set the schema object for all existing storages
793 foreach my $source ($self->all_storages) {
794 $source->set_schema(@_);
800 set a debug flag across all storages
807 foreach my $source ($self->all_storages) {
811 return $self->master->debug;
822 return $self->master->debugobj(@_);
833 return $self->master->debugfh(@_);
844 return $self->master->debugcb(@_);
849 disconnect everything
855 foreach my $source ($self->all_storages) {
856 $source->disconnect(@_);
862 set cursor class on all storages, or return master's
867 my ($self, $cursor_class) = @_;
870 $_->cursor_class($cursor_class) for $self->all_storages;
872 $self->master->cursor_class;
877 set cursor class on all storages, or return master's, alias for L</cursor_class>
883 my ($self, $cursor_class) = @_;
886 $_->cursor($cursor_class) for $self->all_storages;
888 $self->master->cursor;
893 sets the L<DBIx::Class::Storage::DBI/unsafe> option on all storages or returns
894 master's current setting
902 $_->unsafe(@_) for $self->all_storages;
905 return $self->master->unsafe;
908 =head2 disable_sth_caching
910 sets the L<DBIx::Class::Storage::DBI/disable_sth_caching> option on all storages
911 or returns master's current setting
915 sub disable_sth_caching {
919 $_->disable_sth_caching(@_) for $self->all_storages;
922 return $self->master->disable_sth_caching;
925 =head2 lag_behind_master
927 returns the highest Replicant L<DBIx::Class::Storage::DBI/lag_behind_master>
932 sub lag_behind_master {
935 return max map $_->lag_behind_master, $self->replicants;
938 =head2 is_replicating
940 returns true if all replicants return true for
941 L<DBIx::Class::Storage::DBI/is_replicating>
948 return (grep $_->is_replicating, $self->replicants) == ($self->replicants);
951 =head2 connect_call_datetime_setup
953 calls L<DBIx::Class::Storage::DBI/connect_call_datetime_setup> for all storages
957 sub connect_call_datetime_setup {
959 $_->connect_call_datetime_setup for $self->all_storages;
964 $_->_populate_dbh for $self->all_storages;
969 $_->_connect for $self->all_storages;
974 $_->_rebless for $self->all_storages;
977 sub _determine_driver {
979 $_->_determine_driver for $self->all_storages;
982 sub _driver_determined {
986 $_->_driver_determined(@_) for $self->all_storages;
989 return $self->master->_driver_determined;
995 $_->_init for $self->all_storages;
998 sub _run_connection_actions {
1001 $_->_run_connection_actions for $self->all_storages;
1004 sub _do_connection_actions {
1008 $_->_do_connection_actions(@_) for $self->all_storages;
1012 sub connect_call_do_sql {
1014 $_->connect_call_do_sql(@_) for $self->all_storages;
1017 sub disconnect_call_do_sql {
1019 $_->disconnect_call_do_sql(@_) for $self->all_storages;
1022 sub _seems_connected {
1025 return min map $_->_seems_connected, $self->all_storages;
1031 return min map $_->_ping, $self->all_storages;
1034 # not using the normalized_version, because we want to preserve
1035 # version numbers much longer than the conventional xxx.yyyzzz
1036 my $numify_ver = sub {
1038 my @numparts = split /\D+/, $ver;
1039 my $format = '%d.' . (join '', ('%06d') x (@numparts - 1));
1041 return sprintf $format, @numparts;
1046 if (not $self->_dbh_details->{info}) {
1047 $self->_dbh_details->{info} = (
1048 reduce { $a->[0] < $b->[0] ? $a : $b }
1049 map [ $numify_ver->($_->{dbms_version}), $_ ],
1050 map $_->_server_info, $self->all_storages
1054 return $self->next::method;
1057 sub _get_server_version {
1060 return $self->_server_info->{dbms_version};
1065 Due to the fact that replicants can lag behind a master, you must take care to
1066 make sure you use one of the methods to force read queries to a master should
1067 you need realtime data integrity. For example, if you insert a row, and then
1068 immediately re-read it from the database (say, by doing $row->discard_changes)
1069 or you insert a row and then immediately build a query that expects that row
1070 to be an item, you should force the master to handle reads. Otherwise, due to
1071 the lag, there is no certainty your data will be in the expected state.
1073 For data integrity, all transactions automatically use the master storage for
1074 all read and write queries. Using a transaction is the preferred and recommended
1075 method to force the master to handle all read queries.
1077 Otherwise, you can force a single query to use the master with the 'force_pool'
1080 my $row = $resultset->search(undef, {force_pool=>'master'})->find($pk);
1082 This attribute will safely be ignore by non replicated storages, so you can use
1083 the same code for both types of systems.
1085 Lastly, you can use the L</execute_reliably> method, which works very much like
1088 For debugging, you can turn replication on/off with the methods L</set_reliable_storage>
1089 and L</set_balanced_storage>, however this operates at a global level and is not
1090 suitable if you have a shared Schema object being used by multiple processes,
1091 such as on a web application server. You can get around this limitation by
1092 using the Schema clone method.
1094 my $new_schema = $schema->clone;
1095 $new_schema->set_reliable_storage;
1097 ## $new_schema will use only the Master storage for all reads/writes while
1098 ## the $schema object will use replicated storage.
1102 John Napiorkowski <john.napiorkowski@takkle.com>
1104 Based on code originated by:
1106 Norbert Csongrádi <bert@cpan.org>
1107 Peter Siklósi <einon@einon.hu>
1111 You may distribute this code under the same terms as Perl itself.
1115 __PACKAGE__->meta->make_immutable;