lib/DBIx/Class/Schema.pm

   1 package DBIx::Class::Schema;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::Class::DB;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->load_components(qw/Exception/);
  10 __PACKAGE__->mk_classdata('class_registrations' => {});
  11
  12 =head1 NAME
  13
  14 DBIx::Class::Schema - composable schemas
  15
  16 =head1 SYNOPSIS
  17
  18 in My/Schema.pm
  19
  20   package My::Schema;
  21
  22   use base qw/DBIx::Class::Schema/;
  23
  24   __PACKAGE__->load_classes(qw/Foo Bar Baz/);
  25
  26 in My/Schema/Foo.pm
  27
  28   package My::Schema::Foo;
  29
  30   use base qw/DBIx::Class/;
  31
  32   __PACKAGE__->load_components(qw/Core PK::Auto::Pg/); # for example
  33   __PACKAGE__->table('foo');
  34   ...
  35
  36 in My/DB.pm
  37
  38   use My::Schema;
  39
  40   My::Schema->compose_connection('My::DB', $dsn, $user, $pass, $attrs);
  41
  42 then in app code
  43
  44   my @obj = My::DB::Foo->search({}); # My::DB::Foo isa My::Schema::Foo My::DB
  45
  46 =head1 DESCRIPTION
  47
  48 Creates database classes based on a schema. This allows you to have more than
  49 one concurrent connection using the same database classes, by making
  50 subclasses under a new namespace for each connection. If you only need one
  51 class, you should probably use L<DBIx::Class::DB> directly instead.
  52
  53 NB: If you're used to L<Class::DBI> it's worth reading the L</SYNOPSIS>
  54 carefully as DBIx::Class does things a little differently. Note in
  55 particular which module inherits off which.
  56
  57 =head1 METHODS
  58
  59 =over 4
  60
  61 =item register_class <component> <component_class>
  62
  63 Registers the class in the schema's class_registrations. This is a hash
  64 containing database classes, keyed by their monikers. It's used by
  65 compose_connection to create/modify all the existing database classes.
  66
  67 =cut
  68
  69 sub register_class {
  70   my ($class, $name, $to_register) = @_;
  71   my %reg = %{$class->class_registrations};
  72   $reg{$name} = $to_register;
  73   $class->class_registrations(\%reg);
  74 }
  75
  76 =item registered_classes
  77
  78 Simple read-only accessor for the schema's registered classes. See
  79 register_class above if you want to modify it.
  80
  81
  82 =cut
  83
  84 sub registered_classes {
  85   return values %{shift->class_registrations};
  86 }
  87
  88 =item  load_classes [<classes>}
  89
  90 Uses L<Module::Find> to find all classes under the database class' namespace,
  91 or uses the classes you select.  Then it loads the component (using L<use>),
  92 and registers them (using B<register_class>);
  93
  94 =cut
  95
  96 sub load_classes {
  97   my $class = shift;
  98   my @comp = grep { $_ !~ /^#/ } @_;
  99   unless (@comp) {
 100     eval "require Module::Find;";
 101     $class->throw("No arguments to load_classes and couldn't load".
 102       " Module::Find ($@)") if $@;
 103     @comp = map { substr $_, length "${class}::"  }
 104               Module::Find::findallmod($class);
 105   }
 106   foreach my $comp (@comp) {
 107     my $comp_class = "${class}::${comp}";
 108     eval "use $comp_class"; # If it fails, assume the user fixed it
 109     $class->register_class($comp => $comp_class);
 110   }
 111 }
 112
 113 =item compose_connection <target> <@db_info>
 114
 115 This is the most important method in this class. it takes a target namespace,
 116 as well as dbh connection info, and creates a L<DBIx::Class::DB> class as
 117 well as subclasses for each of your database classes in this namespace, using
 118 this connection.
 119
 120 It will also setup a ->table method on the target class, which lets you
 121 resolve database classes based on the schema component name, for example
 122
 123   MyApp::DB->table('Foo') # returns MyApp::DB::Foo,
 124                           # which ISA MyApp::Schema::Foo
 125
 126 This is the recommended API for accessing Schema generated classes, and
 127 using it might give you instant advantages with future versions of DBIC.
 128
 129 =cut
 130
 131 sub compose_connection {
 132   my ($class, $target, @info) = @_;
 133   my $conn_class = "${target}::_db";
 134   $class->setup_connection_class($conn_class, @info);
 135   my %reg = %{ $class->class_registrations };
 136   my %target;
 137   my %map;
 138   while (my ($comp, $comp_class) = each %reg) {
 139     my $target_class = "${target}::${comp}";
 140     $class->inject_base($target_class, $comp_class, $conn_class);
 141     $target_class->table($comp_class->table);
 142     @map{$comp, $comp_class} = ($target_class, $target_class);
 143   }
 144   {
 145     no strict 'refs';
 146     *{"${target}::class"} =
 147       sub {
 148         my ($class, $to_map) = @_;
 149         return $map{$to_map};
 150       };
 151     *{"${target}::classes"} = sub { return \%map; };
 152   }
 153   $conn_class->class_resolver($target);
 154 }
 155
 156 =item setup_connection_class <$target> <@info>
 157
 158 Sets up a database connection class to inject between the schema
 159 and the subclasses the schema creates.
 160
 161 =cut
 162
 163 sub setup_connection_class {
 164   my ($class, $target, @info) = @_;
 165   $class->inject_base($target => 'DBIx::Class::DB');
 166   #$target->load_components('DB');
 167   $target->connection(@info);
 168 }
 169
 170 1;
 171
 172 =back
 173
 174 =head1 AUTHORS
 175
 176 Matt S. Trout <mst@shadowcatsystems.co.uk>
 177
 178 =head1 LICENSE
 179
 180 You may distribute this code under the same terms as Perl itself.
 181
 182 =cut
 183