lib/DBIx/Class/Schema/Loader.pm

   1 package DBIx::Class::Schema::Loader;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema Class::Accessor::Grouped/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use Class::C3;
   8 use Scalar::Util qw/ weaken /;
   9
  10 # Always remember to do all digits for the version even if they're 0
  11 # i.e. first release of 0.XX *must* be 0.XX000. This avoids fBSD ports
  12 # brain damage and presumably various other packaging systems too
  13 our $VERSION = '0.05003';
  14
  15 __PACKAGE__->mk_group_accessors('inherited', qw/
  16                                 _loader_args
  17                                 dump_to_dir
  18                                 _loader_invoked
  19                                 _loader
  20                                 loader_class
  21                                 naming
  22                                 use_namespaces
  23 /);
  24 __PACKAGE__->_loader_args({});
  25
  26 =head1 NAME
  27
  28 DBIx::Class::Schema::Loader - Dynamic definition of a DBIx::Class::Schema
  29
  30 =head1 SYNOPSIS
  31
  32   ### use this module to generate a set of class files
  33
  34   # in a script
  35   use DBIx::Class::Schema::Loader qw/ make_schema_at /;
  36   make_schema_at(
  37       'My::Schema',
  38       { debug => 1,
  39         dump_directory => './lib',
  40       },
  41       [ 'dbi:Pg:dbname="foo"', 'myuser', 'mypassword' ],
  42   );
  43
  44   # from the command line or a shell script with dbicdump (distributed
  45   # with this module).  Do `perldoc dbicdump` for usage.
  46   dbicdump -o dump_directory=./lib \
  47            -o debug=1 \
  48            My::Schema \
  49            'dbi:Pg:dbname=foo' \
  50            myuser \
  51            mypassword
  52
  53   ### or generate and load classes at runtime
  54   # note: this technique is not recommended
  55   # for use in production code
  56
  57   package My::Schema;
  58   use base qw/DBIx::Class::Schema::Loader/;
  59
  60   __PACKAGE__->loader_options(
  61       constraint              => '^foo.*',
  62       # debug                 => 1,
  63   );
  64
  65   #### in application code elsewhere:
  66
  67   use My::Schema;
  68
  69   my $schema1 = My::Schema->connect( $dsn, $user, $password, $attrs);
  70   # -or-
  71   my $schema1 = "My::Schema"; $schema1->connection(as above);
  72
  73 =head1 DESCRIPTION
  74
  75 DBIx::Class::Schema::Loader automates the definition of a
  76 L<DBIx::Class::Schema> by scanning database table definitions and
  77 setting up the columns, primary keys, and relationships.
  78
  79 DBIx::Class::Schema::Loader currently supports only the DBI storage type.  It
  80 has explicit support for L<DBD::Pg>, L<DBD::mysql>, L<DBD::DB2>,
  81 L<DBD::SQLite>, L<DBD::Sybase> (for Sybase ASE and MSSSQL), L<DBD::ODBC> (for
  82 MSSQL) and L<DBD::Oracle>.  Other DBI drivers may function to a greater or
  83 lesser degree with this loader, depending on how much of the DBI spec they
  84 implement, and how standard their implementation is.
  85
  86 Patches to make other DBDs work correctly welcome.
  87
  88 See L<DBIx::Class::Schema::Loader::DBI::Writing> for notes on writing
  89 your own vendor-specific subclass for an unsupported DBD driver.
  90
  91 This module requires L<DBIx::Class> 0.07006 or later, and obsoletes
  92 the older L<DBIx::Class::Loader>.
  93
  94 This module is designed more to get you up and running quickly against
  95 an existing database, or to be effective for simple situations, rather
  96 than to be what you use in the long term for a complex database/project.
  97
  98 That being said, transitioning your code from a Schema generated by this
  99 module to one that doesn't use this module should be straightforward and
 100 painless, so don't shy away from it just for fears of the transition down
 101 the road.
 102
 103 =head1 METHODS
 104
 105 =head2 loader_class
 106
 107 =over 4
 108
 109 =item Argument: $loader_class
 110
 111 =back
 112
 113 Set the loader class to be instantiated when L</connection> is called.
 114 If the classname starts with "::", "DBIx::Class::Schema::Loader" is
 115 prepended. Defaults to L<DBIx::Class::Schema/storage_type> (which must
 116 start with "::" when using L<DBIx::Class::Schema::Loader>).
 117
 118 This is mostly useful for subclassing existing loaders or in conjunction
 119 with L</dump_to_dir>.
 120
 121 =head2 loader_options
 122
 123 =over 4
 124
 125 =item Argument: \%loader_options
 126
 127 =back
 128
 129 Example in Synopsis above demonstrates a few common arguments.  For
 130 detailed information on all of the arguments, most of which are
 131 only useful in fairly complex scenarios, see the
 132 L<DBIx::Class::Schema::Loader::Base> documentation.
 133
 134 If you intend to use C<loader_options>, you must call
 135 C<loader_options> before any connection is made, or embed the
 136 C<loader_options> in the connection information itself as shown
 137 below.  Setting C<loader_options> after the connection has
 138 already been made is useless.
 139
 140 =cut
 141
 142 sub loader_options {
 143     my $self = shift;
 144
 145     my %args = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
 146     $self->_loader_args(\%args);
 147
 148     $self;
 149 }
 150
 151 sub _invoke_loader {
 152     my $self = shift;
 153     my $class = ref $self || $self;
 154
 155     my $args = $self->_loader_args;
 156
 157     # set up the schema/schema_class arguments
 158     $args->{schema} = $self;
 159     $args->{schema_class} = $class;
 160     weaken($args->{schema}) if ref $self;
 161     $args->{dump_directory} ||= $self->dump_to_dir;
 162     $args->{naming} = $self->naming if $self->naming;
 163     $args->{use_namespaces} = $self->use_namespaces if $self->use_namespaces;
 164
 165     # XXX this only works for relative storage_type, like ::DBI ...
 166     my $loader_class = $self->loader_class;
 167     if ($loader_class) {
 168         $loader_class = "DBIx::Class::Schema::Loader${loader_class}" if $loader_class =~ /^::/;
 169         $args->{loader_class} = $loader_class;
 170     };
 171
 172     my $impl = $loader_class || "DBIx::Class::Schema::Loader" . $self->storage_type;
 173     eval { $self->ensure_class_loaded($impl) };
 174     croak qq/Could not load loader class "$impl": "$@"/ if $@;
 175
 176     $self->_loader($impl->new(%$args));
 177     $self->_loader->load;
 178     $self->_loader_invoked(1);
 179
 180     $self;
 181 }
 182
 183 =head2 connection
 184
 185 =over 4
 186
 187 =item Arguments: @args
 188
 189 =item Return Value: $new_schema
 190
 191 =back
 192
 193 See L<DBIx::Class::Schema/connection> for basic usage.
 194
 195 If the final argument is a hashref, and it contains the keys C<loader_options>
 196 or C<loader_class>, those keys will be deleted, and their values value will be
 197 used for the loader options or class, respectively, just as if set via the
 198 L</loader_options> or L</loader_class> methods above.
 199
 200 The actual auto-loading operation (the heart of this module) will be invoked
 201 as soon as the connection information is defined.
 202
 203 =cut
 204
 205 sub connection {
 206     my $self = shift;
 207
 208     if($_[-1] && ref $_[-1] eq 'HASH') {
 209         for my $option (qw/ loader_class loader_options result_base_class schema_base_class/) {
 210             if(my $value = delete $_[-1]->{$option}) {
 211                 $self->$option($value);
 212             }
 213         }
 214         pop @_ if !keys %{$_[-1]};
 215     }
 216
 217     $self = $self->next::method(@_);
 218
 219     my $class = ref $self || $self;
 220     if(!$class->_loader_invoked) {
 221         $self->_invoke_loader
 222     }
 223
 224     return $self;
 225 }
 226
 227 =head2 clone
 228
 229 See L<DBIx::Class::Schema/clone>.
 230
 231 =cut
 232
 233 sub clone {
 234     my $self = shift;
 235
 236     my $clone = $self->next::method(@_);
 237
 238     if($clone->_loader_args) {
 239         $clone->_loader_args->{schema} = $clone;
 240         weaken($clone->_loader_args->{schema});
 241     }
 242
 243     $clone;
 244 }
 245
 246 =head2 dump_to_dir
 247
 248 =over 4
 249
 250 =item Argument: $directory
 251
 252 =back
 253
 254 Calling this as a class method on either L<DBIx::Class::Schema::Loader>
 255 or any derived schema class will cause all schemas to dump
 256 manual versions of themselves to the named directory when they are
 257 loaded.  In order to be effective, this must be set before defining a
 258 connection on this schema class or any derived object (as the loading
 259 happens as soon as both a connection and loader_options are set, and
 260 only once per class).
 261
 262 See L<DBIx::Class::Schema::Loader::Base/dump_directory> for more
 263 details on the dumping mechanism.
 264
 265 This can also be set at module import time via the import option
 266 C<dump_to_dir:/foo/bar> to L<DBIx::Class::Schema::Loader>, where
 267 C</foo/bar> is the target directory.
 268
 269 Examples:
 270
 271     # My::Schema isa DBIx::Class::Schema::Loader, and has connection info
 272     #   hardcoded in the class itself:
 273     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e1
 274
 275     # Same, but no hard-coded connection, so we must provide one:
 276     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e 'My::Schema->connection("dbi:Pg:dbname=foo", ...)'
 277
 278     # Or as a class method, as long as you get it done *before* defining a
 279     #  connection on this schema class or any derived object:
 280     use My::Schema;
 281     My::Schema->dump_to_dir('/foo/bar');
 282     My::Schema->connection(........);
 283
 284     # Or as a class method on the DBIx::Class::Schema::Loader itself, which affects all
 285     #   derived schemas
 286     use My::Schema;
 287     use My::OtherSchema;
 288     DBIx::Class::Schema::Loader->dump_to_dir('/foo/bar');
 289     My::Schema->connection(.......);
 290     My::OtherSchema->connection(.......);
 291
 292     # Another alternative to the above:
 293     use DBIx::Class::Schema::Loader qw| dump_to_dir:/foo/bar |;
 294     use My::Schema;
 295     use My::OtherSchema;
 296     My::Schema->connection(.......);
 297     My::OtherSchema->connection(.......);
 298
 299 =cut
 300
 301 sub import {
 302     my $self = shift;
 303
 304     return if !@_;
 305
 306     my $cpkg = (caller)[0];
 307
 308     foreach my $opt (@_) {
 309         if($opt =~ m{^dump_to_dir:(.*)$}) {
 310             $self->dump_to_dir($1)
 311         }
 312         elsif($opt eq 'make_schema_at') {
 313             no strict 'refs';
 314             *{"${cpkg}::make_schema_at"} = \&make_schema_at;
 315         }
 316         elsif($opt eq 'naming') {
 317             no strict 'refs';
 318             *{"${cpkg}::naming"} = sub { $self->naming(@_) };
 319         }
 320         elsif($opt eq 'use_namespaces') {
 321             no strict 'refs';
 322             *{"${cpkg}::use_namespaces"} = sub { $self->use_namespaces(@_) };
 323         }
 324     }
 325 }
 326
 327 =head2 make_schema_at
 328
 329 =over 4
 330
 331 =item Arguments: $schema_class_name, \%loader_options, \@connect_info
 332
 333 =item Return Value: $schema_class_name
 334
 335 =back
 336
 337 This function creates a DBIx::Class schema from an existing RDBMS
 338 schema.  With the C<dump_directory> option, generates a set of
 339 DBIx::Class classes from an existing database schema read from the
 340 given dsn.  Without a C<dump_directory>, creates schema classes in
 341 memory at runtime without generating on-disk class files.
 342
 343 For a complete list of supported loader_options, see
 344 L<DBIx::Class::Schema::Loader::Base>
 345
 346 This function can be imported in the usual way, as illustrated in
 347 these Examples:
 348
 349     # Simple example, creates as a new class 'New::Schema::Name' in
 350     #  memory in the running perl interpreter.
 351     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 352     make_schema_at(
 353         'New::Schema::Name',
 354         { debug => 1 },
 355         [ 'dbi:Pg:dbname="foo"','postgres' ],
 356     );
 357
 358     # Inside a script, specifying a dump directory in which to write
 359     # class files
 360     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 361     make_schema_at(
 362         'New::Schema::Name',
 363         { debug => 1, dump_directory => './lib' },
 364         [ 'dbi:Pg:dbname="foo"','postgres' ],
 365     );
 366
 367 =cut
 368
 369 sub make_schema_at {
 370     my ($target, $opts, $connect_info) = @_;
 371
 372     {
 373         no strict 'refs';
 374         @{$target . '::ISA'} = qw/DBIx::Class::Schema::Loader/;
 375     }
 376
 377     eval { $target->_loader_invoked(0) };
 378
 379     $target->loader_options($opts);
 380     $target->connection(@$connect_info);
 381 }
 382
 383 =head2 rescan
 384
 385 =over 4
 386
 387 =item Return Value: @new_monikers
 388
 389 =back
 390
 391 Re-scans the database for newly added tables since the initial
 392 load, and adds them to the schema at runtime, including relationships,
 393 etc.  Does not process drops or changes.
 394
 395 Returns a list of the new monikers added.
 396
 397 =cut
 398
 399 sub rescan { my $self = shift; $self->_loader->rescan($self) }
 400
 401 =head2 naming
 402
 403 =over 4
 404
 405 =item Arguments: \%opts | $ver
 406
 407 =back
 408
 409 Controls the naming options for backward compatibility, see
 410 L<DBIx::Class::Schema::Loader::Base/naming> for details.
 411
 412 To upgrade a dynamic schema, use:
 413
 414     __PACKAGE__->naming('current');
 415
 416 Can be imported into your dump script and called as a function as well:
 417
 418     naming('v4');
 419
 420 =head2 use_namespaces
 421
 422 =over 4
 423
 424 =item Arguments: 1|0
 425
 426 =back
 427
 428 Controls the use_namespaces options for backward compatibility, see
 429 L<DBIx::Class::Schema::Loader::Base/use_namespaces> for details.
 430
 431 To upgrade a dynamic schema, use:
 432
 433     __PACKAGE__->use_namespaces(1);
 434
 435 Can be imported into your dump script and called as a function as well:
 436
 437     use_namespaces(1);
 438
 439 =head1 KNOWN ISSUES
 440
 441 =head2 Multiple Database Schemas
 442
 443 Currently the loader is limited to working within a single schema
 444 (using the underlying RDBMS's definition of "schema").  If you have a
 445 multi-schema database with inter-schema relationships (which is easy
 446 to do in PostgreSQL or DB2 for instance), you currently can only
 447 automatically load the tables of one schema, and relationships to
 448 tables in other schemas will be silently ignored.
 449
 450 At some point in the future, an intelligent way around this might be
 451 devised, probably by allowing the C<db_schema> option to be an
 452 arrayref of schemas to load.
 453
 454 In "normal" L<DBIx::Class::Schema> usage, manually-defined
 455 source classes and relationships have no problems crossing vendor schemas.
 456
 457 =head1 ACKNOWLEDGEMENTS
 458
 459 Matt S Trout, all of the #dbix-class folks, and everyone who's ever sent
 460 in a bug report or suggestion.
 461
 462 Based on L<DBIx::Class::Loader> by Sebastian Riedel
 463
 464 Based upon the work of IKEBE Tomohiro
 465
 466 =head1 AUTHOR
 467
 468 blblack: Brandon Black <blblack@gmail.com>
 469
 470 =head1 CONTRIBUTORS
 471
 472 ilmari: Dagfinn Ilmari MannsE<aring>ker <ilmari@ilmari.org>
 473
 474 arcanez: Justin Hunter <justin.d.hunter@gmail.com>
 475
 476 ash: Ash Berlin <ash@cpan.org>
 477
 478 Caelum: Rafael Kitover <rkitover@cpan.org>
 479
 480 TSUNODA Kazuya <drk@drk7.jp>
 481
 482 rbo: Robert Bohne <rbo@cpan.org>
 483
 484 ribasushi: Peter Rabbitson <ribasushi@cpan.org>
 485
 486 gugu: Andrey Kostenko <a.kostenko@rambler-co.ru>
 487
 488 jhannah: Jay Hannah <jay@jays.net>
 489
 490 rbuels: Robert Buels <rmb32@cornell.edu>
 491
 492 timbunce: Tim Bunce <timb@cpan.org>
 493
 494 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
 495
 496 kane: Jos Boumans <kane@cpan.org>
 497
 498 waawaamilk: Nigel McNie <nigel@mcnie.name>
 499
 500 acmoore: Andrew Moore <amoore@cpan.org>
 501
 502 bphillips: Brian Phillips <bphillips@cpan.org>
 503
 504 schwern: Michael G. Schwern <mschwern@cpan.org>
 505
 506 hobbs: Andrew Rodland <arodland@cpan.org>
 507
 508 ... and lots of other folks. If we forgot you, please write the current
 509 maintainer or RT.
 510
 511 =head1 COPYRIGHT & LICENSE
 512
 513 Copyright (c) 2006 - 2009 by the aforementioned
 514 L<DBIx::Class::Schema::Loader/AUTHOR> and
 515 L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 516
 517 This library is free software; you can redistribute it and/or modify it under
 518 the same terms as Perl itself.
 519
 520 =head1 SEE ALSO
 521
 522 L<DBIx::Class>, L<DBIx::Class::Manual::ExampleSchema>
 523
 524 =cut
 525
 526 1;
 527 # vim:et sts=4 sw=4 tw=0: