lib/DBIx/Class/Schema/Loader/Generic.pm

   1 package DBIx::Class::Schema::Loader::Generic;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Schema/;
   7
   8 use Carp;
   9 use Lingua::EN::Inflect;
  10
  11 require DBIx::Class::Core;
  12
  13 __PACKAGE__->mk_classdata('loader_data');
  14
  15 =head1 NAME
  16
  17 DBIx::Class::Schema::Loader::Generic - Generic DBIx::Class::Schema::Loader Implementation.
  18
  19 =head1 SYNOPSIS
  20
  21 See L<DBIx::Class::Schema::Loader>
  22
  23 =head1 DESCRIPTION
  24
  25 =head2 OPTIONS
  26
  27 Available constructor options are:
  28
  29 =head3 additional_base_classes
  30
  31 List of additional base classes your table classes will use.
  32
  33 =head3 left_base_classes
  34
  35 List of additional base classes, that need to be leftmost.
  36
  37 =head3 additional_classes
  38
  39 List of additional classes which your table classes will use.
  40
  41 =head3 constraint
  42
  43 Only load tables matching regex.
  44
  45 =head3 exclude
  46
  47 Exclude tables matching regex.
  48
  49 =head3 debug
  50
  51 Enable debug messages.
  52
  53 =head3 dsn
  54
  55 DBI Data Source Name.
  56
  57 =head3 password
  58
  59 Password.
  60
  61 =head3 relationships
  62
  63 Try to automatically detect/setup has_a and has_many relationships.
  64
  65 =head3 inflect
  66
  67 An hashref, which contains exceptions to Lingua::EN::Inflect::PL().
  68 Useful for foreign language column names.
  69
  70 =head3 user
  71
  72 Username.
  73
  74 =head2 METHODS
  75
  76 =cut
  77
  78 =head3 new
  79
  80 Not intended to be called directly.  This is used internally by the
  81 C<new()> method in L<DBIx::Class::Schema::Loader>.
  82
  83 =cut
  84
  85 sub _load_from_connection {
  86     my ( $class, %args ) = @_;
  87     if ( $args{debug} ) {
  88         no strict 'refs';
  89         *{"$class\::debug_loader"} = sub { 1 };
  90     }
  91     my $additional = $args{additional_classes} || [];
  92     $additional = [$additional] unless ref $additional eq 'ARRAY';
  93     my $additional_base = $args{additional_base_classes} || [];
  94     $additional_base = [$additional_base]
  95       unless ref $additional_base eq 'ARRAY';
  96     my $left_base = $args{left_base_classes} || [];
  97     $left_base = [$left_base] unless ref $left_base eq 'ARRAY';
  98     $class->loader_data({
  99         _datasource =>
 100           [ $args{dsn}, $args{user}, $args{password}, $args{options} ],
 101         _additional      => $additional,
 102         _additional_base => $additional_base,
 103         _left_base       => $left_base,
 104         _constraint      => $args{constraint} || '.*',
 105         _exclude         => $args{exclude},
 106         _relationships   => $args{relationships},
 107         _inflect         => $args{inflect},
 108         _db_schema       => $args{db_schema} || '',
 109         _drop_db_schema  => $args{drop_db_schema},
 110         TABLE_CLASSES    => {},
 111         MONIKERS         => {},
 112     });
 113
 114     $class->connection(@{$class->loader_data->{_datasource}});
 115     warn qq/\### START DBIx::Class::Schema::Loader dump ###\n/ if $class->debug_loader;
 116     $class->_load_classes;
 117     $class->_relationships                            if $class->loader_data->{_relationships};
 118     warn qq/\### END DBIx::Class::Schema::Loader dump ###\n/ if $class->debug_loader;
 119     $class->storage->dbh->disconnect; # XXX this should be ->storage->disconnect later?
 120
 121     1;
 122 }
 123
 124 # The original table class name during Loader,
 125 sub _find_table_class {
 126     my ( $class, $table ) = @_;
 127     return $class->loader_data->{TABLE_CLASSES}->{$table};
 128 }
 129
 130 # Returns the moniker for a given table name,
 131 # for use in $conn->resultset($moniker)
 132
 133 =head3 moniker
 134
 135 Returns the moniker for a given literal table name.  Used
 136 as $schema->resultset($moniker), etc.
 137
 138 =cut
 139 sub moniker {
 140     my ( $class, $table ) = @_;
 141     return $class->loader_data->{MONIKERS}->{$table};
 142 }
 143
 144 =head3 debug_loader
 145
 146 Overload to enable Loader debug messages.
 147
 148 =cut
 149
 150 sub debug_loader { 0 }
 151
 152 =head3 tables
 153
 154 Returns a sorted list of tables.
 155
 156     my @tables = $loader->tables;
 157
 158 =cut
 159
 160 sub tables {
 161     my $class = shift;
 162     return sort keys %{ $class->loader_data->{MONIKERS} };
 163 }
 164
 165 # Overload in your driver class
 166 sub _db_classes { croak "ABSTRACT METHOD" }
 167
 168 # Setup has_a and has_many relationships
 169 sub _belongs_to_many {
 170     my ( $class, $table, $column, $other, $other_column ) = @_;
 171     my $table_class = $class->_find_table_class($table);
 172     my $other_class = $class->_find_table_class($other);
 173
 174     warn qq/\# Belongs_to relationship\n/ if $class->debug_loader;
 175
 176     if($other_column) {
 177         warn qq/$table_class->belongs_to( '$column' => '$other_class',/
 178           .  qq/ { "foreign.$other_column" => "self.$column" },/
 179           .  qq/ { accessor => 'filter' });\n\n/
 180           if $class->debug_loader;
 181         $table_class->belongs_to( $column => $other_class,
 182           { "foreign.$other_column" => "self.$column" },
 183           { accessor => 'filter' }
 184         );
 185     }
 186     else {
 187         warn qq/$table_class->belongs_to( '$column' => '$other_class' );\n\n/
 188           if $class->debug_loader;
 189         $table_class->belongs_to( $column => $other_class );
 190     }
 191
 192     my ($table_class_base) = $table_class =~ /.*::(.+)/;
 193     my $plural = Lingua::EN::Inflect::PL( lc $table_class_base );
 194     $plural = $class->loader_data->{_inflect}->{ lc $table_class_base }
 195       if $class->loader_data->{_inflect}
 196       and exists $class->loader_data->{_inflect}->{ lc $table_class_base };
 197
 198     warn qq/\# Has_many relationship\n/ if $class->debug_loader;
 199
 200     if($other_column) {
 201         warn qq/$other_class->has_many( '$plural' => '$table_class',/
 202           .  qq/ { "foreign.$column" => "self.$other_column" } );\n\n/
 203           if $class->debug_loader;
 204         $other_class->has_many( $plural => $table_class,
 205                                 { "foreign.$column" => "self.$other_column" }
 206                               );
 207     }
 208     else {
 209         warn qq/$other_class->has_many( '$plural' => '$table_class',/
 210           .  qq/'$other_column' );\n\n/
 211           if $class->debug_loader;
 212         $other_class->has_many( $plural => $table_class, $column );
 213     }
 214 }
 215
 216 # Load and setup classes
 217 sub _load_classes {
 218     my $class = shift;
 219
 220     my @tables          = $class->_tables();
 221     my @db_classes      = $class->_db_classes();
 222     my $additional      = join '', map "use $_;\n", @{ $class->loader_data->{_additional} };
 223     my $additional_base = join '', map "use base '$_';\n",
 224       @{ $class->loader_data->{_additional_base} };
 225     my $left_base  = join '', map "use base '$_';\n", @{ $class->loader_data->{_left_base} };
 226     my $constraint = $class->loader_data->{_constraint};
 227     my $exclude    = $class->loader_data->{_exclude};
 228
 229     foreach my $table (@tables) {
 230         next unless $table =~ /$constraint/;
 231         next if ( defined $exclude && $table =~ /$exclude/ );
 232
 233         my ($db_schema, $tbl) = split /\./, $table;
 234         my $tablename = lc $table;
 235         if($tbl) {
 236             $tablename = $class->loader_data->{_drop_db_schema} ? $tbl : lc $table;
 237         }
 238
 239         my $table_moniker = $class->_table2moniker($db_schema, $tbl);
 240         my $table_class = "$class\::$table_moniker";
 241
 242         $class->inject_base( $table_class, 'DBIx::Class::Core' );
 243         $_->require for @db_classes;
 244         $class->inject_base( $table_class, $_ ) for @db_classes;
 245         warn qq/\# Initializing table "$tablename" as "$table_class"\n/ if $class->debug_loader;
 246         $table_class->table(lc $tablename);
 247
 248         my ( $cols, $pks ) = $class->_table_info($table);
 249         carp("$table has no primary key") unless @$pks;
 250         $table_class->add_columns(@$cols);
 251         $table_class->set_primary_key(@$pks) if @$pks;
 252
 253         my $code = "package $table_class;\n$additional_base$additional$left_base";
 254         warn qq/$code/                        if $class->debug_loader;
 255         warn qq/$table_class->table('$tablename');\n/ if $class->debug_loader;
 256         my $columns = join "', '", @$cols;
 257         warn qq/$table_class->add_columns('$columns')\n/ if $class->debug_loader;
 258         my $primaries = join "', '", @$pks;
 259         warn qq/$table_class->set_primary_key('$primaries')\n/ if $class->debug_loader && @$pks;
 260         eval $code;
 261         croak qq/Couldn't load additional classes "$@"/ if $@;
 262         unshift @{"$table_class\::ISA"}, $_ foreach ( @{ $class->loader_data->{_left_base} } );
 263
 264         $class->register_class($table_moniker, $table_class);
 265         $class->loader_data->{TABLE_CLASSES}->{lc $tablename} = $table_class;
 266         $class->loader_data->{MONIKERS}->{lc $tablename} = $table_moniker;
 267     }
 268 }
 269
 270 # Find and setup relationships
 271 sub _relationships {
 272     my $class = shift;
 273     my $dbh = $class->storage->dbh;
 274     foreach my $table ( $class->tables ) {
 275         my $quoter = $dbh->get_info(29) || q{"};
 276         if ( my $sth = $dbh->foreign_key_info( '', $class->loader_data->{_db_schema}, '', '', '', $table ) ) {
 277             for my $res ( @{ $sth->fetchall_arrayref( {} ) } ) {
 278                 my $column = lc $res->{FK_COLUMN_NAME};
 279                 my $other  = lc $res->{UK_TABLE_NAME};
 280                 my $other_column  = lc $res->{UK_COLUMN_NAME};
 281                 $column =~ s/$quoter//g;
 282                 $other =~ s/$quoter//g;
 283                 $other_column =~ s/$quoter//g;
 284                 eval { $class->_belongs_to_many( $table, $column, $other,
 285                   $other_column ) };
 286                 warn qq/\# belongs_to_many failed "$@"\n\n/
 287                   if $@ && $class->debug_loader;
 288             }
 289         }
 290     }
 291 }
 292
 293 # Make a moniker from a table
 294 sub _table2moniker {
 295     my ( $class, $db_schema, $table ) = @_;
 296
 297     my $db_schema_ns;
 298
 299     if($table) {
 300         $db_schema = ucfirst lc $db_schema;
 301         $db_schema_ns = $db_schema if(!$class->loader_data->{_drop_db_schema});
 302     } else {
 303         $table = $db_schema;
 304     }
 305
 306     my $moniker = join '', map ucfirst, split /[\W_]+/, lc $table;
 307     $moniker = $db_schema_ns ? $db_schema_ns . $moniker : $moniker;
 308
 309     return $moniker;
 310 }
 311
 312 # Overload in driver class
 313 sub _tables { croak "ABSTRACT METHOD" }
 314
 315 sub _table_info { croak "ABSTRACT METHOD" }
 316
 317 =head1 SEE ALSO
 318
 319 L<DBIx::Class::Schema::Loader>
 320
 321 =cut
 322
 323 1;