lib/DBIx/Class/SQLMaker.pm

   1 package DBIx::Class::SQLMaker;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::SQLMaker - An SQL::Abstract-based SQL maker class
   9
  10 =head1 DESCRIPTION
  11
  12 This module is a subclass of L<SQL::Abstract> and includes a number of
  13 DBIC-specific workarounds, not yet suitable for inclusion into the
  14 L<SQL::Abstract> core. It also provides all (and more than) the functionality
  15 of L<SQL::Abstract::Limit>, see L<DBIx::Class::SQLMaker::LimitDialects> for
  16 more info.
  17
  18 Currently the enhancements to L<SQL::Abstract> are:
  19
  20 =over
  21
  22 =item * Support for C<JOIN> statements (via extended C<table/from> support)
  23
  24 =item * Support of functions in C<SELECT> lists
  25
  26 =item * C<GROUP BY>/C<HAVING> support (via extensions to the order_by parameter)
  27
  28 =item * Support of C<...FOR UPDATE> type of select statement modifiers
  29
  30 =back
  31
  32 =cut
  33
  34 use base qw/
  35   DBIx::Class::SQLMaker::LimitDialects
  36   SQL::Abstract
  37   DBIx::Class
  38 /;
  39 use mro 'c3';
  40
  41 use Sub::Name 'subname';
  42 use DBIx::Class::Carp;
  43 use namespace::clean;
  44
  45 __PACKAGE__->mk_group_accessors (simple => qw/quote_char name_sep limit_dialect/);
  46
  47 # for when I need a normalized l/r pair
  48 sub _quote_chars {
  49   map
  50     { defined $_ ? $_ : '' }
  51     ( ref $_[0]->{quote_char} ? (@{$_[0]->{quote_char}}) : ( ($_[0]->{quote_char}) x 2 ) )
  52   ;
  53 }
  54
  55 # FIXME when we bring in the storage weaklink, check its schema
  56 # weaklink and channel through $schema->throw_exception
  57 sub throw_exception { DBIx::Class::Exception->throw($_[1]) }
  58
  59 BEGIN {
  60   # reinstall the belch()/puke() functions of SQL::Abstract with custom versions
  61   # that use DBIx::Class::Carp/DBIx::Class::Exception instead of plain Carp
  62   no warnings qw/redefine/;
  63
  64   *SQL::Abstract::belch = subname 'SQL::Abstract::belch' => sub (@) {
  65     my($func) = (caller(1))[3];
  66     carp "[$func] Warning: ", @_;
  67   };
  68
  69   *SQL::Abstract::puke = subname 'SQL::Abstract::puke' => sub (@) {
  70     my($func) = (caller(1))[3];
  71     __PACKAGE__->throw_exception("[$func] Fatal: " . join ('',  @_));
  72   };
  73 }
  74
  75 # the "oh noes offset/top without limit" constant
  76 # limited to 31 bits for sanity (and consistency,
  77 # since it may be handed to the like of sprintf %u)
  78 #
  79 # Also *some* builds of SQLite fail the test
  80 #   some_column BETWEEN ? AND ?: 1, 4294967295
  81 # with the proper integer bind attrs
  82 #
  83 # Implemented as a method, since ::Storage::DBI also
  84 # refers to it (i.e. for the case of software_limit or
  85 # as the value to abuse with MSSQL ordered subqueries)
  86 sub __max_int () { 0x7FFFFFFF };
  87
  88 # we ne longer need to check this - DBIC has ways of dealing with it
  89 # specifically ::Storage::DBI::_resolve_bindattrs()
  90 sub _assert_bindval_matches_bindtype () { 1 };
  91
  92 # poor man's de-qualifier
  93 sub _quote {
  94   $_[0]->next::method( ( $_[0]{_dequalify_idents} and ! ref $_[1] )
  95     ? $_[1] =~ / ([^\.]+) $ /x
  96     : $_[1]
  97   );
  98 }
  99
 100 sub _where_op_NEST {
 101   carp_unique ("-nest in search conditions is deprecated, you most probably wanted:\n"
 102       .q|{..., -and => [ \%cond0, \@cond1, \'cond2', \[ 'cond3', [ col => bind ] ], etc. ], ... }|
 103   );
 104
 105   shift->next::method(@_);
 106 }
 107
 108 # Handle limit-dialect selection
 109 sub select {
 110   my ($self, $table, $fields, $where, $rs_attrs, $limit, $offset) = @_;
 111
 112
 113   ($fields, @{$self->{select_bind}}) = $self->_recurse_fields($fields);
 114
 115   if (defined $offset) {
 116     $self->throw_exception('A supplied offset must be a non-negative integer')
 117       if ( $offset =~ /\D/ or $offset < 0 );
 118   }
 119   $offset ||= 0;
 120
 121   if (defined $limit) {
 122     $self->throw_exception('A supplied limit must be a positive integer')
 123       if ( $limit =~ /\D/ or $limit <= 0 );
 124   }
 125   elsif ($offset) {
 126     $limit = $self->__max_int;
 127   }
 128
 129
 130   my ($sql, @bind);
 131   if ($limit) {
 132     # this is legacy code-flow from SQLA::Limit, it is not set in stone
 133
 134     ($sql, @bind) = $self->next::method ($table, $fields, $where);
 135
 136     my $limiter;
 137
 138     if( $limiter = $self->can ('emulate_limit') ) {
 139       carp_unique(
 140         'Support for the legacy emulate_limit() mechanism inherited from '
 141       . 'SQL::Abstract::Limit has been deprecated, and will be removed when '
 142       . 'DBIC transitions to Data::Query. If your code uses this type of '
 143       . 'limit specification please file an RT and provide the source of '
 144       . 'your emulate_limit() implementation, so an acceptable upgrade-path '
 145       . 'can be devised'
 146       );
 147     }
 148     else {
 149       my $dialect = $self->limit_dialect
 150         or $self->throw_exception( "Unable to generate SQL-limit - no limit dialect specified on $self" );
 151
 152       $limiter = $self->can ("_$dialect")
 153         or $self->throw_exception(__PACKAGE__ . " does not implement the requested dialect '$dialect'");
 154     }
 155
 156     $sql = $self->$limiter (
 157       $sql,
 158       { %{$rs_attrs||{}}, _selector_sql => $fields },
 159       $limit,
 160       $offset
 161     );
 162   }
 163   else {
 164     ($sql, @bind) = $self->next::method ($table, $fields, $where, $rs_attrs);
 165   }
 166
 167   push @{$self->{where_bind}}, @bind;
 168
 169 # this *must* be called, otherwise extra binds will remain in the sql-maker
 170   my @all_bind = $self->_assemble_binds;
 171
 172   $sql .= $self->_lock_select ($rs_attrs->{for})
 173     if $rs_attrs->{for};
 174
 175   return wantarray ? ($sql, @all_bind) : $sql;
 176 }
 177
 178 sub _assemble_binds {
 179   my $self = shift;
 180   return map { @{ (delete $self->{"${_}_bind"}) || [] } } (qw/pre_select select from where group having order limit/);
 181 }
 182
 183 my $for_syntax = {
 184   update => 'FOR UPDATE',
 185   shared => 'FOR SHARE',
 186 };
 187 sub _lock_select {
 188   my ($self, $type) = @_;
 189
 190   my $sql;
 191   if (ref($type) eq 'SCALAR') {
 192     $sql = "FOR $$type";
 193   }
 194   else {
 195     $sql = $for_syntax->{$type} || $self->throw_exception( "Unknown SELECT .. FOR type '$type' requested" );
 196   }
 197
 198   return " $sql";
 199 }
 200
 201 # Handle default inserts
 202 sub insert {
 203 # optimized due to hotttnesss
 204 #  my ($self, $table, $data, $options) = @_;
 205
 206   # SQLA will emit INSERT INTO $table ( ) VALUES ( )
 207   # which is sadly understood only by MySQL. Change default behavior here,
 208   # until SQLA2 comes with proper dialect support
 209   if (! $_[2] or (ref $_[2] eq 'HASH' and !keys %{$_[2]} ) ) {
 210     my @bind;
 211     my $sql = sprintf(
 212       'INSERT INTO %s DEFAULT VALUES', $_[0]->_quote($_[1])
 213     );
 214
 215     if ( ($_[3]||{})->{returning} ) {
 216       my $s;
 217       ($s, @bind) = $_[0]->_insert_returning ($_[3]);
 218       $sql .= $s;
 219     }
 220
 221     return ($sql, @bind);
 222   }
 223
 224   next::method(@_);
 225 }
 226
 227 sub _recurse_fields {
 228   my ($self, $fields) = @_;
 229   my $ref = ref $fields;
 230   return $self->_quote($fields) unless $ref;
 231   return $$fields if $ref eq 'SCALAR';
 232
 233   if ($ref eq 'ARRAY') {
 234     my (@select, @bind);
 235     for my $field (@$fields) {
 236       my ($select, @new_bind) = $self->_recurse_fields($field);
 237       push @select, $select;
 238       push @bind, @new_bind;
 239     }
 240     return (join(', ', @select), @bind);
 241   }
 242   elsif ($ref eq 'HASH') {
 243     my %hash = %$fields;  # shallow copy
 244
 245     my $as = delete $hash{-as};   # if supplied
 246
 247     my ($func, $rhs, @toomany) = %hash;
 248
 249     # there should be only one pair
 250     if (@toomany) {
 251       $self->throw_exception( "Malformed select argument - too many keys in hash: " . join (',', keys %$fields ) );
 252     }
 253
 254     if (lc ($func) eq 'distinct' && ref $rhs eq 'ARRAY' && @$rhs > 1) {
 255       $self->throw_exception (
 256         'The select => { distinct => ... } syntax is not supported for multiple columns.'
 257        .' Instead please use { group_by => [ qw/' . (join ' ', @$rhs) . '/ ] }'
 258        .' or { select => [ qw/' . (join ' ', @$rhs) . '/ ], distinct => 1 }'
 259       );
 260     }
 261
 262     my ($rhs_sql, @rhs_bind) = $self->_recurse_fields($rhs);
 263     my $select = sprintf ('%s( %s )%s',
 264       $self->_sqlcase($func),
 265       $rhs_sql,
 266       $as
 267         ? sprintf (' %s %s', $self->_sqlcase('as'), $self->_quote ($as) )
 268         : ''
 269     );
 270
 271     return ($select, @rhs_bind);
 272   }
 273   elsif ( $ref eq 'REF' and ref($$fields) eq 'ARRAY' ) {
 274     return @{$$fields};
 275   }
 276   else {
 277     $self->throw_exception( $ref . qq{ unexpected in _recurse_fields()} );
 278   }
 279 }
 280
 281
 282 # this used to be a part of _order_by but is broken out for clarity.
 283 # What we have been doing forever is hijacking the $order arg of
 284 # SQLA::select to pass in arbitrary pieces of data (first the group_by,
 285 # then pretty much the entire resultset attr-hash, as more and more
 286 # things in the SQLA space need to have more info about the $rs they
 287 # create SQL for. The alternative would be to keep expanding the
 288 # signature of _select with more and more positional parameters, which
 289 # is just gross. All hail SQLA2!
 290 sub _parse_rs_attrs {
 291   my ($self, $arg) = @_;
 292
 293   my $sql = '';
 294
 295   if ($arg->{group_by}) {
 296     if ( my ($group_sql, @group_bind) = $self->_recurse_fields($arg->{group_by}) ) {
 297       $sql .= $self->_sqlcase(' group by ') . $group_sql;
 298       push @{$self->{group_bind}}, @group_bind;
 299     }
 300   }
 301
 302   if (defined $arg->{having}) {
 303     my ($frag, @bind) = $self->_recurse_where($arg->{having});
 304     push(@{$self->{having_bind}}, @bind);
 305     $sql .= $self->_sqlcase(' having ') . $frag;
 306   }
 307
 308   if (defined $arg->{order_by}) {
 309     $sql .= $self->_order_by ($arg->{order_by});
 310   }
 311
 312   return $sql;
 313 }
 314
 315 sub _order_by {
 316   my ($self, $arg) = @_;
 317
 318   # check that we are not called in legacy mode (order_by as 4th argument)
 319   if (ref $arg eq 'HASH' and not grep { $_ =~ /^-(?:desc|asc)/i } keys %$arg ) {
 320     return $self->_parse_rs_attrs ($arg);
 321   }
 322   else {
 323     my ($sql, @bind) = $self->next::method($arg);
 324     push @{$self->{order_bind}}, @bind;
 325     return $sql;
 326   }
 327 }
 328
 329 sub _split_order_chunk {
 330   my ($self, $chunk) = @_;
 331
 332   # strip off sort modifiers, but always succeed, so $1 gets reset
 333   $chunk =~ s/ (?: \s+ (ASC|DESC) )? \s* $//ix;
 334
 335   return (
 336     $chunk,
 337     ( $1 and uc($1) eq 'DESC' ) ? 1 : 0,
 338   );
 339 }
 340
 341 sub _table {
 342 # optimized due to hotttnesss
 343 #  my ($self, $from) = @_;
 344   if (my $ref = ref $_[1] ) {
 345     if ($ref eq 'ARRAY') {
 346       return $_[0]->_recurse_from(@{$_[1]});
 347     }
 348     elsif ($ref eq 'HASH') {
 349       return $_[0]->_recurse_from($_[1]);
 350     }
 351     elsif ($ref eq 'REF' && ref ${$_[1]} eq 'ARRAY') {
 352       my ($sql, @bind) = @{ ${$_[1]} };
 353       push @{$_[0]->{from_bind}}, @bind;
 354       return $sql
 355     }
 356   }
 357   return $_[0]->next::method ($_[1]);
 358 }
 359
 360 sub _generate_join_clause {
 361     my ($self, $join_type) = @_;
 362
 363     $join_type = $self->{_default_jointype}
 364       if ! defined $join_type;
 365
 366     return sprintf ('%s JOIN ',
 367       $join_type ?  $self->_sqlcase($join_type) : ''
 368     );
 369 }
 370
 371 sub _recurse_from {
 372   my $self = shift;
 373   return join (' ', $self->_gen_from_blocks(@_) );
 374 }
 375
 376 sub _gen_from_blocks {
 377   my ($self, $from, @joins) = @_;
 378
 379   my @fchunks = $self->_from_chunk_to_sql($from);
 380
 381   for (@joins) {
 382     my ($to, $on) = @$_;
 383
 384     # check whether a join type exists
 385     my $to_jt = ref($to) eq 'ARRAY' ? $to->[0] : $to;
 386     my $join_type;
 387     if (ref($to_jt) eq 'HASH' and defined($to_jt->{-join_type})) {
 388       $join_type = $to_jt->{-join_type};
 389       $join_type =~ s/^\s+ | \s+$//xg;
 390     }
 391
 392     my @j = $self->_generate_join_clause( $join_type );
 393
 394     if (ref $to eq 'ARRAY') {
 395       push(@j, '(', $self->_recurse_from(@$to), ')');
 396     }
 397     else {
 398       push(@j, $self->_from_chunk_to_sql($to));
 399     }
 400
 401     my ($sql, @bind) = $self->_join_condition($on);
 402     push(@j, ' ON ', $sql);
 403     push @{$self->{from_bind}}, @bind;
 404
 405     push @fchunks, join '', @j;
 406   }
 407
 408   return @fchunks;
 409 }
 410
 411 sub _from_chunk_to_sql {
 412   my ($self, $fromspec) = @_;
 413
 414   return join (' ', do {
 415     if (! ref $fromspec) {
 416       $self->_quote($fromspec);
 417     }
 418     elsif (ref $fromspec eq 'SCALAR') {
 419       $$fromspec;
 420     }
 421     elsif (ref $fromspec eq 'REF' and ref $$fromspec eq 'ARRAY') {
 422       push @{$self->{from_bind}}, @{$$fromspec}[1..$#$$fromspec];
 423       $$fromspec->[0];
 424     }
 425     elsif (ref $fromspec eq 'HASH') {
 426       my ($as, $table, $toomuch) = ( map
 427         { $_ => $fromspec->{$_} }
 428         ( grep { $_ !~ /^\-/ } keys %$fromspec )
 429       );
 430
 431       $self->throw_exception( "Only one table/as pair expected in from-spec but an exra '$toomuch' key present" )
 432         if defined $toomuch;
 433
 434       ($self->_from_chunk_to_sql($table), $self->_quote($as) );
 435     }
 436     else {
 437       $self->throw_exception('Unsupported from refkind: ' . ref $fromspec );
 438     }
 439   });
 440 }
 441
 442 sub _join_condition {
 443   my ($self, $cond) = @_;
 444
 445   # Backcompat for the old days when a plain hashref
 446   # { 't1.col1' => 't2.col2' } meant ON t1.col1 = t2.col2
 447   # Once things settle we should start warning here so that
 448   # folks unroll their hacks
 449   if (
 450     ref $cond eq 'HASH'
 451       and
 452     keys %$cond == 1
 453       and
 454     (keys %$cond)[0] =~ /\./
 455       and
 456     ! ref ( (values %$cond)[0] )
 457   ) {
 458     $cond = { keys %$cond => { -ident => values %$cond } }
 459   }
 460   elsif ( ref $cond eq 'ARRAY' ) {
 461     # do our own ORing so that the hashref-shim above is invoked
 462     my @parts;
 463     my @binds;
 464     foreach my $c (@$cond) {
 465       my ($sql, @bind) = $self->_join_condition($c);
 466       push @binds, @bind;
 467       push @parts, $sql;
 468     }
 469     return join(' OR ', @parts), @binds;
 470   }
 471
 472   return $self->_recurse_where($cond);
 473 }
 474
 475 # This is hideously ugly, but SQLA does not understand multicol IN expressions
 476 # FIXME TEMPORARY - DQ should have native syntax for this
 477 # moved here to raise API questions
 478 #
 479 # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
 480 sub _where_op_multicolumn_in {
 481   my ($self, $lhs, $rhs) = @_;
 482
 483   if (! ref $lhs or ref $lhs eq 'ARRAY') {
 484     my (@sql, @bind);
 485     for (ref $lhs ? @$lhs : $lhs) {
 486       if (! ref $_) {
 487         push @sql, $self->_quote($_);
 488       }
 489       elsif (ref $_ eq 'SCALAR') {
 490         push @sql, $$_;
 491       }
 492       elsif (ref $_ eq 'REF' and ref $$_ eq 'ARRAY') {
 493         my ($s, @b) = @$$_;
 494         push @sql, $s;
 495         push @bind, @b;
 496       }
 497       else {
 498         $self->throw_exception("ARRAY of @{[ ref $_ ]}es unsupported for multicolumn IN lhs...");
 499       }
 500     }
 501     $lhs = \[ join(', ', @sql), @bind];
 502   }
 503   elsif (ref $lhs eq 'SCALAR') {
 504     $lhs = \[ $$lhs ];
 505   }
 506   elsif (ref $lhs eq 'REF' and ref $$lhs eq 'ARRAY' ) {
 507     # noop
 508   }
 509   else {
 510     $self->throw_exception( ref($lhs) . "es unsupported for multicolumn IN lhs...");
 511   }
 512
 513   # is this proper...?
 514   $rhs = \[ $self->_recurse_where($rhs) ];
 515
 516   for ($lhs, $rhs) {
 517     $$_->[0] = "( $$_->[0] )"
 518       unless $$_->[0] =~ /^ \s* \( .* \) \s* $/xs;
 519   }
 520
 521   \[ join( ' IN ', shift @$$lhs, shift @$$rhs ), @$$lhs, @$$rhs ];
 522 }
 523
 524 1;
 525
 526 =head1 AUTHORS
 527
 528 See L<DBIx::Class/CONTRIBUTORS>.
 529
 530 =head1 LICENSE
 531
 532 You may distribute this code under the same terms as Perl itself.
 533
 534 =cut