lib/DBIx/Class/Row.pm

   1 package DBIx::Class::Row;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class/;
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util ();
   9 use Scope::Guard;
  10
  11 __PACKAGE__->mk_group_accessors('simple' => qw/_source_handle/);
  12
  13 =head1 NAME
  14
  15 DBIx::Class::Row - Basic row methods
  16
  17 =head1 SYNOPSIS
  18
  19 =head1 DESCRIPTION
  20
  21 This class is responsible for defining and doing basic operations on rows
  22 derived from L<DBIx::Class::ResultSource> objects.
  23
  24 Row objects are returned from L<DBIx::Class::ResultSet>s using the
  25 L<create|DBIx::Class::ResultSet/create>, L<find|DBIx::Class::ResultSet/find>,
  26 L<next|DBIx::Class::ResultSet/next> and L<all|DBIx::Class::ResultSet/all> methods,
  27 as well as invocations of 'single' (
  28 L<belongs_to|DBIx::Class::Relationship/belongs_to>,
  29 L<has_one|DBIx::Class::Relationship/has_one> or
  30 L<might_have|DBIx::Class::Relationship/might_have>)
  31 relationship accessors of L<DBIx::Class::Row> objects.
  32
  33 =head1 METHODS
  34
  35 =head2 new
  36
  37   my $row = My::Class->new(\%attrs);
  38
  39   my $row = $schema->resultset('MySource')->new(\%colsandvalues);
  40
  41 =over
  42
  43 =item Arguments: \%attrs or \%colsandvalues
  44
  45 =item Returns: A Row object
  46
  47 =back
  48
  49 While you can create a new row object by calling C<new> directly on
  50 this class, you are better off calling it on a
  51 L<DBIx::Class::ResultSet> object.
  52
  53 When calling it directly, you will not get a complete, usable row
  54 object until you pass or set the C<source_handle> attribute, to a
  55 L<DBIx::Class::ResultSource> instance that is attached to a
  56 L<DBIx::Class::Schema> with a valid connection.
  57
  58 C<$attrs> is a hashref of column name, value data. It can also contain
  59 some other attributes such as the C<source_handle>.
  60
  61 Passing an object, or an arrayref of objects as a value will call
  62 L<DBIx::Class::Relationship::Base/set_from_related> for you. When
  63 passed a hashref or an arrayref of hashrefs as the value, these will
  64 be turned into objects via new_related, and treated as if you had
  65 passed objects.
  66
  67 For a more involved explanation, see L<DBIx::Class::ResultSet/create>.
  68
  69 =cut
  70
  71 ## It needs to store the new objects somewhere, and call insert on that list later when insert is called on this object. We may need an accessor for these so the user can retrieve them, if just doing ->new().
  72 ## This only works because DBIC doesnt yet care to check whether the new_related objects have been passed all their mandatory columns
  73 ## When doing the later insert, we need to make sure the PKs are set.
  74 ## using _relationship_data in new and funky ways..
  75 ## check Relationship::CascadeActions and Relationship::Accessor for compat
  76 ## tests!
  77
  78 sub __new_related_find_or_new_helper {
  79   my ($self, $relname, $data) = @_;
  80   if ($self->__their_pk_needs_us($relname, $data)) {
  81     return $self->result_source
  82                 ->related_source($relname)
  83                 ->resultset
  84                 ->new_result($data);
  85   }
  86   if ($self->result_source->pk_depends_on($relname, $data)) {
  87     return $self->result_source
  88                 ->related_source($relname)
  89                 ->resultset
  90                 ->find_or_create($data);
  91   }
  92   return $self->find_or_new_related($relname, $data);
  93 }
  94
  95 sub __their_pk_needs_us { # this should maybe be in resultsource.
  96   my ($self, $relname, $data) = @_;
  97   my $source = $self->result_source;
  98   my $reverse = $source->reverse_relationship_info($relname);
  99   my $rel_source = $source->related_source($relname);
 100   my $us = { $self->get_columns };
 101   foreach my $key (keys %$reverse) {
 102     # if their primary key depends on us, then we have to
 103     # just create a result and we'll fill it out afterwards
 104     return 1 if $rel_source->pk_depends_on($key, $us);
 105   }
 106   return 0;
 107 }
 108
 109 sub new {
 110   my ($class, $attrs) = @_;
 111   $class = ref $class if ref $class;
 112
 113   my $new = {
 114       _column_data          => {},
 115   };
 116   bless $new, $class;
 117
 118   if (my $handle = delete $attrs->{-source_handle}) {
 119     $new->_source_handle($handle);
 120   }
 121
 122   my $source;
 123   if ($source = delete $attrs->{-result_source}) {
 124     $new->result_source($source);
 125   }
 126
 127   if ($attrs) {
 128     $new->throw_exception("attrs must be a hashref")
 129       unless ref($attrs) eq 'HASH';
 130
 131     my ($related,$inflated);
 132     ## Pretend all the rels are actual objects, unset below if not, for insert() to fix
 133     $new->{_rel_in_storage} = 1;
 134
 135     foreach my $key (keys %$attrs) {
 136       if (ref $attrs->{$key}) {
 137         ## Can we extract this lot to use with update(_or .. ) ?
 138         confess "Can't do multi-create without result source" unless $source;
 139         my $info = $source->relationship_info($key);
 140         if ($info && $info->{attrs}{accessor}
 141           && $info->{attrs}{accessor} eq 'single')
 142         {
 143           my $rel_obj = delete $attrs->{$key};
 144           if(!Scalar::Util::blessed($rel_obj)) {
 145             $rel_obj = $new->__new_related_find_or_new_helper($key, $rel_obj);
 146           }
 147
 148           $new->{_rel_in_storage} = 0 unless ($rel_obj->in_storage);
 149
 150           $new->set_from_related($key, $rel_obj) if $rel_obj->in_storage;
 151           $related->{$key} = $rel_obj;
 152           next;
 153         } elsif ($info && $info->{attrs}{accessor}
 154             && $info->{attrs}{accessor} eq 'multi'
 155             && ref $attrs->{$key} eq 'ARRAY') {
 156           my $others = delete $attrs->{$key};
 157           foreach my $rel_obj (@$others) {
 158             if(!Scalar::Util::blessed($rel_obj)) {
 159               $rel_obj = $new->__new_related_find_or_new_helper($key, $rel_obj);
 160             }
 161
 162             $new->{_rel_in_storage} = 0 unless ($rel_obj->in_storage);
 163             $new->set_from_related($key, $rel_obj) if $rel_obj->in_storage;
 164           }
 165           $related->{$key} = $others;
 166           next;
 167         } elsif ($info && $info->{attrs}{accessor}
 168           && $info->{attrs}{accessor} eq 'filter')
 169         {
 170           ## 'filter' should disappear and get merged in with 'single' above!
 171           my $rel_obj = delete $attrs->{$key};
 172           if(!Scalar::Util::blessed($rel_obj)) {
 173             $rel_obj = $new->__new_related_find_or_new_helper($key, $rel_obj);
 174           }
 175           $new->{_rel_in_storage} = 0 unless ($rel_obj->in_storage);
 176           $inflated->{$key} = $rel_obj;
 177           next;
 178         } elsif ($class->has_column($key)
 179             && $class->column_info($key)->{_inflate_info}) {
 180           $inflated->{$key} = $attrs->{$key};
 181           next;
 182         }
 183       }
 184       $new->throw_exception("No such column $key on $class")
 185         unless $class->has_column($key);
 186       $new->store_column($key => $attrs->{$key});
 187     }
 188
 189     $new->{_relationship_data} = $related if $related;
 190     $new->{_inflated_column} = $inflated if $inflated;
 191   }
 192
 193   return $new;
 194 }
 195
 196 =head2 insert
 197
 198   $row->insert;
 199
 200 =over
 201
 202 =item Arguments: none
 203
 204 =item Returns: The Row object
 205
 206 =back
 207
 208 Inserts an object previously created by L</new> into the database if
 209 it isn't already in there. Returns the object itself. Requires the
 210 object's result source to be set, or the class to have a
 211 result_source_instance method. To insert an entirely new row into
 212 the database, use C<create> (see L<DBIx::Class::ResultSet/create>).
 213
 214 To fetch an uninserted row object, call
 215 L<new|DBIx::Class::ResultSet/new> on a resultset.
 216
 217 This will also insert any uninserted, related objects held inside this
 218 one, see L<DBIx::Class::ResultSet/create> for more details.
 219
 220 =cut
 221
 222 sub insert {
 223   my ($self) = @_;
 224   return $self if $self->in_storage;
 225   my $source = $self->result_source;
 226   $source ||=  $self->result_source($self->result_source_instance)
 227     if $self->can('result_source_instance');
 228   $self->throw_exception("No result_source set on this object; can't insert")
 229     unless $source;
 230
 231   my $rollback_guard;
 232
 233   # Check if we stored uninserted relobjs here in new()
 234   my %related_stuff = (%{$self->{_relationship_data} || {}},
 235                        %{$self->{_inflated_column} || {}});
 236
 237   if(!$self->{_rel_in_storage}) {
 238
 239     # The guard will save us if we blow out of this scope via die
 240     $rollback_guard = $source->storage->txn_scope_guard;
 241
 242     ## Should all be in relationship_data, but we need to get rid of the
 243     ## 'filter' reltype..
 244     ## These are the FK rels, need their IDs for the insert.
 245
 246     my @pri = $self->primary_columns;
 247
 248     REL: foreach my $relname (keys %related_stuff) {
 249
 250       my $rel_obj = $related_stuff{$relname};
 251
 252       next REL unless (Scalar::Util::blessed($rel_obj)
 253                        && $rel_obj->isa('DBIx::Class::Row'));
 254
 255       next REL unless $source->pk_depends_on(
 256                         $relname, { $rel_obj->get_columns }
 257                       );
 258
 259       $rel_obj->insert();
 260       $self->set_from_related($relname, $rel_obj);
 261       delete $related_stuff{$relname};
 262     }
 263   }
 264
 265   my $updated_cols = $source->storage->insert($source, { $self->get_columns });
 266   $self->set_columns($updated_cols);
 267
 268   ## PK::Auto
 269   my @auto_pri = grep {
 270                    !defined $self->get_column($_) ||
 271                    ref($self->get_column($_)) eq 'SCALAR'
 272                  } $self->primary_columns;
 273
 274   if (@auto_pri) {
 275     #$self->throw_exception( "More than one possible key found for auto-inc on ".ref $self )
 276     #  if defined $too_many;
 277
 278     my $storage = $self->result_source->storage;
 279     $self->throw_exception( "Missing primary key but Storage doesn't support last_insert_id" )
 280       unless $storage->can('last_insert_id');
 281     my @ids = $storage->last_insert_id($self->result_source,@auto_pri);
 282     $self->throw_exception( "Can't get last insert id" )
 283       unless (@ids == @auto_pri);
 284     $self->store_column($auto_pri[$_] => $ids[$_]) for 0 .. $#ids;
 285   }
 286
 287   $self->{_dirty_columns} = {};
 288   $self->{related_resultsets} = {};
 289
 290   if(!$self->{_rel_in_storage}) {
 291     ## Now do the has_many rels, that need $selfs ID.
 292     foreach my $relname (keys %related_stuff) {
 293       my $rel_obj = $related_stuff{$relname};
 294       my @cands;
 295       if (Scalar::Util::blessed($rel_obj)
 296           && $rel_obj->isa('DBIx::Class::Row')) {
 297         @cands = ($rel_obj);
 298       } elsif (ref $rel_obj eq 'ARRAY') {
 299         @cands = @$rel_obj;
 300       }
 301       if (@cands) {
 302         my $reverse = $source->reverse_relationship_info($relname);
 303         foreach my $obj (@cands) {
 304           $obj->set_from_related($_, $self) for keys %$reverse;
 305           my $them = { %{$obj->{_relationship_data} || {} }, $obj->get_inflated_columns };
 306           if ($self->__their_pk_needs_us($relname, $them)) {
 307             $obj = $self->find_or_create_related($relname, $them);
 308           } else {
 309             $obj->insert();
 310           }
 311         }
 312       }
 313     }
 314     $rollback_guard->commit;
 315   }
 316
 317   $self->in_storage(1);
 318   undef $self->{_orig_ident};
 319   return $self;
 320 }
 321
 322 =head2 in_storage
 323
 324   $row->in_storage; # Get value
 325   $row->in_storage(1); # Set value
 326
 327 =over
 328
 329 =item Arguments: none or 1|0
 330
 331 =item Returns: 1|0
 332
 333 =back
 334
 335 Indicates whether the object exists as a row in the database or
 336 not. This is set to true when L<DBIx::Class::ResultSet/find>,
 337 L<DBIx::Class::ResultSet/create> or L<DBIx::Class::ResultSet/insert>
 338 are used.
 339
 340 Creating a row object using L<DBIx::Class::ResultSet/new>, or calling
 341 L</delete> on one, sets it to false.
 342
 343 =cut
 344
 345 sub in_storage {
 346   my ($self, $val) = @_;
 347   $self->{_in_storage} = $val if @_ > 1;
 348   return $self->{_in_storage};
 349 }
 350
 351 =head2 update
 352
 353   $row->update(\%columns?)
 354
 355 =over
 356
 357 =item Arguments: none or a hashref
 358
 359 =item Returns: The Row object
 360
 361 =back
 362
 363 Throws an exception if the row object is not yet in the database,
 364 according to L</in_storage>.
 365
 366 This method issues an SQL UPDATE query to commit any changes to the
 367 object to the database if required.
 368
 369 Also takes an optional hashref of C<< column_name => value> >> pairs
 370 to update on the object first. Be aware that the hashref will be
 371 passed to C<set_inflated_columns>, which might edit it in place, so
 372 don't rely on it being the same after a call to C<update>.  If you
 373 need to preserve the hashref, it is sufficient to pass a shallow copy
 374 to C<update>, e.g. ( { %{ $href } } )
 375
 376 If the values passed or any of the column values set on the object
 377 contain scalar references, eg:
 378
 379   $row->last_modified(\'NOW()');
 380   # OR
 381   $row->update({ last_modified => \'NOW()' });
 382
 383 The update will pass the values verbatim into SQL. (See
 384 L<SQL::Abstract> docs).  The values in your Row object will NOT change
 385 as a result of the update call, if you want the object to be updated
 386 with the actual values from the database, call L</discard_changes>
 387 after the update.
 388
 389   $row->update()->discard_changes();
 390
 391 To determine before calling this method, which column values have
 392 changed and will be updated, call L</get_dirty_columns>.
 393
 394 To check if any columns will be updated, call L</is_changed>.
 395
 396 To force a column to be updated, call L</make_column_dirty> before
 397 this method.
 398
 399 =cut
 400
 401 sub update {
 402   my ($self, $upd) = @_;
 403   $self->throw_exception( "Not in database" ) unless $self->in_storage;
 404   my $ident_cond = $self->ident_condition;
 405   $self->throw_exception("Cannot safely update a row in a PK-less table")
 406     if ! keys %$ident_cond;
 407
 408   $self->set_inflated_columns($upd) if $upd;
 409   my %to_update = $self->get_dirty_columns;
 410   return $self unless keys %to_update;
 411   my $rows = $self->result_source->storage->update(
 412                $self->result_source, \%to_update,
 413                $self->{_orig_ident} || $ident_cond
 414              );
 415   if ($rows == 0) {
 416     $self->throw_exception( "Can't update ${self}: row not found" );
 417   } elsif ($rows > 1) {
 418     $self->throw_exception("Can't update ${self}: updated more than one row");
 419   }
 420   $self->{_dirty_columns} = {};
 421   $self->{related_resultsets} = {};
 422   undef $self->{_orig_ident};
 423   return $self;
 424 }
 425
 426 =head2 delete
 427
 428   $row->delete
 429
 430 =over
 431
 432 =item Arguments: none
 433
 434 =item Returns: The Row object
 435
 436 =back
 437
 438 Throws an exception if the object is not in the database according to
 439 L</in_storage>. Runs an SQL DELETE statement using the primary key
 440 values to locate the row.
 441
 442 The object is still perfectly usable, but L</in_storage> will
 443 now return 0 and the object must be reinserted using L</insert>
 444 before it can be used to L</update> the row again.
 445
 446 If you delete an object in a class with a C<has_many> relationship, an
 447 attempt is made to delete all the related objects as well. To turn
 448 this behaviour off, pass C<< cascade_delete => 0 >> in the C<$attr>
 449 hashref of the relationship, see L<DBIx::Class::Relationship>. Any
 450 database-level cascade or restrict will take precedence over a
 451 DBIx-Class-based cascading delete.
 452
 453 If you delete an object within a txn_do() (see L<DBIx::Class::Storage/txn_do>)
 454 and the transaction subsequently fails, the row object will remain marked as
 455 not being in storage. If you know for a fact that the object is still in
 456 storage (i.e. by inspecting the cause of the transaction's failure), you can
 457 use C<< $obj->in_storage(1) >> to restore consistency between the object and
 458 the database. This would allow a subsequent C<< $obj->delete >> to work
 459 as expected.
 460
 461 See also L<DBIx::Class::ResultSet/delete>.
 462
 463 =cut
 464
 465 sub delete {
 466   my $self = shift;
 467   if (ref $self) {
 468     $self->throw_exception( "Not in database" ) unless $self->in_storage;
 469     my $ident_cond = $self->{_orig_ident} || $self->ident_condition;
 470     $self->throw_exception("Cannot safely delete a row in a PK-less table")
 471       if ! keys %$ident_cond;
 472     foreach my $column (keys %$ident_cond) {
 473             $self->throw_exception("Can't delete the object unless it has loaded the primary keys")
 474               unless exists $self->{_column_data}{$column};
 475     }
 476     $self->result_source->storage->delete(
 477       $self->result_source, $ident_cond);
 478     $self->in_storage(undef);
 479   } else {
 480     $self->throw_exception("Can't do class delete without a ResultSource instance")
 481       unless $self->can('result_source_instance');
 482     my $attrs = @_ > 1 && ref $_[$#_] eq 'HASH' ? { %{pop(@_)} } : {};
 483     my $query = ref $_[0] eq 'HASH' ? $_[0] : {@_};
 484     $self->result_source_instance->resultset->search(@_)->delete;
 485   }
 486   return $self;
 487 }
 488
 489 =head2 get_column
 490
 491   my $val = $row->get_column($col);
 492
 493 =over
 494
 495 =item Arguments: $columnname
 496
 497 =item Returns: The value of the column
 498
 499 =back
 500
 501 Throws an exception if the column name given doesn't exist according
 502 to L</has_column>.
 503
 504 Returns a raw column value from the row object, if it has already
 505 been fetched from the database or set by an accessor.
 506
 507 If an L<inflated value|DBIx::Class::InflateColumn> has been set, it
 508 will be deflated and returned.
 509
 510 Note that if you used the C<columns> or the C<select/as>
 511 L<search attributes|DBIx::Class::ResultSet/ATTRIBUTES> on the resultset from
 512 which C<$row> was derived, and B<did not include> C<$columnname> in the list,
 513 this method will return C<undef> even if the database contains some value.
 514
 515 To retrieve all loaded column values as a hash, use L</get_columns>.
 516
 517 =cut
 518
 519 sub get_column {
 520   my ($self, $column) = @_;
 521   $self->throw_exception( "Can't fetch data as class method" ) unless ref $self;
 522   return $self->{_column_data}{$column} if exists $self->{_column_data}{$column};
 523   if (exists $self->{_inflated_column}{$column}) {
 524     return $self->store_column($column,
 525       $self->_deflated_column($column, $self->{_inflated_column}{$column}));
 526   }
 527   $self->throw_exception( "No such column '${column}'" ) unless $self->has_column($column);
 528   return undef;
 529 }
 530
 531 =head2 has_column_loaded
 532
 533   if ( $row->has_column_loaded($col) ) {
 534      print "$col has been loaded from db";
 535   }
 536
 537 =over
 538
 539 =item Arguments: $columnname
 540
 541 =item Returns: 0|1
 542
 543 =back
 544
 545 Returns a true value if the column value has been loaded from the
 546 database (or set locally).
 547
 548 =cut
 549
 550 sub has_column_loaded {
 551   my ($self, $column) = @_;
 552   $self->throw_exception( "Can't call has_column data as class method" ) unless ref $self;
 553   return 1 if exists $self->{_inflated_column}{$column};
 554   return exists $self->{_column_data}{$column};
 555 }
 556
 557 =head2 get_columns
 558
 559   my %data = $row->get_columns;
 560
 561 =over
 562
 563 =item Arguments: none
 564
 565 =item Returns: A hash of columnname, value pairs.
 566
 567 =back
 568
 569 Returns all loaded column data as a hash, containing raw values. To
 570 get just one value for a particular column, use L</get_column>.
 571
 572 =cut
 573
 574 sub get_columns {
 575   my $self = shift;
 576   if (exists $self->{_inflated_column}) {
 577     foreach my $col (keys %{$self->{_inflated_column}}) {
 578       $self->store_column($col, $self->_deflated_column($col, $self->{_inflated_column}{$col}))
 579         unless exists $self->{_column_data}{$col};
 580     }
 581   }
 582   return %{$self->{_column_data}};
 583 }
 584
 585 =head2 get_dirty_columns
 586
 587   my %data = $row->get_dirty_columns;
 588
 589 =over
 590
 591 =item Arguments: none
 592
 593 =item Returns: A hash of column, value pairs
 594
 595 =back
 596
 597 Only returns the column, value pairs for those columns that have been
 598 changed on this object since the last L</update> or L</insert> call.
 599
 600 See L</get_columns> to fetch all column/value pairs.
 601
 602 =cut
 603
 604 sub get_dirty_columns {
 605   my $self = shift;
 606   return map { $_ => $self->{_column_data}{$_} }
 607            keys %{$self->{_dirty_columns}};
 608 }
 609
 610 =head2 make_column_dirty
 611
 612   $row->make_column_dirty($col)
 613
 614 =over
 615
 616 =item Arguments: $columnname
 617
 618 =item Returns: undefined
 619
 620 =back
 621
 622 Throws an exception if the column does not exist.
 623
 624 Marks a column as having been changed regardless of whether it has
 625 really changed.
 626
 627 =cut
 628 sub make_column_dirty {
 629   my ($self, $column) = @_;
 630
 631   $self->throw_exception( "No such column '${column}'" )
 632     unless exists $self->{_column_data}{$column} || $self->has_column($column);
 633   $self->{_dirty_columns}{$column} = 1;
 634 }
 635
 636 =head2 get_inflated_columns
 637
 638   my %inflated_data = $obj->get_inflated_columns;
 639
 640 =over
 641
 642 =item Arguments: none
 643
 644 =item Returns: A hash of column, object|value pairs
 645
 646 =back
 647
 648 Returns a hash of all column keys and associated values. Values for any
 649 columns set to use inflation will be inflated and returns as objects.
 650
 651 See L</get_columns> to get the uninflated values.
 652
 653 See L<DBIx::Class::InflateColumn> for how to setup inflation.
 654
 655 =cut
 656
 657 sub get_inflated_columns {
 658   my $self = shift;
 659   return map {
 660     my $accessor = $self->column_info($_)->{'accessor'} || $_;
 661     ($_ => $self->$accessor);
 662   } $self->columns;
 663 }
 664
 665 =head2 set_column
 666
 667   $row->set_column($col => $val);
 668
 669 =over
 670
 671 =item Arguments: $columnname, $value
 672
 673 =item Returns: $value
 674
 675 =back
 676
 677 Sets a raw column value. If the new value is different from the old one,
 678 the column is marked as dirty for when you next call L</update>.
 679
 680 If passed an object or reference as a value, this method will happily
 681 attempt to store it, and a later L</insert> or L</update> will try and
 682 stringify/numify as appropriate. To set an object to be deflated
 683 instead, see L</set_inflated_columns>.
 684
 685 =cut
 686
 687 sub set_column {
 688   my ($self, $column, $new_value) = @_;
 689
 690   $self->{_orig_ident} ||= $self->ident_condition;
 691   my $old_value = $self->get_column($column);
 692
 693   $self->store_column($column, $new_value);
 694   $self->{_dirty_columns}{$column} = 1
 695     if (defined $old_value xor defined $new_value) || (defined $old_value && $old_value ne $new_value);
 696
 697   # XXX clear out the relation cache for this column
 698   delete $self->{related_resultsets}{$column};
 699
 700   return $new_value;
 701 }
 702
 703 =head2 set_columns
 704
 705   $row->set_columns({ $col => $val, ... });
 706
 707 =over
 708
 709 =item Arguments: \%columndata
 710
 711 =item Returns: The Row object
 712
 713 =back
 714
 715 Sets multiple column, raw value pairs at once.
 716
 717 Works as L</set_column>.
 718
 719 =cut
 720
 721 sub set_columns {
 722   my ($self,$data) = @_;
 723   foreach my $col (keys %$data) {
 724     $self->set_column($col,$data->{$col});
 725   }
 726   return $self;
 727 }
 728
 729 =head2 set_inflated_columns
 730
 731   $row->set_inflated_columns({ $col => $val, $relname => $obj, ... });
 732
 733 =over
 734
 735 =item Arguments: \%columndata
 736
 737 =item Returns: The Row object
 738
 739 =back
 740
 741 Sets more than one column value at once. Any inflated values are
 742 deflated and the raw values stored.
 743
 744 Any related values passed as Row objects, using the relation name as a
 745 key, are reduced to the appropriate foreign key values and stored. If
 746 instead of related row objects, a hashref of column, value data is
 747 passed, will create the related object first then store.
 748
 749 Will even accept arrayrefs of data as a value to a
 750 L<DBIx::Class::Relationship/has_many> key, and create the related
 751 objects if necessary.
 752
 753 Be aware that the input hashref might be edited in place, so dont rely
 754 on it being the same after a call to C<set_inflated_columns>. If you
 755 need to preserve the hashref, it is sufficient to pass a shallow copy
 756 to C<set_inflated_columns>, e.g. ( { %{ $href } } )
 757
 758 See also L<DBIx::Class::Relationship::Base/set_from_related>.
 759
 760 =cut
 761
 762 sub set_inflated_columns {
 763   my ( $self, $upd ) = @_;
 764   foreach my $key (keys %$upd) {
 765     if (ref $upd->{$key}) {
 766       my $info = $self->relationship_info($key);
 767       if ($info && $info->{attrs}{accessor}
 768         && $info->{attrs}{accessor} eq 'single')
 769       {
 770         my $rel = delete $upd->{$key};
 771         $self->set_from_related($key => $rel);
 772         $self->{_relationship_data}{$key} = $rel;
 773       } elsif ($info && $info->{attrs}{accessor}
 774         && $info->{attrs}{accessor} eq 'multi') {
 775           $self->throw_exception(
 776             "Recursive update is not supported over relationships of type multi ($key)"
 777           );
 778       }
 779       elsif ($self->has_column($key)
 780         && exists $self->column_info($key)->{_inflate_info})
 781       {
 782         $self->set_inflated_column($key, delete $upd->{$key});
 783       }
 784     }
 785   }
 786   $self->set_columns($upd);
 787 }
 788
 789 =head2 copy
 790
 791   my $copy = $orig->copy({ change => $to, ... });
 792
 793 =over
 794
 795 =item Arguments: \%replacementdata
 796
 797 =item Returns: The Row object copy
 798
 799 =back
 800
 801 Inserts a new row into the database, as a copy of the original
 802 object. If a hashref of replacement data is supplied, these will take
 803 precedence over data in the original.
 804
 805 If the row has related objects in a
 806 L<DBIx::Class::Relationship/has_many> then those objects may be copied
 807 too depending on the L<cascade_copy|DBIx::Class::Relationship>
 808 relationship attribute.
 809
 810 =cut
 811
 812 sub copy {
 813   my ($self, $changes) = @_;
 814   $changes ||= {};
 815   my $col_data = { %{$self->{_column_data}} };
 816   foreach my $col (keys %$col_data) {
 817     delete $col_data->{$col}
 818       if $self->result_source->column_info($col)->{is_auto_increment};
 819   }
 820
 821   my $new = { _column_data => $col_data };
 822   bless $new, ref $self;
 823
 824   $new->result_source($self->result_source);
 825   $new->set_inflated_columns($changes);
 826   $new->insert;
 827
 828   # Its possible we'll have 2 relations to the same Source. We need to make
 829   # sure we don't try to insert the same row twice esle we'll violate unique
 830   # constraints
 831   my $rels_copied = {};
 832
 833   foreach my $rel ($self->result_source->relationships) {
 834     my $rel_info = $self->result_source->relationship_info($rel);
 835
 836     next unless $rel_info->{attrs}{cascade_copy};
 837
 838     my $resolved = $self->result_source->resolve_condition(
 839       $rel_info->{cond}, $rel, $new
 840     );
 841
 842     my $copied = $rels_copied->{ $rel_info->{source} } ||= {};
 843     foreach my $related ($self->search_related($rel)) {
 844       my $id_str = join("\0", $related->id);
 845       next if $copied->{$id_str};
 846       $copied->{$id_str} = 1;
 847       my $rel_copy = $related->copy($resolved);
 848     }
 849
 850   }
 851   return $new;
 852 }
 853
 854 =head2 store_column
 855
 856   $row->store_column($col => $val);
 857
 858 =over
 859
 860 =item Arguments: $columnname, $value
 861
 862 =item Returns: The value sent to storage
 863
 864 =back
 865
 866 Set a raw value for a column without marking it as changed. This
 867 method is used internally by L</set_column> which you should probably
 868 be using.
 869
 870 This is the lowest level at which data is set on a row object,
 871 extend this method to catch all data setting methods.
 872
 873 =cut
 874
 875 sub store_column {
 876   my ($self, $column, $value) = @_;
 877   $self->throw_exception( "No such column '${column}'" )
 878     unless exists $self->{_column_data}{$column} || $self->has_column($column);
 879   $self->throw_exception( "set_column called for ${column} without value" )
 880     if @_ < 3;
 881   return $self->{_column_data}{$column} = $value;
 882 }
 883
 884 =head2 inflate_result
 885
 886   Class->inflate_result($result_source, \%me, \%prefetch?)
 887
 888 =over
 889
 890 =item Arguments: $result_source, \%columndata, \%prefetcheddata
 891
 892 =item Returns: A Row object
 893
 894 =back
 895
 896 All L<DBIx::Class::ResultSet> methods that retrieve data from the
 897 database and turn it into row objects call this method.
 898
 899 Extend this method in your Result classes to hook into this process,
 900 for example to rebless the result into a different class.
 901
 902 Reblessing can also be done more easily by setting C<result_class> in
 903 your Result class. See L<DBIx::Class::ResultSource/result_class>.
 904
 905 =cut
 906
 907 sub inflate_result {
 908   my ($class, $source, $me, $prefetch) = @_;
 909
 910   my ($source_handle) = $source;
 911
 912   if ($source->isa('DBIx::Class::ResultSourceHandle')) {
 913       $source = $source_handle->resolve
 914   } else {
 915       $source_handle = $source->handle
 916   }
 917
 918   my $new = {
 919     _source_handle => $source_handle,
 920     _column_data => $me,
 921     _in_storage => 1
 922   };
 923   bless $new, (ref $class || $class);
 924
 925   my $schema;
 926   foreach my $pre (keys %{$prefetch||{}}) {
 927     my $pre_val = $prefetch->{$pre};
 928     my $pre_source = $source->related_source($pre);
 929     $class->throw_exception("Can't prefetch non-existent relationship ${pre}")
 930       unless $pre_source;
 931     if (ref($pre_val->[0]) eq 'ARRAY') { # multi
 932       my @pre_objects;
 933       foreach my $pre_rec (@$pre_val) {
 934         unless ($pre_source->primary_columns == grep { exists $pre_rec->[0]{$_}
 935            and defined $pre_rec->[0]{$_} } $pre_source->primary_columns) {
 936           next;
 937         }
 938         push(@pre_objects, $pre_source->result_class->inflate_result(
 939                              $pre_source, @{$pre_rec}));
 940       }
 941       $new->related_resultset($pre)->set_cache(\@pre_objects);
 942     } elsif (defined $pre_val->[0]) {
 943       my $fetched;
 944       unless ($pre_source->primary_columns == grep { exists $pre_val->[0]{$_}
 945          and !defined $pre_val->[0]{$_} } $pre_source->primary_columns)
 946       {
 947         $fetched = $pre_source->result_class->inflate_result(
 948                       $pre_source, @{$pre_val});
 949       }
 950       $new->related_resultset($pre)->set_cache([ $fetched ]);
 951       my $accessor = $source->relationship_info($pre)->{attrs}{accessor};
 952       $class->throw_exception("No accessor for prefetched $pre")
 953        unless defined $accessor;
 954       if ($accessor eq 'single') {
 955         $new->{_relationship_data}{$pre} = $fetched;
 956       } elsif ($accessor eq 'filter') {
 957         $new->{_inflated_column}{$pre} = $fetched;
 958       } else {
 959        $class->throw_exception("Prefetch not supported with accessor '$accessor'");
 960       }
 961     }
 962   }
 963   return $new;
 964 }
 965
 966 =head2 update_or_insert
 967
 968   $row->update_or_insert
 969
 970 =over
 971
 972 =item Arguments: none
 973
 974 =item Returns: Result of update or insert operation
 975
 976 =back
 977
 978 L</Update>s the object if it's already in the database, according to
 979 L</in_storage>, else L</insert>s it.
 980
 981 =head2 insert_or_update
 982
 983   $obj->insert_or_update
 984
 985 Alias for L</update_or_insert>
 986
 987 =cut
 988
 989 sub insert_or_update { shift->update_or_insert(@_) }
 990
 991 sub update_or_insert {
 992   my $self = shift;
 993   return ($self->in_storage ? $self->update : $self->insert);
 994 }
 995
 996 =head2 is_changed
 997
 998   my @changed_col_names = $row->is_changed();
 999   if ($row->is_changed()) { ... }
1000
1001 =over
1002
1003 =item Arguments: none
1004
1005 =item Returns: 0|1 or @columnnames
1006
1007 =back
1008
1009 In list context returns a list of columns with uncommited changes, or
1010 in scalar context returns a true value if there are uncommitted
1011 changes.
1012
1013 =cut
1014
1015 sub is_changed {
1016   return keys %{shift->{_dirty_columns} || {}};
1017 }
1018
1019 =head2 is_column_changed
1020
1021   if ($row->is_column_changed('col')) { ... }
1022
1023 =over
1024
1025 =item Arguments: $columname
1026
1027 =item Returns: 0|1
1028
1029 =back
1030
1031 Returns a true value if the column has uncommitted changes.
1032
1033 =cut
1034
1035 sub is_column_changed {
1036   my( $self, $col ) = @_;
1037   return exists $self->{_dirty_columns}->{$col};
1038 }
1039
1040 =head2 result_source
1041
1042   my $resultsource = $row->result_source;
1043
1044 =over
1045
1046 =item Arguments: none
1047
1048 =item Returns: a ResultSource instance
1049
1050 =back
1051
1052 Accessor to the L<DBIx::Class::ResultSource> this object was created from.
1053
1054 =cut
1055
1056 sub result_source {
1057     my $self = shift;
1058
1059     if (@_) {
1060         $self->_source_handle($_[0]->handle);
1061     } else {
1062         $self->_source_handle->resolve;
1063     }
1064 }
1065
1066 =head2 register_column
1067
1068   $column_info = { .... };
1069   $class->register_column($column_name, $column_info);
1070
1071 =over
1072
1073 =item Arguments: $columnname, \%columninfo
1074
1075 =item Returns: undefined
1076
1077 =back
1078
1079 Registers a column on the class. If the column_info has an 'accessor'
1080 key, creates an accessor named after the value if defined; if there is
1081 no such key, creates an accessor with the same name as the column
1082
1083 The column_info attributes are described in
1084 L<DBIx::Class::ResultSource/add_columns>
1085
1086 =cut
1087
1088 sub register_column {
1089   my ($class, $col, $info) = @_;
1090   my $acc = $col;
1091   if (exists $info->{accessor}) {
1092     return unless defined $info->{accessor};
1093     $acc = [ $info->{accessor}, $col ];
1094   }
1095   $class->mk_group_accessors('column' => $acc);
1096 }
1097
1098 =head2 get_from_storage
1099
1100   my $copy = $row->get_from_storage($attrs)
1101
1102 =over
1103
1104 =item Arguments: \%attrs
1105
1106 =item Returns: A Row object
1107
1108 =back
1109
1110 Fetches a fresh copy of the Row object from the database and returns it.
1111
1112 If passed the \%attrs argument, will first apply these attributes to
1113 the resultset used to find the row.
1114
1115 This copy can then be used to compare to an existing row object, to
1116 determine if any changes have been made in the database since it was
1117 created.
1118
1119 To just update your Row object with any latest changes from the
1120 database, use L</discard_changes> instead.
1121
1122 The \%attrs argument should be compatible with
1123 L<DBIx::Class::ResultSet/ATTRIBUTES>.
1124
1125 =cut
1126
1127 sub get_from_storage {
1128     my $self = shift @_;
1129     my $attrs = shift @_;
1130     my $resultset = $self->result_source->resultset;
1131
1132     if(defined $attrs) {
1133         $resultset = $resultset->search(undef, $attrs);
1134     }
1135
1136     return $resultset->find($self->{_orig_ident} || $self->ident_condition);
1137 }
1138
1139 =head2 throw_exception
1140
1141 See L<DBIx::Class::Schema/throw_exception>.
1142
1143 =cut
1144
1145 sub throw_exception {
1146   my $self=shift;
1147   if (ref $self && ref $self->result_source && $self->result_source->schema) {
1148     $self->result_source->schema->throw_exception(@_);
1149   } else {
1150     croak(@_);
1151   }
1152 }
1153
1154 =head2 id
1155
1156   my @pk = $row->id;
1157
1158 =over
1159
1160 =item Arguments: none
1161
1162 =item Returns: A list of primary key values
1163
1164 =back
1165
1166 Returns the primary key(s) for a row. Can't be called as a class method.
1167 Actually implemented in L<DBIx::Class::PK>
1168
1169 =head2 discard_changes
1170
1171   $row->discard_changes
1172
1173 =over
1174
1175 =item Arguments: none
1176
1177 =item Returns: nothing (updates object in-place)
1178
1179 =back
1180
1181 Retrieves and sets the row object data from the database, losing any
1182 local changes made.
1183
1184 This method can also be used to refresh from storage, retrieving any
1185 changes made since the row was last read from storage. Actually
1186 implemented in L<DBIx::Class::PK>
1187
1188 =cut
1189
1190 1;
1191
1192 =head1 AUTHORS
1193
1194 Matt S. Trout <mst@shadowcatsystems.co.uk>
1195
1196 =head1 LICENSE
1197
1198 You may distribute this code under the same terms as Perl itself.
1199
1200 =cut