lib/DBIx/Class/Schema/Loader/RelBuilder.pm

   1 package DBIx::Class::Schema::Loader::RelBuilder;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Class::Accessor::Grouped';
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util 'weaken';
   9 use DBIx::Class::Schema::Loader::Utils qw/split_name slurp_file array_eq apply uniq/;
  10 use Try::Tiny;
  11 use List::Util qw/all any first/;
  12 use namespace::clean;
  13 use Lingua::EN::Inflect::Phrase ();
  14 use Lingua::EN::Tagger ();
  15 use String::ToIdentifier::EN ();
  16 use String::ToIdentifier::EN::Unicode ();
  17 use Class::Unload ();
  18 use Class::Inspector ();
  19
  20 our $VERSION = '0.07042';
  21
  22 # Glossary:
  23 #
  24 # local_relname  -- name of relationship from the local table referring to the remote table
  25 # remote_relname -- name of relationship from the remote table referring to the local table
  26 # remote_method  -- relationship type from remote table to local table, usually has_many
  27
  28 =head1 NAME
  29
  30 DBIx::Class::Schema::Loader::RelBuilder - Builds relationships for DBIx::Class::Schema::Loader
  31
  32 =head1 SYNOPSIS
  33
  34 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  35
  36 =head1 DESCRIPTION
  37
  38 This class builds relationships for L<DBIx::Class::Schema::Loader>.  This
  39 is module is not (yet) for external use.
  40
  41 =head1 METHODS
  42
  43 =head2 new
  44
  45 Arguments: $loader object
  46
  47 =head2 generate_code
  48
  49 Arguments:
  50
  51     [
  52         [ local_moniker1 (scalar), fk_info1 (arrayref), uniq_info1 (arrayref) ]
  53         [ local_moniker2 (scalar), fk_info2 (arrayref), uniq_info2 (arrayref) ]
  54         ...
  55     ]
  56
  57 This generates the code for the relationships of each table.
  58
  59 C<local_moniker> is the moniker name of the table which had the REFERENCES
  60 statements.  The fk_info arrayref's contents should take the form:
  61
  62     [
  63         {
  64             local_table    => 'some_table',
  65             local_moniker  => 'SomeTable',
  66             local_columns  => [ 'col2', 'col3' ],
  67             remote_table   => 'another_table_moniker',
  68             remote_moniker => 'AnotherTableMoniker',
  69             remote_columns => [ 'col5', 'col7' ],
  70         },
  71         {
  72             local_table    => 'some_other_table',
  73             local_moniker  => 'SomeOtherTable',
  74             local_columns  => [ 'col1', 'col4' ],
  75             remote_table   => 'yet_another_table_moniker',
  76             remote_moniker => 'YetAnotherTableMoniker',
  77             remote_columns => [ 'col1', 'col2' ],
  78         },
  79         # ...
  80     ],
  81
  82 The uniq_info arrayref's contents should take the form:
  83
  84     [
  85         [
  86             uniq_constraint_name         => [ 'col1', 'col2' ],
  87         ],
  88         [
  89             another_uniq_constraint_name => [ 'col1', 'col2' ],
  90         ],
  91     ],
  92
  93 This method will return the generated relationships as a hashref keyed on the
  94 class names.  The values are arrayrefs of hashes containing method name and
  95 arguments, like so:
  96
  97   {
  98       'Some::Source::Class' => [
  99           { method => 'belongs_to', arguments => [ 'col1', 'Another::Source::Class' ],
 100           { method => 'has_many', arguments => [ 'anothers', 'Yet::Another::Source::Class', 'col15' ],
 101       ],
 102       'Another::Source::Class' => [
 103           # ...
 104       ],
 105       # ...
 106   }
 107
 108 =cut
 109
 110 __PACKAGE__->mk_group_accessors('simple', qw/
 111     loader
 112     schema
 113     inflect_plural
 114     inflect_singular
 115     relationship_attrs
 116     rel_collision_map
 117     rel_name_map
 118     _temp_classes
 119     __tagger
 120 /);
 121
 122 sub new {
 123     my ($class, $loader) = @_;
 124
 125     # from old POD about this constructor:
 126     # C<$schema_class> should be a schema class name, where the source
 127     # classes have already been set up and registered.  Column info,
 128     # primary key, and unique constraints will be drawn from this
 129     # schema for all of the existing source monikers.
 130
 131     # Options inflect_plural and inflect_singular are optional, and
 132     # are better documented in L<DBIx::Class::Schema::Loader::Base>.
 133
 134     my $self = {
 135         loader             => $loader,
 136         schema             => $loader->schema,
 137         inflect_plural     => $loader->inflect_plural,
 138         inflect_singular   => $loader->inflect_singular,
 139         relationship_attrs => $loader->relationship_attrs,
 140         rel_collision_map  => $loader->rel_collision_map,
 141         rel_name_map       => $loader->rel_name_map,
 142         _temp_classes      => [],
 143     };
 144
 145     weaken $self->{loader}; #< don't leak
 146
 147     bless $self => $class;
 148
 149     # validate the relationship_attrs arg
 150     if( defined $self->relationship_attrs ) {
 151         (ref $self->relationship_attrs eq 'HASH' || ref $self->relationship_attrs eq 'CODE')
 152             or croak "relationship_attrs must be a hashref or coderef";
 153     }
 154
 155     return $self;
 156 }
 157
 158
 159 # pluralize a relationship name
 160 sub _inflect_plural {
 161     my ($self, $relname) = @_;
 162
 163     return '' if !defined $relname || $relname eq '';
 164
 165     my $result;
 166     my $mapped = 0;
 167
 168     if( ref $self->inflect_plural eq 'HASH' ) {
 169         if (exists $self->inflect_plural->{$relname}) {
 170             $result = $self->inflect_plural->{$relname};
 171             $mapped = 1;
 172         }
 173     }
 174     elsif( ref $self->inflect_plural eq 'CODE' ) {
 175         my $inflected = $self->inflect_plural->($relname);
 176         if ($inflected) {
 177             $result = $inflected;
 178             $mapped = 1;
 179         }
 180     }
 181
 182     return ($result, $mapped) if $mapped;
 183
 184     return ($self->_to_PL($relname), 0);
 185 }
 186
 187 # Singularize a relationship name
 188 sub _inflect_singular {
 189     my ($self, $relname) = @_;
 190
 191     return '' if !defined $relname || $relname eq '';
 192
 193     my $result;
 194     my $mapped = 0;
 195
 196     if( ref $self->inflect_singular eq 'HASH' ) {
 197         if (exists $self->inflect_singular->{$relname}) {
 198             $result = $self->inflect_singular->{$relname};
 199             $mapped = 1;
 200         }
 201     }
 202     elsif( ref $self->inflect_singular eq 'CODE' ) {
 203         my $inflected = $self->inflect_singular->($relname);
 204         if ($inflected) {
 205             $result = $inflected;
 206             $mapped = 1;
 207         }
 208     }
 209
 210     return ($result, $mapped) if $mapped;
 211
 212     return ($self->_to_S($relname), 0);
 213 }
 214
 215 sub _to_PL {
 216     my ($self, $name) = @_;
 217
 218     $name =~ s/_/ /g;
 219     my $plural = Lingua::EN::Inflect::Phrase::to_PL($name);
 220     $plural =~ s/ /_/g;
 221
 222     return $plural;
 223 }
 224
 225 sub _to_S {
 226     my ($self, $name) = @_;
 227
 228     $name =~ s/_/ /g;
 229     my $singular = Lingua::EN::Inflect::Phrase::to_S($name);
 230     $singular =~ s/ /_/g;
 231
 232     return $singular;
 233 }
 234
 235 sub _default_relationship_attrs { +{
 236     has_many => {
 237         cascade_delete => 0,
 238         cascade_copy   => 0,
 239     },
 240     might_have => {
 241         cascade_delete => 0,
 242         cascade_copy   => 0,
 243     },
 244     belongs_to => {
 245         on_delete => 'CASCADE',
 246         on_update => 'CASCADE',
 247         is_deferrable => 1,
 248     },
 249 } }
 250
 251 # Accessor for options to be passed to each generated relationship type. takes
 252 # the relationship type name and optionally any attributes from the database
 253 # (such as FK ON DELETE/UPDATE and DEFERRABLE clauses), and returns a
 254 # hashref or undef if nothing is set.
 255 #
 256 # The attributes from the database override the default attributes, which in
 257 # turn are overridden by user supplied attributes.
 258 sub _relationship_attrs {
 259     my ( $self, $reltype, $db_attrs, $params ) = @_;
 260     my $r = $self->relationship_attrs;
 261
 262     my %composite = (
 263         %{ $self->_default_relationship_attrs->{$reltype} || {} },
 264         %{ $db_attrs || {} },
 265         (
 266             ref $r eq 'HASH' ? (
 267                 %{ $r->{all} || {} },
 268                 %{ $r->{$reltype} || {} },
 269             )
 270             :
 271             ()
 272         ),
 273     );
 274
 275     if (ref $r eq 'CODE') {
 276         $params->{attrs} = \%composite;
 277
 278         my %ret = %{ $r->(%$params) || {} };
 279
 280         %composite = %ret if %ret;
 281     }
 282
 283     return %composite ? \%composite : undef;
 284 }
 285
 286 sub _strip_id_postfix {
 287     my ($self, $name) = @_;
 288
 289     $name =~ s/_?(?:id|ref|cd|code|num)\z//i;
 290
 291     return $name;
 292 }
 293
 294 sub _remote_attrs {
 295     my ($self, $local_moniker, $local_cols, $fk_attrs, $params) = @_;
 296
 297     # get our set of attrs from _relationship_attrs, which uses the FK attrs if available
 298     my $attrs = $self->_relationship_attrs('belongs_to', $fk_attrs, $params) || {};
 299
 300     # If any referring column is nullable, make 'belongs_to' an
 301     # outer join, unless explicitly set by relationship_attrs
 302     my $nullable = first { $self->schema->source($local_moniker)->column_info($_)->{is_nullable} } @$local_cols;
 303     $attrs->{join_type} = 'LEFT' if $nullable && !defined $attrs->{join_type};
 304
 305     return $attrs;
 306 }
 307
 308 sub _sanitize_name {
 309     my ($self, $name) = @_;
 310
 311     $name = $self->loader->_to_identifier('relationships', $name, '_');
 312
 313     $name =~ s/\W+/_/g; # if naming >= 8 to_identifier takes care of it
 314
 315     return $name;
 316 }
 317
 318 sub _normalize_name {
 319     my ($self, $name) = @_;
 320
 321     $name = $self->_sanitize_name($name);
 322
 323     my @words = split_name $name, $self->loader->_get_naming_v('relationships');
 324
 325     return join '_', map lc, @words;
 326 }
 327
 328 sub _local_relname {
 329     my ($self, $remote_table, $cond) = @_;
 330
 331     my $local_relname;
 332     # for single-column case, set the remote relname to the column
 333     # name, to make filter accessors work, but strip trailing _id
 334     if(scalar keys %{$cond} == 1) {
 335         my ($col) = values %{$cond};
 336         $col = $self->_strip_id_postfix($self->_normalize_name($col));
 337         ($local_relname) = $self->_inflect_singular($col);
 338     }
 339     else {
 340         ($local_relname) = $self->_inflect_singular($self->_normalize_name($remote_table));
 341     }
 342
 343     return $local_relname;
 344 }
 345
 346 sub _resolve_relname_collision {
 347     my ($self, $moniker, $cols, $relname) = @_;
 348
 349     return $relname if $relname eq 'id'; # this shouldn't happen, but just in case
 350
 351     my $table = $self->loader->moniker_to_table->{$moniker};
 352
 353     if ($self->loader->_is_result_class_method($relname, $table)) {
 354         if (my $map = $self->rel_collision_map) {
 355             for my $re (keys %$map) {
 356                 if (my @matches = $relname =~ /$re/) {
 357                     return sprintf $map->{$re}, @matches;
 358                 }
 359             }
 360         }
 361
 362         my $new_relname = $relname;
 363         while ($self->loader->_is_result_class_method($new_relname, $table)) {
 364             $new_relname .= '_rel'
 365         }
 366
 367         warn <<"EOF";
 368 Relationship '$relname' in source '$moniker' for columns '@{[ join ',', @$cols ]}' collides with an inherited method. Renaming to '$new_relname'.
 369 See "RELATIONSHIP NAME COLLISIONS" in perldoc DBIx::Class::Schema::Loader::Base .
 370 EOF
 371
 372         return $new_relname;
 373     }
 374
 375     return $relname;
 376 }
 377
 378 sub generate_code {
 379     my ($self, $tables) = @_;
 380
 381     # make a copy to destroy
 382     my @tables = @$tables;
 383
 384     my $all_code = {};
 385
 386     while (my ($local_moniker, $rels, $uniqs) = @{ shift @tables || [] }) {
 387         my $local_class = $self->schema->class($local_moniker);
 388
 389         my %counters;
 390         foreach my $rel (@$rels) {
 391             next if !$rel->{remote_source};
 392             $counters{$rel->{remote_source}}++;
 393         }
 394
 395         foreach my $rel (@$rels) {
 396             my $remote_moniker = $rel->{remote_source}
 397                 or next;
 398
 399             my $remote_class   = $self->schema->class($remote_moniker);
 400             my $remote_obj     = $self->schema->source($remote_moniker);
 401             my $remote_cols    = $rel->{remote_columns} || [ $remote_obj->primary_columns ];
 402
 403             my $local_cols     = $rel->{local_columns};
 404
 405             if($#$local_cols != $#$remote_cols) {
 406                 croak "Column count mismatch: $local_moniker (@$local_cols) "
 407                     . "$remote_moniker (@$remote_cols)";
 408             }
 409
 410             my %cond;
 411             @cond{@$remote_cols} = @$local_cols;
 412
 413             my ( $local_relname, $remote_relname, $remote_method ) =
 414                 $self->_relnames_and_method( $local_moniker, $rel, \%cond,  $uniqs, \%counters );
 415             my $local_method  = 'belongs_to';
 416
 417             ($local_relname) = $self->_rel_name_map(
 418                 $local_relname, $local_method,
 419                 $local_class, $local_moniker, $local_cols,
 420                 $remote_class, $remote_moniker, $remote_cols,
 421             );
 422             ($remote_relname) = $self->_rel_name_map(
 423                 $remote_relname, $remote_method,
 424                 $remote_class, $remote_moniker, $remote_cols,
 425                 $local_class, $local_moniker, $local_cols,
 426             );
 427
 428             $local_relname = $self->_resolve_relname_collision(
 429                 $local_moniker, $local_cols, $local_relname,
 430             );
 431             $remote_relname = $self->_resolve_relname_collision(
 432                 $remote_moniker, $remote_cols, $remote_relname,
 433             );
 434
 435             my $rel_attrs_params = {
 436                 rel_name      => $local_relname,
 437                 rel_type      => $local_method,
 438                 local_source  => $self->schema->source($local_moniker),
 439                 remote_source => $self->schema->source($remote_moniker),
 440                 local_table   => $rel->{local_table},
 441                 local_cols    => $local_cols,
 442                 remote_table  => $rel->{remote_table},
 443                 remote_cols   => $remote_cols,
 444             };
 445
 446             push @{$all_code->{$local_class}}, {
 447                 method => $local_method,
 448                 args => [
 449                     $local_relname,
 450                     $remote_class,
 451                     \%cond,
 452                     $self->_remote_attrs($local_moniker, $local_cols, $rel->{attrs}, $rel_attrs_params),
 453                 ],
 454                 extra => {
 455                     local_class    => $local_class,
 456                     local_moniker  => $local_moniker,
 457                     remote_moniker => $remote_moniker,
 458                 },
 459             };
 460
 461             my %rev_cond = reverse %cond;
 462             for (keys %rev_cond) {
 463                 $rev_cond{"foreign.$_"} = "self.".$rev_cond{$_};
 464                 delete $rev_cond{$_};
 465             }
 466
 467             $rel_attrs_params = {
 468                 rel_name      => $remote_relname,
 469                 rel_type      => $remote_method,
 470                 local_source  => $self->schema->source($remote_moniker),
 471                 remote_source => $self->schema->source($local_moniker),
 472                 local_table   => $rel->{remote_table},
 473                 local_cols    => $remote_cols,
 474                 remote_table  => $rel->{local_table},
 475                 remote_cols   => $local_cols,
 476             };
 477
 478             push @{$all_code->{$remote_class}}, {
 479                 method => $remote_method,
 480                 args => [
 481                     $remote_relname,
 482                     $local_class,
 483                     \%rev_cond,
 484                     $self->_relationship_attrs($remote_method, {}, $rel_attrs_params),
 485                 ],
 486                 extra => {
 487                     local_class    => $remote_class,
 488                     local_moniker  => $remote_moniker,
 489                     remote_moniker => $local_moniker,
 490                 },
 491             };
 492         }
 493     }
 494
 495     $self->_generate_m2ms($all_code);
 496
 497     # disambiguate rels with the same name
 498     foreach my $class (keys %$all_code) {
 499         my $dups = $self->_duplicates($all_code->{$class});
 500
 501         $self->_disambiguate($all_code, $class, $dups) if $dups;
 502     }
 503
 504     $self->_cleanup;
 505
 506     return $all_code;
 507 }
 508
 509 # Find classes with only 2 FKs which are the PK and make many_to_many bridges for them.
 510 sub _generate_m2ms {
 511     my ($self, $all_code) = @_;
 512
 513     LINK_CLASS:
 514     foreach my $link_class (sort keys %$all_code) {
 515         my @rels = grep $_->{method} eq 'belongs_to', @{$all_code->{$link_class}};
 516         next unless @rels == 2;
 517
 518         my @class;
 519         foreach my $this (0, 1) {
 520             my $that = $this ? 0 : 1;
 521             my %class;
 522             $class[$this] = \%class;
 523             $class{local_moniker}  = $rels[$this]{extra}{remote_moniker};
 524             $class{remote_moniker} = $rels[$that]{extra}{remote_moniker};
 525
 526             $class{class} = $rels[$this]{args}[1];
 527
 528             my %link_cols = map { $_ => 1 } apply { s/^self\.//i } values %{ $rels[$this]{args}[2] };
 529
 530             $class{link_table_rel} = first {
 531                 $_->{method} eq 'has_many'
 532                     and
 533                 $_->{args}[1] eq $link_class
 534                     and
 535                 all { $link_cols{$_} } apply { s/^foreign\.//i } keys %{$_->{args}[2]}
 536             } @{ $all_code->{$class{class}} };
 537
 538             next LINK_CLASS unless $class{link_table_rel};
 539
 540             $class{link_table_rel_name} = $class{link_table_rel}{args}[0];
 541
 542             $class{link_rel} = $rels[$that]{args}[0];
 543
 544             $class{from_cols} = [ apply { s/^self\.//i } values %{
 545                 $class{link_table_rel}->{args}[2]
 546             } ];
 547
 548             $class{to_cols} = [ apply { s/^foreign\.//i } keys %{ $rels[$that]{args}[2] } ];
 549
 550             $class{from_link_cols} = [ apply { s/^self\.//i } values %{ $rels[$this]{args}[2] } ];
 551         }
 552
 553         my $link_moniker = $rels[0]{extra}{local_moniker};
 554
 555         my @link_table_cols =
 556             @{[ $self->schema->source($link_moniker)->columns ]};
 557
 558         my @link_table_primary_cols =
 559             @{[ $self->schema->source($link_moniker)->primary_columns ]};
 560
 561         next unless uniq(@{$class[0]{from_link_cols}}, @{$class[1]{from_link_cols}}) == @link_table_cols
 562             && @link_table_cols == @link_table_primary_cols;
 563
 564         foreach my $this (0, 1) {
 565             my $that = $this ? 0 : 1;
 566             ($class[$this]{m2m_relname}) = $self->_rel_name_map(
 567                 ($self->_inflect_plural($class[$this]{link_rel}))[0],
 568                 'many_to_many',
 569                 @{$class[$this]}{qw(class local_moniker from_cols)},
 570                 $class[$that]{class},
 571                 @{$class[$this]}{qw(remote_moniker to_cols)},
 572                 {
 573                     link_class => $link_class,
 574                     link_moniker => $link_moniker,
 575                     link_rel_name => $class[$this]{link_table_rel_name},
 576                 },
 577             );
 578
 579             $class[$this]{m2m_relname} = $self->_resolve_relname_collision(
 580                 @{$class[$this]}{qw(local_moniker from_cols m2m_relname)},
 581             );
 582         }
 583
 584         for my $this (0, 1) {
 585             my $that = $this ? 0 : 1;
 586
 587             push @{$all_code->{$class[$this]{class}}}, {
 588                 method => 'many_to_many',
 589                 args   => [
 590                     @{$class[$this]}{qw(m2m_relname link_table_rel_name link_rel)},
 591                     $self->_relationship_attrs('many_to_many', {}, {
 592                         rel_type => 'many_to_many',
 593                         rel_name => $class[$this]{class2_relname},
 594                         local_source => $self->schema->source($class[$this]{local_moniker}),
 595                         remote_source => $self->schema->source($class[$this]{remote_moniker}),
 596                         local_table => $self->loader->class_to_table->{$class[$this]{class}},
 597                         local_cols => $class[$this]{from_cols},
 598                         remote_table => $self->loader->class_to_table->{$class[$that]{class}},
 599                         remote_cols => $class[$that]{from_cols},
 600                     }) || (),
 601                 ],
 602                 extra  => {
 603                     local_class    => $class[$this]{class},
 604                     link_class     => $link_class,
 605                     local_moniker  => $class[$this]{local_moniker},
 606                     remote_moniker => $class[$this]{remote_moniker},
 607                 },
 608             };
 609         }
 610     }
 611 }
 612
 613 sub _duplicates {
 614     my ($self, $rels) = @_;
 615
 616     my @rels = map [ $_->{args}[0] => $_ ], @$rels;
 617     my %rel_names;
 618     $rel_names{$_}++ foreach map $_->[0], @rels;
 619
 620     my @dups = grep $rel_names{$_} > 1, keys %rel_names;
 621
 622     my %dups;
 623
 624     foreach my $dup (@dups) {
 625         $dups{$dup} = [ map $_->[1], grep { $_->[0] eq $dup } @rels ];
 626     }
 627
 628     return if not %dups;
 629
 630     return \%dups;
 631 }
 632
 633 sub _tagger {
 634     my $self = shift;
 635
 636     $self->__tagger(Lingua::EN::Tagger->new) unless $self->__tagger;
 637
 638     return $self->__tagger;
 639 }
 640
 641 sub _adjectives {
 642     my ($self, @cols) = @_;
 643
 644     my @adjectives;
 645
 646     foreach my $col (@cols) {
 647         my @words = split_name $col;
 648
 649         my $tagged = $self->_tagger->get_readable(join ' ', @words);
 650
 651         push @adjectives, $tagged =~ m{\G(\w+)/JJ\s+}g;
 652     }
 653
 654     return @adjectives;
 655 }
 656
 657 sub _name_to_identifier {
 658     my ($self, $name) = @_;
 659
 660     my $to_identifier = $self->loader->naming->{force_ascii} ?
 661         \&String::ToIdentifier::EN::to_identifier
 662         : \&String::ToIdentifier::EN::Unicode::to_identifier;
 663
 664     return join '_', map lc, split_name $to_identifier->($name, '_');
 665 }
 666
 667 sub _disambiguate {
 668     my ($self, $all_code, $in_class, $dups) = @_;
 669
 670     DUP: foreach my $dup (keys %$dups) {
 671         my @rels = @{ $dups->{$dup} };
 672
 673         # Check if there are rels to the same table name in different
 674         # schemas/databases, if so qualify them.
 675         my @tables = map $self->loader->moniker_to_table->{$_->{extra}{remote_moniker}},
 676                         @rels;
 677
 678         # databases are different, prepend database
 679         if ($tables[0]->can('database') && (uniq map $_->database||'', @tables) > 1) {
 680             # If any rels are in the same database, we have to distinguish by
 681             # both schema and database.
 682             my %db_counts;
 683             $db_counts{$_}++ for map $_->database, @tables;
 684             my $use_schema = any { $_ > 1 } values %db_counts;
 685
 686             foreach my $i (0..$#rels) {
 687                 my $rel   = $rels[$i];
 688                 my $table = $tables[$i];
 689
 690                 $rel->{args}[0] = $self->_name_to_identifier($table->database)
 691                     . ($use_schema ? ('_' . $self->name_to_identifier($table->schema)) : '')
 692                     . '_' . $rel->{args}[0];
 693             }
 694             next DUP;
 695         }
 696         # schemas are different, prepend schema
 697         elsif ((uniq map $_->schema||'', @tables) > 1) {
 698             foreach my $i (0..$#rels) {
 699                 my $rel   = $rels[$i];
 700                 my $table = $tables[$i];
 701
 702                 $rel->{args}[0] = $self->_name_to_identifier($table->schema)
 703                     . '_' . $rel->{args}[0];
 704             }
 705             next DUP;
 706         }
 707
 708         foreach my $rel (@rels) {
 709             next if $rel->{method} =~ /^(?:belongs_to|many_to_many)\z/;
 710
 711             my @to_cols = apply { s/^foreign\.//i }
 712                 keys %{ $rel->{args}[2] };
 713
 714             my @adjectives = $self->_adjectives(@to_cols);
 715
 716             # If there are no adjectives, and there is only one might_have
 717             # rel to that class, we hardcode 'active'.
 718
 719             my $to_class = $rel->{args}[1];
 720
 721             if ((not @adjectives)
 722                 && (grep { $_->{method} eq 'might_have'
 723                            && $_->{args}[1] eq $to_class } @{ $all_code->{$in_class} }) == 1) {
 724
 725                 @adjectives = 'active';
 726             }
 727
 728             if (@adjectives) {
 729                 my $rel_name = join '_', sort(@adjectives), $rel->{args}[0];
 730
 731                 ($rel_name) = $rel->{method} eq 'might_have' ?
 732                     $self->_inflect_singular($rel_name)
 733                     :
 734                     $self->_inflect_plural($rel_name);
 735
 736                 my ($local_class, $local_moniker, $remote_moniker)
 737                     = @{ $rel->{extra} }
 738                         {qw/local_class local_moniker remote_moniker/};
 739
 740                 my @from_cols = apply { s/^self\.//i }
 741                     values %{ $rel->{args}[2] };
 742
 743                 ($rel_name) = $self->_rel_name_map($rel_name, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 744
 745                 $rel_name = $self->_resolve_relname_collision($local_moniker, \@from_cols, $rel_name);
 746
 747                 $rel->{args}[0] = $rel_name;
 748             }
 749         }
 750     }
 751
 752     # Check again for duplicates, since the heuristics above may not have resolved them all.
 753
 754     if ($dups = $self->_duplicates($all_code->{$in_class})) {
 755         foreach my $dup (keys %$dups) {
 756             # sort by method
 757             my @rels = map $_->[1], sort { $a->[0] <=> $b->[0] } map [
 758                 {
 759                     belongs_to   => 3,
 760                     has_many     => 2,
 761                     might_have   => 1,
 762                     many_to_many => 0,
 763                 }->{$_->{method}}, $_
 764             ], @{ $dups->{$dup} };
 765
 766             my $rel_num = 2;
 767
 768             foreach my $rel (@rels[1 .. $#rels]) {
 769                 my $inflect_type = $rel->{method} =~ /^(?:many_to_many|has_many)\z/ ?
 770                     'inflect_plural'
 771                     :
 772                     'inflect_singular';
 773
 774                 my $inflect_method = "_$inflect_type";
 775
 776                 my $relname_new_uninflected = $rel->{args}[0] . "_$rel_num";
 777
 778                 $rel_num++;
 779
 780                 my ($local_class, $local_moniker, $remote_moniker)
 781                     = @{ $rel->{extra} }
 782                         {qw/local_class local_moniker remote_moniker/};
 783
 784                 my (@from_cols, @to_cols, $to_class);
 785
 786                 if ($rel->{method} eq 'many_to_many') {
 787                     @from_cols = apply { s/^self\.//i } values %{
 788                         (first { $_->{args}[0] eq $rel->{args}[1] } @{ $all_code->{$local_class} })
 789                             ->{args}[2]
 790                     };
 791                     @to_cols   = apply { s/^foreign\.//i } keys %{
 792                         (first { $_->{args}[0] eq $rel->{args}[2] }
 793                             @{ $all_code->{ $rel->{extra}{link_class} } })
 794                                 ->{args}[2]
 795                     };
 796                     $to_class  = $self->schema->source($remote_moniker)->result_class;
 797                 }
 798                 else {
 799                     @from_cols = apply { s/^self\.//i }    values %{ $rel->{args}[2] };
 800                     @to_cols   = apply { s/^foreign\.//i } keys   %{ $rel->{args}[2] };
 801                     $to_class  = $rel->{args}[1];
 802                 }
 803
 804                 my ($relname_new, $inflect_mapped) =
 805                     $self->$inflect_method($relname_new_uninflected);
 806
 807                 my $rel_name_mapped;
 808
 809                 ($relname_new, $rel_name_mapped) = $self->_rel_name_map($relname_new, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 810
 811                 my $mapped = $inflect_mapped || $rel_name_mapped;
 812
 813                 warn <<"EOF" unless $mapped;
 814 Could not find a proper name for relationship '$relname_new' in source
 815 '$local_moniker' for columns '@{[ join ',', @from_cols ]}'. Supply a value in
 816 '$inflect_type' for '$relname_new_uninflected' or 'rel_name_map' for
 817 '$relname_new' to name this relationship.
 818 EOF
 819
 820                 $relname_new = $self->_resolve_relname_collision($local_moniker, \@from_cols, $relname_new);
 821
 822                 $rel->{args}[0] = $relname_new;
 823             }
 824         }
 825     }
 826 }
 827
 828 sub _relnames_and_method {
 829     my ( $self, $local_moniker, $rel, $cond, $uniqs, $counters ) = @_;
 830
 831     my $remote_moniker  = $rel->{remote_source};
 832     my $remote_obj      = $self->schema->source( $remote_moniker );
 833     my $remote_class    = $self->schema->class(  $remote_moniker );
 834     my $local_relname   = $self->_local_relname( $rel->{remote_table}, $cond);
 835
 836     my $local_cols      = $rel->{local_columns};
 837     my $local_table     = $rel->{local_table};
 838     my $local_class     = $self->schema->class($local_moniker);
 839     my $local_source    = $self->schema->source($local_moniker);
 840
 841     my $remote_relname_uninflected = $self->_normalize_name($local_table);
 842     my ($remote_relname) = $self->_inflect_plural($self->_normalize_name($local_table));
 843
 844     my $remote_method = 'has_many';
 845
 846     # If the local columns have a UNIQUE constraint, this is a one-to-one rel
 847     if (array_eq([ $local_source->primary_columns ], $local_cols) ||
 848             first { array_eq($_->[1], $local_cols) } @$uniqs) {
 849         $remote_method   = 'might_have';
 850         ($remote_relname) = $self->_inflect_singular($remote_relname_uninflected);
 851     }
 852
 853     # If more than one rel between this pair of tables, use the local
 854     # col names to distinguish, unless the rel was created previously.
 855     if ($counters->{$remote_moniker} > 1) {
 856         my $relationship_exists = 0;
 857
 858         if (-f (my $existing_remote_file = $self->loader->get_dump_filename($remote_class))) {
 859             my $class = "${remote_class}Temporary";
 860
 861             if (not Class::Inspector->loaded($class)) {
 862                 my $code = slurp_file $existing_remote_file;
 863
 864                 $code =~ s/(?<=package $remote_class)/Temporary/g;
 865
 866                 $code =~ s/__PACKAGE__->meta->make_immutable[^;]*;//g;
 867
 868                 eval $code;
 869                 die $@ if $@;
 870
 871                 push @{ $self->_temp_classes }, $class;
 872             }
 873
 874             if ($class->has_relationship($remote_relname)) {
 875                 my $rel_cols = [ sort { $a cmp $b } apply { s/^foreign\.//i }
 876                     (keys %{ $class->relationship_info($remote_relname)->{cond} }) ];
 877
 878                 $relationship_exists = 1 if array_eq([ sort @$local_cols ], $rel_cols);
 879             }
 880         }
 881
 882         if (not $relationship_exists) {
 883             my $colnames = q{_} . $self->_normalize_name(join '_', @$local_cols);
 884             $local_relname .= $colnames if keys %$cond > 1;
 885
 886             $remote_relname = $self->_strip_id_postfix($self->_normalize_name($local_table . $colnames));
 887
 888             $remote_relname_uninflected = $remote_relname;
 889             ($remote_relname) = $self->_inflect_plural($remote_relname);
 890
 891             # if colnames were added and this is a might_have, re-inflect
 892             if ($remote_method eq 'might_have') {
 893                 ($remote_relname) = $self->_inflect_singular($remote_relname_uninflected);
 894             }
 895         }
 896     }
 897
 898     return ($local_relname, $remote_relname, $remote_method);
 899 }
 900
 901 sub _rel_name_map {
 902     my ($self, $relname, $method, $local_class, $local_moniker, $local_cols,
 903         $remote_class, $remote_moniker, $remote_cols, $extra) = @_;
 904
 905     my $info = {
 906         %{$extra || {}},
 907         name           => $relname,
 908         type           => $method,
 909         local_class    => $local_class,
 910         local_moniker  => $local_moniker,
 911         local_columns  => $local_cols,
 912         remote_class   => $remote_class,
 913         remote_moniker => $remote_moniker,
 914         remote_columns => $remote_cols,
 915     };
 916
 917     $self->_run_user_map($self->rel_name_map, $info);
 918 }
 919
 920 sub _run_user_map {
 921     my ($self, $map, $info) = @_;
 922
 923     my $new_name = $info->{name};
 924     my $mapped = 0;
 925
 926     if ('HASH' eq ref($map)) {
 927         my $name = $info->{name};
 928         my $moniker = $info->{local_moniker};
 929         if ($map->{$moniker} and 'HASH' eq ref($map->{$moniker})
 930             and $map->{$moniker}{$name}
 931         ) {
 932             $new_name = $map->{$moniker}{$name};
 933             $mapped   = 1;
 934         }
 935         elsif ($map->{$name} and not 'HASH' eq ref($map->{$name})) {
 936             $new_name = $map->{$name};
 937             $mapped   = 1;
 938         }
 939     }
 940     elsif ('CODE' eq ref($map)) {
 941         my $cb = sub {
 942             my ($cb_map) = @_;
 943             croak "reentered rel_name_map must be a hashref"
 944                 unless 'HASH' eq ref($cb_map);
 945             my ($cb_name, $cb_mapped) = $self->_run_user_map($cb_map, $info);
 946             return $cb_mapped && $cb_name;
 947         };
 948         my $name = $map->($info, $cb);
 949         if ($name) {
 950             $new_name = $name;
 951             $mapped   = 1;
 952         }
 953     }
 954
 955     return ($new_name, $mapped);
 956 }
 957
 958 sub _cleanup {
 959     my $self = shift;
 960
 961     for my $class (@{ $self->_temp_classes }) {
 962         Class::Unload->unload($class);
 963     }
 964
 965     $self->_temp_classes([]);
 966 }
 967
 968 =head1 AUTHOR
 969
 970 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 971
 972 =head1 LICENSE
 973
 974 This library is free software; you can redistribute it and/or modify it under
 975 the same terms as Perl itself.
 976
 977 =cut
 978
 979 1;
 980 # vim:et sts=4 sw=4 tw=0: