lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either on of the two undef or both undef
 660   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 661     return defined $left ? $left : $right;
 662   }
 663
 664   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 665
 666   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 667
 668     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 669     my @fin = shift @vals;
 670
 671     for my $v (@vals) {
 672       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 673     }
 674
 675     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 676   }
 677
 678   $cond;
 679 }
 680
 681 =head2 search_literal
 682
 683 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 684 should only be used in that context. C<search_literal> is a convenience
 685 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 686 want to ensure columns are bound correctly, use L</search>.
 687
 688 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 689 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 690 require C<search_literal>.
 691
 692 =over 4
 693
 694 =item Arguments: $sql_fragment, @standalone_bind_values
 695
 696 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 697
 698 =back
 699
 700   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 701   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 702
 703 Pass a literal chunk of SQL to be added to the conditional part of the
 704 resultset query.
 705
 706 Example of how to use C<search> instead of C<search_literal>
 707
 708   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 709   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 710
 711 =cut
 712
 713 sub search_literal {
 714   my ($self, $sql, @bind) = @_;
 715   my $attr;
 716   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 717     $attr = pop @bind;
 718   }
 719   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 720 }
 721
 722 =head2 find
 723
 724 =over 4
 725
 726 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 727
 728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 729
 730 =back
 731
 732 Finds and returns a single row based on supplied criteria. Takes either a
 733 hashref with the same format as L</create> (including inference of foreign
 734 keys from related objects), or a list of primary key values in the same
 735 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 736 declaration on the L</result_source>.
 737
 738 In either case an attempt is made to combine conditions already existing on
 739 the resultset with the condition passed to this method.
 740
 741 To aid with preparing the correct query for the storage you may supply the
 742 C<key> attribute, which is the name of a
 743 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 744 unique constraint corresponding to the
 745 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 746 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 747 to construct a query that satisfies the named unique constraint fully (
 748 non-NULL values for each column member of the constraint) an exception is
 749 thrown.
 750
 751 If no C<key> is specified, the search is carried over all unique constraints
 752 which are fully defined by the available condition.
 753
 754 If no such constraint is found, C<find> currently defaults to a simple
 755 C<< search->(\%column_values) >> which may or may not do what you expect.
 756 Note that this fallback behavior may be deprecated in further versions. If
 757 you need to search with arbitrary conditions - use L</search>. If the query
 758 resulting from this fallback produces more than one row, a warning to the
 759 effect is issued, though only the first row is constructed and returned as
 760 C<$result_object>.
 761
 762 In addition to C<key>, L</find> recognizes and applies standard
 763 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 764
 765 Note that if you have extra concerns about the correctness of the resulting
 766 query you need to specify the C<key> attribute and supply the entire condition
 767 as an argument to find (since it is not always possible to perform the
 768 combination of the resultset condition with the supplied one, especially if
 769 the resultset condition contains literal sql).
 770
 771 For example, to find a row by its primary key:
 772
 773   my $cd = $schema->resultset('CD')->find(5);
 774
 775 You can also find a row by a specific unique constraint:
 776
 777   my $cd = $schema->resultset('CD')->find(
 778     {
 779       artist => 'Massive Attack',
 780       title  => 'Mezzanine',
 781     },
 782     { key => 'cd_artist_title' }
 783   );
 784
 785 See also L</find_or_create> and L</update_or_create>.
 786
 787 =cut
 788
 789 sub find {
 790   my $self = shift;
 791   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 792
 793   my $rsrc = $self->result_source;
 794
 795   my $constraint_name;
 796   if (exists $attrs->{key}) {
 797     $constraint_name = defined $attrs->{key}
 798       ? $attrs->{key}
 799       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 800     ;
 801   }
 802
 803   # Parse out the condition from input
 804   my $call_cond;
 805
 806   if (ref $_[0] eq 'HASH') {
 807     $call_cond = { %{$_[0]} };
 808   }
 809   else {
 810     # if only values are supplied we need to default to 'primary'
 811     $constraint_name = 'primary' unless defined $constraint_name;
 812
 813     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 814
 815     $self->throw_exception(
 816       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 817     ) unless @c_cols;
 818
 819     $self->throw_exception (
 820       'find() expects either a column/value hashref, or a list of values '
 821     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 822     ) unless @c_cols == @_;
 823
 824     @{$call_cond}{@c_cols} = @_;
 825   }
 826
 827   # process relationship data if any
 828   for my $key (keys %$call_cond) {
 829     if (
 830       length ref($call_cond->{$key})
 831         and
 832       my $relinfo = $rsrc->relationship_info($key)
 833         and
 834       # implicitly skip has_many's (likely MC)
 835       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 836     ) {
 837       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 838         $relinfo->{cond}, $val, $key, $key
 839       );
 840
 841       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 842          if $crosstable or ref($rel_cond) ne 'HASH';
 843
 844       # supplement condition
 845       # relationship conditions take precedence (?)
 846       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 847     }
 848   }
 849
 850   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 851   my $final_cond;
 852   if (defined $constraint_name) {
 853     $final_cond = $self->_qualify_cond_columns (
 854
 855       $self->result_source->_minimal_valueset_satisfying_constraint(
 856         constraint_name => $constraint_name,
 857         values => ($self->_merge_with_rscond($call_cond))[0],
 858         carp_on_nulls => 1,
 859       ),
 860
 861       $alias,
 862     );
 863   }
 864   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 865     # This means that we got here after a merger of relationship conditions
 866     # in ::Relationship::Base::search_related (the row method), and furthermore
 867     # the relationship is of the 'single' type. This means that the condition
 868     # provided by the relationship (already attached to $self) is sufficient,
 869     # as there can be only one row in the database that would satisfy the
 870     # relationship
 871   }
 872   else {
 873     my (@unique_queries, %seen_column_combinations);
 874
 875     # no key was specified - fall down to heuristics mode:
 876     # run through all unique queries registered on the resultset, and
 877     # 'OR' all qualifying queries together
 878     #
 879     # always start from 'primary' if it exists at all
 880     for my $c_name ( sort {
 881         $a eq 'primary' ? -1
 882       : $b eq 'primary' ? 1
 883       : $a cmp $b
 884     } $rsrc->unique_constraint_names) {
 885
 886       next if $seen_column_combinations{
 887         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 888       }++;
 889
 890       push @unique_queries, try {
 891         $self->result_source->_minimal_valueset_satisfying_constraint(
 892           constraint_name => $c_name,
 893           values => ($self->_merge_with_rscond($call_cond))[0],
 894         ),
 895       } || ();
 896     }
 897
 898     $final_cond = @unique_queries
 899       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 900       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 901     ;
 902   }
 903
 904   # Run the query, passing the result_class since it should propagate for find
 905   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 906   if ($rs->_resolved_attrs->{collapse}) {
 907     my $row = $rs->next;
 908     carp "Query returned more than one row" if $rs->next;
 909     return $row;
 910   }
 911   else {
 912     return $rs->single;
 913   }
 914 }
 915
 916 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 917 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 918 #
 919 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 920 # condition. It is provided for overrides until a saner way forward is devised
 921 #
 922 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 923 # the road. Please adjust your tests accordingly to catch this situation early
 924 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 925 #
 926 # The method will not be removed without an adequately complete replacement
 927 # for strict-mode enforcement
 928 sub _non_unique_find_fallback {
 929   my ($self, $cond, $attrs) = @_;
 930
 931   return $self->_qualify_cond_columns(
 932     $cond,
 933     exists $attrs->{alias}
 934       ? $attrs->{alias}
 935       : $self->{attrs}{alias}
 936   );
 937 }
 938
 939
 940 sub _qualify_cond_columns {
 941   my ($self, $cond, $alias) = @_;
 942
 943   my %aliased = %$cond;
 944   for (keys %aliased) {
 945     $aliased{"$alias.$_"} = delete $aliased{$_}
 946       if $_ !~ /\./;
 947   }
 948
 949   return \%aliased;
 950 }
 951
 952 sub _build_unique_cond {
 953   carp_unique sprintf
 954     '_build_unique_cond is a private method, and moreover is about to go '
 955   . 'away. Please contact the development team at %s if you believe you '
 956   . 'have a genuine use for this method, in order to discuss alternatives.',
 957     DBIx::Class::_ENV_::HELP_URL,
 958   ;
 959
 960   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 961
 962   $self->result_source->_minimal_valueset_satisfying_constraint(
 963     constraint_name => $constraint_name,
 964     values => $cond,
 965     carp_on_nulls => !$croak_on_null
 966   );
 967 }
 968
 969 =head2 search_related
 970
 971 =over 4
 972
 973 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 974
 975 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 976
 977 =back
 978
 979   $new_rs = $cd_rs->search_related('artist', {
 980     name => 'Emo-R-Us',
 981   });
 982
 983 Searches the specified relationship, optionally specifying a condition and
 984 attributes for matching records. See L</ATTRIBUTES> for more information.
 985
 986 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 987 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 988
 989 See also L</search_related_rs>.
 990
 991 =cut
 992
 993 sub search_related {
 994   return shift->related_resultset(shift)->search(@_);
 995 }
 996
 997 =head2 search_related_rs
 998
 999 This method works exactly the same as search_related, except that
