lib/DBIx/Class/Schema/Loader/SQLite.pm

   1 package DBIx::Class::Schema::Loader::SQLite;
   2
   3 use strict;
   4 use base qw/DBIx::Class::Schema::Loader::Generic/;
   5 use Text::Balanced qw( extract_bracketed );
   6 use Carp;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::Schema::Loader::SQLite - DBIx::Class::Schema::Loader SQLite Implementation.
  11
  12 =head1 SYNOPSIS
  13
  14   use DBIx::Class::Schema::Loader;
  15
  16   # $loader is a DBIx::Class::Schema::Loader::SQLite
  17   my $loader = DBIx::Class::Schema::Loader->new(
  18     dsn       => "dbi:SQLite:dbname=/path/to/dbfile",
  19   );
  20
  21 =head1 DESCRIPTION
  22
  23 See L<DBIx::Class::Schema::Loader>.
  24
  25 =cut
  26
  27 sub _db_classes {
  28     return qw/DBIx::Class::PK::Auto::SQLite/;
  29 }
  30
  31 # XXX this really needs a re-factor
  32 sub _relationships {
  33     my $class = shift;
  34     foreach my $table ( $class->tables ) {
  35
  36         my $dbh = $class->storage->dbh;
  37         my $sth = $dbh->prepare(<<"");
  38 SELECT sql FROM sqlite_master WHERE tbl_name = ?
  39
  40         $sth->execute($table);
  41         my ($sql) = $sth->fetchrow_array;
  42         $sth->finish;
  43
  44         # Cut "CREATE TABLE ( )" blabla...
  45         $sql =~ /^[\w\s]+\((.*)\)$/si;
  46         my $cols = $1;
  47
  48         # strip single-line comments
  49         $cols =~ s/\-\-.*\n/\n/g;
  50
  51         # temporarily replace any commas inside parens,
  52         # so we don't incorrectly split on them below
  53         my $cols_no_bracketed_commas = $cols;
  54         while ( my $extracted =
  55             ( extract_bracketed( $cols, "()", "[^(]*" ) )[0] )
  56         {
  57             my $replacement = $extracted;
  58             $replacement              =~ s/,/--comma--/g;
  59             $replacement              =~ s/^\(//;
  60             $replacement              =~ s/\)$//;
  61             $cols_no_bracketed_commas =~ s/$extracted/$replacement/m;
  62         }
  63
  64         # Split column definitions
  65         for my $col ( split /,/, $cols_no_bracketed_commas ) {
  66
  67             # put the paren-bracketed commas back, to help
  68             # find multi-col fks below
  69             $col =~ s/\-\-comma\-\-/,/g;
  70
  71             $col =~ s/^\s*FOREIGN\s+KEY\s*//i;
  72
  73             # Strip punctuations around key and table names
  74             $col =~ s/[\[\]'"]/ /g;
  75             $col =~ s/^\s+//gs;
  76
  77             # Grab reference
  78             if ( $col =~ /^\((.*)\)\s+REFERENCES\s+(\w+)\s*\((.*)\)/i ) {
  79                 chomp $col;
  80
  81                 my ($cols, $f_table, $f_cols) = ($1, $2, $3);
  82                 my @cols = map { s/\s*//g; $_ } split(/\s*,\s*/,$cols);
  83                 my @f_cols = map { s/\s*//g; $_ } split(/\s*,\s*/,$f_cols);
  84
  85                 die "Mismatched column count in rel for $table => $f_table"
  86                   if @cols != @f_cols;
  87
  88                 my $cond = {};
  89                 for(my $i = 0 ; $i < @cols; $i++) {
  90                     $cond->{$f_cols[$i]} = $cols[$i];
  91                 }
  92
  93                 eval { $class->_belongs_to_many( $table, $f_table, $cond ) };
  94                 warn qq/\# belongs_to_many failed "$@"\n\n/
  95                   if $@ && $class->debug_loader;
  96             }
  97         }
  98     }
  99 }
 100
 101 sub _tables {
 102     my $class = shift;
 103     my $dbh = $class->storage->dbh;
 104     my $sth  = $dbh->prepare("SELECT * FROM sqlite_master");
 105     $sth->execute;
 106     my @tables;
 107     while ( my $row = $sth->fetchrow_hashref ) {
 108         next unless lc( $row->{type} ) eq 'table';
 109         push @tables, $row->{tbl_name};
 110     }
 111     return @tables;
 112 }
 113
 114 sub _table_info {
 115     my ( $class, $table ) = @_;
 116
 117     # find all columns.
 118     my $dbh = $class->storage->dbh;
 119     my $sth = $dbh->prepare("PRAGMA table_info('$table')");
 120     $sth->execute();
 121     my @columns;
 122     while ( my $row = $sth->fetchrow_hashref ) {
 123         push @columns, $row->{name};
 124     }
 125     $sth->finish;
 126
 127     # find primary key. so complex ;-(
 128     $sth = $dbh->prepare(<<'SQL');
 129 SELECT sql FROM sqlite_master WHERE tbl_name = ?
 130 SQL
 131     $sth->execute($table);
 132     my ($sql) = $sth->fetchrow_array;
 133     $sth->finish;
 134     my ($primary) = $sql =~ m/
 135     (?:\(|\,) # either a ( to start the definition or a , for next
 136     \s*       # maybe some whitespace
 137     (\w+)     # the col name
 138     [^,]*     # anything but the end or a ',' for next column
 139     PRIMARY\sKEY/sxi;
 140     my @pks;
 141
 142     if ($primary) {
 143         @pks = ($primary);
 144     }
 145     else {
 146         my ($pks) = $sql =~ m/PRIMARY\s+KEY\s*\(\s*([^)]+)\s*\)/i;
 147         @pks = split( m/\s*\,\s*/, $pks ) if $pks;
 148     }
 149     return ( \@columns, \@pks );
 150 }
 151
 152 =head1 SEE ALSO
 153
 154 L<DBIx::Schema::Class::Loader>
 155
 156 =cut
 157
 158 1;