lib/DBIx/Class/Schema/Journal.pm

   1 package DBIx::Class::Schema::Journal;
   2
   3 use base qw/DBIx::Class/;
   4
   5 use Scalar::Util 'blessed';
   6 use DBIx::Class::Schema::Journal::DB;
   7
   8 __PACKAGE__->mk_classdata('journal_storage_type');
   9 __PACKAGE__->mk_classdata('journal_connection');
  10 __PACKAGE__->mk_classdata('journal_deploy_on_connect');
  11 __PACKAGE__->mk_classdata('journal_sources'); ## [ source names ]
  12 __PACKAGE__->mk_classdata('journal_user'); ## [ class, field for user id ]
  13 __PACKAGE__->mk_classdata('_journal_schema'); ## schema object for journal
  14 __PACKAGE__->mk_classdata('journal_nested_changesets');
  15
  16 our $VERSION = '0.01';
  17
  18 use strict;
  19 use warnings;
  20
  21 # sub throw_exception
  22 # {
  23 # }
  24
  25 # sub exception_action
  26 # {
  27 #     my $self = shift;
  28 # #    print STDERR Carp::longmess;
  29
  30 #     $self->next::method(@_);
  31 # }
  32
  33 # sub load_classes
  34 # {
  35 #     my $class = shift;
  36
  37
  38 #     $class->next::method(@_);
  39
  40 # }
  41
  42 sub connection
  43 {
  44     my $self = shift;
  45     my $schema = $self->next::method(@_);
  46
  47 #   print STDERR join(":", $self->sources), "\n";
  48
  49     my $journal_schema = DBIx::Class::Schema::Journal::DB->compose_namespace(blessed($self) . '::Journal');
  50
  51     if($self->journal_connection)
  52     {
  53         if($self->journal_storage_type)
  54         {
  55             $journal_schema->storage_type($self->journal_storage_type);
  56         }
  57         $journal_schema->connection(@{ $self->journal_connection });
  58     } else {
  59         $journal_schema->storage( $schema->storage );
  60     }
  61
  62     $self->_journal_schema($journal_schema);
  63
  64
  65     ## Create auditlog+history per table
  66     my %j_sources = map { $_ => 1 } $self->journal_sources
  67                                       ? @{$self->journal_sources}
  68                                       : $self->sources;
  69
  70     foreach my $s_name ($self->sources)
  71     {
  72         next unless($j_sources{$s_name});
  73         $self->create_journal_for($s_name);
  74         $self->class($s_name)->load_components('Journal');
  75 #        print STDERR "$s_name :", $self->class($s_name), "\n";
  76     }
  77
  78     if ( $self->journal_nested_changesets ) {
  79         $self->_journal_schema->nested_changesets(1);
  80         die "FIXME nested changeset schema not yet supported... add parent_id to ChangeSet here";
  81     }
  82
  83     $self->journal_schema_deploy()
  84         if $self->journal_deploy_on_connect;
  85
  86     ## Set up relationship between changeset->user_id and this schema's user
  87     if(!@{$self->journal_user || []})
  88     {
  89         #warn "No Journal User set!"; # no need to warn, user_id is useful even without a rel
  90         return $schema;
  91     }
  92
  93     $self->_journal_schema->class('ChangeSet')->belongs_to('user', @{$self->journal_user});
  94     $self->_journal_schema->storage->disconnect();
  95
  96     return $schema;
  97 }
  98
  99 sub deploy
 100 {
 101     my ( $self, $sqlt_args, @args ) = @_;
 102
 103     $self->next::method($sqlt_args, @args);
 104
 105     $self->journal_schema_deploy($sqlt_args, @args);
 106 }
 107
 108 sub journal_schema_deploy
 109 {
 110     my ( $self, $sqlt_args, @args ) = @_;
 111
 112     $self->_journal_schema->deploy( $sqlt_args, @args );
 113 }
 114
 115 sub get_audit_log_class_name
 116 {
 117     my ($self, $sourcename) = @_;
 118
 119     return blessed($self->_journal_schema) . "::${sourcename}AuditLog";
 120 }
 121
 122 sub get_audit_history_class_name
 123 {
 124     my ($self, $sourcename) = @_;
 125
 126     return blessed($self->_journal_schema) . "::${sourcename}AuditHistory";
 127 }
 128
 129 sub create_journal_for
 130 {
 131     my ($self, $s_name) = @_;
 132
 133     my $source = $self->source($s_name);
 134     my $logclass = $self->get_audit_log_class_name($s_name);
 135
 136     DBIx::Class::Componentised->inject_base($logclass, 'DBIx::Class::Schema::Journal::DB::AuditLog');
 137     $logclass->journal_define_table($source);
 138
 139     my $log_source = "${s_name}AuditLog";
 140     $self->_journal_schema->register_class($log_source, $logclass);
 141
 142
 143     my $histclass = $self->get_audit_history_class_name($s_name);
 144     DBIx::Class::Componentised->inject_base($histclass, 'DBIx::Class::Schema::Journal::DB::AuditHistory');
 145     $histclass->table(lc($s_name) . "_audit_history");
 146 #    $histclass->result_source_instance->name(lc($s_name) . "_audit_hisory");
 147
 148     foreach my $column ( $source->columns ) {
 149         my $info = $source->column_info($column);
 150
 151         my %hist_info = %$info;
 152
 153         delete $hist_info{$_} for qw(
 154             is_foreign_key
 155             is_primary_key
 156             is_auto_increment
 157             default_value
 158         );
 159
 160         $hist_info{is_nullable} = 1;
 161
 162         $histclass->add_column($column => \%hist_info);
 163     }
 164
 165     my $hist_source = "${s_name}AuditHistory";
 166     $self->_journal_schema->register_class($hist_source, $histclass);
 167
 168     return ( $log_source, $hist_source );
 169 }
 170
 171 sub txn_do
 172 {
 173     my ($self, $user_code, @args) = @_;
 174
 175     my $jschema = $self->_journal_schema;
 176
 177     my $code = $user_code;
 178
 179     my $current_changeset = $jschema->_current_changeset;
 180     if ( !$current_changeset || $self->journal_nested_changesets )
 181     {
 182         my $current_changeset_ref = $jschema->_current_changeset_container;
 183
 184         unless ( $current_changeset_ref ) {
 185             # this is a hash because scalar refs can't be localized
 186             $current_changeset_ref = { };
 187             $jschema->_current_changeset_container($current_changeset_ref);
 188         }
 189
 190         # wrap the thunk with a new changeset creation
 191         $code = sub {
 192             my $changeset = $jschema->journal_create_changeset( parent_id => $current_changeset );
 193             local $current_changeset_ref->{changeset} = $changeset->id;
 194             $user_code->(@_);
 195         };
 196
 197     }
 198
 199     if ( $jschema->storage != $self->storage ) {
 200         my $inner_code = $code;
 201         $code = sub { $jschema->txn_do($inner_code, @_) };
 202     }
 203
 204     return $self->next::method($code, @args);
 205 }
 206
 207 sub changeset_user
 208 {
 209     my ($self, $userid) = @_;
 210
 211     return $self->_journal_schema->current_user() if(@_ == 1);
 212
 213     $self->_journal_schema->current_user($userid);
 214 }
 215
 216 sub changeset_session
 217 {
 218     my ($self, $sessionid) = @_;
 219
 220     return $self->_journal_schema->current_session() if(@_ == 1);
 221
 222     $self->_journal_schema->current_session($sessionid);
 223 }
 224
 225
 226 1;