1000 it guarantees a resultset, even in list context.
1001
1002 =cut
1003
1004 sub search_related_rs {
1005   return shift->related_resultset(shift)->search_rs(@_);
1006 }
1007
1008 =head2 cursor
1009
1010 =over 4
1011
1012 =item Arguments: none
1013
1014 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1015
1016 =back
1017
1018 Returns a storage-driven cursor to the given resultset. See
1019 L<DBIx::Class::Cursor> for more information.
1020
1021 =cut
1022
1023 sub cursor {
1024   my $self = shift;
1025
1026   return $self->{cursor} ||= do {
1027     my $attrs = $self->_resolved_attrs;
1028     $self->result_source->storage->select(
1029       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1030     );
1031   };
1032 }
1033
1034 =head2 single
1035
1036 =over 4
1037
1038 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1039
1040 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1041
1042 =back
1043
1044   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1045
1046 Inflates the first result without creating a cursor if the resultset has
1047 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1048 of L</search>.
1049
1050 While this method can take an optional search condition (just like L</search>)
1051 being a fast-code-path it does not recognize search attributes. If you need to
1052 add extra joins or similar, call L</search> and then chain-call L</single> on the
1053 L<DBIx::Class::ResultSet> returned.
1054
1055 =over
1056
1057 =item B<Note>
1058
1059 As of 0.08100, this method enforces the assumption that the preceding
1060 query returns only one row. If more than one row is returned, you will receive
1061 a warning:
1062
1063   Query returned more than one row
1064
1065 In this case, you should be using L</next> or L</find> instead, or if you really
1066 know what you are doing, use the L</rows> attribute to explicitly limit the size
1067 of the resultset.
1068
1069 This method will also throw an exception if it is called on a resultset prefetching
1070 has_many, as such a prefetch implies fetching multiple rows from the database in
1071 order to assemble the resulting object.
1072
1073 =back
1074
1075 =cut
1076
1077 sub single {
1078   my ($self, $where) = @_;
1079   if(@_ > 2) {
1080       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1081   }
1082
1083   my $attrs = { %{$self->_resolved_attrs} };
1084
1085   $self->throw_exception(
1086     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1087   ) if $attrs->{collapse};
1088
1089   if ($where) {
1090     if (defined $attrs->{where}) {
1091       $attrs->{where} = {
1092         '-and' =>
1093             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1094                $where, delete $attrs->{where} ]
1095       };
1096     } else {
1097       $attrs->{where} = $where;
1098     }
1099   }
1100
1101   my $data = [ $self->result_source->storage->select_single(
1102     $attrs->{from}, $attrs->{select},
1103     $attrs->{where}, $attrs
1104   )];
1105
1106   return undef unless @$data;
1107   $self->{_stashed_rows} = [ $data ];
1108   $self->_construct_results->[0];
1109 }
1110
1111 =head2 get_column
1112
1113 =over 4
1114
1115 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1116
1117 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1118
1119 =back
1120
1121   my $max_length = $rs->get_column('length')->max;
1122
1123 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1124
1125 =cut
1126
1127 sub get_column {
1128   my ($self, $column) = @_;
1129   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1130   return $new;
1131 }
1132
1133 =head2 search_like
1134
1135 =over 4
1136
1137 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1138
1139 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1140
1141 =back
1142
1143   # WHERE title LIKE '%blue%'
1144   $cd_rs = $rs->search_like({ title => '%blue%'});
1145
1146 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1147 that this is simply a convenience method retained for ex Class::DBI users.
1148 You most likely want to use L</search> with specific operators.
1149
1150 For more information, see L<DBIx::Class::Manual::Cookbook>.
1151
1152 This method is deprecated and will be removed in 0.09. Use L</search()>
1153 instead. An example conversion is:
1154
1155   ->search_like({ foo => 'bar' });
1156
1157   # Becomes
1158
1159   ->search({ foo => { like => 'bar' } });
1160
1161 =cut
1162
1163 sub search_like {
1164   my $class = shift;
1165   carp_unique (
1166     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1167    .' Instead use ->search({ x => { -like => "y%" } })'
1168    .' (note the outer pair of {}s - they are important!)'
1169   );
1170   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1171   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1172   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1173   return $class->search($query, { %$attrs });
1174 }
1175
1176 =head2 slice
1177
1178 =over 4
1179
1180 =item Arguments: $first, $last
1181
1182 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1183
1184 =back
1185
1186 Returns a resultset or object list representing a subset of elements from the
1187 resultset slice is called on. Indexes are from 0, i.e., to get the first
1188 three records, call:
1189
1190   my ($one, $two, $three) = $rs->slice(0, 2);
1191
1192 =cut
1193
1194 sub slice {
1195   my ($self, $min, $max) = @_;
1196   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1197   $attrs->{offset} = $self->{attrs}{offset} || 0;
1198   $attrs->{offset} += $min;
1199   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1200   return $self->search(undef, $attrs);
1201 }
1202
1203 =head2 next
1204
1205 =over 4
1206
1207 =item Arguments: none
1208
1209 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1210
1211 =back
1212
1213 Returns the next element in the resultset (C<undef> is there is none).
1214
1215 Can be used to efficiently iterate over records in the resultset:
1216
1217   my $rs = $schema->resultset('CD')->search;
1218   while (my $cd = $rs->next) {
1219     print $cd->title;
1220   }
1221
1222 Note that you need to store the resultset object, and call C<next> on it.
1223 Calling C<< resultset('Table')->next >> repeatedly will always return the
1224 first record from the resultset.
1225
1226 =cut
1227
1228 sub next {
1229   my ($self) = @_;
1230
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241
1242   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1243
1244   $self->{_stashed_results} = $self->_construct_results
1245     or return undef;
1246
1247   return shift @{$self->{_stashed_results}};
1248 }
1249
1250 # Constructs as many results as it can in one pass while respecting
1251 # cursor laziness. Several modes of operation:
1252 #
1253 # * Always builds everything present in @{$self->{_stashed_rows}}
1254 # * If called with $fetch_all true - pulls everything off the cursor and
1255 #   builds all result structures (or objects) in one pass
1256 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1257 #   and if the resultset is ordered properly by the left side:
1258 #   * Fetches stuff off the cursor until the "master object" changes,
1259 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1260 #   OR
1261 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1262 #     was requested (there is no other way to collapse except for an
1263 #     eager cursor)
1264 # * If no collapse is requested - just get the next row, construct and
1265 #   return
1266 sub _construct_results {
1267   my ($self, $fetch_all) = @_;
1268
1269   my $rsrc = $self->result_source;
1270   my $attrs = $self->_resolved_attrs;
1271
1272   if (
1273     ! $fetch_all
1274       and
1275     ! $attrs->{order_by}
1276       and
1277     $attrs->{collapse}
1278       and
1279     my @pcols = $rsrc->primary_columns
1280   ) {
1281     # default order for collapsing unless the user asked for something
1282     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1283     $attrs->{_ordered_for_collapse} = 1;
1284     $attrs->{_order_is_artificial} = 1;
1285   }
1286
1287   # this will be used as both initial raw-row collector AND as a RV of
1288   # _construct_results. Not regrowing the array twice matters a lot...
1289   # a surprising amount actually
1290   my $rows = delete $self->{_stashed_rows};
1291
1292   my $cursor; # we may not need one at all
1293
1294   my $did_fetch_all = $fetch_all;
1295
1296   if ($fetch_all) {
1297     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1298     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1299   }
1300   elsif( $attrs->{collapse} ) {
1301
1302     # a cursor will need to be closed over in case of collapse
1303     $cursor = $self->cursor;
1304
1305     $attrs->{_ordered_for_collapse} = (
1306       (
1307         $attrs->{order_by}
1308           and
1309         $rsrc->schema
1310               ->storage
1311                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1312       ) ? 1 : 0
1313     ) unless defined $attrs->{_ordered_for_collapse};
1314
1315     if (! $attrs->{_ordered_for_collapse}) {
1316       $did_fetch_all = 1;
1317
1318       # instead of looping over ->next, use ->all in stealth mode
1319       # *without* calling a ->reset afterwards
1320       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1321       if (! $cursor->{_done}) {
1322         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1323         $cursor->{_done} = 1;
1324       }
1325     }
1326   }
1327
1328   if (! $did_fetch_all and ! @{$rows||[]} ) {
1329     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1330     $cursor ||= $self->cursor;
1331     if (scalar (my @r = $cursor->next) ) {
1332       $rows = [ \@r ];
1333     }
1334   }
1335
1336   return undef unless @{$rows||[]};
1337
1338   # sanity check - people are too clever for their own good
1339   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1340
1341     my $multiplied_selectors;
1342     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1343       if (
1344         $aliastypes->{multiplying}{$sel_alias}
1345           or
1346         $aliastypes->{premultiplied}{$sel_alias}
1347       ) {
1348         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1349       }
1350     }
1351
1352     for my $i (0 .. $#{$attrs->{as}} ) {
1353       my $sel = $attrs->{select}[$i];
1354
1355       if (ref $sel eq 'SCALAR') {
1356         $sel = $$sel;
1357       }
1358       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1359         $sel = $$sel->[0];
1360       }
1361
1362       $self->throw_exception(
1363         'Result collapse not possible - selection from a has_many source redirected to the main object'
1364       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1365     }
1366   }
1367
1368   # hotspot - skip the setter
1369   my $res_class = $self->_result_class;
1370
1371   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1372     $res_class->can ('inflate_result')
1373       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1374   };
1375
1376   my $infmap = $attrs->{as};
1377
1378   $self->{_result_inflator}{is_core_row} = ( (
1379     $inflator_cref
1380       ==
1381     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1383
1384   $self->{_result_inflator}{is_hri} = ( (
1385     ! $self->{_result_inflator}{is_core_row}
1386       and
1387     $inflator_cref == (
1388       require DBIx::Class::ResultClass::HashRefInflator
1389         &&
1390       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1391     )
1392   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1393
1394
1395   if ($attrs->{_simple_passthrough_construction}) {
1396     # construct a much simpler array->hash folder for the one-table HRI cases right here
1397     if ($self->{_result_inflator}{is_hri}) {
1398       for my $r (@$rows) {
1399         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1400       }
1401     }
1402     # FIXME SUBOPTIMAL this is a very very very hot spot
1403     # while rather optimal we can *still* do much better, by
1404     # building a smarter Row::inflate_result(), and
1405     # switch to feeding it data via a much leaner interface
1406     #
1407     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1408     # this particular resultset size
1409     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1410       for my $r (@$rows) {
1411         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1412       }
1413     }
1414     else {
1415       eval sprintf (
1416         ( $self->{_result_inflator}{is_core_row}
1417           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1418           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1419           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1420         ),
1421         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1422       );
1423     }
1424   }
1425   else {
1426     my $parser_type =
1427         $self->{_result_inflator}{is_hri}       ? 'hri'
1428       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1429       :                                           'classic_nonpruning'
1430     ;
1431
1432     # $args and $attrs to _mk_row_parser are separated to delineate what is
1433     # core collapser stuff and what is dbic $rs specific
1434     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1435       eval => 1,
1436       inflate_map => $infmap,
1437       collapse => $attrs->{collapse},
1438       premultiplied => $attrs->{_main_source_premultiplied},
1439       hri_style => $self->{_result_inflator}{is_hri},
1440       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1441     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1442
1443     # column_info metadata historically hasn't been too reliable.
1444     # We need to start fixing this somehow (the collapse resolver
1445     # can't work without it). Add an explicit check for the *main*
1446     # result, hopefully this will gradually weed out such errors
1447     #
1448     # FIXME - this is a temporary kludge that reduces performance
1449     # It is however necessary for the time being
1450     my ($unrolled_non_null_cols_to_check, $err);
1451
1452     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1453
1454       $err =
1455         'Collapse aborted due to invalid ResultSource metadata - the following '
1456       . 'selections are declared non-nullable but NULLs were retrieved: '
1457       ;
1458
1459       my @violating_idx;
1460       COL: for my $i (@$check_non_null_cols) {
1461         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1462       }
1463
1464       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1465         if @violating_idx;
1466
1467       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1468     }
1469
1470     my $next_cref =
1471       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1472     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1473 sub {
1474   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1475   my @r = $cursor->next or return;
1476   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1477     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1478   }
1479   \@r
1480 }
1481 EOS
1482     : sub {
1483         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1484         my @r = $cursor->next or return;
1485         \@r
1486       }
1487     ;
1488
1489     $self->{_row_parser}{$parser_type}{cref}->(
1490       $rows,
1491       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1492     );
1493
1494     # simple in-place substitution, does not regrow $rows
1495     if ($self->{_result_inflator}{is_core_row}) {
1496       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1497     }
1498     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1499     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1500       # the inflator may be a multiplier/reductor - put it in list ctx
1501       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1502     }
1503   }
1504
1505   # The @$rows check seems odd at first - why wouldn't we want to warn
1506   # regardless? The issue is things like find() etc, where the user
1507   # *knows* only one result will come back. In these cases the ->all
1508   # is not a pessimization, but rather something we actually want
1509   carp_unique(
1510     'Unable to properly collapse has_many results in iterator mode due '
1511   . 'to order criteria - performed an eager cursor slurp underneath. '
1512   . 'Consider using ->all() instead'
1513   ) if ( ! $fetch_all and @$rows > 1 );
1514
1515   return $rows;
1516 }
1517
1518 =head2 result_source
1519
1520 =over 4
1521
1522 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1523
1524 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1525
1526 =back
1527
1528 An accessor for the primary ResultSource object from which this ResultSet
1529 is derived.
1530
1531 =head2 result_class
1532
1533 =over 4
1534
1535 =item Arguments: $result_class?
1536
1537 =item Return Value: $result_class
1538
1539 =back
1540
1541 An accessor for the class to use when creating result objects. Defaults to
1542 C<< result_source->result_class >> - which in most cases is the name of the
1543 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1544
1545 Note that changing the result_class will also remove any components
1546 that were originally loaded in the source class via
1547 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1548 in the original source class will not run.
1549
1550 =cut
1551
1552 sub result_class {
1553   my ($self, $result_class) = @_;
1554   if ($result_class) {
1555
1556     # don't fire this for an object
1557     $self->ensure_class_loaded($result_class)
1558       unless ref($result_class);
1559
1560     if ($self->get_cache) {
1561       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1562     }
1563     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1564     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1565       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1566     }
1567
1568     $self->_result_class($result_class);
1569
1570     delete $self->{_result_inflator};
1571   }
1572   $self->_result_class;
1573 }
1574
1575 =head2 count
1576
1577 =over 4
1578
1579 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1580
1581 =item Return Value: $count
1582
1583 =back
1584
1585 Performs an SQL C<COUNT> with the same query as the resultset was built
1586 with to find the number of elements. Passing arguments is equivalent to
1587 C<< $rs->search ($cond, \%attrs)->count >>
1588
1589 =cut
1590
1591 sub count {
1592   my $self = shift;
1593   return $self->search(@_)->count if @_ and defined $_[0];
1594   return scalar @{ $self->get_cache } if $self->get_cache;
1595
1596   my $attrs = { %{ $self->_resolved_attrs } };
1597
1598   # this is a little optimization - it is faster to do the limit
1599   # adjustments in software, instead of a subquery
1600   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1601
1602   my $crs;
1603   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1604     $crs = $self->_count_subq_rs ($attrs);
1605   }
1606   else {
1607     $crs = $self->_count_rs ($attrs);
1608   }
1609   my $count = $crs->next;
1610
1611   $count -= $offset if $offset;
1612   $count = $rows if $rows and $rows < $count;
1613   $count = 0 if ($count < 0);
1614
1615   return $count;
1616 }
1617
1618 =head2 count_rs
1619
1620 =over 4
1621
1622 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1623
1624 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1625
1626 =back
1627
1628 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1629 This can be very handy for subqueries:
1630
1631   ->search( { amount => $some_rs->count_rs->as_query } )
1632
1633 As with regular resultsets the SQL query will be executed only after
1634 the resultset is accessed via L</next> or L</all>. That would return
1635 the same single value obtainable via L</count>.
1636
1637 =cut
1638
1639 sub count_rs {
1640   my $self = shift;
1641   return $self->search(@_)->count_rs if @_;
1642
1643   # this may look like a lack of abstraction (count() does about the same)
1644   # but in fact an _rs *must* use a subquery for the limits, as the
1645   # software based limiting can not be ported if this $rs is to be used
1646   # in a subquery itself (i.e. ->as_query)
1647   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1648     return $self->_count_subq_rs($self->{_attrs});
1649   }
1650   else {
1651     return $self->_count_rs($self->{_attrs});
1652   }
1653 }
1654
1655 #
1656 # returns a ResultSetColumn object tied to the count query
1657 #
1658 sub _count_rs {
1659   my ($self, $attrs) = @_;
1660
1661   my $rsrc = $self->result_source;
1662
1663   my $tmp_attrs = { %$attrs };
1664   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1665   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1666
1667   # overwrite the selector (supplied by the storage)
1668   $rsrc->resultset_class->new($rsrc, {
1669     %$tmp_attrs,
1670     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1671     as => 'count',
1672   })->get_column ('count');
1673 }
1674
1675 #
1676 # same as above but uses a subquery
1677 #
1678 sub _count_subq_rs {
1679   my ($self, $attrs) = @_;
1680
1681   my $rsrc = $self->result_source;
1682
1683   my $sub_attrs = { %$attrs };
1684   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1685   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1686
1687   # if we multi-prefetch we group_by something unique, as this is what we would
1688   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1689   if ( $attrs->{collapse}  ) {
1690     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1691       $rsrc->_identifying_column_set || $self->throw_exception(
1692         'Unable to construct a unique group_by criteria properly collapsing the '
1693       . 'has_many prefetch before count()'
1694       );
1695     } ]
1696   }
1697
1698   # Calculate subquery selector
1699   if (my $g = $sub_attrs->{group_by}) {
1700
1701     my $sql_maker = $rsrc->storage->sql_maker;
1702
1703     # necessary as the group_by may refer to aliased functions
1704     my $sel_index;
1705     for my $sel (@{$attrs->{select}}) {
1706       $sel_index->{$sel->{-as}} = $sel
1707         if (ref $sel eq 'HASH' and $sel->{-as});
1708     }
1709
1710     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1711     # also look for named aggregates referred in the having clause
1712     # having often contains scalarrefs - thus parse it out entirely
1713     my @parts = @$g;
1714     if ($attrs->{having}) {
1715       local $sql_maker->{having_bind};
1716       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1717       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1718       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1719         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1720         # if we don't unset it we screw up retarded but unfortunately working
1721         # 'MAX(foo.bar)' => { '>', 3 }
1722         $sql_maker->{name_sep} = '';
1723       }
1724
1725       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1726
1727       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1728       my %seen_having;
1729
1730       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1731       # and if all fails for an utterly naive quoted scalar-with-function
1732       while ($having_sql =~ /
1733         $rquote $sep $lquote (.+?) $rquote
1734           |
1735         [\s,] \w+ \. (\w+) [\s,]
1736           |
1737         [\s,] $lquote (.+?) $rquote [\s,]
1738       /gx) {
1739         my $part = $1 || $2 || $3;  # one of them matched if we got here
1740         unless ($seen_having{$part}++) {
1741           push @parts, $part;
1742         }
1743       }
1744     }
1745
1746     for (@parts) {
1747       my $colpiece = $sel_index->{$_} || $_;
1748
1749       # unqualify join-based group_by's. Arcane but possible query
1750       # also horrible horrible hack to alias a column (not a func.)
1751       # (probably need to introduce SQLA syntax)
1752       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1753         my $as = $colpiece;
1754         $as =~ s/\./__/;
1755         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1756       }
1757       push @{$sub_attrs->{select}}, $colpiece;
1758     }
1759   }
1760   else {
1761     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1762     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1763   }
1764
1765   return $rsrc->resultset_class
1766                ->new ($rsrc, $sub_attrs)
1767                 ->as_subselect_rs
1768                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1769                   ->get_column ('count');
1770 }
1771
1772
1773 =head2 count_literal
1774
1775 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1776 should only be used in that context. See L</search_literal> for further info.
1777
1778 =over 4
1779
1780 =item Arguments: $sql_fragment, @standalone_bind_values
1781
1782 =item Return Value: $count
1783
1784 =back
1785
1786 Counts the results in a literal query. Equivalent to calling L</search_literal>
1787 with the passed arguments, then L</count>.
1788
1789 =cut
1790
1791 sub count_literal { shift->search_literal(@_)->count; }
1792
1793 =head2 all
1794
1795 =over 4
1796
1797 =item Arguments: none
1798
1799 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1800
1801 =back
1802
1803 Returns all elements in the resultset.
1804
1805 =cut
1806
1807 sub all {
1808   my $self = shift;
1809   if(@_) {
1810     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1811   }
1812
1813   delete @{$self}{qw/_stashed_rows _stashed_results/};
1814
1815   if (my $c = $self->get_cache) {
1816     return @$c;
1817   }
1818
1819   $self->cursor->reset;
1820
1821   my $objs = $self->_construct_results('fetch_all') || [];
1822
1823   $self->set_cache($objs) if $self->{attrs}{cache};
1824
1825   return @$objs;
1826 }
1827
1828 =head2 reset
1829
1830 =over 4
1831
1832 =item Arguments: none
1833
1834 =item Return Value: $self
1835
1836 =back
1837
1838 Resets the resultset's cursor, so you can iterate through the elements again.
1839 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1840 another query.
1841
1842 =cut
1843
1844 sub reset {
1845   my ($self) = @_;
1846
1847   delete @{$self}{qw/_stashed_rows _stashed_results/};
1848   $self->{all_cache_position} = 0;
1849   $self->cursor->reset;
1850   return $self;
1851 }
1852
1853 =head2 first
1854
1855 =over 4
1856
1857 =item Arguments: none
1858
1859 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1860
1861 =back
1862
1863 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1864 an object for the first result (or C<undef> if the resultset is empty).
1865
1866 =cut
1867
1868 sub first {
1869   return $_[0]->reset->next;
1870 }
1871
1872
1873 # _rs_update_delete
1874 #
1875 # Determines whether and what type of subquery is required for the $rs operation.
1876 # If grouping is necessary either supplies its own, or verifies the current one
1877 # After all is done delegates to the proper storage method.
1878
1879 sub _rs_update_delete {
1880   my ($self, $op, $values) = @_;
1881
1882   my $rsrc = $self->result_source;
1883   my $storage = $rsrc->schema->storage;
1884
1885   my $attrs = { %{$self->_resolved_attrs} };
1886
1887   my $join_classifications;
1888   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1889
1890   # do we need a subquery for any reason?
1891   my $needs_subq = (
1892     defined $existing_group_by
1893       or
1894     # if {from} is unparseable wrap a subq
1895     ref($attrs->{from}) ne 'ARRAY'
1896       or
1897     # limits call for a subq
1898     $self->_has_resolved_attr(qw/rows offset/)
1899   );
1900
1901   # simplify the joinmap, so we can further decide if a subq is necessary
1902   if (!$needs_subq and @{$attrs->{from}} > 1) {
1903
1904     ($attrs->{from}, $join_classifications) =
1905       $storage->_prune_unused_joins ($attrs);
1906
1907     # any non-pruneable non-local restricting joins imply subq
1908     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1909   }
1910
1911   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1912   $needs_subq ||= (
1913     (ref $attrs->{from}[0]) ne 'HASH'
1914       or
1915     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1916   );
1917
1918   my ($cond, $guard);
1919   # do we need anything like a subquery?
1920   if (! $needs_subq) {
1921     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1922     # a condition containing 'me' or other table prefixes will not work
1923     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1924     $cond = do {
1925       my $sqla = $rsrc->storage->sql_maker;
1926       local $sqla->{_dequalify_idents} = 1;
1927       \[ $sqla->_recurse_where($self->{cond}) ];
1928     };
1929   }
1930   else {
1931     # we got this far - means it is time to wrap a subquery
1932     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1933       sprintf(
1934         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1935         $op,
1936         $rsrc->source_name,
1937       )
1938     );
1939
1940     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1941     delete $attrs->{$_} for qw/select as collapse/;
1942     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1943
1944     # this will be consumed by the pruner waaaaay down the stack
1945     $attrs->{_force_prune_multiplying_joins} = 1;
1946
1947     my $subrs = (ref $self)->new($rsrc, $attrs);
1948
1949     if (@$idcols == 1) {
1950       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1951     }
1952     elsif ($storage->_use_multicolumn_in) {
1953       # no syntax for calling this properly yet
1954       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1955       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1956         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1957         $subrs->as_query
1958       ),
1959     }
1960     else {
1961       # if all else fails - get all primary keys and operate over a ORed set
1962       # wrap in a transaction for consistency
1963       # this is where the group_by/multiplication starts to matter
1964       if (
1965         $existing_group_by
1966           or
1967         # we do not need to check pre-multipliers, since if the premulti is there, its
1968         # parent (who is multi) will be there too
1969         keys %{ $join_classifications->{multiplying} || {} }
1970       ) {
1971         # make sure if there is a supplied group_by it matches the columns compiled above
1972         # perfectly. Anything else can not be sanely executed on most databases so croak
1973         # right then and there
1974         if ($existing_group_by) {
1975           my @current_group_by = map
1976             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1977             @$existing_group_by
1978           ;
1979
1980           if (
1981             join ("\x00", sort @current_group_by)
1982               ne
1983             join ("\x00", sort @{$attrs->{columns}} )
1984           ) {
1985             $self->throw_exception (
1986               "You have just attempted a $op operation on a resultset which does group_by"
1987               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1988               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1989               . ' kind of queries. Please retry the operation with a modified group_by or'
1990               . ' without using one at all.'
1991             );
1992           }
1993         }
1994
1995         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1996       }
1997
1998       $guard = $storage->txn_scope_guard;
1999
2000       for my $row ($subrs->cursor->all) {
2001         push @$cond, { map
2002           { $idcols->[$_] => $row->[$_] }
2003           (0 .. $#$idcols)
2004         };
2005       }
2006     }
2007   }
2008
2009   my $res = $cond ? $storage->$op (
2010     $rsrc,
2011     $op eq 'update' ? $values : (),
2012     $cond,
2013   ) : '0E0';
2014
2015   $guard->commit if $guard;
2016
2017   return $res;
2018 }
2019
2020 =head2 update
2021
2022 =over 4
2023
2024 =item Arguments: \%values
2025
2026 =item Return Value: $underlying_storage_rv
2027
2028 =back
2029
2030 Sets the specified columns in the resultset to the supplied values in a
2031 single query. Note that this will not run any accessor/set_column/update
2032 triggers, nor will it update any result object instances derived from this
2033 resultset (this includes the contents of the L<resultset cache|/set_cache>
2034 if any). See L</update_all> if you need to execute any on-update
2035 triggers or cascades defined either by you or a
2036 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2037
2038 The return value is a pass through of what the underlying
2039 storage backend returned, and may vary. See L<DBI/execute> for the most
2040 common case.
2041
2042 =head3 CAVEAT
2043
2044 Note that L</update> does not process/deflate any of the values passed in.
2045 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2046 ensure manually that any value passed to this method will stringify to
2047 something the RDBMS knows how to deal with. A notable example is the
2048 handling of L<DateTime> objects, for more info see:
2049 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2050
2051 =cut
2052
2053 sub update {
2054   my ($self, $values) = @_;
2055   $self->throw_exception('Values for update must be a hash')
2056     unless ref $values eq 'HASH';
2057
2058   return $self->_rs_update_delete ('update', $values);
2059 }
2060
2061 =head2 update_all
2062
2063 =over 4
2064
2065 =item Arguments: \%values
2066
2067 =item Return Value: 1
2068
2069 =back
2070
2071 Fetches all objects and updates them one at a time via
2072 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2073 triggers, while L</update> will not.
2074
2075 =cut
2076
2077 sub update_all {
2078   my ($self, $values) = @_;
2079   $self->throw_exception('Values for update_all must be a hash')
2080     unless ref $values eq 'HASH';
2081
2082   my $guard = $self->result_source->schema->txn_scope_guard;
2083   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2084   $guard->commit;
2085   return 1;
2086 }
2087
2088 =head2 delete
2089
2090 =over 4
2091
2092 =item Arguments: none
2093
2094 =item Return Value: $underlying_storage_rv
2095
2096 =back
2097
2098 Deletes the rows matching this resultset in a single query. Note that this
2099 will not run any delete triggers, nor will it alter the
2100 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2101 derived from this resultset (this includes the contents of the
2102 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2103 execute any on-delete triggers or cascades defined either by you or a
2104 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2105
2106 The return value is a pass through of what the underlying storage backend
2107 returned, and may vary. See L<DBI/execute> for the most common case.
2108
2109 =cut
2110
2111 sub delete {
2112   my $self = shift;
2113   $self->throw_exception('delete does not accept any arguments')
2114     if @_;
2115
2116   return $self->_rs_update_delete ('delete');
2117 }
2118
2119 =head2 delete_all
2120
2121 =over 4
2122
2123 =item Arguments: none
2124
2125 =item Return Value: 1
2126
2127 =back
2128
2129 Fetches all objects and deletes them one at a time via
2130 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2131 triggers, while L</delete> will not.
2132
2133 =cut
2134
2135 sub delete_all {
2136   my $self = shift;
2137   $self->throw_exception('delete_all does not accept any arguments')
2138     if @_;
2139
2140   my $guard = $self->result_source->schema->txn_scope_guard;
2141   $_->delete for $self->all;
2142   $guard->commit;
2143   return 1;
2144 }
2145
2146 =head2 populate
2147
2148 =over 4
2149
2150 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2151
2152 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2153
2154 =back
2155
2156 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2157 arrayrefs.
2158
2159 =over
2160
2161 =item NOTE
2162
2163 The context of this method call has an important effect on what is
2164 submitted to storage. In void context data is fed directly to fastpath
2165 insertion routines provided by the underlying storage (most often
2166 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2167 L<insert|DBIx::Class::Row/insert> calls on the
2168 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2169 augmentation of these methods provided by components. For example if you
2170 are using something like L<DBIx::Class::UUIDColumns> to create primary
2171 keys for you, you will find that your PKs are empty.  In this case you
2172 will have to explicitly force scalar or list context in order to create
2173 those values.
2174
2175 =back
2176
2177 In non-void (scalar or list) context, this method is simply a wrapper
2178 for L</create>. Depending on list or scalar context either a list of
2179 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2180 containing these objects is returned.
2181
2182 When supplying data in "arrayref of arrayrefs" invocation style, the
2183 first element should be a list of column names and each subsequent
2184 element should be a data value in the earlier specified column order.
2185 For example:
2186
2187   $schema->resultset("Artist")->populate([
2188     [ qw( artistid name ) ],
2189     [ 100, 'A Formally Unknown Singer' ],
2190     [ 101, 'A singer that jumped the shark two albums ago' ],
2191     [ 102, 'An actually cool singer' ],
2192   ]);
2193
2194 For the arrayref of hashrefs style each hashref should be a structure
2195 suitable for passing to L</create>. Multi-create is also permitted with
2196 this syntax.
2197
2198   $schema->resultset("Artist")->populate([
2199      { artistid => 4, name => 'Manufactured Crap', cds => [
2200         { title => 'My First CD', year => 2006 },
2201         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2202       ],
2203      },
2204      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2205         { title => 'My parents sold me to a record company', year => 2005 },
2206         { title => 'Why Am I So Ugly?', year => 2006 },
2207         { title => 'I Got Surgery and am now Popular', year => 2007 }
2208       ],
2209      },
2210   ]);
2211
2212 If you attempt a void-context multi-create as in the example above (each
2213 Artist also has the related list of CDs), and B<do not> supply the
2214 necessary autoinc foreign key information, this method will proxy to the
2215 less efficient L</create>, and then throw the Result objects away. In this
2216 case there are obviously no benefits to using this method over L</create>.
2217
2218 =cut
2219
2220 sub populate {
2221   my $self = shift;
2222
2223   my ($data, $guard);
2224
2225   # this is naive and just a quick check
2226   # the types will need to be checked more thoroughly when the
2227   # multi-source populate gets added
2228   if (ref $_[0] eq 'ARRAY') {
2229     return unless @{$_[0]};
2230
2231     $data = $_[0] if (ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY');
2232   }
2233
2234   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs')
2235     unless $data;
2236
2237   # FIXME - no cref handling
2238   # At this point assume either hashes or arrays
2239
2240   if(defined wantarray) {
2241     my @results;
2242
2243     $guard = $self->result_source->schema->storage->txn_scope_guard
2244       if ( @$data > 2 or ( @$data == 2 and ref $data->[0] eq 'ARRAY' ) );
2245
2246     if (ref $data->[0] eq 'ARRAY') {
2247       @results = map
2248         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2249         @{$data}[1 .. $#$data]
2250       ;
2251     }
2252     else {
2253       @results = map { $self->new_result($_)->insert } @$data;
2254     }
2255
2256     $guard->commit if $guard;
2257     return wantarray ? @results : \@results;
2258   }
2259
2260   # we have to deal with *possibly incomplete* related data
2261   # this means we have to walk the data structure twice
2262   # whether we want this or not
2263   # jnap, I hate you ;)
2264   my $rsrc = $self->result_source;
2265   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2266
2267   my ($colinfo, $colnames, $slices_with_rels);
2268   my $data_start = 0;
2269
2270   DATA_SLICE:
2271   for my $i (0 .. $#$data) {
2272
2273     my $current_slice_seen_rel_infos;
2274
2275 ### Determine/Supplement collists
2276 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2277     if( ref $data->[$i] eq 'ARRAY' ) {
2278
2279       # positional(!) explicit column list
2280       if ($i == 0) {
2281
2282         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2283           for 0 .. $#{$data->[0]};
2284
2285         $data_start = 1;
2286
2287         next DATA_SLICE;
2288       }
2289       else {
2290         for (values %$colinfo) {
2291           if ($_->{is_rel} ||= (
2292             $rel_info->{$_->{name}}
2293               and
2294             (
2295               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2296                 or
2297               ref $data->[$i][$_->{pos}] eq 'HASH'
2298                 or
2299               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2300             )
2301               and
2302             1
2303           )) {
2304
2305             # moar sanity check... sigh
2306             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2307               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2308                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2309                 return my $throwaway = $self->populate(@_);
2310               }
2311             }
2312
2313             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2314           }
2315         }
2316       }
2317
2318      if ($current_slice_seen_rel_infos) {
2319         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2320
2321         # this is needed further down to decide whether or not to fallback to create()
2322         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2323           for 0 .. $#$colnames;
2324       }
2325     }
2326     elsif( ref $data->[$i] eq 'HASH' ) {
2327
2328       for ( sort keys %{$data->[$i]} ) {
2329
2330         $colinfo->{$_} ||= do {
2331
2332           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2333             if $data_start; # it will be 0 on AoH, 1 on AoA
2334
2335           push @$colnames, $_;
2336
2337           # RV
2338           { pos => $#$colnames, name => $_ }
2339         };
2340
2341         if ($colinfo->{$_}{is_rel} ||= (
2342           $rel_info->{$_}
2343             and
2344           (
2345             ref $data->[$i]{$_} eq 'ARRAY'
2346               or
2347             ref $data->[$i]{$_} eq 'HASH'
2348               or
2349             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2350           )
2351             and
2352           1
2353         )) {
2354
2355           # moar sanity check... sigh
2356           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2357             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2358               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2359               return my $throwaway = $self->populate(@_);
2360             }
2361           }
2362
2363           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2364         }
2365       }
2366
2367       if ($current_slice_seen_rel_infos) {
2368         push @$slices_with_rels, $data->[$i];
2369
2370         # this is needed further down to decide whether or not to fallback to create()
2371         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2372           for keys %{$data->[$i]};
2373       }
2374     }
2375     else {
2376       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2377     }
2378
2379     if ( grep
2380       { $_->{attrs}{is_depends_on} }
2381       @{ $current_slice_seen_rel_infos || [] }
2382     ) {
2383       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2384       return my $throwaway = $self->populate(@_);
2385     }
2386   }
2387
2388   if( $slices_with_rels ) {
2389
2390     # need to exclude the rel "columns"
2391     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2392
2393     # extra sanity check - ensure the main source is in fact identifiable
2394     # the localizing of nullability is insane, but oh well... the use-case is legit
2395     my $ci = $rsrc->columns_info($colnames);
2396
2397     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2398       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2399
2400     unless( $rsrc->_identifying_column_set($ci) ) {
2401       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2402       return my $throwaway = $self->populate(@_);
2403     }
2404   }
2405
2406 ### inherit the data locked in the conditions of the resultset
2407   my ($rs_data) = $self->_merge_with_rscond({});
2408   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2409
2410   # if anything left - decompose rs_data
2411   my $rs_data_vals;
2412   if (keys %$rs_data) {
2413      push @$rs_data_vals, $rs_data->{$_}
2414       for sort keys %$rs_data;
2415   }
2416
2417 ### start work
2418   $guard = $rsrc->schema->storage->txn_scope_guard
2419     if $slices_with_rels;
2420
2421 ### main source data
2422   # FIXME - need to switch entirely to a coderef-based thing,
2423   # so that large sets aren't copied several times... I think
2424   $rsrc->storage->insert_bulk(
2425     $rsrc,
2426     [ @$colnames, sort keys %$rs_data ],
2427     [ map {
2428       ref $data->[$_] eq 'ARRAY'
2429       ? (
2430           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2431         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2432         :                     $data->[$_]
2433       )
2434       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2435     } $data_start .. $#$data ],
2436   );
2437
2438 ### do the children relationships
2439   if ( $slices_with_rels ) {
2440     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2441       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2442
2443     for my $sl (@$slices_with_rels) {
2444
2445       my ($main_proto, $main_proto_rs);
2446       for my $rel (@rels) {
2447         next unless defined $sl->{$rel};
2448
2449         $main_proto ||= {
2450           %$rs_data,
2451           (map { $_ => $sl->{$_} } @$colnames),
2452         };
2453
2454         unless (defined $colinfo->{$rel}{rs}) {
2455
2456           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2457
2458           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2459             rel_name => $rel,
2460             self_alias => "\xFE", # irrelevant
2461             foreign_alias => "\xFF", # irrelevant
2462           )->{identity_map} || {} } };
2463
2464         }
2465
2466         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2467           {
2468             $_ => { '=' =>
2469               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2470                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2471                  ->as_query
2472             }
2473           }
2474           keys %{$colinfo->{$rel}{fk_map}}
2475         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2476
2477         1;
2478       }
2479     }
2480   }
2481
2482   $guard->commit if $guard;
2483 }
2484
2485 =head2 pager
2486
2487 =over 4
2488
2489 =item Arguments: none
2490
2491 =item Return Value: L<$pager|Data::Page>
2492
2493 =back
2494
2495 Returns a L<Data::Page> object for the current resultset. Only makes
2496 sense for queries with a C<page> attribute.
2497
2498 To get the full count of entries for a paged resultset, call
2499 C<total_entries> on the L<Data::Page> object.
2500
2501 =cut
2502
2503 sub pager {
2504   my ($self) = @_;
2505
2506   return $self->{pager} if $self->{pager};
2507
2508   my $attrs = $self->{attrs};
2509   if (!defined $attrs->{page}) {
2510     $self->throw_exception("Can't create pager for non-paged rs");
2511   }
2512   elsif ($attrs->{page} <= 0) {
2513     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2514   }
2515   $attrs->{rows} ||= 10;
2516
2517   # throw away the paging flags and re-run the count (possibly
2518   # with a subselect) to get the real total count
2519   my $count_attrs = { %$attrs };
2520   delete @{$count_attrs}{qw/rows offset page pager/};
2521
2522   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2523
2524   require DBIx::Class::ResultSet::Pager;
2525   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2526     sub { $total_rs->count },  #lazy-get the total
2527     $attrs->{rows},
2528     $self->{attrs}{page},
2529   );
2530 }
2531
2532 =head2 page
2533
2534 =over 4
2535
2536 =item Arguments: $page_number
2537
2538 =item Return Value: L<$resultset|/search>
2539
2540 =back
2541
2542 Returns a resultset for the $page_number page of the resultset on which page
2543 is called, where each page contains a number of rows equal to the 'rows'
2544 attribute set on the resultset (10 by default).
2545
2546 =cut
2547
2548 sub page {
2549   my ($self, $page) = @_;
2550   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2551 }
2552
2553 =head2 new_result
2554
2555 =over 4
2556
2557 =item Arguments: \%col_data
2558
2559 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2560
2561 =back
2562
2563 Creates a new result object in the resultset's result class and returns
2564 it. The row is not inserted into the database at this point, call
2565 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2566 will tell you whether the result object has been inserted or not.
2567
2568 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2569
2570 =cut
2571
2572 sub new_result {
2573   my ($self, $values) = @_;
2574
2575   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2576     if @_ > 2;
2577
2578   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2579     unless (ref $values eq 'HASH');
2580
2581   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2582
2583   my $new = $self->result_class->new({
2584     %$merged_cond,
2585     ( @$cols_from_relations
2586       ? (-cols_from_relations => $cols_from_relations)
2587       : ()
2588     ),
2589     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2590   });
2591
2592   if (
2593     reftype($new) eq 'HASH'
2594       and
2595     ! keys %$new
2596       and
2597     blessed($new)
2598   ) {
2599     carp_unique (sprintf (
2600       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2601       $self->result_class,
2602     ));
2603   }
2604
2605   $new;
2606 }
2607
2608 # _merge_with_rscond
2609 #
2610 # Takes a simple hash of K/V data and returns its copy merged with the
2611 # condition already present on the resultset. Additionally returns an
2612 # arrayref of value/condition names, which were inferred from related
2613 # objects (this is needed for in-memory related objects)
2614 sub _merge_with_rscond {
2615   my ($self, $data) = @_;
2616
2617   my ($implied_data, @cols_from_relations);
2618
2619   my $alias = $self->{attrs}{alias};
2620
2621   if (! defined $self->{cond}) {
2622     # just massage $data below
2623   }
2624   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2625     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2626     @cols_from_relations = keys %{ $implied_data || {} };
2627   }
2628   else {
2629     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2630     $implied_data = { map {
2631       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2632     } keys %$eqs };
2633   }
2634
2635   return (
2636     { map
2637       { %{ $self->_remove_alias($_, $alias) } }
2638       # precedence must be given to passed values over values inherited from
2639       # the cond, so the order here is important.
2640       ( $implied_data||(), $data)
2641     },
2642     \@cols_from_relations
2643   );
2644 }
2645
2646 # _has_resolved_attr
2647 #
2648 # determines if the resultset defines at least one
2649 # of the attributes supplied
2650 #
2651 # used to determine if a subquery is necessary
2652 #
2653 # supports some virtual attributes:
2654 #   -join
2655 #     This will scan for any joins being present on the resultset.
2656 #     It is not a mere key-search but a deep inspection of {from}
2657 #
2658
2659 sub _has_resolved_attr {
2660   my ($self, @attr_names) = @_;
2661
2662   my $attrs = $self->_resolved_attrs;
2663
2664   my %extra_checks;
2665
2666   for my $n (@attr_names) {
2667     if (grep { $n eq $_ } (qw/-join/) ) {
2668       $extra_checks{$n}++;
2669       next;
2670     }
2671
2672     my $attr =  $attrs->{$n};
2673
2674     next if not defined $attr;
2675
2676     if (ref $attr eq 'HASH') {
2677       return 1 if keys %$attr;
2678     }
2679     elsif (ref $attr eq 'ARRAY') {
2680       return 1 if @$attr;
2681     }
2682     else {
2683       return 1 if $attr;
2684     }
2685   }
2686
2687   # a resolved join is expressed as a multi-level from
2688   return 1 if (
2689     $extra_checks{-join}
2690       and
2691     ref $attrs->{from} eq 'ARRAY'
2692       and
2693     @{$attrs->{from}} > 1
2694   );
2695
2696   return 0;
2697 }
2698
2699 # _remove_alias
2700 #
2701 # Remove the specified alias from the specified query hash. A copy is made so
2702 # the original query is not modified.
2703
2704 sub _remove_alias {
2705   my ($self, $query, $alias) = @_;
2706
2707   my %orig = %{ $query || {} };
2708   my %unaliased;
2709
2710   foreach my $key (keys %orig) {
2711     if ($key !~ /\./) {
2712       $unaliased{$key} = $orig{$key};
2713       next;
2714     }
2715     $unaliased{$1} = $orig{$key}
2716       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2717   }
2718
2719   return \%unaliased;
2720 }
2721
2722 =head2 as_query
2723
2724 =over 4
2725
2726 =item Arguments: none
2727
2728 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2729
2730 =back
2731
2732 Returns the SQL query and bind vars associated with the invocant.
2733
2734 This is generally used as the RHS for a subquery.
2735
2736 =cut
2737
2738 sub as_query {
2739   my $self = shift;
2740
2741   my $attrs = { %{ $self->_resolved_attrs } };
2742
2743   my $aq = $self->result_source->storage->_select_args_to_query (
2744     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2745   );
2746
2747   $aq;
2748 }
2749
2750 =head2 find_or_new
2751
2752 =over 4
2753
2754 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2755
2756 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2757
2758 =back
2759
2760   my $artist = $schema->resultset('Artist')->find_or_new(
2761     { artist => 'fred' }, { key => 'artists' });
2762
2763   $cd->cd_to_producer->find_or_new({ producer => $producer },
2764                                    { key => 'primary' });
2765
2766 Find an existing record from this resultset using L</find>. if none exists,
2767 instantiate a new result object and return it. The object will not be saved
2768 into your storage until you call L<DBIx::Class::Row/insert> on it.
2769
2770 You most likely want this method when looking for existing rows using a unique
2771 constraint that is not the primary key, or looking for related rows.
2772
2773 If you want objects to be saved immediately, use L</find_or_create> instead.
2774
2775 B<Note>: Make sure to read the documentation of L</find> and understand the
2776 significance of the C<key> attribute, as its lack may skew your search, and
2777 subsequently result in spurious new objects.
2778
2779 B<Note>: Take care when using C<find_or_new> with a table having
2780 columns with default values that you intend to be automatically
2781 supplied by the database (e.g. an auto_increment primary key column).
2782 In normal usage, the value of such columns should NOT be included at
2783 all in the call to C<find_or_new>, even when set to C<undef>.
2784
2785 =cut
2786
2787 sub find_or_new {
2788   my $self     = shift;
2789   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2790   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2791   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2792     return $row;
2793   }
2794   return $self->new_result($hash);
2795 }
2796
2797 =head2 create
2798
2799 =over 4
2800
2801 =item Arguments: \%col_data
2802
2803 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2804
2805 =back
2806
2807 Attempt to create a single new row or a row with multiple related rows
2808 in the table represented by the resultset (and related tables). This
2809 will not check for duplicate rows before inserting, use
2810 L</find_or_create> to do that.
2811
2812 To create one row for this resultset, pass a hashref of key/value
2813 pairs representing the columns of the table and the values you wish to
2814 store. If the appropriate relationships are set up, foreign key fields
2815 can also be passed an object representing the foreign row, and the
2816 value will be set to its primary key.
2817
2818 To create related objects, pass a hashref of related-object column values
2819 B<keyed on the relationship name>. If the relationship is of type C<multi>
2820 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2821 The process will correctly identify columns holding foreign keys, and will
2822 transparently populate them from the keys of the corresponding relation.
2823 This can be applied recursively, and will work correctly for a structure
2824 with an arbitrary depth and width, as long as the relationships actually
2825 exists and the correct column data has been supplied.
2826
2827 Instead of hashrefs of plain related data (key/value pairs), you may
2828 also pass new or inserted objects. New objects (not inserted yet, see
2829 L</new_result>), will be inserted into their appropriate tables.
2830
2831 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2832
2833 Example of creating a new row.
2834
2835   $person_rs->create({
2836     name=>"Some Person",
2837     email=>"somebody@someplace.com"
2838   });
2839
2840 Example of creating a new row and also creating rows in a related C<has_many>
2841 or C<has_one> resultset.  Note Arrayref.
2842
2843   $artist_rs->create(
2844      { artistid => 4, name => 'Manufactured Crap', cds => [
2845         { title => 'My First CD', year => 2006 },
2846         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2847       ],
2848      },
2849   );
2850
2851 Example of creating a new row and also creating a row in a related
2852 C<belongs_to> resultset. Note Hashref.
2853
2854   $cd_rs->create({
2855     title=>"Music for Silly Walks",
2856     year=>2000,
2857     artist => {
2858       name=>"Silly Musician",
2859     }
2860   });
2861
2862 =over
2863
2864 =item WARNING
2865
2866 When subclassing ResultSet never attempt to override this method. Since
2867 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2868 lot of the internals simply never call it, so your override will be
2869 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2870 or L<DBIx::Class::Row/insert> depending on how early in the
2871 L</create> process you need to intervene. See also warning pertaining to
2872 L</new>.
2873
2874 =back
2875
2876 =cut
2877
2878 sub create {
2879   #my ($self, $col_data) = @_;
2880   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2881   return shift->new_result(shift)->insert;
2882 }
2883
2884 =head2 find_or_create
2885
2886 =over 4
2887
2888 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2889
2890 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2891
2892 =back
2893
2894   $cd->cd_to_producer->find_or_create({ producer => $producer },
2895                                       { key => 'primary' });
2896
2897 Tries to find a record based on its primary key or unique constraints; if none
2898 is found, creates one and returns that instead.
2899
2900   my $cd = $schema->resultset('CD')->find_or_create({
2901     cdid   => 5,
2902     artist => 'Massive Attack',
2903     title  => 'Mezzanine',
2904     year   => 2005,
2905   });
2906
2907 Also takes an optional C<key> attribute, to search by a specific key or unique
2908 constraint. For example:
2909
2910   my $cd = $schema->resultset('CD')->find_or_create(
2911     {
2912       artist => 'Massive Attack',
2913       title  => 'Mezzanine',
2914     },
2915     { key => 'cd_artist_title' }
2916   );
2917
2918 B<Note>: Make sure to read the documentation of L</find> and understand the
2919 significance of the C<key> attribute, as its lack may skew your search, and
2920 subsequently result in spurious row creation.
2921
2922 B<Note>: Because find_or_create() reads from the database and then
2923 possibly inserts based on the result, this method is subject to a race
2924 condition. Another process could create a record in the table after
2925 the find has completed and before the create has started. To avoid
2926 this problem, use find_or_create() inside a transaction.
2927
2928 B<Note>: Take care when using C<find_or_create> with a table having
2929 columns with default values that you intend to be automatically
2930 supplied by the database (e.g. an auto_increment primary key column).
2931 In normal usage, the value of such columns should NOT be included at
2932 all in the call to C<find_or_create>, even when set to C<undef>.
2933
2934 See also L</find> and L</update_or_create>. For information on how to declare
2935 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2936
2937 If you need to know if an existing row was found or a new one created use
2938 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2939 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2940 database!
2941
2942   my $cd = $schema->resultset('CD')->find_or_new({
2943     cdid   => 5,
2944     artist => 'Massive Attack',
2945     title  => 'Mezzanine',
2946     year   => 2005,
2947   });
2948
2949   if( !$cd->in_storage ) {
2950       # do some stuff
2951       $cd->insert;
2952   }
2953
2954 =cut
2955
2956 sub find_or_create {
2957   my $self     = shift;
2958   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2959   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2960   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2961     return $row;
2962   }
2963   return $self->new_result($hash)->insert;
2964 }
2965
2966 =head2 update_or_create
2967
2968 =over 4
2969
2970 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2971
2972 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2973
2974 =back
2975
2976   $resultset->update_or_create({ col => $val, ... });
2977
2978 Like L</find_or_create>, but if a row is found it is immediately updated via
2979 C<< $found_row->update (\%col_data) >>.
2980
2981
2982 Takes an optional C<key> attribute to search on a specific unique constraint.
2983 For example:
2984
2985   # In your application
2986   my $cd = $schema->resultset('CD')->update_or_create(
2987     {
2988       artist => 'Massive Attack',
2989       title  => 'Mezzanine',
2990       year   => 1998,
2991     },
2992     { key => 'cd_artist_title' }
2993   );
2994
2995   $cd->cd_to_producer->update_or_create({
2996     producer => $producer,
2997     name => 'harry',
2998   }, {
2999     key => 'primary',
3000   });
3001
3002 B<Note>: Make sure to read the documentation of L</find> and understand the
3003 significance of the C<key> attribute, as its lack may skew your search, and
3004 subsequently result in spurious row creation.
3005
3006 B<Note>: Take care when using C<update_or_create> with a table having
3007 columns with default values that you intend to be automatically
3008 supplied by the database (e.g. an auto_increment primary key column).
3009 In normal usage, the value of such columns should NOT be included at
3010 all in the call to C<update_or_create>, even when set to C<undef>.
3011
3012 See also L</find> and L</find_or_create>. For information on how to declare
3013 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3014
3015 If you need to know if an existing row was updated or a new one created use
3016 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3017 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3018 database!
3019
3020 =cut
3021
3022 sub update_or_create {
3023   my $self = shift;
3024   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3025   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3026
3027   my $row = $self->find($cond, $attrs);
3028   if (defined $row) {
3029     $row->update($cond);
3030     return $row;
3031   }
3032
3033   return $self->new_result($cond)->insert;
3034 }
3035
3036 =head2 update_or_new
3037
3038 =over 4
3039
3040 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3041
3042 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3043
3044 =back
3045
3046   $resultset->update_or_new({ col => $val, ... });
3047
3048 Like L</find_or_new> but if a row is found it is immediately updated via
3049 C<< $found_row->update (\%col_data) >>.
3050
3051 For example:
3052
3053   # In your application
3054   my $cd = $schema->resultset('CD')->update_or_new(
3055     {
3056       artist => 'Massive Attack',
3057       title  => 'Mezzanine',
3058       year   => 1998,
3059     },
3060     { key => 'cd_artist_title' }
3061   );
3062
3063   if ($cd->in_storage) {
3064       # the cd was updated
3065   }
3066   else {
3067       # the cd is not yet in the database, let's insert it
3068       $cd->insert;
3069   }
3070
3071 B<Note>: Make sure to read the documentation of L</find> and understand the
3072 significance of the C<key> attribute, as its lack may skew your search, and
3073 subsequently result in spurious new objects.
3074
3075 B<Note>: Take care when using C<update_or_new> with a table having
3076 columns with default values that you intend to be automatically
3077 supplied by the database (e.g. an auto_increment primary key column).
3078 In normal usage, the value of such columns should NOT be included at
3079 all in the call to C<update_or_new>, even when set to C<undef>.
3080
3081 See also L</find>, L</find_or_create> and L</find_or_new>.
3082
3083 =cut
3084
3085 sub update_or_new {
3086     my $self  = shift;
3087     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3088     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3089
3090     my $row = $self->find( $cond, $attrs );
3091     if ( defined $row ) {
3092         $row->update($cond);
3093         return $row;
3094     }
3095
3096     return $self->new_result($cond);
3097 }
3098
3099 =head2 get_cache
3100
3101 =over 4
3102
3103 =item Arguments: none
3104
3105 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3106
3107 =back
3108
3109 Gets the contents of the cache for the resultset, if the cache is set.
3110
3111 The cache is populated either by using the L</prefetch> attribute to
3112 L</search> or by calling L</set_cache>.
3113
3114 =cut
3115
3116 sub get_cache {
3117   shift->{all_cache};
3118 }
3119
3120 =head2 set_cache
3121
3122 =over 4
3123
3124 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3125
3126 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3127
3128 =back
3129
3130 Sets the contents of the cache for the resultset. Expects an arrayref
3131 of objects of the same class as those produced by the resultset. Note that
3132 if the cache is set, the resultset will return the cached objects rather
3133 than re-querying the database even if the cache attr is not set.
3134
3135 The contents of the cache can also be populated by using the
3136 L</prefetch> attribute to L</search>.
3137
3138 =cut
3139
3140 sub set_cache {
3141   my ( $self, $data ) = @_;
3142   $self->throw_exception("set_cache requires an arrayref")
3143       if defined($data) && (ref $data ne 'ARRAY');
3144   $self->{all_cache} = $data;
3145 }
3146
3147 =head2 clear_cache
3148
3149 =over 4
3150
3151 =item Arguments: none
3152
3153 =item Return Value: undef
3154
3155 =back
3156
3157 Clears the cache for the resultset.
3158
3159 =cut
3160
3161 sub clear_cache {
3162   shift->set_cache(undef);
3163 }
3164
3165 =head2 is_paged
3166
3167 =over 4
3168
3169 =item Arguments: none
3170
3171 =item Return Value: true, if the resultset has been paginated
3172
3173 =back
3174
3175 =cut
3176
3177 sub is_paged {
3178   my ($self) = @_;
3179   return !!$self->{attrs}{page};
3180 }
3181
3182 =head2 is_ordered
3183
3184 =over 4
3185
3186 =item Arguments: none
3187
3188 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3189
3190 =back
3191
3192 =cut
3193
3194 sub is_ordered {
3195   my ($self) = @_;
3196   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3197 }
3198
3199 =head2 related_resultset
3200
3201 =over 4
3202
3203 =item Arguments: $rel_name
3204
3205 =item Return Value: L<$resultset|/search>
3206
3207 =back
3208
3209 Returns a related resultset for the supplied relationship name.
3210
3211   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3212
3213 =cut
3214
3215 sub related_resultset {
3216   my ($self, $rel) = @_;
3217
3218   return $self->{related_resultsets}{$rel}
3219     if defined $self->{related_resultsets}{$rel};
3220
3221   return $self->{related_resultsets}{$rel} = do {
3222     my $rsrc = $self->result_source;
3223     my $rel_info = $rsrc->relationship_info($rel);
3224
3225     $self->throw_exception(
3226       "search_related: result source '" . $rsrc->source_name .
3227         "' has no such relationship $rel")
3228       unless $rel_info;
3229
3230     my $attrs = $self->_chain_relationship($rel);
3231
3232     my $join_count = $attrs->{seen_join}{$rel};
3233
3234     my $alias = $self->result_source->storage
3235         ->relname_to_table_alias($rel, $join_count);
3236
3237     # since this is search_related, and we already slid the select window inwards
3238     # (the select/as attrs were deleted in the beginning), we need to flip all
3239     # left joins to inner, so we get the expected results
3240     # read the comment on top of the actual function to see what this does
3241     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3242
3243
3244     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3245     delete @{$attrs}{qw(result_class alias)};
3246
3247     my $rel_source = $rsrc->related_source($rel);
3248
3249     my $new = do {
3250
3251       # The reason we do this now instead of passing the alias to the
3252       # search_rs below is that if you wrap/overload resultset on the
3253       # source you need to know what alias it's -going- to have for things
3254       # to work sanely (e.g. RestrictWithObject wants to be able to add
3255       # extra query restrictions, and these may need to be $alias.)
3256
3257       my $rel_attrs = $rel_source->resultset_attributes;
3258       local $rel_attrs->{alias} = $alias;
3259
3260       $rel_source->resultset
3261                  ->search_rs(
3262                      undef, {
3263                        %$attrs,
3264                        where => $attrs->{where},
3265                    });
3266     };
3267
3268     if (my $cache = $self->get_cache) {
3269       my @related_cache = map
3270         { $_->related_resultset($rel)->get_cache || () }
3271         @$cache
3272       ;
3273
3274       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3275     }
3276
3277     $new;
3278   };
3279 }
3280
3281 =head2 current_source_alias
3282
3283 =over 4
3284
3285 =item Arguments: none
3286
3287 =item Return Value: $source_alias
3288
3289 =back
3290
3291 Returns the current table alias for the result source this resultset is built
3292 on, that will be used in the SQL query. Usually it is C<me>.
3293
3294 Currently the source alias that refers to the result set returned by a
3295 L</search>/L</find> family method depends on how you got to the resultset: it's
3296 C<me> by default, but eg. L</search_related> aliases it to the related result
3297 source name (and keeps C<me> referring to the original result set). The long
3298 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3299 (and make this method unnecessary).
3300
3301 Thus it's currently necessary to use this method in predefined queries (see
3302 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3303 source alias of the current result set:
3304
3305   # in a result set class
3306   sub modified_by {
3307     my ($self, $user) = @_;
3308
3309     my $me = $self->current_source_alias;
3310
3311     return $self->search({
3312       "$me.modified" => $user->id,
3313     });
3314   }
3315
3316 =cut
3317
3318 sub current_source_alias {
3319   return (shift->{attrs} || {})->{alias} || 'me';
3320 }
3321
3322 =head2 as_subselect_rs
3323
3324 =over 4
3325
3326 =item Arguments: none
3327
3328 =item Return Value: L<$resultset|/search>
3329
3330 =back
3331
3332 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3333 "virtual view" by including it as a subquery within the from clause.  From this
3334 point on, any joined tables are inaccessible to ->search on the resultset (as if
3335 it were simply where-filtered without joins).  For example:
3336
3337  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3338
3339  # 'x' now pollutes the query namespace
3340
3341  # So the following works as expected
3342  my $ok_rs = $rs->search({'x.other' => 1});
3343
3344  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3345  # def) we look for one row with contradictory terms and join in another table
3346  # (aliased 'x_2') which we never use
3347  my $broken_rs = $rs->search({'x.name' => 'def'});
3348
3349  my $rs2 = $rs->as_subselect_rs;
3350
3351  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3352  my $not_joined_rs = $rs2->search({'x.other' => 1});
3353
3354  # works as expected: finds a 'table' row related to two x rows (abc and def)
3355  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3356
3357 Another example of when one might use this would be to select a subset of
3358 columns in a group by clause:
3359
3360  my $rs = $schema->resultset('Bar')->search(undef, {
3361    group_by => [qw{ id foo_id baz_id }],
3362  })->as_subselect_rs->search(undef, {
3363    columns => [qw{ id foo_id }]
3364  });
3365
3366 In the above example normally columns would have to be equal to the group by,
3367 but because we isolated the group by into a subselect the above works.
3368
3369 =cut
3370
3371 sub as_subselect_rs {
3372   my $self = shift;
3373
3374   my $attrs = $self->_resolved_attrs;
3375
3376   my $fresh_rs = (ref $self)->new (
3377     $self->result_source
3378   );
3379
3380   # these pieces will be locked in the subquery
3381   delete $fresh_rs->{cond};
3382   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3383
3384   return $fresh_rs->search( {}, {
3385     from => [{
3386       $attrs->{alias} => $self->as_query,
3387       -alias  => $attrs->{alias},
3388       -rsrc   => $self->result_source,
3389     }],
3390     alias => $attrs->{alias},
3391   });
3392 }
3393
3394 # This code is called by search_related, and makes sure there
3395 # is clear separation between the joins before, during, and
3396 # after the relationship. This information is needed later
3397 # in order to properly resolve prefetch aliases (any alias
3398 # with a relation_chain_depth less than the depth of the
3399 # current prefetch is not considered)
3400 #
3401 # The increments happen twice per join. An even number means a
3402 # relationship specified via a search_related, whereas an odd
3403 # number indicates a join/prefetch added via attributes
3404 #
3405 # Also this code will wrap the current resultset (the one we
3406 # chain to) in a subselect IFF it contains limiting attributes
3407 sub _chain_relationship {
3408   my ($self, $rel) = @_;
3409   my $source = $self->result_source;
3410   my $attrs = { %{$self->{attrs}||{}} };
3411
3412   # we need to take the prefetch the attrs into account before we
3413   # ->_resolve_join as otherwise they get lost - captainL
3414   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3415
3416   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3417
3418   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3419
3420   my $from;
3421   my @force_subq_attrs = qw/offset rows group_by having/;
3422
3423   if (
3424     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3425       ||
3426     $self->_has_resolved_attr (@force_subq_attrs)
3427   ) {
3428     # Nuke the prefetch (if any) before the new $rs attrs
3429     # are resolved (prefetch is useless - we are wrapping
3430     # a subquery anyway).
3431     my $rs_copy = $self->search;
3432     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3433       $rs_copy->{attrs}{join},
3434       delete $rs_copy->{attrs}{prefetch},
3435     );
3436
3437     $from = [{
3438       -rsrc   => $source,
3439       -alias  => $attrs->{alias},
3440       $attrs->{alias} => $rs_copy->as_query,
3441     }];
3442     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3443     $seen->{-relation_chain_depth} = 0;
3444   }
3445   elsif ($attrs->{from}) {  #shallow copy suffices
3446     $from = [ @{$attrs->{from}} ];
3447   }
3448   else {
3449     $from = [{
3450       -rsrc  => $source,
3451       -alias => $attrs->{alias},
3452       $attrs->{alias} => $source->from,
3453     }];
3454   }
3455
3456   my $jpath = ($seen->{-relation_chain_depth})
3457     ? $from->[-1][0]{-join_path}
3458     : [];
3459
3460   my @requested_joins = $source->_resolve_join(
3461     $join,
3462     $attrs->{alias},
3463     $seen,
3464     $jpath,
3465   );
3466
3467   push @$from, @requested_joins;
3468
3469   $seen->{-relation_chain_depth}++;
3470
3471   # if $self already had a join/prefetch specified on it, the requested
3472   # $rel might very well be already included. What we do in this case
3473   # is effectively a no-op (except that we bump up the chain_depth on
3474   # the join in question so we could tell it *is* the search_related)
3475   my $already_joined;
3476
3477   # we consider the last one thus reverse
3478   for my $j (reverse @requested_joins) {
3479     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3480     if ($rel eq $last_j) {
3481       $j->[0]{-relation_chain_depth}++;
3482       $already_joined++;
3483       last;
3484     }
3485   }
3486
3487   unless ($already_joined) {
3488     push @$from, $source->_resolve_join(
3489       $rel,
3490       $attrs->{alias},
3491       $seen,
3492       $jpath,
3493     );
3494   }
3495
3496   $seen->{-relation_chain_depth}++;
3497
3498   return {%$attrs, from => $from, seen_join => $seen};
3499 }
3500
3501 sub _resolved_attrs {
3502   my $self = shift;
3503   return $self->{_attrs} if $self->{_attrs};
3504
3505   my $attrs  = { %{ $self->{attrs} || {} } };
3506   my $source = $attrs->{result_source} = $self->result_source;
3507   my $alias  = $attrs->{alias};
3508
3509   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3510     if $attrs->{collapse} and $attrs->{distinct};
3511
3512   # default selection list
3513   $attrs->{columns} = [ $source->columns ]
3514     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3515
3516   # merge selectors together
3517   for (qw/columns select as/) {
3518     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3519       if $attrs->{$_} or $attrs->{"+$_"};
3520   }
3521
3522   # disassemble columns
3523   my (@sel, @as);
3524   if (my $cols = delete $attrs->{columns}) {
3525     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3526       if (ref $c eq 'HASH') {
3527         for my $as (sort keys %$c) {
3528           push @sel, $c->{$as};
3529           push @as, $as;
3530         }
3531       }
3532       else {
3533         push @sel, $c;
3534         push @as, $c;
3535       }
3536     }
3537   }
3538
3539   # when trying to weed off duplicates later do not go past this point -
3540   # everything added from here on is unbalanced "anyone's guess" stuff
3541   my $dedup_stop_idx = $#as;
3542
3543   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3544     if $attrs->{as};
3545   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3546     if $attrs->{select};
3547
3548   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3549   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3550
3551   # disqualify all $alias.col as-bits (inflate-map mandated)
3552   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3553
3554   # de-duplicate the result (remove *identical* select/as pairs)
3555   # and also die on duplicate {as} pointing to different {select}s
3556   # not using a c-style for as the condition is prone to shrinkage
3557   my $seen;
3558   my $i = 0;
3559   while ($i <= $dedup_stop_idx) {
3560     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3561       splice @sel, $i, 1;
3562       splice @as, $i, 1;
3563       $dedup_stop_idx--;
3564     }
3565     elsif ($seen->{$as[$i]}++) {
3566       $self->throw_exception(
3567         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3568       );
3569     }
3570     else {
3571       $i++;
3572     }
3573   }
3574
3575   $attrs->{select} = \@sel;
3576   $attrs->{as} = \@as;
3577
3578   $attrs->{from} ||= [{
3579     -rsrc   => $source,
3580     -alias  => $self->{attrs}{alias},
3581     $self->{attrs}{alias} => $source->from,
3582   }];
3583
3584   if ( $attrs->{join} || $attrs->{prefetch} ) {
3585
3586     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3587       if ref $attrs->{from} ne 'ARRAY';
3588
3589     my $join = (delete $attrs->{join}) || {};
3590
3591     if ( defined $attrs->{prefetch} ) {
3592       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3593     }
3594
3595     $attrs->{from} =    # have to copy here to avoid corrupting the original
3596       [
3597         @{ $attrs->{from} },
3598         $source->_resolve_join(
3599           $join,
3600           $alias,
3601           { %{ $attrs->{seen_join} || {} } },
3602           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3603             ? $attrs->{from}[-1][0]{-join_path}
3604             : []
3605           ,
3606         )
3607       ];
3608   }
3609
3610   if ( defined $attrs->{order_by} ) {
3611     $attrs->{order_by} = (
3612       ref( $attrs->{order_by} ) eq 'ARRAY'
3613       ? [ @{ $attrs->{order_by} } ]
3614       : [ $attrs->{order_by} || () ]
3615     );
3616   }
3617
3618   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3619     $attrs->{group_by} = [ $attrs->{group_by} ];
3620   }
3621
3622
3623   # generate selections based on the prefetch helper
3624   my ($prefetch, @prefetch_select, @prefetch_as);
3625   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3626     if defined $attrs->{prefetch};
3627
3628   if ($prefetch) {
3629
3630     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3631       if $attrs->{_dark_selector};
3632
3633     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3634       if defined $attrs->{collapse} and ! $attrs->{collapse};
3635
3636     $attrs->{collapse} = 1;
3637
3638     # this is a separate structure (we don't look in {from} directly)
3639     # as the resolver needs to shift things off the lists to work
3640     # properly (identical-prefetches on different branches)
3641     my $join_map = {};
3642     if (ref $attrs->{from} eq 'ARRAY') {
3643
3644       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3645
3646       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3647         next unless $j->[0]{-alias};
3648         next unless $j->[0]{-join_path};
3649         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3650
3651         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3652
3653         my $p = $join_map;
3654         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3655         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3656       }
3657     }
3658
3659     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3660
3661     # save these for after distinct resolution
3662     @prefetch_select = map { $_->[0] } @prefetch;
3663     @prefetch_as = map { $_->[1] } @prefetch;
3664   }
3665
3666   # run through the resulting joinstructure (starting from our current slot)
3667   # and unset collapse if proven unnecessary
3668   #
3669   # also while we are at it find out if the current root source has
3670   # been premultiplied by previous related_source chaining
3671   #
3672   # this allows to predict whether a root object with all other relation
3673   # data set to NULL is in fact unique
3674   if ($attrs->{collapse}) {
3675
3676     if (ref $attrs->{from} eq 'ARRAY') {
3677
3678       if (@{$attrs->{from}} == 1) {
3679         # no joins - no collapse
3680         $attrs->{collapse} = 0;
3681       }
3682       else {
3683         # find where our table-spec starts
3684         my @fromlist = @{$attrs->{from}};
3685         while (@fromlist) {
3686           my $t = shift @fromlist;
3687
3688           my $is_multi;
3689           # me vs join from-spec distinction - a ref means non-root
3690           if (ref $t eq 'ARRAY') {
3691             $t = $t->[0];
3692             $is_multi ||= ! $t->{-is_single};
3693           }
3694           last if ($t->{-alias} && $t->{-alias} eq $alias);
3695           $attrs->{_main_source_premultiplied} ||= $is_multi;
3696         }
3697
3698         # no non-singles remaining, nor any premultiplication - nothing to collapse
3699         if (
3700           ! $attrs->{_main_source_premultiplied}
3701             and
3702           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3703         ) {
3704           $attrs->{collapse} = 0;
3705         }
3706       }
3707     }
3708
3709     else {
3710       # if we can not analyze the from - err on the side of safety
3711       $attrs->{_main_source_premultiplied} = 1;
3712     }
3713   }
3714
3715   # generate the distinct induced group_by before injecting the prefetched select/as parts
3716   if (delete $attrs->{distinct}) {
3717     if ($attrs->{group_by}) {
3718       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3719     }
3720     else {
3721       $attrs->{_grouped_by_distinct} = 1;
3722       # distinct affects only the main selection part, not what prefetch may add below
3723       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3724
3725       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3726       # The thinking is: if we are collapsing the subquerying prefetch engine will
3727       # rip stuff apart for us anyway, and we do not want to have a potentially
3728       # function-converted external order_by
3729       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3730       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3731     }
3732   }
3733
3734   # inject prefetch-bound selection (if any)
3735   push @{$attrs->{select}}, @prefetch_select;
3736   push @{$attrs->{as}}, @prefetch_as;
3737
3738   $attrs->{_simple_passthrough_construction} = !(
3739     $attrs->{collapse}
3740       or
3741     grep { $_ =~ /\./ } @{$attrs->{as}}
3742   );
3743
3744   # if both page and offset are specified, produce a combined offset
3745   # even though it doesn't make much sense, this is what pre 081xx has
3746   # been doing
3747   if (my $page = delete $attrs->{page}) {
3748     $attrs->{offset} =
3749       ($attrs->{rows} * ($page - 1))
3750             +
3751       ($attrs->{offset} || 0)
3752     ;
3753   }
3754
3755   return $self->{_attrs} = $attrs;
3756 }
3757
3758 sub _rollout_attr {
3759   my ($self, $attr) = @_;
3760
3761   if (ref $attr eq 'HASH') {
3762     return $self->_rollout_hash($attr);
3763   } elsif (ref $attr eq 'ARRAY') {
3764     return $self->_rollout_array($attr);
3765   } else {
3766     return [$attr];
3767   }
3768 }
3769
3770 sub _rollout_array {
3771   my ($self, $attr) = @_;
3772
3773   my @rolled_array;
3774   foreach my $element (@{$attr}) {
3775     if (ref $element eq 'HASH') {
3776       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3777     } elsif (ref $element eq 'ARRAY') {
3778       #  XXX - should probably recurse here
3779       push( @rolled_array, @{$self->_rollout_array($element)} );
3780     } else {
3781       push( @rolled_array, $element );
3782     }
3783   }
3784   return \@rolled_array;
3785 }
3786
3787 sub _rollout_hash {
3788   my ($self, $attr) = @_;
3789
3790   my @rolled_array;
3791   foreach my $key (keys %{$attr}) {
3792     push( @rolled_array, { $key => $attr->{$key} } );
3793   }
3794   return \@rolled_array;
3795 }
3796
3797 sub _calculate_score {
3798   my ($self, $a, $b) = @_;
3799
3800   if (defined $a xor defined $b) {
3801     return 0;
3802   }
3803   elsif (not defined $a) {
3804     return 1;
3805   }
3806
3807   if (ref $b eq 'HASH') {
3808     my ($b_key) = keys %{$b};
3809     if (ref $a eq 'HASH') {
3810       my ($a_key) = keys %{$a};
3811       if ($a_key eq $b_key) {
3812         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3813       } else {
3814         return 0;
3815       }
3816     } else {
3817       return ($a eq $b_key) ? 1 : 0;
3818     }
3819   } else {
3820     if (ref $a eq 'HASH') {
3821       my ($a_key) = keys %{$a};
3822       return ($b eq $a_key) ? 1 : 0;
3823     } else {
3824       return ($b eq $a) ? 1 : 0;
3825     }
3826   }
3827 }
3828
3829 sub _merge_joinpref_attr {
3830   my ($self, $orig, $import) = @_;
3831
3832   return $import unless defined($orig);
3833   return $orig unless defined($import);
3834
3835   $orig = $self->_rollout_attr($orig);
3836   $import = $self->_rollout_attr($import);
3837
3838   my $seen_keys;
3839   foreach my $import_element ( @{$import} ) {
3840     # find best candidate from $orig to merge $b_element into
3841     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3842     foreach my $orig_element ( @{$orig} ) {
3843       my $score = $self->_calculate_score( $orig_element, $import_element );
3844       if ($score > $best_candidate->{score}) {
3845         $best_candidate->{position} = $position;
3846         $best_candidate->{score} = $score;
3847       }
3848       $position++;
3849     }
3850     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3851     $import_key = '' if not defined $import_key;
3852
3853     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3854       push( @{$orig}, $import_element );
3855     } else {
3856       my $orig_best = $orig->[$best_candidate->{position}];
3857       # merge orig_best and b_element together and replace original with merged
3858       if (ref $orig_best ne 'HASH') {
3859         $orig->[$best_candidate->{position}] = $import_element;
3860       } elsif (ref $import_element eq 'HASH') {
3861         my ($key) = keys %{$orig_best};
3862         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3863       }
3864     }
3865     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3866   }
3867
3868   return @$orig ? $orig : ();
3869 }
3870
3871 {
3872   my $hm;
3873
3874   sub _merge_attr {
3875     $hm ||= do {
3876       require Hash::Merge;
3877       my $hm = Hash::Merge->new;
3878
3879       $hm->specify_behavior({
3880         SCALAR => {
3881           SCALAR => sub {
3882             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3883
3884             if ($defl xor $defr) {
3885               return [ $defl ? $_[0] : $_[1] ];
3886             }
3887             elsif (! $defl) {
3888               return [];
3889             }
3890             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3891               return [ $_[0] ];
3892             }
3893             else {
3894               return [$_[0], $_[1]];
3895             }
3896           },
3897           ARRAY => sub {
3898             return $_[1] if !defined $_[0];
3899             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3900             return [$_[0], @{$_[1]}]
3901           },
3902           HASH  => sub {
3903             return [] if !defined $_[0] and !keys %{$_[1]};
3904             return [ $_[1] ] if !defined $_[0];
3905             return [ $_[0] ] if !keys %{$_[1]};
3906             return [$_[0], $_[1]]
3907           },
3908         },
3909         ARRAY => {
3910           SCALAR => sub {
3911             return $_[0] if !defined $_[1];
3912             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3913             return [@{$_[0]}, $_[1]]
3914           },
3915           ARRAY => sub {
3916             my @ret = @{$_[0]} or return $_[1];
3917             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3918             my %idx = map { $_ => 1 } @ret;
3919             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3920             \@ret;
3921           },
3922           HASH => sub {
3923             return [ $_[1] ] if ! @{$_[0]};
3924             return $_[0] if !keys %{$_[1]};
3925             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3926             return [ @{$_[0]}, $_[1] ];
3927           },
3928         },
3929         HASH => {
3930           SCALAR => sub {
3931             return [] if !keys %{$_[0]} and !defined $_[1];
3932             return [ $_[0] ] if !defined $_[1];
3933             return [ $_[1] ] if !keys %{$_[0]};
3934             return [$_[0], $_[1]]
3935           },
3936           ARRAY => sub {
3937             return [] if !keys %{$_[0]} and !@{$_[1]};
3938             return [ $_[0] ] if !@{$_[1]};
3939             return $_[1] if !keys %{$_[0]};
3940             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3941             return [ $_[0], @{$_[1]} ];
3942           },
3943           HASH => sub {
3944             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3945             return [ $_[0] ] if !keys %{$_[1]};
3946             return [ $_[1] ] if !keys %{$_[0]};
3947             return [ $_[0] ] if $_[0] eq $_[1];
3948             return [ $_[0], $_[1] ];
3949           },
3950         }
3951       } => 'DBIC_RS_ATTR_MERGER');
3952       $hm;
3953     };
3954
3955     return $hm->merge ($_[1], $_[2]);
3956   }
3957 }
3958
3959 sub STORABLE_freeze {
3960   my ($self, $cloning) = @_;
3961   my $to_serialize = { %$self };
3962
3963   # A cursor in progress can't be serialized (and would make little sense anyway)
3964   # the parser can be regenerated (and can't be serialized)
3965   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3966
3967   # nor is it sensical to store a not-yet-fired-count pager
3968   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3969     delete $to_serialize->{pager};
3970   }
3971
3972   Storable::nfreeze($to_serialize);
3973 }
3974
3975 # need this hook for symmetry
3976 sub STORABLE_thaw {
3977   my ($self, $cloning, $serialized) = @_;
3978
3979   %$self = %{ Storable::thaw($serialized) };
3980
3981   $self;
3982 }
3983
3984
3985 =head2 throw_exception
3986
3987 See L<DBIx::Class::Schema/throw_exception> for details.
3988
3989 =cut
3990
3991 sub throw_exception {
3992   my $self=shift;
3993
3994   if (ref $self and my $rsrc = $self->result_source) {
3995     $rsrc->throw_exception(@_)
3996   }
3997   else {
3998     DBIx::Class::Exception->throw(@_);
3999   }
4000 }
4001
4002 1;
4003
4004 __END__
4005
4006 # XXX: FIXME: Attributes docs need clearing up
4007
4008 =head1 ATTRIBUTES
4009
4010 Attributes are used to refine a ResultSet in various ways when
4011 searching for data. They can be passed to any method which takes an
4012 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4013 L</count>.
4014
4015 Default attributes can be set on the result class using
4016 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4017 the CAVEATS on that feature before using it!)
4018
4019 These are in no particular order:
4020
4021 =head2 order_by
4022
4023 =over 4
4024
4025 =item Value: ( $order_by | \@order_by | \%order_by )
4026
4027 =back
4028
4029 Which column(s) to order the results by.
4030
4031 [The full list of suitable values is documented in
4032 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4033 common options.]
4034
4035 If a single column name, or an arrayref of names is supplied, the
4036 argument is passed through directly to SQL. The hashref syntax allows
4037 for connection-agnostic specification of ordering direction:
4038
4039  For descending order:
4040
4041   order_by => { -desc => [qw/col1 col2 col3/] }
4042
4043  For explicit ascending order:
4044
4045   order_by => { -asc => 'col' }
4046
4047 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4048 supported, although you are strongly encouraged to use the hashref
4049 syntax as outlined above.
4050
4051 =head2 columns
4052
4053 =over 4
4054
4055 =item Value: \@columns | \%columns | $column
4056
4057 =back
4058
4059 Shortcut to request a particular set of columns to be retrieved. Each
4060 column spec may be a string (a table column name), or a hash (in which
4061 case the key is the C<as> value, and the value is used as the C<select>
4062 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4063 it and sets C<select> from that, then auto-populates C<as> from
4064 C<select> as normal. (You may also use the C<cols> attribute, as in
4065 earlier versions of DBIC, but this is deprecated)
4066
4067 Essentially C<columns> does the same as L</select> and L</as>.
4068
4069     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4070
4071 is the same as
4072
4073     select => [qw(some_column another_column)],
4074     as     => [qw(some_column dbic_slot)]
4075
4076 If you want to individually retrieve related columns (in essence perform
4077 manual prefetch) you have to make sure to specify the correct inflation slot
4078 chain such that it matches existing relationships:
4079
4080     my $rs = $schema->resultset('Artist')->search({}, {
4081         # required to tell DBIC to collapse has_many relationships
4082         collapse => 1,
4083         join     => { cds => 'tracks'},
4084         '+columns'  => {
4085           'cds.cdid'         => 'cds.cdid',
4086           'cds.tracks.title' => 'tracks.title',
4087         },
4088     });
4089
4090 =head2 +columns
4091
4092 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4093 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4094 with a unary plus operator before it, which is the same as simply C<columns>.
4095
4096 =over 4
4097
4098 =item Value: \@extra_columns
4099
4100 =back
4101
4102 Indicates additional columns to be selected from storage. Works the same as
4103 L</columns> but adds columns to the current selection. (You may also use the
4104 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4105 deprecated)
4106
4107   $schema->resultset('CD')->search(undef, {
4108     '+columns' => ['artist.name'],
4109     join => ['artist']
4110   });
4111
4112 would return all CDs and include a 'name' column to the information
4113 passed to object inflation. Note that the 'artist' is the name of the
4114 column (or relationship) accessor, and 'name' is the name of the column
4115 accessor in the related table.
4116
4117 =head2 select
4118
4119 =over 4
4120
4121 =item Value: \@select_columns
4122
4123 =back
4124
4125 Indicates which columns should be selected from the storage. You can use
4126 column names, or in the case of RDBMS back ends, function or stored procedure
4127 names:
4128
4129   $rs = $schema->resultset('Employee')->search(undef, {
4130     select => [
4131       'name',
4132       { count => 'employeeid' },
4133       { max => { length => 'name' }, -as => 'longest_name' }
4134     ]
4135   });
4136
4137   # Equivalent SQL
4138   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4139
4140 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4141 use L</select>, to instruct DBIx::Class how to store the result of the column.
4142 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4143 identifier aliasing. You can however alias a function, so you can use it in
4144 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4145 attribute> supplied as shown in the example above.
4146
4147 =head2 +select
4148
4149 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4150 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4151 with a unary plus operator before it, which is the same as simply C<select>.
4152
4153 =over 4
4154
4155 =item Value: \@extra_select_columns
4156
4157 =back
4158
4159 Indicates additional columns to be selected from storage.  Works the same as
4160 L</select> but adds columns to the current selection, instead of specifying
4161 a new explicit list.
4162
4163 =head2 as
4164
4165 =over 4
4166
4167 =item Value: \@inflation_names
4168
4169 =back
4170
4171 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4172 slot name in which the column value will be stored within the
4173 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4174 identifier by the C<get_column> method (or via the object accessor B<if one
4175 with the same name already exists>) as shown below. The L</as> attribute has
4176 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4177
4178   $rs = $schema->resultset('Employee')->search(undef, {
4179     select => [
4180       'name',
4181       { count => 'employeeid' },
4182       { max => { length => 'name' }, -as => 'longest_name' }
4183     ],
4184     as => [qw/
4185       name
4186       employee_count
4187       max_name_length
4188     /],
4189   });
4190
4191 If the object against which the search is performed already has an accessor
4192 matching a column name specified in C<as>, the value can be retrieved using
4193 the accessor as normal:
4194
4195   my $name = $employee->name();
4196
4197 If on the other hand an accessor does not exist in the object, you need to
4198 use C<get_column> instead:
4199
4200   my $employee_count = $employee->get_column('employee_count');
4201
4202 You can create your own accessors if required - see
4203 L<DBIx::Class::Manual::Cookbook> for details.
4204
4205 =head2 +as
4206
4207 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4208 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4209 with a unary plus operator before it, which is the same as simply C<as>.
4210
4211 =over 4
4212
4213 =item Value: \@extra_inflation_names
4214
4215 =back
4216
4217 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4218
4219 =head2 join
4220
4221 =over 4
4222
4223 =item Value: ($rel_name | \@rel_names | \%rel_names)
4224
4225 =back
4226
4227 Contains a list of relationships that should be joined for this query.  For
4228 example:
4229
4230   # Get CDs by Nine Inch Nails
4231   my $rs = $schema->resultset('CD')->search(
4232     { 'artist.name' => 'Nine Inch Nails' },
4233     { join => 'artist' }
4234   );
4235
4236 Can also contain a hash reference to refer to the other relation's relations.
4237 For example:
4238
4239   package MyApp::Schema::Track;
4240   use base qw/DBIx::Class/;
4241   __PACKAGE__->table('track');
4242   __PACKAGE__->add_columns(qw/trackid cd position title/);
4243   __PACKAGE__->set_primary_key('trackid');
4244   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4245   1;
4246
4247   # In your application
4248   my $rs = $schema->resultset('Artist')->search(
4249     { 'track.title' => 'Teardrop' },
4250     {
4251       join     => { cd => 'track' },
4252       order_by => 'artist.name',
4253     }
4254   );
4255
4256 You need to use the relationship (not the table) name in  conditions,
4257 because they are aliased as such. The current table is aliased as "me", so
4258 you need to use me.column_name in order to avoid ambiguity. For example:
4259
4260   # Get CDs from 1984 with a 'Foo' track
4261   my $rs = $schema->resultset('CD')->search(
4262     {
4263       'me.year' => 1984,
4264       'tracks.name' => 'Foo'
4265     },
4266     { join => 'tracks' }
4267   );
4268
4269 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4270 similarly for a third time). For e.g.
4271
4272   my $rs = $schema->resultset('Artist')->search({
4273     'cds.title'   => 'Down to Earth',
4274     'cds_2.title' => 'Popular',
4275   }, {
4276     join => [ qw/cds cds/ ],
4277   });
4278
4279 will return a set of all artists that have both a cd with title 'Down
4280 to Earth' and a cd with title 'Popular'.
4281
4282 If you want to fetch related objects from other tables as well, see L</prefetch>
4283 below.
4284
4285  NOTE: An internal join-chain pruner will discard certain joins while
4286  constructing the actual SQL query, as long as the joins in question do not
4287  affect the retrieved result. This for example includes 1:1 left joins
4288  that are not part of the restriction specification (WHERE/HAVING) nor are
4289  a part of the query selection.
4290
4291 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4292
4293 =head2 collapse
4294
4295 =over 4
4296
4297 =item Value: (0 | 1)
4298
4299 =back
4300
4301 When set to a true value, indicates that any rows fetched from joined has_many
4302 relationships are to be aggregated into the corresponding "parent" object. For
4303 example, the resultset:
4304
4305   my $rs = $schema->resultset('CD')->search({}, {
4306     '+columns' => [ qw/ tracks.title tracks.position / ],
4307     join => 'tracks',
4308     collapse => 1,
4309   });
4310
4311 While executing the following query:
4312
4313   SELECT me.*, tracks.title, tracks.position
4314     FROM cd me
4315     LEFT JOIN track tracks
4316       ON tracks.cdid = me.cdid
4317
4318 Will return only as many objects as there are rows in the CD source, even
4319 though the result of the query may span many rows. Each of these CD objects
4320 will in turn have multiple "Track" objects hidden behind the has_many
4321 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4322 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4323 product"), with each CD object containing exactly one of all fetched Track data.
4324
4325 When a collapse is requested on a non-ordered resultset, an order by some
4326 unique part of the main source (the left-most table) is inserted automatically.
4327 This is done so that the resultset is allowed to be "lazy" - calling
4328 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4329 object with all of its related data.
4330
4331 If an L</order_by> is already declared, and orders the resultset in a way that
4332 makes collapsing as described above impossible (e.g. C<< ORDER BY
4333 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4334 switch to "eager" mode and slurp the entire resultset before constructing the
4335 first object returned by L</next>.
4336
4337 Setting this attribute on a resultset that does not join any has_many
4338 relations is a no-op.
4339
4340 For a more in-depth discussion, see L</PREFETCHING>.
4341
4342 =head2 prefetch
4343
4344 =over 4
4345
4346 =item Value: ($rel_name | \@rel_names | \%rel_names)
4347
4348 =back
4349
4350 This attribute is a shorthand for specifying a L</join> spec, adding all
4351 columns from the joined related sources as L</+columns> and setting
4352 L</collapse> to a true value. For example, the following two queries are
4353 equivalent:
4354
4355   my $rs = $schema->resultset('Artist')->search({}, {
4356     prefetch => { cds => ['genre', 'tracks' ] },
4357   });
4358
4359 and
4360
4361   my $rs = $schema->resultset('Artist')->search({}, {
4362     join => { cds => ['genre', 'tracks' ] },
4363     collapse => 1,
4364     '+columns' => [
4365       (map
4366         { +{ "cds.$_" => "cds.$_" } }
4367         $schema->source('Artist')->related_source('cds')->columns
4368       ),
4369       (map
4370         { +{ "cds.genre.$_" => "genre.$_" } }
4371         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4372       ),
4373       (map
4374         { +{ "cds.tracks.$_" => "tracks.$_" } }
4375         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4376       ),
4377     ],
4378   });
4379
4380 Both producing the following SQL:
4381
4382   SELECT  me.artistid, me.name, me.rank, me.charfield,
4383           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4384           genre.genreid, genre.name,
4385           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4386     FROM artist me
4387     LEFT JOIN cd cds
4388       ON cds.artist = me.artistid
4389     LEFT JOIN genre genre
4390       ON genre.genreid = cds.genreid
4391     LEFT JOIN track tracks
4392       ON tracks.cd = cds.cdid
4393   ORDER BY me.artistid
4394
4395 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4396 the arguments are properly merged and generally do the right thing. For
4397 example, you may want to do the following:
4398
4399   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4400     { 'genre.genreid' => undef },
4401     {
4402       join => { cds => 'genre' },
4403       prefetch => 'cds',
4404     }
4405   );
4406
4407 Which generates the following SQL:
4408
4409   SELECT  me.artistid, me.name, me.rank, me.charfield,
4410           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4411     FROM artist me
4412     LEFT JOIN cd cds
4413       ON cds.artist = me.artistid
4414     LEFT JOIN genre genre
4415       ON genre.genreid = cds.genreid
4416   WHERE genre.genreid IS NULL
4417   ORDER BY me.artistid
4418
4419 For a more in-depth discussion, see L</PREFETCHING>.
4420
4421 =head2 alias
4422
4423 =over 4
4424
4425 =item Value: $source_alias
4426
4427 =back
4428
4429 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4430 nested search queries (sub-SELECTs) might need specific aliases set to
4431 reference inner queries.  For example:
4432
4433    my $q = $rs
4434       ->related_resultset('CDs')
4435       ->related_resultset('Tracks')
4436       ->search({
4437          'track.id' => { -ident => 'none_search.id' },
4438       })
4439       ->as_query;
4440
4441    my $ids = $self->search({
4442       -not_exists => $q,
4443    }, {
4444       alias    => 'none_search',
4445       group_by => 'none_search.id',
4446    })->get_column('id')->as_query;
4447
4448    $self->search({ id => { -in => $ids } })
4449
4450 This attribute is directly tied to L</current_source_alias>.
4451
4452 =head2 page
4453
4454 =over 4
4455
4456 =item Value: $page
4457
4458 =back
4459
4460 Makes the resultset paged and specifies the page to retrieve. Effectively
4461 identical to creating a non-pages resultset and then calling ->page($page)
4462 on it.
4463
4464 If L</rows> attribute is not specified it defaults to 10 rows per page.
4465
4466 When you have a paged resultset, L</count> will only return the number
4467 of rows in the page. To get the total, use the L</pager> and call
4468 C<total_entries> on it.
4469
4470 =head2 rows
4471
4472 =over 4
4473
4474 =item Value: $rows
4475
4476 =back
4477
4478 Specifies the maximum number of rows for direct retrieval or the number of
4479 rows per page if the page attribute or method is used.
4480
4481 =head2 offset
4482
4483 =over 4
4484
4485 =item Value: $offset
4486
4487 =back
4488
4489 Specifies the (zero-based) row number for the  first row to be returned, or the
4490 of the first row of the first page if paging is used.
4491
4492 =head2 software_limit
4493
4494 =over 4
4495
4496 =item Value: (0 | 1)
4497
4498 =back
4499
4500 When combined with L</rows> and/or L</offset> the generated SQL will not
4501 include any limit dialect stanzas. Instead the entire result will be selected
4502 as if no limits were specified, and DBIC will perform the limit locally, by
4503 artificially advancing and finishing the resulting L</cursor>.
4504
4505 This is the recommended way of performing resultset limiting when no sane RDBMS
4506 implementation is available (e.g.
4507 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4508 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4509
4510 =head2 group_by
4511
4512 =over 4
4513
4514 =item Value: \@columns
4515
4516 =back
4517
4518 A arrayref of columns to group by. Can include columns of joined tables.
4519
4520   group_by => [qw/ column1 column2 ... /]
4521
4522 =head2 having
4523
4524 =over 4
4525
4526 =item Value: $condition
4527
4528 =back
4529
4530 HAVING is a select statement attribute that is applied between GROUP BY and
4531 ORDER BY. It is applied to the after the grouping calculations have been
4532 done.
4533
4534   having => { 'count_employee' => { '>=', 100 } }
4535
4536 or with an in-place function in which case literal SQL is required:
4537
4538   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4539
4540 =head2 distinct
4541
4542 =over 4
4543
4544 =item Value: (0 | 1)
4545
4546 =back
4547
4548 Set to 1 to automatically generate a L</group_by> clause based on the selection
4549 (including intelligent handling of L</order_by> contents). Note that the group
4550 criteria calculation takes place over the B<final> selection. This includes
4551 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4552 L</search> calls, and standalone columns selected via
4553 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4554 extra selections specified via L</prefetch> - such selections are explicitly
4555 excluded from group criteria calculations.
4556
4557 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4558 setting is ignored and an appropriate warning is issued.
4559
4560 =head2 where
4561
4562 =over 4
4563
4564 Adds to the WHERE clause.
4565
4566   # only return rows WHERE deleted IS NULL for all searches
4567   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4568
4569 Can be overridden by passing C<< { where => undef } >> as an attribute
4570 to a resultset.
4571
4572 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4573
4574 =back
4575
4576 =head2 cache
4577
4578 Set to 1 to cache search results. This prevents extra SQL queries if you
4579 revisit rows in your ResultSet:
4580
4581   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4582
4583   while( my $artist = $resultset->next ) {
4584     ... do stuff ...
4585   }
4586
4587   $rs->first; # without cache, this would issue a query
4588
4589 By default, searches are not cached.
4590
4591 For more examples of using these attributes, see
4592 L<DBIx::Class::Manual::Cookbook>.
4593
4594 =head2 for
4595
4596 =over 4
4597
4598 =item Value: ( 'update' | 'shared' | \$scalar )
4599
4600 =back
4601
4602 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4603 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4604 query.
4605
4606 =head1 PREFETCHING
4607
4608 DBIx::Class supports arbitrary related data prefetching from multiple related
4609 sources. Any combination of relationship types and column sets are supported.
4610 If L<collapsing|/collapse> is requested, there is an additional requirement of
4611 selecting enough data to make every individual object uniquely identifiable.
4612
4613 Here are some more involved examples, based on the following relationship map:
4614
4615   # Assuming:
4616   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4617   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4618   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4619
4620   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4621
4622   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4623
4624
4625
4626   my $rs = $schema->resultset('Tag')->search(
4627     undef,
4628     {
4629       prefetch => {
4630         cd => 'artist'
4631       }
4632     }
4633   );
4634
4635 The initial search results in SQL like the following:
4636
4637   SELECT tag.*, cd.*, artist.* FROM tag
4638   JOIN cd ON tag.cd = cd.cdid
4639   JOIN artist ON cd.artist = artist.artistid
4640
4641 L<DBIx::Class> has no need to go back to the database when we access the
4642 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4643 case.
4644
4645 Simple prefetches will be joined automatically, so there is no need
4646 for a C<join> attribute in the above search.
4647
4648 The L</prefetch> attribute can be used with any of the relationship types
4649 and multiple prefetches can be specified together. Below is a more complex
4650 example that prefetches a CD's artist, its liner notes (if present),
4651 the cover image, the tracks on that CD, and the guests on those
4652 tracks.
4653
4654   my $rs = $schema->resultset('CD')->search(
4655     undef,
4656     {
4657       prefetch => [
4658         { artist => 'record_label'},  # belongs_to => belongs_to
4659         'liner_note',                 # might_have
4660         'cover_image',                # has_one
4661         { tracks => 'guests' },       # has_many => has_many
4662       ]
4663     }
4664   );
4665
4666 This will produce SQL like the following:
4667
4668   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4669          tracks.*, guests.*
4670     FROM cd me
4671     JOIN artist artist
4672       ON artist.artistid = me.artistid
4673     JOIN record_label record_label
4674       ON record_label.labelid = artist.labelid
4675     LEFT JOIN track tracks
4676       ON tracks.cdid = me.cdid
4677     LEFT JOIN guest guests
4678       ON guests.trackid = track.trackid
4679     LEFT JOIN liner_notes liner_note
4680       ON liner_note.cdid = me.cdid
4681     JOIN cd_artwork cover_image
4682       ON cover_image.cdid = me.cdid
4683   ORDER BY tracks.cd
4684
4685 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4686 C<tracks>, and C<guests> of the CD will all be available through the
4687 relationship accessors without the need for additional queries to the
4688 database.
4689
4690 =head3 CAVEATS
4691
4692 Prefetch does a lot of deep magic. As such, it may not behave exactly
4693 as you might expect.
4694
4695 =over 4
4696
4697 =item *
4698
4699 Prefetch uses the L</cache> to populate the prefetched relationships. This
4700 may or may not be what you want.
4701
4702 =item *
4703
4704 If you specify a condition on a prefetched relationship, ONLY those
4705 rows that match the prefetched condition will be fetched into that relationship.
4706 This means that adding prefetch to a search() B<may alter> what is returned by
4707 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4708
4709   my $artist_rs = $schema->resultset('Artist')->search({
4710       'cds.year' => 2008,
4711   }, {
4712       join => 'cds',
4713   });
4714
4715   my $count = $artist_rs->first->cds->count;
4716
4717   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4718
4719   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4720
4721   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4722
4723 That cmp_ok() may or may not pass depending on the datasets involved. In other
4724 words the C<WHERE> condition would apply to the entire dataset, just like
4725 it would in regular SQL. If you want to add a condition only to the "right side"
4726 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4727 condition|DBIx::Class::Relationship::Base/condition>
4728
4729 =back
4730
4731 =head1 DBIC BIND VALUES
4732
4733 Because DBIC may need more information to bind values than just the column name
4734 and value itself, it uses a special format for both passing and receiving bind
4735 values.  Each bind value should be composed of an arrayref of
4736 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4737
4738 =over 4
4739
4740 =item dbd_attrs
4741
4742 If present (in any form), this is what is being passed directly to bind_param.
4743 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4744 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4745
4746 If this is specified, all other bind options described below are ignored.
4747
4748 =item sqlt_datatype
4749
4750 If present, this is used to infer the actual bind attribute by passing to
4751 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4752 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4753
4754 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4755 currently drivers are expected to "Do the Right Thing" when given a common
4756 datatype name.  (Not ideal, but that's what we got at this point.)
4757
4758 =item sqlt_size
4759
4760 Currently used to correctly allocate buffers for bind_param_inout().
4761 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4762 or to a sensible value based on the "data_type".
4763
4764 =item dbic_colname
4765
4766 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4767 explicitly specified they are never overridden).  Also used by some weird DBDs,
4768 where the column name should be available at bind_param time (e.g. Oracle).
4769
4770 =back
4771
4772 For backwards compatibility and convenience, the following shortcuts are
4773 supported:
4774
4775   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4776   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4777   [ undef,   $val ] === [ {}, $val ]
4778   $val              === [ {}, $val ]
4779
4780 =head1 AUTHOR AND CONTRIBUTORS
4781
4782 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4783
4784 =head1 LICENSE
4785
4786 You may distribute this code under the same terms as Perl itself.
4787