lib/DBIx/Class/Schema/Loader/DBI/Oracle.pm

   1 package # hide from pause/cpan for now, as there's a permissions
   2         # issue and it's screwing the rest of the package
   3   DBIx::Class::Schema::Loader::DBI::Oracle;
   4
   5 use strict;
   6 use warnings;
   7 use base 'DBIx::Class::Schema::Loader::DBI';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use Class::C3;
  10
  11 our $VERSION = '0.04004';
  12
  13 =head1 NAME
  14
  15 DBIx::Class::Schema::Loader::DBI::Oracle - DBIx::Class::Schema::Loader::DBI
  16 Oracle Implementation.
  17
  18 =head1 SYNOPSIS
  19
  20   package My::Schema;
  21   use base qw/DBIx::Class::Schema::Loader/;
  22
  23   __PACKAGE__->loader_options( debug => 1 );
  24
  25   1;
  26
  27 =head1 DESCRIPTION
  28
  29 See L<DBIx::Class::Schema::Loader::Base>.
  30
  31 This module is considered experimental and not well tested yet.
  32
  33 =cut
  34
  35 sub _setup {
  36     my $self = shift;
  37
  38     $self->next::method(@_);
  39
  40     my $dbh = $self->schema->storage->dbh;
  41     $self->{db_schema} ||= $dbh->selectrow_array('SELECT USER FROM DUAL', {});
  42 }
  43
  44
  45 sub _table_columns {
  46     my ($self, $table) = @_;
  47
  48     my $dbh = $self->schema->storage->dbh;
  49
  50     my $sth = $dbh->prepare($self->schema->storage->sql_maker->select($table, undef, \'1 = 0'));
  51     $sth->execute;
  52     return \@{$sth->{NAME_lc}};
  53 }
  54
  55 sub _tables_list {
  56     my $self = shift;
  57
  58     my $dbh = $self->schema->storage->dbh;
  59
  60     my @tables;
  61     for my $table ( $dbh->tables(undef, $self->db_schema, '%', 'TABLE,VIEW') ) { #catalog, schema, table, type
  62         my $quoter = $dbh->get_info(29);
  63         $table =~ s/$quoter//g;
  64
  65         # remove "user." (schema) prefixes
  66         $table =~ s/\w+\.//;
  67
  68         next if $table eq 'PLAN_TABLE';
  69         $table = lc $table;
  70         push @tables, $1
  71           if $table =~ /\A(\w+)\z/;
  72     }
  73     return @tables;
  74 }
  75
  76 sub _table_uniq_info {
  77     my ($self, $table) = @_;
  78
  79     my $dbh = $self->schema->storage->dbh;
  80
  81     my $sth = $dbh->prepare_cached(
  82         q{
  83             SELECT constraint_name, ucc.column_name
  84             FROM user_constraints JOIN user_cons_columns ucc USING (constraint_name)
  85             WHERE ucc.table_name=? AND constraint_type='U'
  86         },
  87         {}, 1);
  88
  89     $sth->execute(uc $table);
  90     my %constr_names;
  91     while(my $constr = $sth->fetchrow_arrayref) {
  92         my $constr_name = lc $constr->[0];
  93         my $constr_def  = lc $constr->[1];
  94         $constr_name =~ s/\Q$self->{_quoter}\E//;
  95         $constr_def =~ s/\Q$self->{_quoter}\E//;
  96         push @{$constr_names{$constr_name}}, $constr_def;
  97     }
  98
  99     my @uniqs = map { [ $_ => $constr_names{$_} ] } keys %constr_names;
 100     return \@uniqs;
 101 }
 102
 103 sub _table_pk_info {
 104     my ($self, $table) = @_;
 105     return $self->next::method(uc $table);
 106 }
 107
 108 sub _table_fk_info {
 109     my ($self, $table) = @_;
 110
 111     my $rels = $self->next::method(uc $table);
 112
 113     foreach my $rel (@$rels) {
 114         $rel->{remote_table} = lc $rel->{remote_table};
 115     }
 116
 117     return $rels;
 118 }
 119
 120 sub _columns_info_for {
 121     my ($self, $table) = @_;
 122     return $self->next::method(uc $table);
 123 }
 124
 125 =head1 SEE ALSO
 126
 127 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 128 L<DBIx::Class::Schema::Loader::DBI>
 129
 130 =head1 AUTHOR
 131
 132 TSUNODA Kazuya C<drk@drk7.jp>
 133
 134 =cut
 135
 136 1;