lib/DBIx/Class/Schema/Loader/Generic.pm

   1 package DBIx::Class::Schema::Loader::Generic;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Schema/;
   7
   8 use Carp;
   9 use Lingua::EN::Inflect;
  10
  11 require DBIx::Class::Core;
  12
  13 __PACKAGE__->mk_classdata('_loader_data');
  14 __PACKAGE__->mk_classdata('_loader_debug' => 0);
  15
  16 =head1 NAME
  17
  18 DBIx::Class::Schema::Loader::Generic - Generic DBIx::Class::Schema::Loader Implementation.
  19
  20 =head1 SYNOPSIS
  21
  22 See L<DBIx::Class::Schema::Loader>
  23
  24 =head1 DESCRIPTION
  25
  26 =head2 OPTIONS
  27
  28 Available constructor options are:
  29
  30 =head3 additional_base_classes
  31
  32 List of additional base classes your table classes will use.
  33
  34 =head3 left_base_classes
  35
  36 List of additional base classes, that need to be leftmost.
  37
  38 =head3 additional_classes
  39
  40 List of additional classes which your table classes will use.
  41
  42 =head3 constraint
  43
  44 Only load tables matching regex.
  45
  46 =head3 exclude
  47
  48 Exclude tables matching regex.
  49
  50 =head3 debug
  51
  52 Enable debug messages.
  53
  54 =head3 dsn
  55
  56 DBI Data Source Name.
  57
  58 =head3 password
  59
  60 Password.
  61
  62 =head3 relationships
  63
  64 Try to automatically detect/setup has_a and has_many relationships.
  65
  66 =head3 inflect
  67
  68 An hashref, which contains exceptions to Lingua::EN::Inflect::PL().
  69 Useful for foreign language column names.
  70
  71 =head3 user
  72
  73 Username.
  74
  75 =head2 METHODS
  76
  77 =cut
  78
  79 =head3 new
  80
  81 Not intended to be called directly.  This is used internally by the
  82 C<new()> method in L<DBIx::Class::Schema::Loader>.
  83
  84 =cut
  85
  86 sub _load_from_connection {
  87     my ( $class, %args ) = @_;
  88
  89     $class->_loader_debug( $args{debug} ? 1 : 0);
  90
  91     my $additional = $args{additional_classes} || [];
  92     $additional = [$additional] unless ref $additional eq 'ARRAY';
  93
  94     my $additional_base = $args{additional_base_classes} || [];
  95     $additional_base = [$additional_base]
  96       unless ref $additional_base eq 'ARRAY';
  97
  98     my $left_base = $args{left_base_classes} || [];
  99     $left_base = [$left_base] unless ref $left_base eq 'ARRAY';
 100
 101     $class->_loader_data({
 102         datasource =>
 103           [ $args{dsn}, $args{user}, $args{password}, $args{options} ],
 104         additional      => $additional,
 105         additional_base => $additional_base,
 106         left_base       => $left_base,
 107         constraint      => $args{constraint} || '.*',
 108         exclude         => $args{exclude},
 109         relationships   => $args{relationships},
 110         inflect         => $args{inflect},
 111         db_schema       => $args{db_schema} || '',
 112         drop_db_schema  => $args{drop_db_schema},
 113         TABLE_CLASSES   => {},
 114         MONIKERS        => {},
 115     });
 116
 117     $class->connection(@{$class->_loader_data->{datasource}});
 118     warn qq/\### START DBIx::Class::Schema::Loader dump ###\n/
 119         if $class->_loader_debug;
 120     $class->_loader_load_classes;
 121     $class->_loader_relationships if $class->_loader_data->{relationships};
 122     warn qq/\### END DBIx::Class::Schema::Loader dump ###\n/
 123         if $class->_loader_debug;
 124     $class->storage->dbh->disconnect; # XXX this should be ->storage->disconnect later?
 125
 126     1;
 127 }
 128
 129 # The original table class name during Loader,
 130 sub _loader_find_table_class {
 131     my ( $class, $table ) = @_;
 132     return $class->_loader_data->{TABLE_CLASSES}->{$table};
 133 }
 134
 135 # Returns the moniker for a given table name,
 136 # for use in $conn->resultset($moniker)
 137
 138 =head3 moniker
 139
 140 Returns the moniker for a given literal table name.  Used
 141 as $schema->resultset($moniker), etc.
 142
 143 =cut
 144 sub moniker {
 145     my ( $class, $table ) = @_;
 146     return $class->_loader_data->{MONIKERS}->{$table};
 147 }
 148
 149 =head3 tables
 150
 151 Returns a sorted list of tables.
 152
 153     my @tables = $loader->tables;
 154
 155 =cut
 156
 157 sub tables {
 158     my $class = shift;
 159     return sort keys %{ $class->_loader_data->{MONIKERS} };
 160 }
 161
 162 # Overload in your driver class
 163 sub _loader_db_classes { croak "ABSTRACT METHOD" }
 164
 165 # Setup has_a and has_many relationships
 166 sub _loader_make_relations {
 167     use Data::Dumper;
 168
 169     my ( $class, $table, $other, $cond ) = @_;
 170     my $table_class = $class->_loader_find_table_class($table);
 171     my $other_class = $class->_loader_find_table_class($other);
 172
 173     my $table_relname = lc $table;
 174     my $other_relname = lc $other;
 175
 176     if(my $inflections = $class->_loader_data->{inflect}) {
 177         $table_relname = $inflections->{$table_relname}
 178           if exists $inflections->{$table_relname};
 179     }
 180     else {
 181         $table_relname = Lingua::EN::Inflect::PL($table_relname);
 182     }
 183
 184     # for single-column case, set the relname to the column name,
 185     # to make filter accessors work
 186     if(scalar keys %$cond == 1) {
 187         my ($col) = keys %$cond;
 188         $other_relname = $cond->{$col};
 189     }
 190
 191     my $rev_cond = { reverse %$cond };
 192
 193     warn qq/\# Belongs_to relationship\n/ if $class->_loader_debug;
 194
 195     warn qq/$table_class->belongs_to( '$other_relname' => '$other_class',/
 196       .  Dumper($cond)
 197       .  qq/);\n\n/
 198       if $class->_loader_debug;
 199
 200     $table_class->belongs_to( $other_relname => $other_class, $cond);
 201
 202     warn qq/\# Has_many relationship\n/ if $class->_loader_debug;
 203
 204     warn qq/$other_class->has_many( '$table_relname' => '$table_class',/
 205       .  Dumper($rev_cond)
 206       .  qq/);\n\n/
 207       if $class->_loader_debug;
 208
 209     $other_class->has_many( $table_relname => $table_class, $rev_cond);
 210 }
 211
 212 # Load and setup classes
 213 sub _loader_load_classes {
 214     my $class = shift;
 215
 216     my @tables          = $class->_loader_tables();
 217     my @db_classes      = $class->_loader_db_classes();
 218     my $additional      = join '', map "use $_;\n", @{ $class->_loader_data->{additional} };
 219     my $additional_base = join '', map "use base '$_';\n",
 220       @{ $class->_loader_data->{additional_base} };
 221     my $left_base  = join '', map "use base '$_';\n", @{ $class->_loader_data->{left_base} };
 222     my $constraint = $class->_loader_data->{constraint};
 223     my $exclude    = $class->_loader_data->{exclude};
 224
 225     foreach my $table (@tables) {
 226         next unless $table =~ /$constraint/;
 227         next if ( defined $exclude && $table =~ /$exclude/ );
 228
 229         my ($db_schema, $tbl) = split /\./, $table;
 230         my $tablename = lc $table;
 231         if($tbl) {
 232             $tablename = $class->_loader_data->{drop_db_schema} ? $tbl : lc $table;
 233         }
 234
 235         my $table_moniker = $class->_loader_table2moniker($db_schema, $tbl);
 236         my $table_class = "$class\::$table_moniker";
 237
 238         $class->inject_base( $table_class, 'DBIx::Class::Core' );
 239         $_->require for @db_classes;
 240         $class->inject_base( $table_class, $_ ) for @db_classes;
 241         warn qq/\# Initializing table "$tablename" as "$table_class"\n/ if $class->_loader_debug;
 242         $table_class->table(lc $tablename);
 243
 244         my ( $cols, $pks ) = $class->_loader_table_info($table);
 245         carp("$table has no primary key") unless @$pks;
 246         $table_class->add_columns(@$cols);
 247         $table_class->set_primary_key(@$pks) if @$pks;
 248
 249         my $code = "package $table_class;\n$additional_base$additional$left_base";
 250         warn qq/$code/                        if $class->_loader_debug;
 251         warn qq/$table_class->table('$tablename');\n/ if $class->_loader_debug;
 252         my $columns = join "', '", @$cols;
 253         warn qq/$table_class->add_columns('$columns')\n/ if $class->_loader_debug;
 254         my $primaries = join "', '", @$pks;
 255         warn qq/$table_class->set_primary_key('$primaries')\n/ if $class->_loader_debug && @$pks;
 256         eval $code;
 257         croak qq/Couldn't load additional classes "$@"/ if $@;
 258         unshift @{"$table_class\::ISA"}, $_ foreach ( @{ $class->_loader_data->{left_base} } );
 259
 260         $class->register_class($table_moniker, $table_class);
 261         $class->_loader_data->{TABLE_CLASSES}->{lc $tablename} = $table_class;
 262         $class->_loader_data->{MONIKERS}->{lc $tablename} = $table_moniker;
 263     }
 264 }
 265
 266 # Find and setup relationships
 267 sub _loader_relationships {
 268     my $class = shift;
 269     my $dbh = $class->storage->dbh;
 270     my $quoter = $dbh->get_info(29) || q{"};
 271     foreach my $table ( $class->tables ) {
 272         my $rels = {};
 273         my $sth = $dbh->foreign_key_info( '',
 274             $class->_loader_data->{db_schema}, '', '', '', $table );
 275         next if !$sth;
 276         while(my $raw_rel = $sth->fetchrow_hashref) {
 277             my $uk_tbl  = lc $raw_rel->{UK_TABLE_NAME};
 278             my $uk_col  = lc $raw_rel->{UK_COLUMN_NAME};
 279             my $fk_col  = lc $raw_rel->{FK_COLUMN_NAME};
 280             $uk_tbl =~ s/$quoter//g;
 281             $uk_col =~ s/$quoter//g;
 282             $fk_col =~ s/$quoter//g;
 283             $rels->{$uk_tbl}->{$uk_col} = $fk_col;
 284         }
 285
 286         foreach my $reltbl (keys %$rels) {
 287             my $cond = $rels->{$reltbl};
 288             eval { $class->_loader_make_relations( $table, $reltbl, $cond ) };
 289               warn qq/\# belongs_to_many failed "$@"\n\n/
 290                 if $@ && $class->_loader_debug;
 291         }
 292     }
 293 }
 294
 295 # Make a moniker from a table
 296 sub _loader_table2moniker {
 297     my ( $class, $db_schema, $table ) = @_;
 298
 299     my $db_schema_ns;
 300
 301     if($table) {
 302         $db_schema = ucfirst lc $db_schema;
 303         $db_schema_ns = $db_schema if(!$class->_loader_data->{drop_db_schema});
 304     } else {
 305         $table = $db_schema;
 306     }
 307
 308     my $moniker = join '', map ucfirst, split /[\W_]+/, lc $table;
 309     $moniker = $db_schema_ns ? $db_schema_ns . $moniker : $moniker;
 310
 311     return $moniker;
 312 }
 313
 314 # Overload in driver class
 315 sub _loader_tables { croak "ABSTRACT METHOD" }
 316
 317 sub _loader_table_info { croak "ABSTRACT METHOD" }
 318
 319 =head1 SEE ALSO
 320
 321 L<DBIx::Class::Schema::Loader>
 322
 323 =cut
 324
 325 1;