lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360   if ($rows) {
 361     $rs->set_cache($rows);
 362   }
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, $attrs);
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that ordering can be thrown away in things like Top limit
1288   $sub_attrs->{-for_count_only} = 1;
1289
1290   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1291
1292   $attrs->{from} = [{
1293     -alias => 'count_subq',
1294     -source_handle => $rsrc->handle,
1295     count_subq => $sub_rs->as_query,
1296   }];
1297
1298   # the subquery replaces this
1299   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1300
1301   return $self->_count_rs ($attrs);
1302 }
1303
1304
1305 # The DBIC relationship chaining implementation is pretty simple - every
1306 # new related_relationship is pushed onto the {from} stack, and the {select}
1307 # window simply slides further in. This means that when we count somewhere
1308 # in the middle, we got to make sure that everything in the join chain is an
1309 # actual inner join, otherwise the count will come back with unpredictable
1310 # results (a resultset may be generated with _some_ rows regardless of if
1311 # the relation which the $rs currently selects has rows or not). E.g.
1312 # $artist_rs->cds->count - normally generates:
1313 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1314 # which actually returns the number of artists * (number of cds || 1)
1315 #
1316 # So what we do here is crawl {from}, determine if the current alias is at
1317 # the top of the stack, and if not - make sure the chain is inner-joined down
1318 # to the root.
1319 #
1320 sub _switch_to_inner_join_if_needed {
1321   my ($self, $from, $alias) = @_;
1322
1323   # subqueries and other oddness is naturally not supported
1324   return $from if (
1325     ref $from ne 'ARRAY'
1326       ||
1327     @$from <= 1
1328       ||
1329     ref $from->[0] ne 'HASH'
1330       ||
1331     ! $from->[0]{-alias}
1332       ||
1333     $from->[0]{-alias} eq $alias
1334   );
1335
1336   my $switch_branch;
1337   JOINSCAN:
1338   for my $j (@{$from}[1 .. $#$from]) {
1339     if ($j->[0]{-alias} eq $alias) {
1340       $switch_branch = $j->[0]{-join_path};
1341       last JOINSCAN;
1342     }
1343   }
1344
1345   # something else went wrong
1346   return $from unless $switch_branch;
1347
1348   # So it looks like we will have to switch some stuff around.
1349   # local() is useless here as we will be leaving the scope
1350   # anyway, and deep cloning is just too fucking expensive
1351   # So replace the inner hashref manually
1352   my @new_from = ($from->[0]);
1353   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1354
1355   for my $j (@{$from}[1 .. $#$from]) {
1356     my $jalias = $j->[0]{-alias};
1357
1358     if ($sw_idx->{$jalias}) {
1359       my %attrs = %{$j->[0]};
1360       delete $attrs{-join_type};
1361       push @new_from, [
1362         \%attrs,
1363         @{$j}[ 1 .. $#$j ],
1364       ];
1365     }
1366     else {
1367       push @new_from, $j;
1368     }
1369   }
1370
1371   return \@new_from;
1372 }
1373
1374
1375 sub _bool {
1376   return 1;
1377 }
1378
1379 =head2 count_literal
1380
1381 =over 4
1382
1383 =item Arguments: $sql_fragment, @bind_values
1384
1385 =item Return Value: $count
1386
1387 =back
1388
1389 Counts the results in a literal query. Equivalent to calling L</search_literal>
1390 with the passed arguments, then L</count>.
1391
1392 =cut
1393
1394 sub count_literal { shift->search_literal(@_)->count; }
1395
1396 =head2 all
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: @objects
1403
1404 =back
1405
1406 Returns all elements in the resultset. Called implicitly if the resultset
1407 is returned in list context.
1408
1409 =cut
1410
1411 sub all {
1412   my $self = shift;
1413   if(@_) {
1414       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1415   }
1416
1417   return @{ $self->get_cache } if $self->get_cache;
1418
1419   my @obj;
1420
1421   if (keys %{$self->_resolved_attrs->{collapse}}) {
1422     # Using $self->cursor->all is really just an optimisation.
1423     # If we're collapsing has_many prefetches it probably makes
1424     # very little difference, and this is cleaner than hacking
1425     # _construct_object to survive the approach
1426     $self->cursor->reset;
1427     my @row = $self->cursor->next;
1428     while (@row) {
1429       push(@obj, $self->_construct_object(@row));
1430       @row = (exists $self->{stashed_row}
1431                ? @{delete $self->{stashed_row}}
1432                : $self->cursor->next);
1433     }
1434   } else {
1435     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1436   }
1437
1438   $self->set_cache(\@obj) if $self->{attrs}{cache};
1439
1440   return @obj;
1441 }
1442
1443 =head2 reset
1444
1445 =over 4
1446
1447 =item Arguments: none
1448
1449 =item Return Value: $self
1450
1451 =back
1452
1453 Resets the resultset's cursor, so you can iterate through the elements again.
1454 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1455 another query.
1456
1457 =cut
1458
1459 sub reset {
1460   my ($self) = @_;
1461   delete $self->{_attrs} if exists $self->{_attrs};
1462   $self->{all_cache_position} = 0;
1463   $self->cursor->reset;
1464   return $self;
1465 }
1466
1467 =head2 first
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: $object?
1474
1475 =back
1476
1477 Resets the resultset and returns an object for the first result (if the
1478 resultset returns anything).
1479
1480 =cut
1481
1482 sub first {
1483   return $_[0]->reset->next;
1484 }
1485
1486
1487 # _rs_update_delete
1488 #
1489 # Determines whether and what type of subquery is required for the $rs operation.
1490 # If grouping is necessary either supplies its own, or verifies the current one
1491 # After all is done delegates to the proper storage method.
1492
1493 sub _rs_update_delete {
1494   my ($self, $op, $values) = @_;
1495
1496   my $rsrc = $self->result_source;
1497
1498   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1499   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1500
1501   if ($needs_group_by_subq or $needs_subq) {
1502
1503     # make a new $rs selecting only the PKs (that's all we really need)
1504     my $attrs = $self->_resolved_attrs_copy;
1505
1506     delete $attrs->{$_} for qw/collapse select as/;
1507     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1508
1509     if ($needs_group_by_subq) {
1510       # make sure no group_by was supplied, or if there is one - make sure it matches
1511       # the columns compiled above perfectly. Anything else can not be sanely executed
1512       # on most databases so croak right then and there
1513
1514       if (my $g = $attrs->{group_by}) {
1515         my @current_group_by = map
1516           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1517           @$g
1518         ;
1519
1520         if (
1521           join ("\x00", sort @current_group_by)
1522             ne
1523           join ("\x00", sort @{$attrs->{columns}} )
1524         ) {
1525           $self->throw_exception (
1526             "You have just attempted a $op operation on a resultset which does group_by"
1527             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1528             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1529             . ' kind of queries. Please retry the operation with a modified group_by or'
1530             . ' without using one at all.'
1531           );
1532         }
1533       }
1534       else {
1535         $attrs->{group_by} = $attrs->{columns};
1536       }
1537     }
1538
1539     my $subrs = (ref $self)->new($rsrc, $attrs);
1540
1541     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1542   }
1543   else {
1544     return $rsrc->storage->$op(
1545       $rsrc,
1546       $op eq 'update' ? $values : (),
1547       $self->_cond_for_update_delete,
1548     );
1549   }
1550 }
1551
1552
1553 # _cond_for_update_delete
1554 #
1555 # update/delete require the condition to be modified to handle
1556 # the differing SQL syntax available.  This transforms the $self->{cond}
1557 # appropriately, returning the new condition.
1558
1559 sub _cond_for_update_delete {
1560   my ($self, $full_cond) = @_;
1561   my $cond = {};
1562
1563   $full_cond ||= $self->{cond};
1564   # No-op. No condition, we're updating/deleting everything
1565   return $cond unless ref $full_cond;
1566
1567   if (ref $full_cond eq 'ARRAY') {
1568     $cond = [
1569       map {
1570         my %hash;
1571         foreach my $key (keys %{$_}) {
1572           $key =~ /([^.]+)$/;
1573           $hash{$1} = $_->{$key};
1574         }
1575         \%hash;
1576       } @{$full_cond}
1577     ];
1578   }
1579   elsif (ref $full_cond eq 'HASH') {
1580     if ((keys %{$full_cond})[0] eq '-and') {
1581       $cond->{-and} = [];
1582       my @cond = @{$full_cond->{-and}};
1583        for (my $i = 0; $i < @cond; $i++) {
1584         my $entry = $cond[$i];
1585         my $hash;
1586         if (ref $entry eq 'HASH') {
1587           $hash = $self->_cond_for_update_delete($entry);
1588         }
1589         else {
1590           $entry =~ /([^.]+)$/;
1591           $hash->{$1} = $cond[++$i];
1592         }
1593         push @{$cond->{-and}}, $hash;
1594       }
1595     }
1596     else {
1597       foreach my $key (keys %{$full_cond}) {
1598         $key =~ /([^.]+)$/;
1599         $cond->{$1} = $full_cond->{$key};
1600       }
1601     }
1602   }
1603   else {
1604     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1605   }
1606
1607   return $cond;
1608 }
1609
1610
1611 =head2 update
1612
1613 =over 4
1614
1615 =item Arguments: \%values
1616
1617 =item Return Value: $storage_rv
1618
1619 =back
1620
1621 Sets the specified columns in the resultset to the supplied values in a
1622 single query. Return value will be true if the update succeeded or false
1623 if no records were updated; exact type of success value is storage-dependent.
1624
1625 =cut
1626
1627 sub update {
1628   my ($self, $values) = @_;
1629   $self->throw_exception('Values for update must be a hash')
1630     unless ref $values eq 'HASH';
1631
1632   return $self->_rs_update_delete ('update', $values);
1633 }
1634
1635 =head2 update_all
1636
1637 =over 4
1638
1639 =item Arguments: \%values
1640
1641 =item Return Value: 1
1642
1643 =back
1644
1645 Fetches all objects and updates them one at a time. Note that C<update_all>
1646 will run DBIC cascade triggers, while L</update> will not.
1647
1648 =cut
1649
1650 sub update_all {
1651   my ($self, $values) = @_;
1652   $self->throw_exception('Values for update_all must be a hash')
1653     unless ref $values eq 'HASH';
1654   foreach my $obj ($self->all) {
1655     $obj->set_columns($values)->update;
1656   }
1657   return 1;
1658 }
1659
1660 =head2 delete
1661
1662 =over 4
1663
1664 =item Arguments: none
1665
1666 =item Return Value: $storage_rv
1667
1668 =back
1669
1670 Deletes the contents of the resultset from its result source. Note that this
1671 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1672 to run. See also L<DBIx::Class::Row/delete>.
1673
1674 Return value will be the amount of rows deleted; exact type of return value
1675 is storage-dependent.
1676
1677 =cut
1678
1679 sub delete {
1680   my $self = shift;
1681   $self->throw_exception('delete does not accept any arguments')
1682     if @_;
1683
1684   return $self->_rs_update_delete ('delete');
1685 }
1686
1687 =head2 delete_all
1688
1689 =over 4
1690
1691 =item Arguments: none
1692
1693 =item Return Value: 1
1694
1695 =back
1696
1697 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1698 will run DBIC cascade triggers, while L</delete> will not.
1699
1700 =cut
1701
1702 sub delete_all {
1703   my $self = shift;
1704   $self->throw_exception('delete_all does not accept any arguments')
1705     if @_;
1706
1707   $_->delete for $self->all;
1708   return 1;
1709 }
1710
1711 =head2 populate
1712
1713 =over 4
1714
1715 =item Arguments: \@data;
1716
1717 =back
1718
1719 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1720 For the arrayref of hashrefs style each hashref should be a structure suitable
1721 forsubmitting to a $resultset->create(...) method.
1722
1723 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1724 to insert the data, as this is a faster method.
1725
1726 Otherwise, each set of data is inserted into the database using
1727 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1728 accumulated into an array. The array itself, or an array reference
1729 is returned depending on scalar or list context.
1730
1731 Example:  Assuming an Artist Class that has many CDs Classes relating:
1732
1733   my $Artist_rs = $schema->resultset("Artist");
1734
1735   ## Void Context Example
1736   $Artist_rs->populate([
1737      { artistid => 4, name => 'Manufactured Crap', cds => [
1738         { title => 'My First CD', year => 2006 },
1739         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1740       ],
1741      },
1742      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1743         { title => 'My parents sold me to a record company' ,year => 2005 },
1744         { title => 'Why Am I So Ugly?', year => 2006 },
1745         { title => 'I Got Surgery and am now Popular', year => 2007 }
1746       ],
1747      },
1748   ]);
1749
1750   ## Array Context Example
1751   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1752     { name => "Artist One"},
1753     { name => "Artist Two"},
1754     { name => "Artist Three", cds=> [
1755     { title => "First CD", year => 2007},
1756     { title => "Second CD", year => 2008},
1757   ]}
1758   ]);
1759
1760   print $ArtistOne->name; ## response is 'Artist One'
1761   print $ArtistThree->cds->count ## reponse is '2'
1762
1763 For the arrayref of arrayrefs style,  the first element should be a list of the
1764 fieldsnames to which the remaining elements are rows being inserted.  For
1765 example:
1766
1767   $Arstist_rs->populate([
1768     [qw/artistid name/],
1769     [100, 'A Formally Unknown Singer'],
1770     [101, 'A singer that jumped the shark two albums ago'],
1771     [102, 'An actually cool singer.'],
1772   ]);
1773
1774 Please note an important effect on your data when choosing between void and
1775 wantarray context. Since void context goes straight to C<insert_bulk> in
1776 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1777 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1778 create primary keys for you, you will find that your PKs are empty.  In this
1779 case you will have to use the wantarray context in order to create those
1780 values.
1781
1782 =cut
1783
1784 sub populate {
1785   my $self = shift @_;
1786   my $data = ref $_[0][0] eq 'HASH'
1787     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1788     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1789
1790   if(defined wantarray) {
1791     my @created;
1792     foreach my $item (@$data) {
1793       push(@created, $self->create($item));
1794     }
1795     return wantarray ? @created : \@created;
1796   } else {
1797     my ($first, @rest) = @$data;
1798
1799     require overload;
1800     my @names = grep {
1801       (not ref $first->{$_}) || (ref $first->{$_} eq 'SCALAR') ||
1802         (overload::Method($first->{$_}, '""'))
1803     } keys %$first;
1804
1805     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1806     my @pks = $self->result_source->primary_columns;
1807
1808     ## do the belongs_to relationships
1809     foreach my $index (0..$#$data) {
1810
1811       # delegate to create() for any dataset without primary keys with specified relationships
1812       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1813         for my $r (@rels) {
1814           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1815             my @ret = $self->populate($data);
1816             return;
1817           }
1818         }
1819       }
1820
1821       foreach my $rel (@rels) {
1822         next unless ref $data->[$index]->{$rel} eq "HASH";
1823         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1824         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1825         my $related = $result->result_source->_resolve_condition(
1826           $result->result_source->relationship_info($reverse)->{cond},
1827           $self,
1828           $result,
1829         );
1830
1831         delete $data->[$index]->{$rel};
1832         $data->[$index] = {%{$data->[$index]}, %$related};
1833
1834         push @names, keys %$related if $index == 0;
1835       }
1836     }
1837
1838     ## do bulk insert on current row
1839     my @values = map { [ @$_{@names} ] } @$data;
1840
1841     $self->result_source->storage->insert_bulk(
1842       $self->result_source,
1843       \@names,
1844       \@values,
1845     );
1846
1847     ## do the has_many relationships
1848     foreach my $item (@$data) {
1849
1850       foreach my $rel (@rels) {
1851         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1852
1853         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1854      || $self->throw_exception('Cannot find the relating object.');
1855
1856         my $child = $parent->$rel;
1857
1858         my $related = $child->result_source->_resolve_condition(
1859           $parent->result_source->relationship_info($rel)->{cond},
1860           $child,
1861           $parent,
1862         );
1863
1864         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1865         my @populate = map { {%$_, %$related} } @rows_to_add;
1866
1867         $child->populate( \@populate );
1868       }
1869     }
1870   }
1871 }
1872
1873 =head2 _normalize_populate_args ($args)
1874
1875 Private method used by L</populate> to normalize its incoming arguments.  Factored
1876 out in case you want to subclass and accept new argument structures to the
1877 L</populate> method.
1878
1879 =cut
1880
1881 sub _normalize_populate_args {
1882   my ($self, $data) = @_;
1883   my @names = @{shift(@$data)};
1884   my @results_to_create;
1885   foreach my $datum (@$data) {
1886     my %result_to_create;
1887     foreach my $index (0..$#names) {
1888       $result_to_create{$names[$index]} = $$datum[$index];
1889     }
1890     push @results_to_create, \%result_to_create;
1891   }
1892   return \@results_to_create;
1893 }
1894
1895 =head2 pager
1896
1897 =over 4
1898
1899 =item Arguments: none
1900
1901 =item Return Value: $pager
1902
1903 =back
1904
1905 Return Value a L<Data::Page> object for the current resultset. Only makes
1906 sense for queries with a C<page> attribute.
1907
1908 To get the full count of entries for a paged resultset, call
1909 C<total_entries> on the L<Data::Page> object.
1910
1911 =cut
1912
1913 sub pager {
1914   my ($self) = @_;
1915
1916   return $self->{pager} if $self->{pager};
1917
1918   my $attrs = $self->{attrs};
1919   $self->throw_exception("Can't create pager for non-paged rs")
1920     unless $self->{attrs}{page};
1921   $attrs->{rows} ||= 10;
1922
1923   # throw away the paging flags and re-run the count (possibly
1924   # with a subselect) to get the real total count
1925   my $count_attrs = { %$attrs };
1926   delete $count_attrs->{$_} for qw/rows offset page pager/;
1927   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1928
1929   return $self->{pager} = Data::Page->new(
1930     $total_count,
1931     $attrs->{rows},
1932     $self->{attrs}{page}
1933   );
1934 }
1935
1936 =head2 page
1937
1938 =over 4
1939
1940 =item Arguments: $page_number
1941
1942 =item Return Value: $rs
1943
1944 =back
1945
1946 Returns a resultset for the $page_number page of the resultset on which page
1947 is called, where each page contains a number of rows equal to the 'rows'
1948 attribute set on the resultset (10 by default).
1949
1950 =cut
1951
1952 sub page {
1953   my ($self, $page) = @_;
1954   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1955 }
1956
1957 =head2 new_result
1958
1959 =over 4
1960
1961 =item Arguments: \%vals
1962
1963 =item Return Value: $rowobject
1964
1965 =back
1966
1967 Creates a new row object in the resultset's result class and returns
1968 it. The row is not inserted into the database at this point, call
1969 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1970 will tell you whether the row object has been inserted or not.
1971
1972 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1973
1974 =cut
1975
1976 sub new_result {
1977   my ($self, $values) = @_;
1978   $self->throw_exception( "new_result needs a hash" )
1979     unless (ref $values eq 'HASH');
1980
1981   my %new;
1982   my $alias = $self->{attrs}{alias};
1983
1984   if (
1985     defined $self->{cond}
1986     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1987   ) {
1988     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1989     $new{-from_resultset} = [ keys %new ] if keys %new;
1990   } else {
1991     $self->throw_exception(
1992       "Can't abstract implicit construct, condition not a hash"
1993     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1994
1995     my $collapsed_cond = (
1996       $self->{cond}
1997         ? $self->_collapse_cond($self->{cond})
1998         : {}
1999     );
2000
2001     # precendence must be given to passed values over values inherited from
2002     # the cond, so the order here is important.
2003     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
2004     while( my($col,$value) = each %implied ){
2005       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
2006         $new{$col} = $value->{'='};
2007         next;
2008       }
2009       $new{$col} = $value if $self->_is_deterministic_value($value);
2010     }
2011   }
2012
2013   %new = (
2014     %new,
2015     %{ $self->_remove_alias($values, $alias) },
2016     -source_handle => $self->_source_handle,
2017     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2018   );
2019
2020   return $self->result_class->new(\%new);
2021 }
2022
2023 # _is_deterministic_value
2024 #
2025 # Make an effor to strip non-deterministic values from the condition,
2026 # to make sure new_result chokes less
2027
2028 sub _is_deterministic_value {
2029   my $self = shift;
2030   my $value = shift;
2031   my $ref_type = ref $value;
2032   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2033   return 1 if Scalar::Util::blessed($value);
2034   return 0;
2035 }
2036
2037 # _has_resolved_attr
2038 #
2039 # determines if the resultset defines at least one
2040 # of the attributes supplied
2041 #
2042 # used to determine if a subquery is neccessary
2043 #
2044 # supports some virtual attributes:
2045 #   -join
2046 #     This will scan for any joins being present on the resultset.
2047 #     It is not a mere key-search but a deep inspection of {from}
2048 #
2049
2050 sub _has_resolved_attr {
2051   my ($self, @attr_names) = @_;
2052
2053   my $attrs = $self->_resolved_attrs;
2054
2055   my %extra_checks;
2056
2057   for my $n (@attr_names) {
2058     if (grep { $n eq $_ } (qw/-join/) ) {
2059       $extra_checks{$n}++;
2060       next;
2061     }
2062
2063     my $attr =  $attrs->{$n};
2064
2065     next if not defined $attr;
2066
2067     if (ref $attr eq 'HASH') {
2068       return 1 if keys %$attr;
2069     }
2070     elsif (ref $attr eq 'ARRAY') {
2071       return 1 if @$attr;
2072     }
2073     else {
2074       return 1 if $attr;
2075     }
2076   }
2077
2078   # a resolved join is expressed as a multi-level from
2079   return 1 if (
2080     $extra_checks{-join}
2081       and
2082     ref $attrs->{from} eq 'ARRAY'
2083       and
2084     @{$attrs->{from}} > 1
2085   );
2086
2087   return 0;
2088 }
2089
2090 # _collapse_cond
2091 #
2092 # Recursively collapse the condition.
2093
2094 sub _collapse_cond {
2095   my ($self, $cond, $collapsed) = @_;
2096
2097   $collapsed ||= {};
2098
2099   if (ref $cond eq 'ARRAY') {
2100     foreach my $subcond (@$cond) {
2101       next unless ref $subcond;  # -or
2102       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2103     }
2104   }
2105   elsif (ref $cond eq 'HASH') {
2106     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2107       foreach my $subcond (@{$cond->{-and}}) {
2108         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2109       }
2110     }
2111     else {
2112       foreach my $col (keys %$cond) {
2113         my $value = $cond->{$col};
2114         $collapsed->{$col} = $value;
2115       }
2116     }
2117   }
2118
2119   return $collapsed;
2120 }
2121
2122 # _remove_alias
2123 #
2124 # Remove the specified alias from the specified query hash. A copy is made so
2125 # the original query is not modified.
2126
2127 sub _remove_alias {
2128   my ($self, $query, $alias) = @_;
2129
2130   my %orig = %{ $query || {} };
2131   my %unaliased;
2132
2133   foreach my $key (keys %orig) {
2134     if ($key !~ /\./) {
2135       $unaliased{$key} = $orig{$key};
2136       next;
2137     }
2138     $unaliased{$1} = $orig{$key}
2139       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2140   }
2141
2142   return \%unaliased;
2143 }
2144
2145 =head2 as_query (EXPERIMENTAL)
2146
2147 =over 4
2148
2149 =item Arguments: none
2150
2151 =item Return Value: \[ $sql, @bind ]
2152
2153 =back
2154
2155 Returns the SQL query and bind vars associated with the invocant.
2156
2157 This is generally used as the RHS for a subquery.
2158
2159 B<NOTE>: This feature is still experimental.
2160
2161 =cut
2162
2163 sub as_query {
2164   my $self = shift;
2165
2166   my $attrs = $self->_resolved_attrs_copy;
2167
2168   # For future use:
2169   #
2170   # in list ctx:
2171   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2172   # $sql also has no wrapping parenthesis in list ctx
2173   #
2174   my $sqlbind = $self->result_source->storage
2175     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2176
2177   return $sqlbind;
2178 }
2179
2180 =head2 find_or_new
2181
2182 =over 4
2183
2184 =item Arguments: \%vals, \%attrs?
2185
2186 =item Return Value: $rowobject
2187
2188 =back
2189
2190   my $artist = $schema->resultset('Artist')->find_or_new(
2191     { artist => 'fred' }, { key => 'artists' });
2192
2193   $cd->cd_to_producer->find_or_new({ producer => $producer },
2194                                    { key => 'primary });
2195
2196 Find an existing record from this resultset, based on its primary
2197 key, or a unique constraint. If none exists, instantiate a new result
2198 object and return it. The object will not be saved into your storage
2199 until you call L<DBIx::Class::Row/insert> on it.
2200
2201 You most likely want this method when looking for existing rows using
2202 a unique constraint that is not the primary key, or looking for
2203 related rows.
2204
2205 If you want objects to be saved immediately, use L</find_or_create>
2206 instead.
2207
2208 B<Note>: Take care when using C<find_or_new> with a table having
2209 columns with default values that you intend to be automatically
2210 supplied by the database (e.g. an auto_increment primary key column).
2211 In normal usage, the value of such columns should NOT be included at
2212 all in the call to C<find_or_new>, even when set to C<undef>.
2213
2214 =cut
2215
2216 sub find_or_new {
2217   my $self     = shift;
2218   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2219   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2220   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2221     return $row;
2222   }
2223   return $self->new_result($hash);
2224 }
2225
2226 =head2 create
2227
2228 =over 4
2229
2230 =item Arguments: \%vals
2231
2232 =item Return Value: a L<DBIx::Class::Row> $object
2233
2234 =back
2235
2236 Attempt to create a single new row or a row with multiple related rows
2237 in the table represented by the resultset (and related tables). This
2238 will not check for duplicate rows before inserting, use
2239 L</find_or_create> to do that.
2240
2241 To create one row for this resultset, pass a hashref of key/value
2242 pairs representing the columns of the table and the values you wish to
2243 store. If the appropriate relationships are set up, foreign key fields
2244 can also be passed an object representing the foreign row, and the
2245 value will be set to its primary key.
2246
2247 To create related objects, pass a hashref of related-object column values
2248 B<keyed on the relationship name>. If the relationship is of type C<multi>
2249 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2250 The process will correctly identify columns holding foreign keys, and will
2251 transparrently populate them from the keys of the corresponding relation.
2252 This can be applied recursively, and will work correctly for a structure
2253 with an arbitrary depth and width, as long as the relationships actually
2254 exists and the correct column data has been supplied.
2255
2256
2257 Instead of hashrefs of plain related data (key/value pairs), you may
2258 also pass new or inserted objects. New objects (not inserted yet, see
2259 L</new>), will be inserted into their appropriate tables.
2260
2261 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2262
2263 Example of creating a new row.
2264
2265   $person_rs->create({
2266     name=>"Some Person",
2267     email=>"somebody@someplace.com"
2268   });
2269
2270 Example of creating a new row and also creating rows in a related C<has_many>
2271 or C<has_one> resultset.  Note Arrayref.
2272
2273   $artist_rs->create(
2274      { artistid => 4, name => 'Manufactured Crap', cds => [
2275         { title => 'My First CD', year => 2006 },
2276         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2277       ],
2278      },
2279   );
2280
2281 Example of creating a new row and also creating a row in a related
2282 C<belongs_to>resultset. Note Hashref.
2283
2284   $cd_rs->create({
2285     title=>"Music for Silly Walks",
2286     year=>2000,
2287     artist => {
2288       name=>"Silly Musician",
2289     }
2290   });
2291
2292 =over
2293
2294 =item WARNING
2295
2296 When subclassing ResultSet never attempt to override this method. Since
2297 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2298 lot of the internals simply never call it, so your override will be
2299 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2300 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2301 L</create> process you need to intervene.
2302
2303 =back
2304
2305 =cut
2306
2307 sub create {
2308   my ($self, $attrs) = @_;
2309   $self->throw_exception( "create needs a hashref" )
2310     unless ref $attrs eq 'HASH';
2311   return $self->new_result($attrs)->insert;
2312 }
2313
2314 =head2 find_or_create
2315
2316 =over 4
2317
2318 =item Arguments: \%vals, \%attrs?
2319
2320 =item Return Value: $rowobject
2321
2322 =back
2323
2324   $cd->cd_to_producer->find_or_create({ producer => $producer },
2325                                       { key => 'primary' });
2326
2327 Tries to find a record based on its primary key or unique constraints; if none
2328 is found, creates one and returns that instead.
2329
2330   my $cd = $schema->resultset('CD')->find_or_create({
2331     cdid   => 5,
2332     artist => 'Massive Attack',
2333     title  => 'Mezzanine',
2334     year   => 2005,
2335   });
2336
2337 Also takes an optional C<key> attribute, to search by a specific key or unique
2338 constraint. For example:
2339
2340   my $cd = $schema->resultset('CD')->find_or_create(
2341     {
2342       artist => 'Massive Attack',
2343       title  => 'Mezzanine',
2344     },
2345     { key => 'cd_artist_title' }
2346   );
2347
2348 B<Note>: Because find_or_create() reads from the database and then
2349 possibly inserts based on the result, this method is subject to a race
2350 condition. Another process could create a record in the table after
2351 the find has completed and before the create has started. To avoid
2352 this problem, use find_or_create() inside a transaction.
2353
2354 B<Note>: Take care when using C<find_or_create> with a table having
2355 columns with default values that you intend to be automatically
2356 supplied by the database (e.g. an auto_increment primary key column).
2357 In normal usage, the value of such columns should NOT be included at
2358 all in the call to C<find_or_create>, even when set to C<undef>.
2359
2360 See also L</find> and L</update_or_create>. For information on how to declare
2361 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2362
2363 =cut
2364
2365 sub find_or_create {
2366   my $self     = shift;
2367   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2368   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2369   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2370     return $row;
2371   }
2372   return $self->create($hash);
2373 }
2374
2375 =head2 update_or_create
2376
2377 =over 4
2378
2379 =item Arguments: \%col_values, { key => $unique_constraint }?
2380
2381 =item Return Value: $rowobject
2382
2383 =back
2384
2385   $resultset->update_or_create({ col => $val, ... });
2386
2387 First, searches for an existing row matching one of the unique constraints
2388 (including the primary key) on the source of this resultset. If a row is
2389 found, updates it with the other given column values. Otherwise, creates a new
2390 row.
2391
2392 Takes an optional C<key> attribute to search on a specific unique constraint.
2393 For example:
2394
2395   # In your application
2396   my $cd = $schema->resultset('CD')->update_or_create(
2397     {
2398       artist => 'Massive Attack',
2399       title  => 'Mezzanine',
2400       year   => 1998,
2401     },
2402     { key => 'cd_artist_title' }
2403   );
2404
2405   $cd->cd_to_producer->update_or_create({
2406     producer => $producer,
2407     name => 'harry',
2408   }, {
2409     key => 'primary,
2410   });
2411
2412
2413 If no C<key> is specified, it searches on all unique constraints defined on the
2414 source, including the primary key.
2415
2416 If the C<key> is specified as C<primary>, it searches only on the primary key.
2417
2418 See also L</find> and L</find_or_create>. For information on how to declare
2419 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2420
2421 B<Note>: Take care when using C<update_or_create> with a table having
2422 columns with default values that you intend to be automatically
2423 supplied by the database (e.g. an auto_increment primary key column).
2424 In normal usage, the value of such columns should NOT be included at
2425 all in the call to C<update_or_create>, even when set to C<undef>.
2426
2427 =cut
2428
2429 sub update_or_create {
2430   my $self = shift;
2431   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2432   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2433
2434   my $row = $self->find($cond, $attrs);
2435   if (defined $row) {
2436     $row->update($cond);
2437     return $row;
2438   }
2439
2440   return $self->create($cond);
2441 }
2442
2443 =head2 update_or_new
2444
2445 =over 4
2446
2447 =item Arguments: \%col_values, { key => $unique_constraint }?
2448
2449 =item Return Value: $rowobject
2450
2451 =back
2452
2453   $resultset->update_or_new({ col => $val, ... });
2454
2455 First, searches for an existing row matching one of the unique constraints
2456 (including the primary key) on the source of this resultset. If a row is
2457 found, updates it with the other given column values. Otherwise, instantiate
2458 a new result object and return it. The object will not be saved into your storage
2459 until you call L<DBIx::Class::Row/insert> on it.
2460
2461 Takes an optional C<key> attribute to search on a specific unique constraint.
2462 For example:
2463
2464   # In your application
2465   my $cd = $schema->resultset('CD')->update_or_new(
2466     {
2467       artist => 'Massive Attack',
2468       title  => 'Mezzanine',
2469       year   => 1998,
2470     },
2471     { key => 'cd_artist_title' }
2472   );
2473
2474   if ($cd->in_storage) {
2475       # the cd was updated
2476   }
2477   else {
2478       # the cd is not yet in the database, let's insert it
2479       $cd->insert;
2480   }
2481
2482 B<Note>: Take care when using C<update_or_new> with a table having
2483 columns with default values that you intend to be automatically
2484 supplied by the database (e.g. an auto_increment primary key column).
2485 In normal usage, the value of such columns should NOT be included at
2486 all in the call to C<update_or_new>, even when set to C<undef>.
2487
2488 See also L</find>, L</find_or_create> and L</find_or_new>.
2489
2490 =cut
2491
2492 sub update_or_new {
2493     my $self  = shift;
2494     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2495     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2496
2497     my $row = $self->find( $cond, $attrs );
2498     if ( defined $row ) {
2499         $row->update($cond);
2500         return $row;
2501     }
2502
2503     return $self->new_result($cond);
2504 }
2505
2506 =head2 get_cache
2507
2508 =over 4
2509
2510 =item Arguments: none
2511
2512 =item Return Value: \@cache_objects?
2513
2514 =back
2515
2516 Gets the contents of the cache for the resultset, if the cache is set.
2517
2518 The cache is populated either by using the L</prefetch> attribute to
2519 L</search> or by calling L</set_cache>.
2520
2521 =cut
2522
2523 sub get_cache {
2524   shift->{all_cache};
2525 }
2526
2527 =head2 set_cache
2528
2529 =over 4
2530
2531 =item Arguments: \@cache_objects
2532
2533 =item Return Value: \@cache_objects
2534
2535 =back
2536
2537 Sets the contents of the cache for the resultset. Expects an arrayref
2538 of objects of the same class as those produced by the resultset. Note that
2539 if the cache is set the resultset will return the cached objects rather
2540 than re-querying the database even if the cache attr is not set.
2541
2542 The contents of the cache can also be populated by using the
2543 L</prefetch> attribute to L</search>.
2544
2545 =cut
2546
2547 sub set_cache {
2548   my ( $self, $data ) = @_;
2549   $self->throw_exception("set_cache requires an arrayref")
2550       if defined($data) && (ref $data ne 'ARRAY');
2551   $self->{all_cache} = $data;
2552 }
2553
2554 =head2 clear_cache
2555
2556 =over 4
2557
2558 =item Arguments: none
2559
2560 =item Return Value: []
2561
2562 =back
2563
2564 Clears the cache for the resultset.
2565
2566 =cut
2567
2568 sub clear_cache {
2569   shift->set_cache(undef);
2570 }
2571
2572 =head2 is_paged
2573
2574 =over 4
2575
2576 =item Arguments: none
2577
2578 =item Return Value: true, if the resultset has been paginated
2579
2580 =back
2581
2582 =cut
2583
2584 sub is_paged {
2585   my ($self) = @_;
2586   return !!$self->{attrs}{page};
2587 }
2588
2589 =head2 related_resultset
2590
2591 =over 4
2592
2593 =item Arguments: $relationship_name
2594
2595 =item Return Value: $resultset
2596
2597 =back
2598
2599 Returns a related resultset for the supplied relationship name.
2600
2601   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2602
2603 =cut
2604
2605 sub related_resultset {
2606   my ($self, $rel) = @_;
2607
2608   $self->{related_resultsets} ||= {};
2609   return $self->{related_resultsets}{$rel} ||= do {
2610     my $rel_info = $self->result_source->relationship_info($rel);
2611
2612     $self->throw_exception(
2613       "search_related: result source '" . $self->result_source->source_name .
2614         "' has no such relationship $rel")
2615       unless $rel_info;
2616
2617     my ($from,$seen) = $self->_chain_relationship($rel);
2618
2619     my $join_count = $seen->{$rel};
2620     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2621
2622     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2623     my %attrs = %{$self->{attrs}||{}};
2624     delete @attrs{qw(result_class alias)};
2625
2626     my $new_cache;
2627
2628     if (my $cache = $self->get_cache) {
2629       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2630         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2631                         @$cache ];
2632       }
2633     }
2634
2635     my $rel_source = $self->result_source->related_source($rel);
2636
2637     my $new = do {
2638
2639       # The reason we do this now instead of passing the alias to the
2640       # search_rs below is that if you wrap/overload resultset on the
2641       # source you need to know what alias it's -going- to have for things
2642       # to work sanely (e.g. RestrictWithObject wants to be able to add
2643       # extra query restrictions, and these may need to be $alias.)
2644
2645       my $attrs = $rel_source->resultset_attributes;
2646       local $attrs->{alias} = $alias;
2647
2648       $rel_source->resultset
2649                  ->search_rs(
2650                      undef, {
2651                        %attrs,
2652                        join => undef,
2653                        prefetch => undef,
2654                        select => undef,
2655                        as => undef,
2656                        where => $self->{cond},
2657                        seen_join => $seen,
2658                        from => $from,
2659                    });
2660     };
2661     $new->set_cache($new_cache) if $new_cache;
2662     $new;
2663   };
2664 }
2665
2666 =head2 current_source_alias
2667
2668 =over 4
2669
2670 =item Arguments: none
2671
2672 =item Return Value: $source_alias
2673
2674 =back
2675
2676 Returns the current table alias for the result source this resultset is built
2677 on, that will be used in the SQL query. Usually it is C<me>.
2678
2679 Currently the source alias that refers to the result set returned by a
2680 L</search>/L</find> family method depends on how you got to the resultset: it's
2681 C<me> by default, but eg. L</search_related> aliases it to the related result
2682 source name (and keeps C<me> referring to the original result set). The long
2683 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2684 (and make this method unnecessary).
2685
2686 Thus it's currently necessary to use this method in predefined queries (see
2687 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2688 source alias of the current result set:
2689
2690   # in a result set class
2691   sub modified_by {
2692     my ($self, $user) = @_;
2693
2694     my $me = $self->current_source_alias;
2695
2696     return $self->search(
2697       "$me.modified" => $user->id,
2698     );
2699   }
2700
2701 =cut
2702
2703 sub current_source_alias {
2704   my ($self) = @_;
2705
2706   return ($self->{attrs} || {})->{alias} || 'me';
2707 }
2708
2709 # This code is called by search_related, and makes sure there
2710 # is clear separation between the joins before, during, and
2711 # after the relationship. This information is needed later
2712 # in order to properly resolve prefetch aliases (any alias
2713 # with a relation_chain_depth less than the depth of the
2714 # current prefetch is not considered)
2715 #
2716 # The increments happen in 1/2s to make it easier to correlate the
2717 # join depth with the join path. An integer means a relationship
2718 # specified via a search_related, whereas a fraction means an added
2719 # join/prefetch via attributes
2720 sub _chain_relationship {
2721   my ($self, $rel) = @_;
2722   my $source = $self->result_source;
2723   my $attrs = $self->{attrs};
2724
2725   my $from = [ @{
2726       $attrs->{from}
2727         ||
2728       [{
2729         -source_handle => $source->handle,
2730         -alias => $attrs->{alias},
2731         $attrs->{alias} => $source->from,
2732       }]
2733   }];
2734
2735   my $seen = { %{$attrs->{seen_join} || {} } };
2736   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2737     ? $from->[-1][0]{-join_path}
2738     : [];
2739
2740
2741   # we need to take the prefetch the attrs into account before we
2742   # ->_resolve_join as otherwise they get lost - captainL
2743   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2744
2745   my @requested_joins = $source->_resolve_join(
2746     $merged,
2747     $attrs->{alias},
2748     $seen,
2749     $jpath,
2750   );
2751
2752   push @$from, @requested_joins;
2753
2754   $seen->{-relation_chain_depth} += 0.5;
2755
2756   # if $self already had a join/prefetch specified on it, the requested
2757   # $rel might very well be already included. What we do in this case
2758   # is effectively a no-op (except that we bump up the chain_depth on
2759   # the join in question so we could tell it *is* the search_related)
2760   my $already_joined;
2761
2762
2763   # we consider the last one thus reverse
2764   for my $j (reverse @requested_joins) {
2765     if ($rel eq $j->[0]{-join_path}[-1]) {
2766       $j->[0]{-relation_chain_depth} += 0.5;
2767       $already_joined++;
2768       last;
2769     }
2770   }
2771
2772 # alternative way to scan the entire chain - not backwards compatible
2773 #  for my $j (reverse @$from) {
2774 #    next unless ref $j eq 'ARRAY';
2775 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2776 #      $j->[0]{-relation_chain_depth} += 0.5;
2777 #      $already_joined++;
2778 #      last;
2779 #    }
2780 #  }
2781
2782   unless ($already_joined) {
2783     push @$from, $source->_resolve_join(
2784       $rel,
2785       $attrs->{alias},
2786       $seen,
2787       $jpath,
2788     );
2789   }
2790
2791   $seen->{-relation_chain_depth} += 0.5;
2792
2793   return ($from,$seen);
2794 }
2795
2796 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2797 sub _resolved_attrs_copy {
2798   my $self = shift;
2799   return { %{$self->_resolved_attrs (@_)} };
2800 }
2801
2802 sub _resolved_attrs {
2803   my $self = shift;
2804   return $self->{_attrs} if $self->{_attrs};
2805
2806   my $attrs  = { %{ $self->{attrs} || {} } };
2807   my $source = $self->result_source;
2808   my $alias  = $attrs->{alias};
2809
2810   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2811   my @colbits;
2812
2813   # build columns (as long as select isn't set) into a set of as/select hashes
2814   unless ( $attrs->{select} ) {
2815
2816     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2817       ? @{ delete $attrs->{columns}}
2818       : (
2819           ( delete $attrs->{columns} )
2820             ||
2821           $source->columns
2822         )
2823     ;
2824
2825     @colbits = map {
2826       ( ref($_) eq 'HASH' )
2827       ? $_
2828       : {
2829           (
2830             /^\Q${alias}.\E(.+)$/
2831               ? "$1"
2832               : "$_"
2833           )
2834             =>
2835           (
2836             /\./
2837               ? "$_"
2838               : "${alias}.$_"
2839           )
2840         }
2841     } @cols;
2842   }
2843
2844   # add the additional columns on
2845   foreach ( 'include_columns', '+columns' ) {
2846       push @colbits, map {
2847           ( ref($_) eq 'HASH' )
2848             ? $_
2849             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2850       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2851   }
2852
2853   # start with initial select items
2854   if ( $attrs->{select} ) {
2855     $attrs->{select} =
2856         ( ref $attrs->{select} eq 'ARRAY' )
2857       ? [ @{ $attrs->{select} } ]
2858       : [ $attrs->{select} ];
2859     $attrs->{as} = (
2860       $attrs->{as}
2861       ? (
2862         ref $attrs->{as} eq 'ARRAY'
2863         ? [ @{ $attrs->{as} } ]
2864         : [ $attrs->{as} ]
2865         )
2866       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2867     );
2868   }
2869   else {
2870
2871     # otherwise we intialise select & as to empty
2872     $attrs->{select} = [];
2873     $attrs->{as}     = [];
2874   }
2875
2876   # now add colbits to select/as
2877   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2878   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2879
2880   my $adds;
2881   if ( $adds = delete $attrs->{'+select'} ) {
2882     $adds = [$adds] unless ref $adds eq 'ARRAY';
2883     push(
2884       @{ $attrs->{select} },
2885       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2886     );
2887   }
2888   if ( $adds = delete $attrs->{'+as'} ) {
2889     $adds = [$adds] unless ref $adds eq 'ARRAY';
2890     push( @{ $attrs->{as} }, @$adds );
2891   }
2892
2893   $attrs->{from} ||= [ {
2894     -source_handle => $source->handle,
2895     -alias => $self->{attrs}{alias},
2896     $self->{attrs}{alias} => $source->from,
2897   } ];
2898
2899   if ( $attrs->{join} || $attrs->{prefetch} ) {
2900
2901     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2902       if ref $attrs->{from} ne 'ARRAY';
2903
2904     my $join = delete $attrs->{join} || {};
2905
2906     if ( defined $attrs->{prefetch} ) {
2907       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2908     }
2909
2910     $attrs->{from} =    # have to copy here to avoid corrupting the original
2911       [
2912         @{ $attrs->{from} },
2913         $source->_resolve_join(
2914           $join,
2915           $alias,
2916           { %{ $attrs->{seen_join} || {} } },
2917           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2918             ? $attrs->{from}[-1][0]{-join_path}
2919             : []
2920           ,
2921         )
2922       ];
2923   }
2924
2925   if ( defined $attrs->{order_by} ) {
2926     $attrs->{order_by} = (
2927       ref( $attrs->{order_by} ) eq 'ARRAY'
2928       ? [ @{ $attrs->{order_by} } ]
2929       : [ $attrs->{order_by} || () ]
2930     );
2931   }
2932
2933   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2934     $attrs->{group_by} = [ $attrs->{group_by} ];
2935   }
2936
2937   # generate the distinct induced group_by early, as prefetch will be carried via a
2938   # subquery (since a group_by is present)
2939   if (delete $attrs->{distinct}) {
2940     if ($attrs->{group_by}) {
2941       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2942     }
2943     else {
2944       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2945     }
2946   }
2947
2948   $attrs->{collapse} ||= {};
2949   if ( my $prefetch = delete $attrs->{prefetch} ) {
2950     $prefetch = $self->_merge_attr( {}, $prefetch );
2951
2952     my $prefetch_ordering = [];
2953
2954     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2955
2956     my @prefetch =
2957       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2958
2959     # we need to somehow mark which columns came from prefetch
2960     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2961
2962     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2963     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2964
2965     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2966     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2967   }
2968
2969   # if both page and offset are specified, produce a combined offset
2970   # even though it doesn't make much sense, this is what pre 081xx has
2971   # been doing
2972   if (my $page = delete $attrs->{page}) {
2973     $attrs->{offset} =
2974       ($attrs->{rows} * ($page - 1))
2975             +
2976       ($attrs->{offset} || 0)
2977     ;
2978   }
2979
2980   return $self->{_attrs} = $attrs;
2981 }
2982
2983 sub _joinpath_aliases {
2984   my ($self, $fromspec, $seen) = @_;
2985
2986   my $paths = {};
2987   return $paths unless ref $fromspec eq 'ARRAY';
2988
2989   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2990
2991   if (int ($cur_depth) != $cur_depth) {
2992     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2993   }
2994
2995   for my $j (@$fromspec) {
2996
2997     next if ref $j ne 'ARRAY';
2998     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2999
3000     my $jpath = $j->[0]{-join_path};
3001
3002     my $p = $paths;
3003     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
3004     push @{$p->{-join_aliases} }, $j->[0]{-alias};
3005   }
3006
3007   return $paths;
3008 }
3009
3010 sub _rollout_attr {
3011   my ($self, $attr) = @_;
3012
3013   if (ref $attr eq 'HASH') {
3014     return $self->_rollout_hash($attr);
3015   } elsif (ref $attr eq 'ARRAY') {
3016     return $self->_rollout_array($attr);
3017   } else {
3018     return [$attr];
3019   }
3020 }
3021
3022 sub _rollout_array {
3023   my ($self, $attr) = @_;
3024
3025   my @rolled_array;
3026   foreach my $element (@{$attr}) {
3027     if (ref $element eq 'HASH') {
3028       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3029     } elsif (ref $element eq 'ARRAY') {
3030       #  XXX - should probably recurse here
3031       push( @rolled_array, @{$self->_rollout_array($element)} );
3032     } else {
3033       push( @rolled_array, $element );
3034     }
3035   }
3036   return \@rolled_array;
3037 }
3038
3039 sub _rollout_hash {
3040   my ($self, $attr) = @_;
3041
3042   my @rolled_array;
3043   foreach my $key (keys %{$attr}) {
3044     push( @rolled_array, { $key => $attr->{$key} } );
3045   }
3046   return \@rolled_array;
3047 }
3048
3049 sub _calculate_score {
3050   my ($self, $a, $b) = @_;
3051
3052   if (defined $a xor defined $b) {
3053     return 0;
3054   }
3055   elsif (not defined $a) {
3056     return 1;
3057   }
3058
3059   if (ref $b eq 'HASH') {
3060     my ($b_key) = keys %{$b};
3061     if (ref $a eq 'HASH') {
3062       my ($a_key) = keys %{$a};
3063       if ($a_key eq $b_key) {
3064         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3065       } else {
3066         return 0;
3067       }
3068     } else {
3069       return ($a eq $b_key) ? 1 : 0;
3070     }
3071   } else {
3072     if (ref $a eq 'HASH') {
3073       my ($a_key) = keys %{$a};
3074       return ($b eq $a_key) ? 1 : 0;
3075     } else {
3076       return ($b eq $a) ? 1 : 0;
3077     }
3078   }
3079 }
3080
3081 sub _merge_attr {
3082   my ($self, $orig, $import) = @_;
3083
3084   return $import unless defined($orig);
3085   return $orig unless defined($import);
3086
3087   $orig = $self->_rollout_attr($orig);
3088   $import = $self->_rollout_attr($import);
3089
3090   my $seen_keys;
3091   foreach my $import_element ( @{$import} ) {
3092     # find best candidate from $orig to merge $b_element into
3093     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3094     foreach my $orig_element ( @{$orig} ) {
3095       my $score = $self->_calculate_score( $orig_element, $import_element );
3096       if ($score > $best_candidate->{score}) {
3097         $best_candidate->{position} = $position;
3098         $best_candidate->{score} = $score;
3099       }
3100       $position++;
3101     }
3102     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3103
3104     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3105       push( @{$orig}, $import_element );
3106     } else {
3107       my $orig_best = $orig->[$best_candidate->{position}];
3108       # merge orig_best and b_element together and replace original with merged
3109       if (ref $orig_best ne 'HASH') {
3110         $orig->[$best_candidate->{position}] = $import_element;
3111       } elsif (ref $import_element eq 'HASH') {
3112         my ($key) = keys %{$orig_best};
3113         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3114       }
3115     }
3116     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3117   }
3118
3119   return $orig;
3120 }
3121
3122 sub result_source {
3123     my $self = shift;
3124
3125     if (@_) {
3126         $self->_source_handle($_[0]->handle);
3127     } else {
3128         $self->_source_handle->resolve;
3129     }
3130 }
3131
3132 =head2 throw_exception
3133
3134 See L<DBIx::Class::Schema/throw_exception> for details.
3135
3136 =cut
3137
3138 sub throw_exception {
3139   my $self=shift;
3140
3141   if (ref $self && $self->_source_handle->schema) {
3142     $self->_source_handle->schema->throw_exception(@_)
3143   }
3144   else {
3145     DBIx::Class::Exception->throw(@_);
3146   }
3147 }
3148
3149 # XXX: FIXME: Attributes docs need clearing up
3150
3151 =head1 ATTRIBUTES
3152
3153 Attributes are used to refine a ResultSet in various ways when
3154 searching for data. They can be passed to any method which takes an
3155 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3156 L</count>.
3157
3158 These are in no particular order:
3159
3160 =head2 order_by
3161
3162 =over 4
3163
3164 =item Value: ( $order_by | \@order_by | \%order_by )
3165
3166 =back
3167
3168 Which column(s) to order the results by.
3169
3170 [The full list of suitable values is documented in
3171 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3172 common options.]
3173
3174 If a single column name, or an arrayref of names is supplied, the
3175 argument is passed through directly to SQL. The hashref syntax allows
3176 for connection-agnostic specification of ordering direction:
3177
3178  For descending order:
3179
3180   order_by => { -desc => [qw/col1 col2 col3/] }
3181
3182  For explicit ascending order:
3183
3184   order_by => { -asc => 'col' }
3185
3186 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3187 supported, although you are strongly encouraged to use the hashref
3188 syntax as outlined above.
3189
3190 =head2 columns
3191
3192 =over 4
3193
3194 =item Value: \@columns
3195
3196 =back
3197
3198 Shortcut to request a particular set of columns to be retrieved. Each
3199 column spec may be a string (a table column name), or a hash (in which
3200 case the key is the C<as> value, and the value is used as the C<select>
3201 expression). Adds C<me.> onto the start of any column without a C<.> in
3202 it and sets C<select> from that, then auto-populates C<as> from
3203 C<select> as normal. (You may also use the C<cols> attribute, as in
3204 earlier versions of DBIC.)
3205
3206 =head2 +columns
3207
3208 =over 4
3209
3210 =item Value: \@columns
3211
3212 =back
3213
3214 Indicates additional columns to be selected from storage. Works the same
3215 as L</columns> but adds columns to the selection. (You may also use the
3216 C<include_columns> attribute, as in earlier versions of DBIC). For
3217 example:-
3218
3219   $schema->resultset('CD')->search(undef, {
3220     '+columns' => ['artist.name'],
3221     join => ['artist']
3222   });
3223
3224 would return all CDs and include a 'name' column to the information
3225 passed to object inflation. Note that the 'artist' is the name of the
3226 column (or relationship) accessor, and 'name' is the name of the column
3227 accessor in the related table.
3228
3229 =head2 include_columns
3230
3231 =over 4
3232
3233 =item Value: \@columns
3234
3235 =back
3236
3237 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3238
3239 =head2 select
3240
3241 =over 4
3242
3243 =item Value: \@select_columns
3244
3245 =back
3246
3247 Indicates which columns should be selected from the storage. You can use
3248 column names, or in the case of RDBMS back ends, function or stored procedure
3249 names:
3250
3251   $rs = $schema->resultset('Employee')->search(undef, {
3252     select => [
3253       'name',
3254       { count => 'employeeid' },
3255       { sum => 'salary' }
3256     ]
3257   });
3258
3259 When you use function/stored procedure names and do not supply an C<as>
3260 attribute, the column names returned are storage-dependent. E.g. MySQL would
3261 return a column named C<count(employeeid)> in the above example.
3262
3263 =head2 +select
3264
3265 =over 4
3266
3267 Indicates additional columns to be selected from storage.  Works the same as
3268 L</select> but adds columns to the selection.
3269
3270 =back
3271
3272 =head2 +as
3273
3274 =over 4
3275
3276 Indicates additional column names for those added via L</+select>. See L</as>.
3277
3278 =back
3279
3280 =head2 as
3281
3282 =over 4
3283
3284 =item Value: \@inflation_names
3285
3286 =back
3287
3288 Indicates column names for object inflation. That is, C<as>
3289 indicates the name that the column can be accessed as via the
3290 C<get_column> method (or via the object accessor, B<if one already
3291 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3292
3293 The C<as> attribute is used in conjunction with C<select>,
3294 usually when C<select> contains one or more function or stored
3295 procedure names:
3296
3297   $rs = $schema->resultset('Employee')->search(undef, {
3298     select => [
3299       'name',
3300       { count => 'employeeid' }
3301     ],
3302     as => ['name', 'employee_count'],
3303   });
3304
3305   my $employee = $rs->first(); # get the first Employee
3306
3307 If the object against which the search is performed already has an accessor
3308 matching a column name specified in C<as>, the value can be retrieved using
3309 the accessor as normal:
3310
3311   my $name = $employee->name();
3312
3313 If on the other hand an accessor does not exist in the object, you need to
3314 use C<get_column> instead:
3315
3316   my $employee_count = $employee->get_column('employee_count');
3317
3318 You can create your own accessors if required - see
3319 L<DBIx::Class::Manual::Cookbook> for details.
3320
3321 Please note: This will NOT insert an C<AS employee_count> into the SQL
3322 statement produced, it is used for internal access only. Thus
3323 attempting to use the accessor in an C<order_by> clause or similar
3324 will fail miserably.
3325
3326 To get around this limitation, you can supply literal SQL to your
3327 C<select> attibute that contains the C<AS alias> text, eg:
3328
3329   select => [\'myfield AS alias']
3330
3331 =head2 join
3332
3333 =over 4
3334
3335 =item Value: ($rel_name | \@rel_names | \%rel_names)
3336
3337 =back
3338
3339 Contains a list of relationships that should be joined for this query.  For
3340 example:
3341
3342   # Get CDs by Nine Inch Nails
3343   my $rs = $schema->resultset('CD')->search(
3344     { 'artist.name' => 'Nine Inch Nails' },
3345     { join => 'artist' }
3346   );
3347
3348 Can also contain a hash reference to refer to the other relation's relations.
3349 For example:
3350
3351   package MyApp::Schema::Track;
3352   use base qw/DBIx::Class/;
3353   __PACKAGE__->table('track');
3354   __PACKAGE__->add_columns(qw/trackid cd position title/);
3355   __PACKAGE__->set_primary_key('trackid');
3356   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3357   1;
3358
3359   # In your application
3360   my $rs = $schema->resultset('Artist')->search(
3361     { 'track.title' => 'Teardrop' },
3362     {
3363       join     => { cd => 'track' },
3364       order_by => 'artist.name',
3365     }
3366   );
3367
3368 You need to use the relationship (not the table) name in  conditions,
3369 because they are aliased as such. The current table is aliased as "me", so
3370 you need to use me.column_name in order to avoid ambiguity. For example:
3371
3372   # Get CDs from 1984 with a 'Foo' track
3373   my $rs = $schema->resultset('CD')->search(
3374     {
3375       'me.year' => 1984,
3376       'tracks.name' => 'Foo'
3377     },
3378     { join => 'tracks' }
3379   );
3380
3381 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3382 similarly for a third time). For e.g.
3383
3384   my $rs = $schema->resultset('Artist')->search({
3385     'cds.title'   => 'Down to Earth',
3386     'cds_2.title' => 'Popular',
3387   }, {
3388     join => [ qw/cds cds/ ],
3389   });
3390
3391 will return a set of all artists that have both a cd with title 'Down
3392 to Earth' and a cd with title 'Popular'.
3393
3394 If you want to fetch related objects from other tables as well, see C<prefetch>
3395 below.
3396
3397 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3398
3399 =head2 prefetch
3400
3401 =over 4
3402
3403 =item Value: ($rel_name | \@rel_names | \%rel_names)
3404
3405 =back
3406
3407 Contains one or more relationships that should be fetched along with
3408 the main query (when they are accessed afterwards the data will
3409 already be available, without extra queries to the database).  This is
3410 useful for when you know you will need the related objects, because it
3411 saves at least one query:
3412
3413   my $rs = $schema->resultset('Tag')->search(
3414     undef,
3415     {
3416       prefetch => {
3417         cd => 'artist'
3418       }
3419     }
3420   );
3421
3422 The initial search results in SQL like the following:
3423
3424   SELECT tag.*, cd.*, artist.* FROM tag
3425   JOIN cd ON tag.cd = cd.cdid
3426   JOIN artist ON cd.artist = artist.artistid
3427
3428 L<DBIx::Class> has no need to go back to the database when we access the
3429 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3430 case.
3431
3432 Simple prefetches will be joined automatically, so there is no need
3433 for a C<join> attribute in the above search.
3434
3435 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3436 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3437 with an accessor type of 'single' or 'filter'). A more complex example that
3438 prefetches an artists cds, the tracks on those cds, and the tags associted
3439 with that artist is given below (assuming many-to-many from artists to tags):
3440
3441  my $rs = $schema->resultset('Artist')->search(
3442    undef,
3443    {
3444      prefetch => [
3445        { cds => 'tracks' },
3446        { artist_tags => 'tags' }
3447      ]
3448    }
3449  );
3450
3451
3452 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3453 attributes will be ignored.
3454
3455 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3456 exactly as you might expect.
3457
3458 =over 4
3459
3460 =item *
3461
3462 Prefetch uses the L</cache> to populate the prefetched relationships. This
3463 may or may not be what you want.
3464
3465 =item *
3466
3467 If you specify a condition on a prefetched relationship, ONLY those
3468 rows that match the prefetched condition will be fetched into that relationship.
3469 This means that adding prefetch to a search() B<may alter> what is returned by
3470 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3471
3472   my $artist_rs = $schema->resultset('Artist')->search({
3473       'cds.year' => 2008,
3474   }, {
3475       join => 'cds',
3476   });
3477
3478   my $count = $artist_rs->first->cds->count;
3479
3480   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3481
3482   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3483
3484   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3485
3486 that cmp_ok() may or may not pass depending on the datasets involved. This
3487 behavior may or may not survive the 0.09 transition.
3488
3489 =back
3490
3491 =head2 page
3492
3493 =over 4
3494
3495 =item Value: $page
3496
3497 =back
3498
3499 Makes the resultset paged and specifies the page to retrieve. Effectively
3500 identical to creating a non-pages resultset and then calling ->page($page)
3501 on it.
3502
3503 If L<rows> attribute is not specified it defaults to 10 rows per page.
3504
3505 When you have a paged resultset, L</count> will only return the number
3506 of rows in the page. To get the total, use the L</pager> and call
3507 C<total_entries> on it.
3508
3509 =head2 rows
3510
3511 =over 4
3512
3513 =item Value: $rows
3514
3515 =back
3516
3517 Specifes the maximum number of rows for direct retrieval or the number of
3518 rows per page if the page attribute or method is used.
3519
3520 =head2 offset
3521
3522 =over 4
3523
3524 =item Value: $offset
3525
3526 =back
3527
3528 Specifies the (zero-based) row number for the  first row to be returned, or the
3529 of the first row of the first page if paging is used.
3530
3531 =head2 group_by
3532
3533 =over 4
3534
3535 =item Value: \@columns
3536
3537 =back
3538
3539 A arrayref of columns to group by. Can include columns of joined tables.
3540
3541   group_by => [qw/ column1 column2 ... /]
3542
3543 =head2 having
3544
3545 =over 4
3546
3547 =item Value: $condition
3548
3549 =back
3550
3551 HAVING is a select statement attribute that is applied between GROUP BY and
3552 ORDER BY. It is applied to the after the grouping calculations have been
3553 done.
3554
3555   having => { 'count(employee)' => { '>=', 100 } }
3556
3557 =head2 distinct
3558
3559 =over 4
3560
3561 =item Value: (0 | 1)
3562
3563 =back
3564
3565 Set to 1 to group by all columns. If the resultset already has a group_by
3566 attribute, this setting is ignored and an appropriate warning is issued.
3567
3568 =head2 where
3569
3570 =over 4
3571
3572 Adds to the WHERE clause.
3573
3574   # only return rows WHERE deleted IS NULL for all searches
3575   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3576
3577 Can be overridden by passing C<< { where => undef } >> as an attribute
3578 to a resultset.
3579
3580 =back
3581
3582 =head2 cache
3583
3584 Set to 1 to cache search results. This prevents extra SQL queries if you
3585 revisit rows in your ResultSet:
3586
3587   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3588
3589   while( my $artist = $resultset->next ) {
3590     ... do stuff ...
3591   }
3592
3593   $rs->first; # without cache, this would issue a query
3594
3595 By default, searches are not cached.
3596
3597 For more examples of using these attributes, see
3598 L<DBIx::Class::Manual::Cookbook>.
3599
3600 =head2 for
3601
3602 =over 4
3603
3604 =item Value: ( 'update' | 'shared' )
3605
3606 =back
3607
3608 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3609 ... FOR SHARED.
3610
3611 =cut
3612
3613 1;