lib/DBIx/Class/Schema/Loader/DBI/SQLAnywhere.pm

   1 package DBIx::Class::Schema::Loader::DBI::SQLAnywhere;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   7     DBIx::Class::Schema::Loader::DBI
   8 /;
   9 use mro 'c3';
  10 use List::MoreUtils 'any';
  11 use namespace::clean;
  12 use DBIx::Class::Schema::Loader::Table ();
  13
  14 our $VERSION = '0.07010';
  15
  16 =head1 NAME
  17
  18 DBIx::Class::Schema::Loader::DBI::SQLAnywhere - DBIx::Class::Schema::Loader::DBI
  19 SQL Anywhere Implementation.
  20
  21 =head1 DESCRIPTION
  22
  23 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  24
  25 =cut
  26
  27 sub _system_schemas {
  28     return (qw/dbo SYS diagnostics rs_systabgroup SA_DEBUG/);
  29 }
  30
  31 sub _setup {
  32     my $self = shift;
  33
  34     $self->next::method(@_);
  35
  36     $self->preserve_case(1)
  37         unless defined $self->preserve_case;
  38
  39     $self->schema->storage->sql_maker->quote_char('"');
  40     $self->schema->storage->sql_maker->name_sep('.');
  41
  42     $self->db_schema([($self->dbh->selectrow_array('select user'))[0]])
  43         unless $self->db_schema;
  44
  45     if (ref $self->db_schema eq 'ARRAY' && $self->db_schema->[0] eq '%') {
  46         my @users = grep { my $uname = $_; not any { $_ eq $uname } $self->_system_schemas }
  47             @{ $self->dbh->selectcol_arrayref('select user_name from sysuser') };
  48
  49         $self->db_schema(\@users);
  50     }
  51 }
  52
  53 sub _tables_list {
  54     my ($self, $opts) = @_;
  55
  56     my @tables;
  57
  58     foreach my $schema (@{ $self->db_schema }) {
  59         my $sth = $self->dbh->prepare(<<'EOF');
  60 SELECT t.table_name name
  61 FROM systab t
  62 JOIN sysuser u
  63     ON t.creator = u.user_id
  64 WHERE u.user_name = ?
  65 EOF
  66         $sth->execute($schema);
  67
  68         my @table_names = map @$_, @{ $sth->fetchall_arrayref };
  69
  70         foreach my $table_name (@table_names) {
  71             push @tables, DBIx::Class::Schema::Loader::Table->new(
  72                 loader  => $self,
  73                 name    => $table_name,
  74                 schema  => $schema,
  75             );
  76         }
  77     }
  78
  79     return $self->_filter_tables(\@tables, $opts);
  80 }
  81
  82 sub _columns_info_for {
  83     my $self    = shift;
  84     my ($table) = @_;
  85
  86     my $result = $self->next::method(@_);
  87
  88     my $dbh = $self->schema->storage->dbh;
  89
  90     while (my ($col, $info) = each %$result) {
  91         my $def = $info->{default_value};
  92         if (ref $def eq 'SCALAR' && $$def eq 'autoincrement') {
  93             delete $info->{default_value};
  94             $info->{is_auto_increment} = 1;
  95         }
  96
  97         my ($user_type) = $dbh->selectrow_array(<<'EOF', {}, $table->schema, $table->name, $col);
  98 SELECT ut.type_name
  99 FROM systabcol tc
 100 JOIN systab t
 101     ON tc.table_id = t.table_id
 102 JOIN sysuser u
 103     ON t.creator = u.user_id
 104 JOIN sysusertype ut
 105     ON tc.user_type = ut.type_id
 106 WHERE u.user_name = ? AND t.table_name = ? AND tc.column_name = ?
 107 EOF
 108         $info->{data_type} = $user_type if defined $user_type;
 109
 110         if ($info->{data_type} eq 'double') {
 111             $info->{data_type} = 'double precision';
 112         }
 113
 114         if ($info->{data_type} =~ /^(?:char|varchar|binary|varbinary)\z/ && ref($info->{size}) eq 'ARRAY') {
 115             $info->{size} = $info->{size}[0];
 116         }
 117         elsif ($info->{data_type} !~ /^(?:char|varchar|binary|varbinary|numeric|decimal)\z/) {
 118             delete $info->{size};
 119         }
 120
 121         my $sth = $dbh->prepare(<<'EOF');
 122 SELECT tc.width, tc.scale
 123 FROM systabcol tc
 124 JOIN systab t
 125     ON t.table_id = tc.table_id
 126 JOIN sysuser u
 127     ON t.creator = u.user_id
 128 WHERE u.user_name = ? AND t.table_name = ? AND tc.column_name = ?
 129 EOF
 130         $sth->execute($table->schema, $table->name, $col);
 131         my ($width, $scale) = $sth->fetchrow_array;
 132         $sth->finish;
 133
 134         if ($info->{data_type} =~ /^(?:numeric|decimal)\z/) {
 135             # We do not check for the default precision/scale, because they can be changed as PUBLIC database options.
 136             $info->{size} = [$width, $scale];
 137         }
 138         elsif ($info->{data_type} =~ /^(?:n(?:varchar|char) | varbit)\z/x) {
 139             $info->{size} = $width;
 140         }
 141         elsif ($info->{data_type} eq 'float') {
 142             $info->{data_type} = 'real';
 143         }
 144
 145         delete $info->{default_value} if ref($info->{default_value}) eq 'SCALAR' && ${ $info->{default_value} } eq 'NULL';
 146
 147         if ((eval { lc ${ $info->{default_value} } }||'') eq 'current timestamp') {
 148             ${ $info->{default_value} } = 'current_timestamp';
 149
 150             my $orig_deflt = 'current timestamp';
 151             $info->{original}{default_value} = \$orig_deflt;
 152         }
 153     }
 154
 155     return $result;
 156 }
 157
 158 sub _table_pk_info {
 159     my ($self, $table) = @_;
 160     local $self->dbh->{FetchHashKeyName} = 'NAME_lc';
 161     my $sth = $self->dbh->prepare(qq{sp_pkeys ?, ?});
 162     $sth->execute($table->name, $table->schema);
 163
 164     my @keydata;
 165
 166     while (my $row = $sth->fetchrow_hashref) {
 167         push @keydata, $self->_lc($row->{column_name});
 168     }
 169
 170     return \@keydata;
 171 }
 172
 173 sub _table_fk_info {
 174     my ($self, $table) = @_;
 175
 176     my ($local_cols, $remote_cols, $remote_table, @rels);
 177     my $sth = $self->dbh->prepare(<<'EOF');
 178 SELECT fki.index_name fk_name, fktc.column_name local_column, pku.user_name remote_schema, pkt.table_name remote_table, pktc.column_name remote_column
 179 FROM sysfkey fk
 180 JOIN systab    pkt
 181     ON fk.primary_table_id = pkt.table_id
 182 JOIN sysuser   pku
 183     ON pkt.creator = pku.user_id
 184 JOIN systab    fkt
 185     ON fk.foreign_table_id = fkt.table_id
 186 JOIN sysuser   fku
 187     ON fkt.creator = fku.user_id
 188 JOIN sysidx    pki
 189     ON fk.primary_table_id = pki.table_id  AND fk.primary_index_id    = pki.index_id
 190 JOIN sysidx    fki
 191     ON fk.foreign_table_id = fki.table_id  AND fk.foreign_index_id    = fki.index_id
 192 JOIN sysidxcol fkic
 193     ON fkt.table_id        = fkic.table_id AND fki.index_id           = fkic.index_id
 194 JOIN systabcol pktc
 195     ON pkt.table_id        = pktc.table_id AND fkic.primary_column_id = pktc.column_id
 196 JOIN systabcol fktc
 197     ON fkt.table_id        = fktc.table_id AND fkic.column_id         = fktc.column_id
 198 WHERE fku.user_name = ? AND fkt.table_name = ?
 199 EOF
 200     $sth->execute($table->schema, $table->name);
 201
 202     while (my ($fk, $local_col, $remote_schema, $remote_tab, $remote_col) = $sth->fetchrow_array) {
 203         push @{$local_cols->{$fk}},  $self->_lc($local_col);
 204         push @{$remote_cols->{$fk}}, $self->_lc($remote_col);
 205         $remote_table->{$fk} = DBIx::Class::Schema::Loader::Table->new(
 206             loader  => $self,
 207             name    => $remote_tab,
 208             schema  => $remote_schema,
 209         );
 210     }
 211
 212     foreach my $fk (keys %$remote_table) {
 213         push @rels, {
 214             local_columns => $local_cols->{$fk},
 215             remote_columns => $remote_cols->{$fk},
 216             remote_table => $remote_table->{$fk},
 217         };
 218     }
 219     return \@rels;
 220 }
 221
 222 sub _table_uniq_info {
 223     my ($self, $table) = @_;
 224
 225     my $sth = $self->dbh->prepare(<<'EOF');
 226 SELECT c.constraint_name, tc.column_name
 227 FROM sysconstraint c
 228 JOIN systab t
 229     ON c.table_object_id = t.object_id
 230 JOIN sysuser u
 231     ON t.creator = u.user_id
 232 JOIN sysidx i
 233     ON c.ref_object_id = i.object_id
 234 JOIN sysidxcol ic
 235     ON i.table_id = ic.table_id AND i.index_id = ic.index_id
 236 JOIN systabcol tc
 237     ON ic.table_id = tc.table_id AND ic.column_id = tc.column_id
 238 WHERE c.constraint_type = 'U' AND u.user_name = ? AND t.table_name = ?
 239 EOF
 240     $sth->execute($table->schema, $table->name);
 241
 242     my $constraints;
 243     while (my ($constraint_name, $column) = $sth->fetchrow_array) {
 244         push @{$constraints->{$constraint_name}}, $self->_lc($column);
 245     }
 246
 247     my @uniqs = map { [ $_ => $constraints->{$_} ] } keys %$constraints;
 248     return \@uniqs;
 249 }
 250
 251 =head1 SEE ALSO
 252
 253 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 254 L<DBIx::Class::Schema::Loader::DBI>
 255
 256 =head1 AUTHOR
 257
 258 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 259
 260 =head1 LICENSE
 261
 262 This library is free software; you can redistribute it and/or modify it under
 263 the same terms as Perl itself.
 264
 265 =cut
 266
 267 1;
 268 # vim:et sw=4 sts=4 tw=0: