lib/DBIx/Class/ResultSource/View.pm

   1 package DBIx::Class::ResultSource::View;
   2
   3 use strict;
   4 use warnings;
   5
   6 use DBIx::Class::ResultSet;
   7
   8 use base qw/DBIx::Class/;
   9 __PACKAGE__->load_components(qw/ResultSource/);
  10 __PACKAGE__->mk_group_accessors(
  11   'simple' => qw(is_virtual view_definition)
  12 );
  13
  14 =head1 NAME
  15
  16 DBIx::Class::ResultSource::View - ResultSource object representing a view
  17
  18 =head1 SYNOPSIS
  19
  20   package MyDB::Schema::Result::Year2000CDs;
  21
  22   use base qw/DBIx::Class/;
  23   use DBIx::Class::ResultSource::View;
  24
  25   __PACKAGE__->load_components('Core');
  26   __PACKAGE__->table_class('DBIx::Class::ResultSource::View');
  27
  28   __PACKAGE__->table('year2000cds');
  29   __PACKAGE__->result_source_instance->is_virtual(1);
  30   __PACKAGE__->result_source_instance->view_definition(
  31       "SELECT cdid, artist, title FROM cd WHERE year ='2000'"
  32   );
  33   __PACKAGE__->add_columns(
  34     'cdid' => {
  35       data_type => 'integer',
  36       is_auto_increment => 1,
  37     },
  38     'artist' => {
  39       data_type => 'integer',
  40     },
  41     'title' => {
  42       data_type => 'varchar',
  43       size      => 100,
  44     },
  45   );
  46
  47 =head1 DESCRIPTION
  48
  49 View object that inherits from L<DBIx::Class::ResultSource>
  50
  51 This class extends ResultSource to add basic view support.
  52
  53 A view has a L</view_definition>, which contains a SQL query. The query can
  54 only have parameters if L</is_virtual> is set to true. It may contain JOINs,
  55 sub selects and any other SQL your database supports.
  56
  57 View definition SQL is deployed to your database on
  58 L<DBIx::Class::Schema/deploy> unless you set L</is_virtual> to true.
  59
  60 Deploying the view does B<not> translate it between different database
  61 syntaxes, so be careful what you write in your view SQL.
  62
  63 Virtual views (L</is_virtual> true), are assumed to not
  64 exist in your database as a real view. The L</view_definition> in this
  65 case replaces the view name in a FROM clause in a subselect.
  66
  67 =head1 EXAMPLES
  68
  69 Having created the MyDB::Schema::Year2000CDs schema as shown in the SYNOPSIS
  70 above, you can then:
  71
  72   $2000_cds = $schema->resultset('Year2000CDs')
  73                      ->search()
  74                      ->all();
  75   $count    = $schema->resultset('Year2000CDs')
  76                      ->search()
  77                      ->count();
  78
  79 If you modified the schema to include a placeholder
  80
  81   __PACKAGE__->result_source_instance->view_definition(
  82       "SELECT cdid, artist, title FROM cd WHERE year ='?'"
  83   );
  84
  85 and ensuring you have is_virtual set to true:
  86
  87   __PACKAGE__->result_source_instance->is_virtual(1);
  88
  89 You could now say:
  90
  91   $2001_cds = $schema->resultset('Year2000CDs')
  92                      ->search({}, { bind => [2001] })
  93                      ->all();
  94   $count    = $schema->resultset('Year2000CDs')
  95                      ->search({}, { bind => [2001] })
  96                      ->count();
  97
  98 =head1 SQL EXAMPLES
  99
 100 =over
 101
 102 =item is_virtual set to false
 103
 104   $schema->resultset('Year2000CDs')->all();
 105
 106   SELECT cdid, artist, title FROM year2000cds me
 107
 108 =item is_virtual set to true
 109
 110   $schema->resultset('Year2000CDs')->all();
 111
 112   SELECT cdid, artist, title FROM
 113     (SELECT cdid, artist, title FROM cd WHERE year ='2000') me
 114
 115 =back
 116
 117 =head1 METHODS
 118
 119 =head2 is_virtual
 120
 121   __PACKAGE__->result_source_instance->is_virtual(1);
 122
 123 Set to true for a virtual view, false or unset for a real
 124 database-based view.
 125
 126 =head2 view_definition
 127
 128   __PACKAGE__->result_source_instance->view_definition(
 129       "SELECT cdid, artist, title FROM cd WHERE year ='2000'"
 130       );
 131
 132 An SQL query for your view. Will not be translated across database
 133 syntaxes.
 134
 135
 136 =head1 OVERRIDDEN METHODS
 137
 138 =head2 from
 139
 140 Returns the FROM entry for the table (i.e. the view name)
 141 or the SQL as a subselect if this is a virtual view.
 142
 143 =cut
 144
 145 sub from {
 146   my $self = shift;
 147   return \"(${\$self->view_definition})" if $self->is_virtual;
 148   return $self->name;
 149 }
 150
 151 1;
 152
 153 =head1 AUTHORS
 154
 155 Matt S. Trout <mst@shadowcatsystems.co.uk>
 156
 157 With Contributions from:
 158
 159 Guillermo Roditi E<lt>groditi@cpan.orgE<gt>
 160
 161 Jess Robinson <castaway@desert-island.me.uk>
 162
 163 Wallace Reis <wreis@cpan.org>
 164
 165 =head1 LICENSE
 166
 167 You may distribute this code under the same terms as Perl itself.
 168
 169 =cut
 170