1 package DBIx::Class::Schema;
6 use base 'DBIx::Class';
10 use Scalar::Util qw/weaken blessed/;
11 use DBIx::Class::_Util qw(
12 refcount quote_sub scope_guard
13 is_exception dbic_internal_try
15 use Devel::GlobalDestruction;
18 __PACKAGE__->mk_classdata('class_mappings' => {});
19 __PACKAGE__->mk_classdata('source_registrations' => {});
20 __PACKAGE__->mk_classdata('storage_type' => '::DBI');
21 __PACKAGE__->mk_classdata('storage');
22 __PACKAGE__->mk_classdata('exception_action');
23 __PACKAGE__->mk_classdata('stacktrace' => $ENV{DBIC_TRACE} || 0);
24 __PACKAGE__->mk_classdata('default_resultset_attributes' => {});
28 DBIx::Class::Schema - composable schemas
32 package Library::Schema;
33 use base qw/DBIx::Class::Schema/;
35 # load all Result classes in Library/Schema/Result/
36 __PACKAGE__->load_namespaces();
38 package Library::Schema::Result::CD;
39 use base qw/DBIx::Class::Core/;
41 __PACKAGE__->load_components(qw/InflateColumn::DateTime/); # for example
42 __PACKAGE__->table('cd');
44 # Elsewhere in your code:
45 my $schema1 = Library::Schema->connect(
52 my $schema2 = Library::Schema->connect($coderef_returning_dbh);
54 # fetch objects using Library::Schema::Result::DVD
55 my $resultset = $schema1->resultset('DVD')->search( ... );
56 my @dvd_objects = $schema2->resultset('DVD')->search( ... );
60 Creates database classes based on a schema. This is the recommended way to
61 use L<DBIx::Class> and allows you to use more than one concurrent connection
64 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
65 carefully, as DBIx::Class does things a little differently. Note in
66 particular which module inherits off which.
70 =head2 load_namespaces
74 =item Arguments: %options?
78 package MyApp::Schema;
79 __PACKAGE__->load_namespaces();
81 __PACKAGE__->load_namespaces(
82 result_namespace => 'Res',
83 resultset_namespace => 'RSet',
84 default_resultset_class => '+MyApp::Othernamespace::RSet',
87 With no arguments, this method uses L<Module::Find> to load all of the
88 Result and ResultSet classes under the namespace of the schema from
89 which it is called. For example, C<My::Schema> will by default find
90 and load Result classes named C<My::Schema::Result::*> and ResultSet
91 classes named C<My::Schema::ResultSet::*>.
93 ResultSet classes are associated with Result class of the same name.
94 For example, C<My::Schema::Result::CD> will get the ResultSet class
95 C<My::Schema::ResultSet::CD> if it is present.
97 Both Result and ResultSet namespaces are configurable via the
98 C<result_namespace> and C<resultset_namespace> options.
100 Another option, C<default_resultset_class> specifies a custom default
101 ResultSet class for Result classes with no corresponding ResultSet.
103 All of the namespace and classname options are by default relative to
104 the schema classname. To specify a fully-qualified name, prefix it
105 with a literal C<+>. For example, C<+Other::NameSpace::Result>.
109 You will be warned if ResultSet classes are discovered for which there
110 are no matching Result classes like this:
112 load_namespaces found ResultSet class $classname with no corresponding Result class
114 If a ResultSource instance is found to already have a ResultSet class set
115 using L<resultset_class|DBIx::Class::ResultSource/resultset_class> to some
116 other class, you will be warned like this:
118 We found ResultSet class '$rs_class' for '$result_class', but it seems
119 that you had already set '$result_class' to use '$rs_set' instead
123 # load My::Schema::Result::CD, My::Schema::Result::Artist,
124 # My::Schema::ResultSet::CD, etc...
125 My::Schema->load_namespaces;
127 # Override everything to use ugly names.
128 # In this example, if there is a My::Schema::Res::Foo, but no matching
129 # My::Schema::RSets::Foo, then Foo will have its
130 # resultset_class set to My::Schema::RSetBase
131 My::Schema->load_namespaces(
132 result_namespace => 'Res',
133 resultset_namespace => 'RSets',
134 default_resultset_class => 'RSetBase',
137 # Put things in other namespaces
138 My::Schema->load_namespaces(
139 result_namespace => '+Some::Place::Results',
140 resultset_namespace => '+Another::Place::RSets',
143 To search multiple namespaces for either Result or ResultSet classes,
144 use an arrayref of namespaces for that option. In the case that the
145 same result (or resultset) class exists in multiple namespaces, later
146 entries in the list of namespaces will override earlier ones.
148 My::Schema->load_namespaces(
149 # My::Schema::Results_C::Foo takes precedence over My::Schema::Results_B::Foo :
150 result_namespace => [ 'Results_A', 'Results_B', 'Results_C' ],
151 resultset_namespace => [ '+Some::Place::RSets', 'RSets' ],
156 # Pre-pends our classname to the given relative classname or
157 # class namespace, unless there is a '+' prefix, which will
159 sub _expand_relative_name {
160 my ($class, $name) = @_;
161 $name =~ s/^\+// or $name = "${class}::${name}";
165 # Finds all modules in the supplied namespace, or if omitted in the
166 # namespace of $class. Untaints all findings as they can be assumed
169 require Module::Find;
171 { $_ =~ /(.+)/ } # untaint result
172 Module::Find::findallmod( $_[1] || ref $_[0] || $_[0] )
176 # returns a hash of $shortname => $fullname for every package
177 # found in the given namespaces ($shortname is with the $fullname's
178 # namespace stripped off)
179 sub _map_namespaces {
180 my ($me, $namespaces) = @_;
183 for my $ns (@$namespaces) {
184 $res{ substr($_, length "${ns}::") } = $_
185 for $me->_findallmod($ns);
191 # returns the result_source_instance for the passed class/object,
192 # or dies with an informative message (used by load_namespaces)
193 sub _ns_get_rsrc_instance {
195 my $rs_class = ref ($_[0]) || $_[0];
197 return dbic_internal_try {
198 $rs_class->result_source_instance
200 $me->throw_exception (
201 "Attempt to load_namespaces() class $rs_class failed - are you sure this is a real Result Class?: $_"
206 sub load_namespaces {
207 my ($class, %args) = @_;
209 my $result_namespace = delete $args{result_namespace} || 'Result';
210 my $resultset_namespace = delete $args{resultset_namespace} || 'ResultSet';
212 my $default_resultset_class = delete $args{default_resultset_class};
214 $default_resultset_class = $class->_expand_relative_name($default_resultset_class)
215 if $default_resultset_class;
217 $class->throw_exception('load_namespaces: unknown option(s): '
218 . join(q{,}, map { qq{'$_'} } keys %args))
219 if scalar keys %args;
221 for my $arg ($result_namespace, $resultset_namespace) {
222 $arg = [ $arg ] if ( $arg and ! ref $arg );
224 $class->throw_exception('load_namespaces: namespace arguments must be '
225 . 'a simple string or an arrayref')
226 if ref($arg) ne 'ARRAY';
228 $_ = $class->_expand_relative_name($_) for (@$arg);
231 my $results_by_source_name = $class->_map_namespaces($result_namespace);
232 my $resultsets_by_source_name = $class->_map_namespaces($resultset_namespace);
236 no warnings qw/redefine/;
237 local *Class::C3::reinitialize = sub { } if DBIx::Class::_ENV_::OLD_MRO;
238 use warnings qw/redefine/;
240 # ensure classes are loaded and attached in inheritance order
241 for my $result_class (values %$results_by_source_name) {
242 $class->ensure_class_loaded($result_class);
245 my @source_names_by_subclass_last = sort {
248 scalar @{mro::get_linear_isa( $results_by_source_name->{$a} )}
254 scalar @{mro::get_linear_isa( $results_by_source_name->{$b} )}
257 } keys(%$results_by_source_name);
259 foreach my $source_name (@source_names_by_subclass_last) {
260 my $result_class = $results_by_source_name->{$source_name};
262 my $preset_resultset_class = $class->_ns_get_rsrc_instance ($result_class)->resultset_class;
263 my $found_resultset_class = delete $resultsets_by_source_name->{$source_name};
265 if($preset_resultset_class && $preset_resultset_class ne 'DBIx::Class::ResultSet') {
266 if($found_resultset_class && $found_resultset_class ne $preset_resultset_class) {
267 carp "We found ResultSet class '$found_resultset_class' matching '$results_by_source_name->{$source_name}', but it seems "
268 . "that you had already set the '$results_by_source_name->{$source_name}' resultet to '$preset_resultset_class' instead";
271 # elsif - there may be *no* default_resultset_class, in which case we fallback to
272 # DBIx::Class::Resultset and there is nothing to check
273 elsif($found_resultset_class ||= $default_resultset_class) {
274 $class->ensure_class_loaded($found_resultset_class);
275 if(!$found_resultset_class->isa("DBIx::Class::ResultSet")) {
276 carp "load_namespaces found ResultSet class '$found_resultset_class' that does not subclass DBIx::Class::ResultSet";
279 $class->_ns_get_rsrc_instance ($result_class)->resultset_class($found_resultset_class);
282 my $source_name = $class->_ns_get_rsrc_instance ($result_class)->source_name || $source_name;
284 push(@to_register, [ $source_name, $result_class ]);
288 foreach (sort keys %$resultsets_by_source_name) {
289 carp "load_namespaces found ResultSet class '$resultsets_by_source_name->{$_}' "
290 .'with no corresponding Result class';
293 Class::C3->reinitialize if DBIx::Class::_ENV_::OLD_MRO;
295 $class->register_class(@$_) for (@to_register);
304 =item Arguments: @classes?, { $namespace => [ @classes ] }+
308 L</load_classes> is an alternative method to L</load_namespaces>, both of
309 which serve similar purposes, each with different advantages and disadvantages.
310 In the general case you should use L</load_namespaces>, unless you need to
311 be able to specify that only specific classes are loaded at runtime.
313 With no arguments, this method uses L<Module::Find> to find all classes under
314 the schema's namespace. Otherwise, this method loads the classes you specify
315 (using L<use>), and registers them (using L</"register_class">).
317 It is possible to comment out classes with a leading C<#>, but note that perl
318 will think it's a mistake (trying to use a comment in a qw list), so you'll
319 need to add C<no warnings 'qw';> before your load_classes call.
321 If any classes found do not appear to be Result class files, you will
322 get the following warning:
324 Failed to load $comp_class. Can't find source_name method. Is
325 $comp_class really a full DBIC result class? Fix it, move it elsewhere,
326 or make your load_classes call more specific.
330 My::Schema->load_classes(); # loads My::Schema::CD, My::Schema::Artist,
331 # etc. (anything under the My::Schema namespace)
333 # loads My::Schema::CD, My::Schema::Artist, Other::Namespace::Producer but
334 # not Other::Namespace::LinerNotes nor My::Schema::Track
335 My::Schema->load_classes(qw/ CD Artist #Track /, {
336 Other::Namespace => [qw/ Producer #LinerNotes /],
342 my ($class, @params) = @_;
347 foreach my $param (@params) {
348 if (ref $param eq 'ARRAY') {
349 # filter out commented entries
350 my @modules = grep { $_ !~ /^#/ } @$param;
352 push (@{$comps_for{$class}}, @modules);
354 elsif (ref $param eq 'HASH') {
355 # more than one namespace possible
356 for my $comp ( keys %$param ) {
357 # filter out commented entries
358 my @modules = grep { $_ !~ /^#/ } @{$param->{$comp}};
360 push (@{$comps_for{$comp}}, @modules);
364 # filter out commented entries
365 push (@{$comps_for{$class}}, $param) if $param !~ /^#/;
369 my @comp = map { substr $_, length "${class}::" }
370 $class->_findallmod($class);
371 $comps_for{$class} = \@comp;
376 no warnings qw/redefine/;
377 local *Class::C3::reinitialize = sub { } if DBIx::Class::_ENV_::OLD_MRO;
378 use warnings qw/redefine/;
380 foreach my $prefix (keys %comps_for) {
381 foreach my $comp (@{$comps_for{$prefix}||[]}) {
382 my $comp_class = "${prefix}::${comp}";
383 $class->ensure_class_loaded($comp_class);
385 my $snsub = $comp_class->can('source_name');
387 carp "Failed to load $comp_class. Can't find source_name method. Is $comp_class really a full DBIC result class? Fix it, move it elsewhere, or make your load_classes call more specific.";
390 $comp = $snsub->($comp_class) || $comp;
392 push(@to_register, [ $comp, $comp_class ]);
396 Class::C3->reinitialize if DBIx::Class::_ENV_::OLD_MRO;
398 foreach my $to (@to_register) {
399 $class->register_class(@$to);
407 =item Arguments: $storage_type|{$storage_type, \%args}
409 =item Return Value: $storage_type|{$storage_type, \%args}
411 =item Default value: DBIx::Class::Storage::DBI
415 Set the storage class that will be instantiated when L</connect> is called.
416 If the classname starts with C<::>, the prefix C<DBIx::Class::Storage> is
417 assumed by L</connect>.
419 You want to use this to set subclasses of L<DBIx::Class::Storage::DBI>
420 in cases where the appropriate subclass is not autodetected.
422 If your storage type requires instantiation arguments, those are
423 defined as a second argument in the form of a hashref and the entire
424 value needs to be wrapped into an arrayref or a hashref. We support
425 both types of refs here in order to play nice with your
426 Config::[class] or your choice. See
427 L<DBIx::Class::Storage::DBI::Replicated> for an example of this.
429 =head2 exception_action
433 =item Arguments: $code_reference
435 =item Return Value: $code_reference
437 =item Default value: None
441 When L</throw_exception> is invoked and L</exception_action> is set to a code
442 reference, this reference will be called instead of
443 L<DBIx::Class::Exception/throw>, with the exception message passed as the only
446 Your custom throw code B<must> rethrow the exception, as L</throw_exception> is
447 an integral part of DBIC's internal execution control flow.
452 use base qw/DBIx::Class::Schema/;
453 use My::ExceptionClass;
454 __PACKAGE__->exception_action(sub { My::ExceptionClass->throw(@_) });
455 __PACKAGE__->load_classes;
458 my $schema_obj = My::Schema->connect( .... );
459 $schema_obj->exception_action(sub { My::ExceptionClass->throw(@_) });
465 =item Arguments: boolean
469 Whether L</throw_exception> should include stack trace information.
470 Defaults to false normally, but defaults to true if C<$ENV{DBIC_TRACE}>
473 =head2 sqlt_deploy_hook
477 =item Arguments: $sqlt_schema
481 An optional sub which you can declare in your own Schema class that will get
482 passed the L<SQL::Translator::Schema> object when you deploy the schema via
483 L</create_ddl_dir> or L</deploy>.
485 For an example of what you can do with this, see
486 L<DBIx::Class::Manual::Cookbook/Adding Indexes And Functions To Your SQL>.
488 Note that sqlt_deploy_hook is called by L</deployment_statements>, which in turn
489 is called before L</deploy>. Therefore the hook can be used only to manipulate
490 the L<SQL::Translator::Schema> object before it is turned into SQL fed to the
491 database. If you want to execute post-deploy statements which can not be generated
492 by L<SQL::Translator>, the currently suggested method is to overload L</deploy>
493 and use L<dbh_do|DBIx::Class::Storage::DBI/dbh_do>.
501 =item Arguments: @connectinfo
503 =item Return Value: $new_schema
507 Creates and returns a new Schema object. The connection info set on it
508 is used to create a new instance of the storage backend and set it on
511 See L<DBIx::Class::Storage::DBI/"connect_info"> for DBI-specific
512 syntax on the C<@connectinfo> argument, or L<DBIx::Class::Storage> in
515 Note that C<connect_info> expects an arrayref of arguments, but
516 C<connect> does not. C<connect> wraps its arguments in an arrayref
517 before passing them to C<connect_info>.
521 C<connect> is a convenience method. It is equivalent to calling
522 $schema->clone->connection(@connectinfo). To write your own overloaded
523 version, overload L</connection> instead.
527 sub connect { shift->clone->connection(@_) }
533 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>
535 =item Return Value: L<$resultset|DBIx::Class::ResultSet>
539 my $rs = $schema->resultset('DVD');
541 Returns the L<DBIx::Class::ResultSet> object for the registered source
547 my ($self, $source_name) = @_;
548 $self->throw_exception('resultset() expects a source name')
549 unless defined $source_name;
550 return $self->source($source_name)->resultset;
557 =item Return Value: L<@source_names|DBIx::Class::ResultSource/source_name>
561 my @source_names = $schema->sources;
563 Lists names of all the sources registered on this Schema object.
567 sub sources { keys %{shift->source_registrations} }
573 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>
575 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
579 my $source = $schema->source('Book');
581 Returns the L<DBIx::Class::ResultSource> object for the registered
589 $self->throw_exception("source() expects a source name")
592 my $source_name = shift;
594 my $sreg = $self->source_registrations;
595 return $sreg->{$source_name} if exists $sreg->{$source_name};
597 # if we got here, they probably passed a full class name
598 my $mapped = $self->class_mappings->{$source_name};
599 $self->throw_exception("Can't find source for ${source_name}")
600 unless $mapped && exists $sreg->{$mapped};
601 return $sreg->{$mapped};
608 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>
610 =item Return Value: $classname
614 my $class = $schema->class('CD');
616 Retrieves the Result class name for the given source name.
621 return shift->source(shift)->result_class;
628 =item Arguments: C<$coderef>, @coderef_args?
630 =item Return Value: The return value of $coderef
634 Executes C<$coderef> with (optional) arguments C<@coderef_args> atomically,
635 returning its result (if any). Equivalent to calling $schema->storage->txn_do.
636 See L<DBIx::Class::Storage/"txn_do"> for more information.
638 This interface is preferred over using the individual methods L</txn_begin>,
639 L</txn_commit>, and L</txn_rollback> below.
641 WARNING: If you are connected with C<< AutoCommit => 0 >> the transaction is
642 considered nested, and you will still need to call L</txn_commit> to write your
643 changes when appropriate. You will also want to connect with C<< auto_savepoint =>
644 1 >> to get partial rollback to work, if the storage driver for your database
647 Connecting with C<< AutoCommit => 1 >> is recommended.
654 $self->storage or $self->throw_exception
655 ('txn_do called on $schema without storage');
657 $self->storage->txn_do(@_);
660 =head2 txn_scope_guard
662 Runs C<txn_scope_guard> on the schema's storage. See
663 L<DBIx::Class::Storage/txn_scope_guard>.
667 sub txn_scope_guard {
670 $self->storage or $self->throw_exception
671 ('txn_scope_guard called on $schema without storage');
673 $self->storage->txn_scope_guard(@_);
678 Begins a transaction (does nothing if AutoCommit is off). Equivalent to
679 calling $schema->storage->txn_begin. See
680 L<DBIx::Class::Storage/"txn_begin"> for more information.
687 $self->storage or $self->throw_exception
688 ('txn_begin called on $schema without storage');
690 $self->storage->txn_begin;
695 Commits the current transaction. Equivalent to calling
696 $schema->storage->txn_commit. See L<DBIx::Class::Storage/"txn_commit">
697 for more information.
704 $self->storage or $self->throw_exception
705 ('txn_commit called on $schema without storage');
707 $self->storage->txn_commit;
712 Rolls back the current transaction. Equivalent to calling
713 $schema->storage->txn_rollback. See
714 L<DBIx::Class::Storage/"txn_rollback"> for more information.
721 $self->storage or $self->throw_exception
722 ('txn_rollback called on $schema without storage');
724 $self->storage->txn_rollback;
729 my $storage = $schema->storage;
731 Returns the L<DBIx::Class::Storage> object for this Schema. Grab this
732 if you want to turn on SQL statement debugging at runtime, or set the
733 quote character. For the default storage, the documentation can be
734 found in L<DBIx::Class::Storage::DBI>.
740 =item Arguments: L<$source_name|DBIx::Class::ResultSource/source_name>, [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
742 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
746 A convenience shortcut to L<DBIx::Class::ResultSet/populate>. Equivalent to:
748 $schema->resultset($source_name)->populate([...]);
754 The context of this method call has an important effect on what is
755 submitted to storage. In void context data is fed directly to fastpath
756 insertion routines provided by the underlying storage (most often
757 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
758 L<insert|DBIx::Class::Row/insert> calls on the
759 L<Result|DBIx::Class::Manual::ResultClass> class, including any
760 augmentation of these methods provided by components. For example if you
761 are using something like L<DBIx::Class::UUIDColumns> to create primary
762 keys for you, you will find that your PKs are empty. In this case you
763 will have to explicitly force scalar or list context in order to create
771 my ($self, $name, $data) = @_;
772 my $rs = $self->resultset($name)
773 or $self->throw_exception("'$name' is not a resultset");
775 return $rs->populate($data);
782 =item Arguments: @args
784 =item Return Value: $new_schema
788 Similar to L</connect> except sets the storage object and connection
789 data in-place on the Schema class. You should probably be calling
790 L</connect> to get a proper Schema object instead.
794 Overload C<connection> to change the behaviour of C<connect>.
799 my ($self, @info) = @_;
800 return $self if !@info && $self->storage;
802 my ($storage_class, $args) = ref $self->storage_type
803 ? $self->_normalize_storage_type($self->storage_type)
804 : $self->storage_type
807 $storage_class =~ s/^::/DBIx::Class::Storage::/;
810 $self->ensure_class_loaded ($storage_class);
813 $self->throw_exception(
814 "Unable to load storage class ${storage_class}: $_"
818 my $storage = $storage_class->new( $self => $args||{} );
819 $storage->connect_info(\@info);
820 $self->storage($storage);
824 sub _normalize_storage_type {
825 my ($self, $storage_type) = @_;
826 if(ref $storage_type eq 'ARRAY') {
827 return @$storage_type;
828 } elsif(ref $storage_type eq 'HASH') {
829 return %$storage_type;
831 $self->throw_exception('Unsupported REFTYPE given: '. ref $storage_type);
835 =head2 compose_namespace
839 =item Arguments: $target_namespace, $additional_base_class?
841 =item Return Value: $new_schema
845 For each L<DBIx::Class::ResultSource> in the schema, this method creates a
846 class in the target namespace (e.g. $target_namespace::CD,
847 $target_namespace::Artist) that inherits from the corresponding classes
848 attached to the current schema.
850 It also attaches a corresponding L<DBIx::Class::ResultSource> object to the
851 new $schema object. If C<$additional_base_class> is given, the new composed
852 classes will inherit from first the corresponding class from the current
853 schema then the base class.
855 For example, for a schema with My::Schema::CD and My::Schema::Artist classes,
857 $schema->compose_namespace('My::DB', 'Base::Class');
858 print join (', ', @My::DB::CD::ISA) . "\n";
859 print join (', ', @My::DB::Artist::ISA) ."\n";
861 will produce the output
863 My::Schema::CD, Base::Class
864 My::Schema::Artist, Base::Class
868 sub compose_namespace {
869 my ($self, $target, $base) = @_;
871 my $schema = $self->clone;
873 $schema->source_registrations({});
875 # the original class-mappings must remain - otherwise
876 # reverse_relationship_info will not work
877 #$schema->class_mappings({});
880 no warnings qw/redefine/;
881 local *Class::C3::reinitialize = sub { } if DBIx::Class::_ENV_::OLD_MRO;
882 use warnings qw/redefine/;
884 foreach my $source_name ($self->sources) {
885 my $orig_source = $self->source($source_name);
887 my $target_class = "${target}::${source_name}";
888 $self->inject_base($target_class, $orig_source->result_class, ($base || ()) );
890 # register_source examines result_class, and then returns us a clone
891 my $new_source = $schema->register_source($source_name, bless
892 { %$orig_source, result_class => $target_class },
896 if ($target_class->can('result_source_instance')) {
897 # give the class a schema-less source copy
898 $target_class->result_source_instance( bless
899 { %$new_source, schema => ref $new_source->{schema} || $new_source->{schema} },
905 quote_sub "${target}::${_}" => "shift->schema->$_(\@_)"
906 for qw(class source resultset);
909 Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
914 sub setup_connection_class {
915 my ($class, $target, @info) = @_;
916 $class->inject_base($target => 'DBIx::Class::DB');
917 #$target->load_components('DB');
918 $target->connection(@info);
923 Creates a new savepoint (does nothing outside a transaction).
924 Equivalent to calling $schema->storage->svp_begin. See
925 L<DBIx::Class::Storage/"svp_begin"> for more information.
930 my ($self, $name) = @_;
932 $self->storage or $self->throw_exception
933 ('svp_begin called on $schema without storage');
935 $self->storage->svp_begin($name);
940 Releases a savepoint (does nothing outside a transaction).
941 Equivalent to calling $schema->storage->svp_release. See
942 L<DBIx::Class::Storage/"svp_release"> for more information.
947 my ($self, $name) = @_;
949 $self->storage or $self->throw_exception
950 ('svp_release called on $schema without storage');
952 $self->storage->svp_release($name);
957 Rollback to a savepoint (does nothing outside a transaction).
958 Equivalent to calling $schema->storage->svp_rollback. See
959 L<DBIx::Class::Storage/"svp_rollback"> for more information.
964 my ($self, $name) = @_;
966 $self->storage or $self->throw_exception
967 ('svp_rollback called on $schema without storage');
969 $self->storage->svp_rollback($name);
976 =item Arguments: %attrs?
978 =item Return Value: $new_schema
982 Clones the schema and its associated result_source objects and returns the
983 copy. The resulting copy will have the same attributes as the source schema,
984 except for those attributes explicitly overridden by the provided C<%attrs>.
992 (ref $self ? %$self : ()),
993 (@_ == 1 && ref $_[0] eq 'HASH' ? %{ $_[0] } : @_),
995 bless $clone, (ref $self || $self);
997 $clone->$_(undef) for qw/class_mappings source_registrations storage/;
999 $clone->_copy_state_from($self);
1004 # Needed in Schema::Loader - if you refactor, please make a compatibility shim
1006 sub _copy_state_from {
1007 my ($self, $from) = @_;
1009 $self->class_mappings({ %{$from->class_mappings} });
1010 $self->source_registrations({ %{$from->source_registrations} });
1012 foreach my $source_name ($from->sources) {
1013 my $source = $from->source($source_name);
1014 my $new = $source->new($source);
1015 # we use extra here as we want to leave the class_mappings as they are
1016 # but overwrite the source_registrations entry with the new source
1017 $self->register_extra_source($source_name => $new);
1020 if ($from->storage) {
1021 $self->storage($from->storage);
1022 $self->storage->set_schema($self);
1026 =head2 throw_exception
1030 =item Arguments: $message
1034 Throws an exception. Obeys the exemption rules of L<DBIx::Class::Carp> to report
1035 errors from outer-user's perspective. See L</exception_action> for details on overriding
1036 this method's behavior. If L</stacktrace> is turned on, C<throw_exception>'s
1037 default behavior will provide a detailed stack trace.
1041 sub throw_exception {
1042 my ($self, @args) = @_;
1045 ! DBIx::Class::_Util::in_internal_try()
1047 my $act = $self->exception_action
1052 my $guard = scope_guard {
1053 return if $guard_disarmed;
1054 local $SIG{__WARN__};
1056 !!! DBIx::Class INTERNAL PANIC !!!
1058 The exception_action() handler installed on '$self'
1059 aborted the stacktrace below via a longjmp (either via Return::Multilevel or
1060 plain goto, or Scope::Upper or something equally nefarious). There currently
1061 is nothing safe DBIx::Class can do, aside from displaying this error. A future
1062 version ( 0.082900, when available ) will reduce the cases in which the
1063 handler is invoked, but this is neither a complete solution, nor can it do
1064 anything for other software that might be affected by a similar problem.
1066 !!! FIX YOUR ERROR HANDLING !!!
1068 This guard was activated beginning"
1073 # if it throws - good, we'll assign to @args in the end
1074 # if it doesn't - do different things depending on RV truthiness
1075 if( $act->(@args) ) {
1077 "Invocation of the exception_action handler installed on $self did *not*"
1078 .' result in an exception. DBIx::Class is unable to function without a reliable'
1079 .' exception mechanism, ensure your exception_action does not hide exceptions'
1080 ." (original error: $args[0])"
1085 "The exception_action handler installed on $self returned false instead"
1086 .' of throwing an exception. This behavior has been deprecated, adjust your'
1087 .' handler to always rethrow the supplied error'
1094 # We call this to get the necessary warnings emitted and disregard the RV
1095 # as it's definitely an exception if we got as far as this catch{} block
1101 # Done guarding against https://github.com/PerlDancer/Dancer2/issues/1125
1102 $guard_disarmed = 1;
1105 DBIx::Class::Exception->throw( $args[0], $self->stacktrace );
1112 =item Arguments: \%sqlt_args, $dir
1116 Attempts to deploy the schema to the current storage using L<SQL::Translator>.
1118 See L<SQL::Translator/METHODS> for a list of values for C<\%sqlt_args>.
1119 The most common value for this would be C<< { add_drop_table => 1 } >>
1120 to have the SQL produced include a C<DROP TABLE> statement for each table
1121 created. For quoting purposes supply C<quote_identifiers>.
1123 Additionally, the DBIx::Class parser accepts a C<sources> parameter as a hash
1124 ref or an array ref, containing a list of source to deploy. If present, then
1125 only the sources listed will get deployed. Furthermore, you can use the
1126 C<add_fk_index> parser parameter to prevent the parser from creating an index for each
1132 my ($self, $sqltargs, $dir) = @_;
1133 $self->throw_exception("Can't deploy without storage") unless $self->storage;
1134 $self->storage->deploy($self, undef, $sqltargs, $dir);
1137 =head2 deployment_statements
1141 =item Arguments: See L<DBIx::Class::Storage::DBI/deployment_statements>
1143 =item Return Value: $listofstatements
1147 A convenient shortcut to
1148 C<< $self->storage->deployment_statements($self, @args) >>.
1149 Returns the statements used by L</deploy> and
1150 L<DBIx::Class::Storage/deploy>.
1154 sub deployment_statements {
1157 $self->throw_exception("Can't generate deployment statements without a storage")
1158 if not $self->storage;
1160 $self->storage->deployment_statements($self, @_);
1163 =head2 create_ddl_dir
1167 =item Arguments: See L<DBIx::Class::Storage::DBI/create_ddl_dir>
1171 A convenient shortcut to
1172 C<< $self->storage->create_ddl_dir($self, @args) >>.
1174 Creates an SQL file based on the Schema, for each of the specified
1175 database types, in the given directory.
1179 sub create_ddl_dir {
1182 $self->throw_exception("Can't create_ddl_dir without storage") unless $self->storage;
1183 $self->storage->create_ddl_dir($self, @_);
1190 =item Arguments: $database-type, $version, $directory, $preversion
1192 =item Return Value: $normalised_filename
1196 my $filename = $table->ddl_filename($type, $version, $dir, $preversion)
1198 This method is called by C<create_ddl_dir> to compose a file name out of
1199 the supplied directory, database type and version number. The default file
1200 name format is: C<$dir$schema-$version-$type.sql>.
1202 You may override this method in your schema if you wish to use a different
1207 Prior to DBIx::Class version 0.08100 this method had a different signature:
1209 my $filename = $table->ddl_filename($type, $dir, $version, $preversion)
1211 In recent versions variables $dir and $version were reversed in order to
1212 bring the signature in line with other Schema/Storage methods. If you
1213 really need to maintain backward compatibility, you can do the following
1214 in any overriding methods:
1216 ($dir, $version) = ($version, $dir) if ($DBIx::Class::VERSION < 0.08100);
1221 my ($self, $type, $version, $dir, $preversion) = @_;
1223 $version = "$preversion-$version" if $preversion;
1225 my $class = blessed($self) || $self;
1228 return "$dir/$class-$version-$type.sql";
1233 Provided as the recommended way of thawing schema objects. You can call
1234 C<Storable::thaw> directly if you wish, but the thawed objects will not have a
1235 reference to any schema, so are rather useless.
1240 my ($self, $obj) = @_;
1241 local $DBIx::Class::ResultSourceHandle::thaw_schema = $self;
1242 return Storable::thaw($obj);
1247 This doesn't actually do anything beyond calling L<nfreeze|Storable/SYNOPSIS>,
1248 it is just provided here for symmetry.
1253 return Storable::nfreeze($_[1]);
1260 =item Arguments: $object
1262 =item Return Value: dcloned $object
1266 Recommended way of dcloning L<DBIx::Class::Row> and L<DBIx::Class::ResultSet>
1267 objects so their references to the schema object
1268 (which itself is B<not> cloned) are properly maintained.
1273 my ($self, $obj) = @_;
1274 local $DBIx::Class::ResultSourceHandle::thaw_schema = $self;
1275 return Storable::dclone($obj);
1278 =head2 schema_version
1280 Returns the current schema class' $VERSION in a normalised way.
1284 sub schema_version {
1286 my $class = ref($self)||$self;
1288 # does -not- use $schema->VERSION
1289 # since that varies in results depending on if version.pm is installed, and if
1290 # so the perl or XS versions. If you want this to change, bug the version.pm
1291 # author to make vpp and vxs behave the same.
1296 $version = ${"${class}::VERSION"};
1302 =head2 register_class
1306 =item Arguments: $source_name, $component_class
1310 This method is called by L</load_namespaces> and L</load_classes> to install the found classes into your Schema. You should be using those instead of this one.
1312 You will only need this method if you have your Result classes in
1313 files which are not named after the packages (or all in the same
1314 file). You may also need it to register classes at runtime.
1316 Registers a class which isa DBIx::Class::ResultSourceProxy. Equivalent to
1319 $schema->register_source($source_name, $component_class->result_source_instance);
1323 sub register_class {
1324 my ($self, $source_name, $to_register) = @_;
1325 $self->register_source($source_name => $to_register->result_source_instance);
1328 =head2 register_source
1332 =item Arguments: $source_name, L<$result_source|DBIx::Class::ResultSource>
1336 This method is called by L</register_class>.
1338 Registers the L<DBIx::Class::ResultSource> in the schema with the given
1343 sub register_source { shift->_register_source(@_) }
1345 =head2 unregister_source
1349 =item Arguments: $source_name
1353 Removes the L<DBIx::Class::ResultSource> from the schema for the given source name.
1357 sub unregister_source { shift->_unregister_source(@_) }
1359 =head2 register_extra_source
1363 =item Arguments: $source_name, L<$result_source|DBIx::Class::ResultSource>
1367 As L</register_source> but should be used if the result class already
1368 has a source and you want to register an extra one.
1372 sub register_extra_source { shift->_register_source(@_, { extra => 1 }) }
1374 sub _register_source {
1375 my ($self, $source_name, $source, $params) = @_;
1377 $source = $source->new({ %$source, source_name => $source_name });
1379 $source->schema($self);
1380 weaken $source->{schema} if ref($self);
1382 my %reg = %{$self->source_registrations};
1383 $reg{$source_name} = $source;
1384 $self->source_registrations(\%reg);
1386 return $source if $params->{extra};
1388 my $rs_class = $source->result_class;
1389 if ($rs_class and my $rsrc = dbic_internal_try { $rs_class->result_source_instance } ) {
1390 my %map = %{$self->class_mappings};
1392 exists $map{$rs_class}
1394 $map{$rs_class} ne $source_name
1396 $rsrc ne $_[2] # orig_source
1399 "$rs_class already had a registered source which was replaced by this call. "
1400 . 'Perhaps you wanted register_extra_source(), though it is more likely you did '
1401 . 'something wrong.'
1405 $map{$rs_class} = $source_name;
1406 $self->class_mappings(\%map);
1412 my $global_phase_destroy;
1414 ### NO detected_reinvoked_destructor check
1415 ### This code very much relies on being called multuple times
1417 return if $global_phase_destroy ||= in_global_destruction;
1420 my $srcs = $self->source_registrations;
1422 for my $source_name (keys %$srcs) {
1423 # find first source that is not about to be GCed (someone other than $self
1424 # holds a reference to it) and reattach to it, weakening our own link
1426 # during global destruction (if we have not yet bailed out) this should throw
1427 # which will serve as a signal to not try doing anything else
1428 # however beware - on older perls the exception seems randomly untrappable
1429 # due to some weird race condition during thread joining :(((
1430 if (length ref $srcs->{$source_name} and refcount($srcs->{$source_name}) > 1) {
1431 local $SIG{__DIE__} if $SIG{__DIE__};
1434 $srcs->{$source_name}->schema($self);
1435 weaken $srcs->{$source_name};
1438 $global_phase_destroy = 1;
1445 # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage
1446 # collected before leaving this scope. Depending on the code above, this
1447 # may very well be just a preventive measure guarding future modifications
1451 sub _unregister_source {
1452 my ($self, $source_name) = @_;
1453 my %reg = %{$self->source_registrations};
1455 my $source = delete $reg{$source_name};
1456 $self->source_registrations(\%reg);
1457 if ($source->result_class) {
1458 my %map = %{$self->class_mappings};
1459 delete $map{$source->result_class};
1460 $self->class_mappings(\%map);
1465 =head2 compose_connection (DEPRECATED)
1469 =item Arguments: $target_namespace, @db_info
1471 =item Return Value: $new_schema
1475 DEPRECATED. You probably wanted compose_namespace.
1477 Actually, you probably just wanted to call connect.
1481 (hidden due to deprecation)
1483 Calls L<DBIx::Class::Schema/"compose_namespace"> to the target namespace,
1484 calls L<DBIx::Class::Schema/connection> with @db_info on the new schema,
1485 then injects the L<DBix::Class::ResultSetProxy> component and a
1486 resultset_instance classdata entry on all the new classes, in order to support
1487 $target_namespaces::$class->search(...) method calls.
1489 This is primarily useful when you have a specific need for class method access
1490 to a connection. In normal usage it is preferred to call
1491 L<DBIx::Class::Schema/connect> and use the resulting schema object to operate
1492 on L<DBIx::Class::ResultSet> objects with L<DBIx::Class::Schema/resultset> for
1499 sub compose_connection {
1500 my ($self, $target, @info) = @_;
1502 carp_once "compose_connection deprecated as of 0.08000"
1503 unless $INC{"DBIx/Class/CDBICompat.pm"};
1506 require DBIx::Class::ResultSetProxy;
1509 $self->throw_exception
1510 ("No arguments to load_classes and couldn't load DBIx::Class::ResultSetProxy ($_)")
1513 if ($self eq $target) {
1514 # Pathological case, largely caused by the docs on early C::M::DBIC::Plain
1515 foreach my $source_name ($self->sources) {
1516 my $source = $self->source($source_name);
1517 my $class = $source->result_class;
1518 $self->inject_base($class, 'DBIx::Class::ResultSetProxy');
1519 $class->mk_classdata(resultset_instance => $source->resultset);
1520 $class->mk_classdata(class_resolver => $self);
1522 $self->connection(@info);
1526 my $schema = $self->compose_namespace($target, 'DBIx::Class::ResultSetProxy');
1527 quote_sub "${target}::schema", '$s', { '$s' => \$schema };
1529 $schema->connection(@info);
1530 foreach my $source_name ($schema->sources) {
1531 my $source = $schema->source($source_name);
1532 my $class = $source->result_class;
1533 #warn "$source_name $class $source ".$source->storage;
1534 $class->mk_classdata(result_source_instance => $source);
1535 $class->mk_classdata(resultset_instance => $source->resultset);
1536 $class->mk_classdata(class_resolver => $schema);
1541 =head1 FURTHER QUESTIONS?
1543 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
1545 =head1 COPYRIGHT AND LICENSE
1547 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
1548 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
1549 redistribute it and/or modify it under the same terms as the
1550 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.