lib/DBIx/Class/Schema/Loader/DBI/Oracle.pm

   1 package DBIx::Class::Schema::Loader::DBI::Oracle;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   7     DBIx::Class::Schema::Loader::DBI
   8 /;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Class::C3;
  11
  12 our $VERSION = '0.07000';
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema::Loader::DBI::Oracle - DBIx::Class::Schema::Loader::DBI
  17 Oracle Implementation.
  18
  19 =head1 DESCRIPTION
  20
  21 See L<DBIx::Class::Schema::Loader::Base>.
  22
  23 =cut
  24
  25 sub _setup {
  26     my $self = shift;
  27
  28     $self->next::method(@_);
  29
  30     my $dbh = $self->schema->storage->dbh;
  31
  32     my ($current_schema) = $dbh->selectrow_array('SELECT USER FROM DUAL', {});
  33
  34     $self->{db_schema} ||= $current_schema;
  35
  36     if (lc($self->db_schema) ne lc($current_schema)) {
  37         $dbh->do('ALTER SESSION SET current_schema=' . $self->db_schema);
  38     }
  39
  40     if (not defined $self->preserve_case) {
  41         $self->preserve_case(0);
  42     }
  43     elsif ($self->preserve_case) {
  44         $self->schema->storage->sql_maker->quote_char('"');
  45         $self->schema->storage->sql_maker->name_sep('.');
  46     }
  47 }
  48
  49 sub _table_as_sql {
  50     my ($self, $table) = @_;
  51
  52     return $self->_quote_table_name($table);
  53 }
  54
  55 sub _tables_list {
  56     my ($self, $opts) = @_;
  57
  58     my $dbh = $self->schema->storage->dbh;
  59
  60     my @tables;
  61     for my $table ( $dbh->tables(undef, $self->db_schema, '%', 'TABLE,VIEW') ) { #catalog, schema, table, type
  62         my $quoter = $dbh->get_info(29);
  63         $table =~ s/$quoter//g;
  64
  65         # remove "user." (schema) prefixes
  66         $table =~ s/\w+\.//;
  67
  68         next if $table eq 'PLAN_TABLE';
  69         $table = $self->_lc($table);
  70         push @tables, $1
  71           if $table =~ /\A(\w+)\z/;
  72     }
  73
  74     return $self->_filter_tables(\@tables, $opts);
  75 }
  76
  77 sub _table_columns {
  78     my ($self, $table) = @_;
  79
  80     my $dbh = $self->schema->storage->dbh;
  81
  82     my $sth = $dbh->column_info(undef, $self->db_schema, $self->_uc($table), '%');
  83
  84     return [ map $self->_lc($_->{COLUMN_NAME}), @{ $sth->fetchall_arrayref({ COLUMN_NAME => 1 }) || [] } ];
  85 }
  86
  87 sub _table_uniq_info {
  88     my ($self, $table) = @_;
  89
  90     my $dbh = $self->schema->storage->dbh;
  91
  92     my $sth = $dbh->prepare_cached(
  93         q{
  94             SELECT constraint_name, acc.column_name
  95             FROM all_constraints JOIN all_cons_columns acc USING (constraint_name)
  96             WHERE acc.table_name=? and acc.owner = ? AND constraint_type='U'
  97             ORDER BY acc.position
  98         },
  99         {}, 1);
 100
 101     $sth->execute($self->_uc($table),$self->{db_schema} );
 102     my %constr_names;
 103     while(my $constr = $sth->fetchrow_arrayref) {
 104         my $constr_name = $self->_lc($constr->[0]);
 105         my $constr_col  = $self->_lc($constr->[1]);
 106         $constr_name =~ s/\Q$self->{_quoter}\E//;
 107         $constr_col  =~ s/\Q$self->{_quoter}\E//;
 108         push @{$constr_names{$constr_name}}, $constr_col;
 109     }
 110
 111     my @uniqs = map { [ $_ => $constr_names{$_} ] } keys %constr_names;
 112     return \@uniqs;
 113 }
 114
 115 sub _table_pk_info {
 116     my ($self, $table) = (shift, shift);
 117
 118     return $self->next::method($self->_uc($table), @_);
 119 }
 120
 121 sub _table_fk_info {
 122     my ($self, $table) = (shift, shift);
 123
 124     my $rels = $self->next::method($self->_uc($table), @_);
 125
 126     foreach my $rel (@$rels) {
 127         $rel->{remote_table} = $self->_lc($rel->{remote_table});
 128     }
 129
 130     return $rels;
 131 }
 132
 133 sub _columns_info_for {
 134     my ($self, $table) = (shift, shift);
 135
 136     my $result = $self->next::method($self->_uc($table), @_);
 137
 138     my $dbh = $self->schema->storage->dbh;
 139
 140     local $dbh->{LongReadLen} = 100000;
 141     local $dbh->{LongTruncOk} = 1;
 142
 143     my $sth = $dbh->prepare_cached(q{
 144 SELECT atc.column_name, ut.trigger_body
 145 FROM all_triggers ut
 146 JOIN all_trigger_cols atc USING (trigger_name)
 147 WHERE atc.table_name = ?
 148 AND lower(column_usage) LIKE '%new%' AND lower(column_usage) LIKE '%out%'
 149 AND upper(trigger_type) LIKE '%BEFORE EACH ROW%' AND lower(triggering_event) LIKE '%insert%'
 150     }, {}, 1);
 151
 152     $sth->execute($self->_uc($table));
 153
 154     while (my ($col_name, $trigger_body) = $sth->fetchrow_array) {
 155         $col_name = $self->_lc($col_name);
 156
 157         $result->{$col_name}{is_auto_increment} = 1;
 158
 159         if (my ($seq_name) = $trigger_body =~ /"?(\w+)"?\.nextval/i) {
 160             $seq_name = $self->_lc($seq_name);
 161
 162             $result->{$col_name}{sequence} = $seq_name;
 163         }
 164     }
 165
 166     while (my ($col, $info) = each %$result) {
 167         no warnings 'uninitialized';
 168
 169         if ($info->{data_type} =~ /^(?:n?[cb]lob|long(?: raw)?|bfile|date|binary_(?:float|double)|rowid)\z/i) {
 170             delete $info->{size};
 171         }
 172
 173         if ($info->{data_type} =~ /^n(?:var)?char2?\z/i) {
 174             $info->{size} = $info->{size} / 2;
 175         }
 176         elsif (lc($info->{data_type}) eq 'number') {
 177             $info->{original}{data_type} = 'number';
 178             $info->{data_type}           = 'numeric';
 179
 180             if (eval { $info->{size}[0] == 38 && $info->{size}[1] == 0 }) {
 181                 $info->{original}{size} = $info->{size};
 182
 183                 $info->{data_type} = 'integer';
 184                 delete $info->{size};
 185             }
 186         }
 187         elsif (my ($precision) = $info->{data_type} =~ /^timestamp\((\d+)\)(?: with (?:local )?time zone)?\z/i) {
 188             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 189
 190             if ($precision == 6) {
 191                 delete $info->{size};
 192             }
 193             else {
 194                 $info->{size} = $precision;
 195             }
 196         }
 197         elsif (($precision) = $info->{data_type} =~ /^interval year\((\d+)\) to month\z/i) {
 198             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 199
 200             if ($precision == 2) {
 201                 delete $info->{size};
 202             }
 203             else {
 204                 $info->{size} = $precision;
 205             }
 206         }
 207         elsif (my ($day_precision, $second_precision) = $info->{data_type} =~ /^interval day\((\d+)\) to second\((\d+)\)\z/i) {
 208             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 209
 210             if ($day_precision == 2 && $second_precision == 6) {
 211                 delete $info->{size};
 212             }
 213             else {
 214                 $info->{size} = [ $day_precision, $second_precision ];
 215             }
 216         }
 217         elsif (lc($info->{data_type}) eq 'float') {
 218             $info->{original}{data_type} = 'float';
 219             $info->{original}{size}      = $info->{size};
 220
 221             if ($info->{size} <= 63) {
 222                 $info->{data_type} = 'real';
 223             }
 224             else {
 225                 $info->{data_type} = 'double precision';
 226             }
 227             delete $info->{size};
 228         }
 229         elsif (lc($info->{data_type}) eq 'urowid' && $info->{size} == 4000) {
 230             delete $info->{size};
 231         }
 232         elsif (lc($info->{data_type}) eq 'date') {
 233             $info->{data_type}           = 'datetime';
 234             $info->{original}{data_type} = 'date';
 235         }
 236         elsif (lc($info->{data_type}) eq 'binary_float') {
 237             $info->{data_type}           = 'real';
 238             $info->{original}{data_type} = 'binary_float';
 239         }
 240         elsif (lc($info->{data_type}) eq 'binary_double') {
 241             $info->{data_type}           = 'double precision';
 242             $info->{original}{data_type} = 'binary_double';
 243         }
 244
 245         if ((eval { lc(${ $info->{default_value} }) }||'') eq 'sysdate') {
 246             my $current_timestamp  = 'current_timestamp';
 247             $info->{default_value} = \$current_timestamp;
 248
 249             my $sysdate = 'sysdate';
 250             $info->{original}{default_value} = \$sysdate;
 251         }
 252     }
 253
 254     return $result;
 255 }
 256
 257 =head1 SEE ALSO
 258
 259 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 260 L<DBIx::Class::Schema::Loader::DBI>
 261
 262 =head1 AUTHOR
 263
 264 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 265
 266 =head1 LICENSE
 267
 268 This library is free software; you can redistribute it and/or modify it under
 269 the same terms as Perl itself.
 270
 271 =cut
 272
 273 1;
 274 # vim:et sts=4 sw=4 tw=0: