lib/DBIx/Class/Schema/Loader/DBI/Pg.pm

   1 package DBIx::Class::Schema::Loader::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   7     DBIx::Class::Schema::Loader::DBI
   8 /;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Class::C3;
  11
  12 our $VERSION = '0.07000';
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
  17 PostgreSQL Implementation.
  18
  19 =head1 SYNOPSIS
  20
  21   package My::Schema;
  22   use base qw/DBIx::Class::Schema::Loader/;
  23
  24   __PACKAGE__->loader_options( debug => 1 );
  25
  26   1;
  27
  28 =head1 DESCRIPTION
  29
  30 See L<DBIx::Class::Schema::Loader::Base>.
  31
  32 =cut
  33
  34 sub _setup {
  35     my $self = shift;
  36
  37     $self->next::method(@_);
  38
  39     $self->{db_schema} ||= 'public';
  40
  41     if (not defined $self->preserve_case) {
  42         $self->preserve_case(0);
  43     }
  44 }
  45
  46 sub _table_uniq_info {
  47     my ($self, $table) = @_;
  48
  49     # Use the default support if available
  50     return $self->next::method($table)
  51         if $DBD::Pg::VERSION >= 1.50;
  52
  53     my @uniqs;
  54     my $dbh = $self->schema->storage->dbh;
  55
  56     # Most of the SQL here is mostly based on
  57     #   Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
  58     #   John Siracusa to use his superior SQL code :)
  59
  60     my $attr_sth = $self->{_cache}->{pg_attr_sth} ||= $dbh->prepare(
  61         q{SELECT attname FROM pg_catalog.pg_attribute
  62         WHERE attrelid = ? AND attnum = ?}
  63     );
  64
  65     my $uniq_sth = $self->{_cache}->{pg_uniq_sth} ||= $dbh->prepare(
  66         q{SELECT x.indrelid, i.relname, x.indkey
  67         FROM
  68           pg_catalog.pg_index x
  69           JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
  70           JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
  71           JOIN pg_catalog.pg_constraint con ON con.conname = i.relname
  72           LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
  73         WHERE
  74           x.indisunique = 't' AND
  75           c.relkind     = 'r' AND
  76           i.relkind     = 'i' AND
  77           con.contype   = 'u' AND
  78           n.nspname     = ? AND
  79           c.relname     = ?}
  80     );
  81
  82     $uniq_sth->execute($self->db_schema, $table);
  83     while(my $row = $uniq_sth->fetchrow_arrayref) {
  84         my ($tableid, $indexname, $col_nums) = @$row;
  85         $col_nums =~ s/^\s+//;
  86         my @col_nums = split(/\s+/, $col_nums);
  87         my @col_names;
  88
  89         foreach (@col_nums) {
  90             $attr_sth->execute($tableid, $_);
  91             my $name_aref = $attr_sth->fetchrow_arrayref;
  92             push(@col_names, $name_aref->[0]) if $name_aref;
  93         }
  94
  95         if(!@col_names) {
  96             warn "Failed to parse UNIQUE constraint $indexname on $table";
  97         }
  98         else {
  99             push(@uniqs, [ $indexname => \@col_names ]);
 100         }
 101     }
 102
 103     return \@uniqs;
 104 }
 105
 106 sub _table_comment {
 107     my ( $self, $table ) = @_;
 108      my ($table_comment) = $self->schema->storage->dbh->selectrow_array(
 109         q{SELECT obj_description(oid)
 110             FROM pg_class
 111             WHERE relname=? AND relnamespace=(
 112                 SELECT oid FROM pg_namespace WHERE nspname=?)
 113         }, undef, $table, $self->db_schema
 114         );
 115     return $table_comment
 116 }
 117
 118
 119 sub _column_comment {
 120     my ( $self, $table, $column_number ) = @_;
 121      my ($table_oid) = $self->schema->storage->dbh->selectrow_array(
 122         q{SELECT oid
 123             FROM pg_class
 124             WHERE relname=? AND relnamespace=(
 125                 SELECT oid FROM pg_namespace WHERE nspname=?)
 126         }, undef, $table, $self->db_schema
 127         );
 128     return $self->schema->storage->dbh->selectrow_array('SELECT col_description(?,?)', undef, $table_oid,
 129     $column_number );
 130 }
 131
 132 # Make sure data_type's that don't need it don't have a 'size' column_info, and
 133 # set the correct precision for datetime and varbit types.
 134 sub _columns_info_for {
 135     my $self = shift;
 136     my ($table) = @_;
 137
 138     my $result = $self->next::method(@_);
 139
 140     while (my ($col, $info) = each %$result) {
 141         my $data_type = $info->{data_type};
 142
 143         # these types are fixed size
 144         if ($data_type =~
 145 /^(?:bigint|int8|bigserial|serial8|boolean|bool|box|bytea|cidr|circle|date|double precision|float8|inet|integer|int|int4|line|lseg|macaddr|money|path|point|polygon|real|float4|smallint|int2|serial|serial4|text)\z/i) {
 146             delete $info->{size};
 147         }
 148 # for datetime types, check if it has a precision or not
 149         elsif ($data_type =~ /^(?:interval|time|timestamp)\b/i) {
 150             if (lc($data_type) eq 'timestamp without time zone') {
 151                 $info->{data_type} = 'timestamp';
 152             }
 153
 154             my ($precision) = $self->schema->storage->dbh
 155                 ->selectrow_array(<<EOF, {}, $table, $col);
 156 SELECT datetime_precision
 157 FROM information_schema.columns
 158 WHERE table_name = ? and column_name = ?
 159 EOF
 160
 161             if ($data_type =~ /^time\b/i) {
 162                 if ((not $precision) || $precision !~ /^\d/) {
 163                     delete $info->{size};
 164                 }
 165                 else {
 166                     my ($integer_datetimes) = $self->schema->storage->dbh
 167                         ->selectrow_array('show integer_datetimes');
 168
 169                     my $max_precision =
 170                         $integer_datetimes =~ /^on\z/i ? 6 : 10;
 171
 172                     if ($precision == $max_precision) {
 173                         delete $info->{size};
 174                     }
 175                     else {
 176                         $info->{size} = $precision;
 177                     }
 178                 }
 179             }
 180             elsif ((not $precision) || $precision !~ /^\d/ || $precision == 6) {
 181                 delete $info->{size};
 182             }
 183             else {
 184                 $info->{size} = $precision;
 185             }
 186         }
 187         elsif ($data_type =~ /^(?:bit(?: varying)?|varbit)\z/i) {
 188             $info->{data_type} = 'varbit' if $data_type =~ /var/i;
 189
 190             my ($precision) = $self->schema->storage->dbh
 191                 ->selectrow_array(<<EOF, {}, $table, $col);
 192 SELECT character_maximum_length
 193 FROM information_schema.columns
 194 WHERE table_name = ? and column_name = ?
 195 EOF
 196
 197             $info->{size} = $precision if $precision;
 198
 199             $info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
 200         }
 201         elsif ($data_type =~ /^(?:numeric|decimal)\z/i && (my $size = $info->{size})) {
 202             $size =~ s/\s*//g;
 203
 204             my ($scale, $precision) = split /,/, $size;
 205
 206             $info->{size} = [ $precision, $scale ];
 207         }
 208         elsif (lc($data_type) eq 'character varying') {
 209             $info->{data_type} = 'varchar';
 210
 211             $info->{data_type} = 'text' if not $info->{size};
 212         }
 213         elsif (lc($data_type) eq 'character') {
 214             $info->{data_type} = 'char';
 215         }
 216
 217 # process SERIAL columns
 218         if (ref($info->{default_value}) eq 'SCALAR' && ${ $info->{default_value} } =~ /\bnextval\(['"](\w+)/i) {
 219             $info->{is_auto_increment} = 1;
 220             $info->{sequence}          = $1;
 221             delete $info->{default_value};
 222         }
 223
 224 # alias now() to current_timestamp for deploying to other DBs
 225         if (eval { lc ${ $info->{default_value} }||'' eq 'now()' }) {
 226             # do not use a ref to a constant, that breaks Data::Dump output
 227             ${$info->{default_value}} = 'current_timestamp';
 228         }
 229     }
 230
 231     return $result;
 232 }
 233
 234 =head1 SEE ALSO
 235
 236 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 237 L<DBIx::Class::Schema::Loader::DBI>
 238
 239 =head1 AUTHOR
 240
 241 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 242
 243 =head1 LICENSE
 244
 245 This library is free software; you can redistribute it and/or modify it under
 246 the same terms as Perl itself.
 247
 248 =cut
 249
 250 1;