lib/DBIx/Class/Schema/Journal.pm

   1 package DBIx::Class::Schema::Journal;
   2
   3 use base qw/DBIx::Class/;
   4
   5 use Scalar::Util 'blessed';
   6 use DBIx::Class::Schema::Journal::DB;
   7 use Class::C3::Componentised ();
   8
   9 __PACKAGE__->mk_classdata('journal_storage_type');
  10 __PACKAGE__->mk_classdata('journal_connection');
  11 __PACKAGE__->mk_classdata('journal_deploy_on_connect');
  12 __PACKAGE__->mk_classdata('journal_sources'); ## [ source names ]
  13 __PACKAGE__->mk_classdata('journal_user'); ## [ class, field for user id ]
  14 __PACKAGE__->mk_classdata('journal_copy_sources');
  15 __PACKAGE__->mk_classdata('__journal_schema_prototype');
  16 __PACKAGE__->mk_classdata('_journal_schema'); ## schema object for journal
  17 __PACKAGE__->mk_classdata('journal_component');
  18 __PACKAGE__->mk_classdata('journal_nested_changesets');
  19
  20 use strict;
  21 use warnings;
  22
  23
  24 sub _journal_schema_prototype
  25 {
  26     my $self = shift;
  27     if (my $proto = $self->__journal_schema_prototype)
  28     {
  29           return $proto;
  30     }
  31     my $c = blessed($self)||$self;
  32     my $journal_schema_class = "${c}::_JOURNAL";
  33     Class::C3::Componentised->inject_base($journal_schema_class, 'DBIx::Class::Schema::Journal::DB');
  34     my $proto = $self->__journal_schema_prototype
  35     (
  36         $journal_schema_class->compose_namespace
  37         (
  38             $c.'::Journal'
  39         )
  40     );
  41     my $comp = $self->journal_component || "Journal";
  42
  43     ## Create auditlog+history per table
  44     my %j_sources = map { $_ => 1 } $self->journal_sources
  45                                       ? @{$self->journal_sources}
  46                                       : $self->sources;
  47
  48     foreach my $s_name ($self->sources)
  49     {
  50         next unless($j_sources{$s_name});
  51         $self->create_journal_for($s_name => $proto);
  52         $self->class($s_name)->load_components($comp);
  53     }
  54     return $proto;
  55 }
  56
  57 sub connection
  58 {
  59     my $self = shift;
  60     my $schema = $self->next::method(@_);
  61
  62     my $journal_schema = (ref $self||$self)->_journal_schema_prototype->clone;
  63
  64     if($self->journal_connection)
  65     {
  66         if($self->journal_storage_type)
  67         {
  68             $journal_schema->storage_type($self->journal_storage_type);
  69         }
  70         $journal_schema->connection(@{ $self->journal_connection });
  71     } else {
  72         $journal_schema->storage( $schema->storage );
  73     }
  74
  75     $self->_journal_schema($journal_schema);
  76
  77
  78     if ( $self->journal_nested_changesets ) {
  79         $self->_journal_schema->nested_changesets(1);
  80         die "FIXME nested changeset schema not yet supported... add parent_id to ChangeSet here";
  81     }
  82
  83     $self->journal_schema_deploy()
  84         if $self->journal_deploy_on_connect;
  85
  86     ## Set up relationship between changeset->user_id and this schema's user
  87     if(!@{$self->journal_user || []})
  88     {
  89         #warn "No Journal User set!"; # no need to warn, user_id is useful even without a rel
  90         return $schema;
  91     }
  92
  93     $self->_journal_schema->class('ChangeSet')->belongs_to('user', @{$self->journal_user});
  94     $self->_journal_schema->storage->disconnect();
  95
  96     return $schema;
  97 }
  98
  99 sub deploy
 100 {
 101     my ( $self, $sqlt_args, @args ) = @_;
 102
 103     $self->next::method($sqlt_args, @args);
 104
 105     $self->journal_schema_deploy($sqlt_args, @args);
 106 }
 107
 108 sub journal_schema_deploy
 109 {
 110     my ( $self, $sqlt_args, @args ) = @_;
 111
 112     $self->_journal_schema->deploy( $sqlt_args, @args );
 113 }
 114
 115 sub create_journal_for
 116 {
 117     my ($self, $s_name, $journal_schema) = @_;
 118
 119     my $source = $self->source($s_name);
 120
 121     foreach my $audit (qw(AuditLog AuditHistory)) {
 122         my $audit_source = $s_name.$audit;
 123         my $class = blessed($journal_schema) . "::$audit_source";
 124
 125         Class::C3::Componentised->inject_base($class, "DBIx::Class::Schema::Journal::DB::$audit");
 126
 127         $class->journal_define_table($source);
 128
 129         $journal_schema->register_class($audit_source, $class);
 130
 131         if ($self->journal_copy_sources)
 132         {
 133             $self->register_class($audit_source, $class);
 134         }
 135     }
 136 }
 137
 138 sub txn_do
 139 {
 140     my ($self, $user_code, @args) = @_;
 141
 142     my $jschema = $self->_journal_schema;
 143
 144     my $code = $user_code;
 145
 146     my $current_changeset = $jschema->_current_changeset;
 147     if ( !$current_changeset || $self->journal_nested_changesets )
 148     {
 149         my $current_changeset_ref = $jschema->_current_changeset_container;
 150
 151         unless ( $current_changeset_ref ) {
 152             # this is a hash because scalar refs can't be localized
 153             $current_changeset_ref = { };
 154             $jschema->_current_changeset_container($current_changeset_ref);
 155         }
 156
 157         # wrap the thunk with a new changeset creation
 158         $code = sub {
 159             my $changeset = $jschema->journal_create_changeset( parent_id => $current_changeset );
 160             local $current_changeset_ref->{changeset} = $changeset->id;
 161             $user_code->(@_);
 162         };
 163
 164     }
 165
 166     if ( $jschema->storage != $self->storage ) {
 167         my $inner_code = $code;
 168         $code = sub { $jschema->txn_do($inner_code, @_) };
 169     }
 170
 171     return $self->next::method($code, @args);
 172 }
 173
 174 sub changeset_user
 175 {
 176     my ($self, $userid) = @_;
 177
 178     return $self->_journal_schema->current_user() if(@_ == 1);
 179
 180     $self->_journal_schema->current_user($userid);
 181 }
 182
 183 sub changeset_session
 184 {
 185     my ($self, $sessionid) = @_;
 186
 187     return $self->_journal_schema->current_session() if(@_ == 1);
 188
 189     $self->_journal_schema->current_session($sessionid);
 190 }
 191
 192
 193 1;