lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 966   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 967   @new = $self->{_attrs}{record_filter}->(@new)
 968     if exists $self->{_attrs}{record_filter};
 969   return @new;
 970 }
 971
 972 sub _collapse_result {
 973   my ($self, $as_proto, $row) = @_;
 974
 975   my @copy = @$row;
 976
 977   # 'foo'         => [ undef, 'foo' ]
 978   # 'foo.bar'     => [ 'foo', 'bar' ]
 979   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 980
 981   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 982
 983   my %collapse = %{$self->{_attrs}{collapse}||{}};
 984
 985   my @pri_index;
 986
 987   # if we're doing collapsing (has_many prefetch) we need to grab records
 988   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 989   # we know we don't have to bother.
 990
 991   # the reason for not using the collapse stuff directly is because if you
 992   # had for e.g. two artists in a row with no cds, the collapse info for
 993   # both would be NULL (undef) so you'd lose the second artist
 994
 995   # store just the index so we can check the array positions from the row
 996   # without having to contruct the full hash
 997
 998   if (keys %collapse) {
 999     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1000     foreach my $i (0 .. $#construct_as) {
1001       next if defined($construct_as[$i][0]); # only self table
1002       if (delete $pri{$construct_as[$i][1]}) {
1003         push(@pri_index, $i);
1004       }
1005       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1006     }
1007   }
1008
1009   # no need to do an if, it'll be empty if @pri_index is empty anyway
1010
1011   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1012
1013   my @const_rows;
1014
1015   do { # no need to check anything at the front, we always want the first row
1016
1017     my %const;
1018
1019     foreach my $this_as (@construct_as) {
1020       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1021     }
1022
1023     push(@const_rows, \%const);
1024
1025   } until ( # no pri_index => no collapse => drop straight out
1026       !@pri_index
1027     or
1028       do { # get another row, stash it, drop out if different PK
1029
1030         @copy = $self->cursor->next;
1031         $self->{stashed_row} = \@copy;
1032
1033         # last thing in do block, counts as true if anything doesn't match
1034
1035         # check xor defined first for NULL vs. NOT NULL then if one is
1036         # defined the other must be so check string equality
1037
1038         grep {
1039           (defined $pri_vals{$_} ^ defined $copy[$_])
1040           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1041         } @pri_index;
1042       }
1043   );
1044
1045   my $alias = $self->{attrs}{alias};
1046   my $info = [];
1047
1048   my %collapse_pos;
1049
1050   my @const_keys;
1051
1052   foreach my $const (@const_rows) {
1053     scalar @const_keys or do {
1054       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1055     };
1056     foreach my $key (@const_keys) {
1057       if (length $key) {
1058         my $target = $info;
1059         my @parts = split(/\./, $key);
1060         my $cur = '';
1061         my $data = $const->{$key};
1062         foreach my $p (@parts) {
1063           $target = $target->[1]->{$p} ||= [];
1064           $cur .= ".${p}";
1065           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1066             # collapsing at this point and on final part
1067             my $pos = $collapse_pos{$cur};
1068             CK: foreach my $ck (@ckey) {
1069               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1070                 $collapse_pos{$cur} = $data;
1071                 delete @collapse_pos{ # clear all positioning for sub-entries
1072                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1073                 };
1074                 push(@$target, []);
1075                 last CK;
1076               }
1077             }
1078           }
1079           if (exists $collapse{$cur}) {
1080             $target = $target->[-1];
1081           }
1082         }
1083         $target->[0] = $data;
1084       } else {
1085         $info->[0] = $const->{$key};
1086       }
1087     }
1088   }
1089
1090   return $info;
1091 }
1092
1093 =head2 result_source
1094
1095 =over 4
1096
1097 =item Arguments: $result_source?
1098
1099 =item Return Value: $result_source
1100
1101 =back
1102
1103 An accessor for the primary ResultSource object from which this ResultSet
1104 is derived.
1105
1106 =head2 result_class
1107
1108 =over 4
1109
1110 =item Arguments: $result_class?
1111
1112 =item Return Value: $result_class
1113
1114 =back
1115
1116 An accessor for the class to use when creating row objects. Defaults to
1117 C<< result_source->result_class >> - which in most cases is the name of the
1118 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1119
1120 Note that changing the result_class will also remove any components
1121 that were originally loaded in the source class via
1122 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1123 in the original source class will not run.
1124
1125 =cut
1126
1127 sub result_class {
1128   my ($self, $result_class) = @_;
1129   if ($result_class) {
1130     $self->ensure_class_loaded($result_class);
1131     $self->_result_class($result_class);
1132   }
1133   $self->_result_class;
1134 }
1135
1136 =head2 count
1137
1138 =over 4
1139
1140 =item Arguments: $cond, \%attrs??
1141
1142 =item Return Value: $count
1143
1144 =back
1145
1146 Performs an SQL C<COUNT> with the same query as the resultset was built
1147 with to find the number of elements. Passing arguments is equivalent to
1148 C<< $rs->search ($cond, \%attrs)->count >>
1149
1150 =cut
1151
1152 sub count {
1153   my $self = shift;
1154   return $self->search(@_)->count if @_ and defined $_[0];
1155   return scalar @{ $self->get_cache } if $self->get_cache;
1156
1157   my $attrs = $self->_resolved_attrs_copy;
1158
1159   # this is a little optimization - it is faster to do the limit
1160   # adjustments in software, instead of a subquery
1161   my $rows = delete $attrs->{rows};
1162   my $offset = delete $attrs->{offset};
1163
1164   my $crs;
1165   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1166     $crs = $self->_count_subq_rs ($attrs);
1167   }
1168   else {
1169     $crs = $self->_count_rs ($attrs);
1170   }
1171   my $count = $crs->next;
1172
1173   $count -= $offset if $offset;
1174   $count = $rows if $rows and $rows < $count;
1175   $count = 0 if ($count < 0);
1176
1177   return $count;
1178 }
1179
1180 =head2 count_rs
1181
1182 =over 4
1183
1184 =item Arguments: $cond, \%attrs??
1185
1186 =item Return Value: $count_rs
1187
1188 =back
1189
1190 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1191 This can be very handy for subqueries:
1192
1193   ->search( { amount => $some_rs->count_rs->as_query } )
1194
1195 As with regular resultsets the SQL query will be executed only after
1196 the resultset is accessed via L</next> or L</all>. That would return
1197 the same single value obtainable via L</count>.
1198
1199 =cut
1200
1201 sub count_rs {
1202   my $self = shift;
1203   return $self->search(@_)->count_rs if @_;
1204
1205   # this may look like a lack of abstraction (count() does about the same)
1206   # but in fact an _rs *must* use a subquery for the limits, as the
1207   # software based limiting can not be ported if this $rs is to be used
1208   # in a subquery itself (i.e. ->as_query)
1209   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1210     return $self->_count_subq_rs;
1211   }
1212   else {
1213     return $self->_count_rs;
1214   }
1215 }
1216
1217 #
1218 # returns a ResultSetColumn object tied to the count query
1219 #
1220 sub _count_rs {
1221   my ($self, $attrs) = @_;
1222
1223   my $rsrc = $self->result_source;
1224   $attrs ||= $self->_resolved_attrs;
1225
1226   my $tmp_attrs = { %$attrs };
1227
1228   # take off any limits, record_filter is cdbi, and no point of ordering a count
1229   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1230
1231   # overwrite the selector (supplied by the storage)
1232   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1233   $tmp_attrs->{as} = 'count';
1234
1235   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1236
1237   return $tmp_rs;
1238 }
1239
1240 #
1241 # same as above but uses a subquery
1242 #
1243 sub _count_subq_rs {
1244   my ($self, $attrs) = @_;
1245
1246   my $rsrc = $self->result_source;
1247   $attrs ||= $self->_resolved_attrs_copy;
1248
1249   my $sub_attrs = { %$attrs };
1250
1251   # these can not go in the subquery, and there is no point of ordering it
1252   delete $sub_attrs->{$_} for qw/collapse select as order_by/;
1253
1254   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1255   # clobber old group_by regardless
1256   if ( keys %{$attrs->{collapse}} ) {
1257     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1258   }
1259
1260   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1261
1262   # this is so that ordering can be thrown away in things like Top limit
1263   $sub_attrs->{-for_count_only} = 1;
1264
1265   $attrs->{from} = [{
1266     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1267   }];
1268
1269   # the subquery replaces this
1270   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1271
1272   return $self->_count_rs ($attrs);
1273 }
1274
1275
1276 sub _bool {
1277   return 1;
1278 }
1279
1280 =head2 count_literal
1281
1282 =over 4
1283
1284 =item Arguments: $sql_fragment, @bind_values
1285
1286 =item Return Value: $count
1287
1288 =back
1289
1290 Counts the results in a literal query. Equivalent to calling L</search_literal>
1291 with the passed arguments, then L</count>.
1292
1293 =cut
1294
1295 sub count_literal { shift->search_literal(@_)->count; }
1296
1297 =head2 all
1298
1299 =over 4
1300
1301 =item Arguments: none
1302
1303 =item Return Value: @objects
1304
1305 =back
1306
1307 Returns all elements in the resultset. Called implicitly if the resultset
1308 is returned in list context.
1309
1310 =cut
1311
1312 sub all {
1313   my $self = shift;
1314   if(@_) {
1315       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1316   }
1317
1318   return @{ $self->get_cache } if $self->get_cache;
1319
1320   my @obj;
1321
1322   # TODO: don't call resolve here
1323   if (keys %{$self->_resolved_attrs->{collapse}}) {
1324 #  if ($self->{attrs}{prefetch}) {
1325       # Using $self->cursor->all is really just an optimisation.
1326       # If we're collapsing has_many prefetches it probably makes
1327       # very little difference, and this is cleaner than hacking
1328       # _construct_object to survive the approach
1329     my @row = $self->cursor->next;
1330     while (@row) {
1331       push(@obj, $self->_construct_object(@row));
1332       @row = (exists $self->{stashed_row}
1333                ? @{delete $self->{stashed_row}}
1334                : $self->cursor->next);
1335     }
1336   } else {
1337     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1338   }
1339
1340   $self->set_cache(\@obj) if $self->{attrs}{cache};
1341   return @obj;
1342 }
1343
1344 =head2 reset
1345
1346 =over 4
1347
1348 =item Arguments: none
1349
1350 =item Return Value: $self
1351
1352 =back
1353
1354 Resets the resultset's cursor, so you can iterate through the elements again.
1355
1356 =cut
1357
1358 sub reset {
1359   my ($self) = @_;
1360   delete $self->{_attrs} if exists $self->{_attrs};
1361   $self->{all_cache_position} = 0;
1362   $self->cursor->reset;
1363   return $self;
1364 }
1365
1366 =head2 first
1367
1368 =over 4
1369
1370 =item Arguments: none
1371
1372 =item Return Value: $object?
1373
1374 =back
1375
1376 Resets the resultset and returns an object for the first result (if the
1377 resultset returns anything).
1378
1379 =cut
1380
1381 sub first {
1382   return $_[0]->reset->next;
1383 }
1384
1385
1386 # _rs_update_delete
1387 #
1388 # Determines whether and what type of subquery is required for the $rs operation.
1389 # If grouping is necessary either supplies its own, or verifies the current one
1390 # After all is done delegates to the proper storage method.
1391
1392 sub _rs_update_delete {
1393   my ($self, $op, $values) = @_;
1394
1395   my $rsrc = $self->result_source;
1396
1397   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1398   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1399
1400   if ($needs_group_by_subq or $needs_subq) {
1401
1402     # make a new $rs selecting only the PKs (that's all we really need)
1403     my $attrs = $self->_resolved_attrs_copy;
1404
1405     delete $attrs->{$_} for qw/collapse select as/;
1406     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1407
1408     if ($needs_group_by_subq) {
1409       # make sure no group_by was supplied, or if there is one - make sure it matches
1410       # the columns compiled above perfectly. Anything else can not be sanely executed
1411       # on most databases so croak right then and there
1412
1413       if (my $g = $attrs->{group_by}) {
1414         my @current_group_by = map
1415           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1416           (ref $g eq 'ARRAY' ? @$g : $g );
1417
1418         if (
1419           join ("\x00", sort @current_group_by)
1420             ne
1421           join ("\x00", sort @{$attrs->{columns}} )
1422         ) {
1423           $self->throw_exception (
1424             "You have just attempted a $op operation on a resultset which does group_by"
1425             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1426             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1427             . ' kind of queries. Please retry the operation with a modified group_by or'
1428             . ' without using one at all.'
1429           );
1430         }
1431       }
1432       else {
1433         $attrs->{group_by} = $attrs->{columns};
1434       }
1435     }
1436
1437     my $subrs = (ref $self)->new($rsrc, $attrs);
1438
1439     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1440   }
1441   else {
1442     return $rsrc->storage->$op(
1443       $rsrc,
1444       $op eq 'update' ? $values : (),
1445       $self->_cond_for_update_delete,
1446     );
1447   }
1448 }
1449
1450
1451 # _cond_for_update_delete
1452 #
1453 # update/delete require the condition to be modified to handle
1454 # the differing SQL syntax available.  This transforms the $self->{cond}
1455 # appropriately, returning the new condition.
1456
1457 sub _cond_for_update_delete {
1458   my ($self, $full_cond) = @_;
1459   my $cond = {};
1460
1461   $full_cond ||= $self->{cond};
1462   # No-op. No condition, we're updating/deleting everything
1463   return $cond unless ref $full_cond;
1464
1465   if (ref $full_cond eq 'ARRAY') {
1466     $cond = [
1467       map {
1468         my %hash;
1469         foreach my $key (keys %{$_}) {
1470           $key =~ /([^.]+)$/;
1471           $hash{$1} = $_->{$key};
1472         }
1473         \%hash;
1474       } @{$full_cond}
1475     ];
1476   }
1477   elsif (ref $full_cond eq 'HASH') {
1478     if ((keys %{$full_cond})[0] eq '-and') {
1479       $cond->{-and} = [];
1480       my @cond = @{$full_cond->{-and}};
1481        for (my $i = 0; $i < @cond; $i++) {
1482         my $entry = $cond[$i];
1483         my $hash;
1484         if (ref $entry eq 'HASH') {
1485           $hash = $self->_cond_for_update_delete($entry);
1486         }
1487         else {
1488           $entry =~ /([^.]+)$/;
1489           $hash->{$1} = $cond[++$i];
1490         }
1491         push @{$cond->{-and}}, $hash;
1492       }
1493     }
1494     else {
1495       foreach my $key (keys %{$full_cond}) {
1496         $key =~ /([^.]+)$/;
1497         $cond->{$1} = $full_cond->{$key};
1498       }
1499     }
1500   }
1501   else {
1502     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1503   }
1504
1505   return $cond;
1506 }
1507
1508
1509 =head2 update
1510
1511 =over 4
1512
1513 =item Arguments: \%values
1514
1515 =item Return Value: $storage_rv
1516
1517 =back
1518
1519 Sets the specified columns in the resultset to the supplied values in a
1520 single query. Return value will be true if the update succeeded or false
1521 if no records were updated; exact type of success value is storage-dependent.
1522
1523 =cut
1524
1525 sub update {
1526   my ($self, $values) = @_;
1527   $self->throw_exception('Values for update must be a hash')
1528     unless ref $values eq 'HASH';
1529
1530   return $self->_rs_update_delete ('update', $values);
1531 }
1532
1533 =head2 update_all
1534
1535 =over 4
1536
1537 =item Arguments: \%values
1538
1539 =item Return Value: 1
1540
1541 =back
1542
1543 Fetches all objects and updates them one at a time. Note that C<update_all>
1544 will run DBIC cascade triggers, while L</update> will not.
1545
1546 =cut
1547
1548 sub update_all {
1549   my ($self, $values) = @_;
1550   $self->throw_exception('Values for update_all must be a hash')
1551     unless ref $values eq 'HASH';
1552   foreach my $obj ($self->all) {
1553     $obj->set_columns($values)->update;
1554   }
1555   return 1;
1556 }
1557
1558 =head2 delete
1559
1560 =over 4
1561
1562 =item Arguments: none
1563
1564 =item Return Value: $storage_rv
1565
1566 =back
1567
1568 Deletes the contents of the resultset from its result source. Note that this
1569 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1570 to run. See also L<DBIx::Class::Row/delete>.
1571
1572 Return value will be the amount of rows deleted; exact type of return value
1573 is storage-dependent.
1574
1575 =cut
1576
1577 sub delete {
1578   my $self = shift;
1579   $self->throw_exception('delete does not accept any arguments')
1580     if @_;
1581
1582   return $self->_rs_update_delete ('delete');
1583 }
1584
1585 =head2 delete_all
1586
1587 =over 4
1588
1589 =item Arguments: none
1590
1591 =item Return Value: 1
1592
1593 =back
1594
1595 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1596 will run DBIC cascade triggers, while L</delete> will not.
1597
1598 =cut
1599
1600 sub delete_all {
1601   my $self = shift;
1602   $self->throw_exception('delete_all does not accept any arguments')
1603     if @_;
1604
1605   $_->delete for $self->all;
1606   return 1;
1607 }
1608
1609 =head2 populate
1610
1611 =over 4
1612
1613 =item Arguments: \@data;
1614
1615 =back
1616
1617 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1618 For the arrayref of hashrefs style each hashref should be a structure suitable
1619 forsubmitting to a $resultset->create(...) method.
1620
1621 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1622 to insert the data, as this is a faster method.
1623
1624 Otherwise, each set of data is inserted into the database using
1625 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1626 accumulated into an array. The array itself, or an array reference
1627 is returned depending on scalar or list context.
1628
1629 Example:  Assuming an Artist Class that has many CDs Classes relating:
1630
1631   my $Artist_rs = $schema->resultset("Artist");
1632
1633   ## Void Context Example
1634   $Artist_rs->populate([
1635      { artistid => 4, name => 'Manufactured Crap', cds => [
1636         { title => 'My First CD', year => 2006 },
1637         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1638       ],
1639      },
1640      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1641         { title => 'My parents sold me to a record company' ,year => 2005 },
1642         { title => 'Why Am I So Ugly?', year => 2006 },
1643         { title => 'I Got Surgery and am now Popular', year => 2007 }
1644       ],
1645      },
1646   ]);
1647
1648   ## Array Context Example
1649   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1650     { name => "Artist One"},
1651     { name => "Artist Two"},
1652     { name => "Artist Three", cds=> [
1653     { title => "First CD", year => 2007},
1654     { title => "Second CD", year => 2008},
1655   ]}
1656   ]);
1657
1658   print $ArtistOne->name; ## response is 'Artist One'
1659   print $ArtistThree->cds->count ## reponse is '2'
1660
1661 For the arrayref of arrayrefs style,  the first element should be a list of the
1662 fieldsnames to which the remaining elements are rows being inserted.  For
1663 example:
1664
1665   $Arstist_rs->populate([
1666     [qw/artistid name/],
1667     [100, 'A Formally Unknown Singer'],
1668     [101, 'A singer that jumped the shark two albums ago'],
1669     [102, 'An actually cool singer.'],
1670   ]);
1671
1672 Please note an important effect on your data when choosing between void and
1673 wantarray context. Since void context goes straight to C<insert_bulk> in
1674 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1675 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1676 create primary keys for you, you will find that your PKs are empty.  In this
1677 case you will have to use the wantarray context in order to create those
1678 values.
1679
1680 =cut
1681
1682 sub populate {
1683   my $self = shift @_;
1684   my $data = ref $_[0][0] eq 'HASH'
1685     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1686     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1687
1688   if(defined wantarray) {
1689     my @created;
1690     foreach my $item (@$data) {
1691       push(@created, $self->create($item));
1692     }
1693     return wantarray ? @created : \@created;
1694   } else {
1695     my ($first, @rest) = @$data;
1696
1697     my @names = grep {!ref $first->{$_}} keys %$first;
1698     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1699     my @pks = $self->result_source->primary_columns;
1700
1701     ## do the belongs_to relationships
1702     foreach my $index (0..$#$data) {
1703
1704       # delegate to create() for any dataset without primary keys with specified relationships
1705       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1706         for my $r (@rels) {
1707           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1708             my @ret = $self->populate($data);
1709             return;
1710           }
1711         }
1712       }
1713
1714       foreach my $rel (@rels) {
1715         next unless ref $data->[$index]->{$rel} eq "HASH";
1716         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1717         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1718         my $related = $result->result_source->_resolve_condition(
1719           $result->result_source->relationship_info($reverse)->{cond},
1720           $self,
1721           $result,
1722         );
1723
1724         delete $data->[$index]->{$rel};
1725         $data->[$index] = {%{$data->[$index]}, %$related};
1726
1727         push @names, keys %$related if $index == 0;
1728       }
1729     }
1730
1731     ## do bulk insert on current row
1732     my @values = map { [ @$_{@names} ] } @$data;
1733
1734     $self->result_source->storage->insert_bulk(
1735       $self->result_source,
1736       \@names,
1737       \@values,
1738     );
1739
1740     ## do the has_many relationships
1741     foreach my $item (@$data) {
1742
1743       foreach my $rel (@rels) {
1744         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1745
1746         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1747      || $self->throw_exception('Cannot find the relating object.');
1748
1749         my $child = $parent->$rel;
1750
1751         my $related = $child->result_source->_resolve_condition(
1752           $parent->result_source->relationship_info($rel)->{cond},
1753           $child,
1754           $parent,
1755         );
1756
1757         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1758         my @populate = map { {%$_, %$related} } @rows_to_add;
1759
1760         $child->populate( \@populate );
1761       }
1762     }
1763   }
1764 }
1765
1766 =head2 _normalize_populate_args ($args)
1767
1768 Private method used by L</populate> to normalize its incoming arguments.  Factored
1769 out in case you want to subclass and accept new argument structures to the
1770 L</populate> method.
1771
1772 =cut
1773
1774 sub _normalize_populate_args {
1775   my ($self, $data) = @_;
1776   my @names = @{shift(@$data)};
1777   my @results_to_create;
1778   foreach my $datum (@$data) {
1779     my %result_to_create;
1780     foreach my $index (0..$#names) {
1781       $result_to_create{$names[$index]} = $$datum[$index];
1782     }
1783     push @results_to_create, \%result_to_create;
1784   }
1785   return \@results_to_create;
1786 }
1787
1788 =head2 pager
1789
1790 =over 4
1791
1792 =item Arguments: none
1793
1794 =item Return Value: $pager
1795
1796 =back
1797
1798 Return Value a L<Data::Page> object for the current resultset. Only makes
1799 sense for queries with a C<page> attribute.
1800
1801 To get the full count of entries for a paged resultset, call
1802 C<total_entries> on the L<Data::Page> object.
1803
1804 =cut
1805
1806 sub pager {
1807   my ($self) = @_;
1808
1809   return $self->{pager} if $self->{pager};
1810
1811   my $attrs = $self->{attrs};
1812   $self->throw_exception("Can't create pager for non-paged rs")
1813     unless $self->{attrs}{page};
1814   $attrs->{rows} ||= 10;
1815
1816   # throw away the paging flags and re-run the count (possibly
1817   # with a subselect) to get the real total count
1818   my $count_attrs = { %$attrs };
1819   delete $count_attrs->{$_} for qw/rows offset page pager/;
1820   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1821
1822   return $self->{pager} = Data::Page->new(
1823     $total_count,
1824     $attrs->{rows},
1825     $self->{attrs}{page}
1826   );
1827 }
1828
1829 =head2 page
1830
1831 =over 4
1832
1833 =item Arguments: $page_number
1834
1835 =item Return Value: $rs
1836
1837 =back
1838
1839 Returns a resultset for the $page_number page of the resultset on which page
1840 is called, where each page contains a number of rows equal to the 'rows'
1841 attribute set on the resultset (10 by default).
1842
1843 =cut
1844
1845 sub page {
1846   my ($self, $page) = @_;
1847   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1848 }
1849
1850 =head2 new_result
1851
1852 =over 4
1853
1854 =item Arguments: \%vals
1855
1856 =item Return Value: $rowobject
1857
1858 =back
1859
1860 Creates a new row object in the resultset's result class and returns
1861 it. The row is not inserted into the database at this point, call
1862 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1863 will tell you whether the row object has been inserted or not.
1864
1865 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1866
1867 =cut
1868
1869 sub new_result {
1870   my ($self, $values) = @_;
1871   $self->throw_exception( "new_result needs a hash" )
1872     unless (ref $values eq 'HASH');
1873
1874   my %new;
1875   my $alias = $self->{attrs}{alias};
1876
1877   if (
1878     defined $self->{cond}
1879     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1880   ) {
1881     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1882     $new{-from_resultset} = [ keys %new ] if keys %new;
1883   } else {
1884     $self->throw_exception(
1885       "Can't abstract implicit construct, condition not a hash"
1886     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1887
1888     my $collapsed_cond = (
1889       $self->{cond}
1890         ? $self->_collapse_cond($self->{cond})
1891         : {}
1892     );
1893
1894     # precendence must be given to passed values over values inherited from
1895     # the cond, so the order here is important.
1896     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1897     while( my($col,$value) = each %implied ){
1898       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1899         $new{$col} = $value->{'='};
1900         next;
1901       }
1902       $new{$col} = $value if $self->_is_deterministic_value($value);
1903     }
1904   }
1905
1906   %new = (
1907     %new,
1908     %{ $self->_remove_alias($values, $alias) },
1909     -source_handle => $self->_source_handle,
1910     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1911   );
1912
1913   return $self->result_class->new(\%new);
1914 }
1915
1916 # _is_deterministic_value
1917 #
1918 # Make an effor to strip non-deterministic values from the condition,
1919 # to make sure new_result chokes less
1920
1921 sub _is_deterministic_value {
1922   my $self = shift;
1923   my $value = shift;
1924   my $ref_type = ref $value;
1925   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1926   return 1 if Scalar::Util::blessed($value);
1927   return 0;
1928 }
1929
1930 # _has_resolved_attr
1931 #
1932 # determines if the resultset defines at least one
1933 # of the attributes supplied
1934 #
1935 # used to determine if a subquery is neccessary
1936
1937 sub _has_resolved_attr {
1938   my ($self, @attr_names) = @_;
1939
1940   my $attrs = $self->_resolved_attrs;
1941
1942   my $join_check_req;
1943
1944   for my $n (@attr_names) {
1945     ++$join_check_req if $n eq '-join';
1946
1947     my $attr =  $attrs->{$n};
1948
1949     next if not defined $attr;
1950
1951     if (ref $attr eq 'HASH') {
1952       return 1 if keys %$attr;
1953     }
1954     elsif (ref $attr eq 'ARRAY') {
1955       return 1 if @$attr;
1956     }
1957     else {
1958       return 1 if $attr;
1959     }
1960   }
1961
1962   # a resolved join is expressed as a multi-level from
1963   return 1 if (
1964     $join_check_req
1965       and
1966     ref $attrs->{from} eq 'ARRAY'
1967       and
1968     @{$attrs->{from}} > 1
1969   );
1970
1971   return 0;
1972 }
1973
1974 # _collapse_cond
1975 #
1976 # Recursively collapse the condition.
1977
1978 sub _collapse_cond {
1979   my ($self, $cond, $collapsed) = @_;
1980
1981   $collapsed ||= {};
1982
1983   if (ref $cond eq 'ARRAY') {
1984     foreach my $subcond (@$cond) {
1985       next unless ref $subcond;  # -or
1986       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1987     }
1988   }
1989   elsif (ref $cond eq 'HASH') {
1990     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1991       foreach my $subcond (@{$cond->{-and}}) {
1992         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1993       }
1994     }
1995     else {
1996       foreach my $col (keys %$cond) {
1997         my $value = $cond->{$col};
1998         $collapsed->{$col} = $value;
1999       }
2000     }
2001   }
2002
2003   return $collapsed;
2004 }
2005
2006 # _remove_alias
2007 #
2008 # Remove the specified alias from the specified query hash. A copy is made so
2009 # the original query is not modified.
2010
2011 sub _remove_alias {
2012   my ($self, $query, $alias) = @_;
2013
2014   my %orig = %{ $query || {} };
2015   my %unaliased;
2016
2017   foreach my $key (keys %orig) {
2018     if ($key !~ /\./) {
2019       $unaliased{$key} = $orig{$key};
2020       next;
2021     }
2022     $unaliased{$1} = $orig{$key}
2023       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2024   }
2025
2026   return \%unaliased;
2027 }
2028
2029 =head2 as_query (EXPERIMENTAL)
2030
2031 =over 4
2032
2033 =item Arguments: none
2034
2035 =item Return Value: \[ $sql, @bind ]
2036
2037 =back
2038
2039 Returns the SQL query and bind vars associated with the invocant.
2040
2041 This is generally used as the RHS for a subquery.
2042
2043 B<NOTE>: This feature is still experimental.
2044
2045 =cut
2046
2047 sub as_query {
2048   my $self = shift;
2049
2050   my $attrs = $self->_resolved_attrs_copy;
2051
2052   # For future use:
2053   #
2054   # in list ctx:
2055   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2056   # $sql also has no wrapping parenthesis in list ctx
2057   #
2058   my $sqlbind = $self->result_source->storage
2059     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2060
2061   return $sqlbind;
2062 }
2063
2064 =head2 find_or_new
2065
2066 =over 4
2067
2068 =item Arguments: \%vals, \%attrs?
2069
2070 =item Return Value: $rowobject
2071
2072 =back
2073
2074   my $artist = $schema->resultset('Artist')->find_or_new(
2075     { artist => 'fred' }, { key => 'artists' });
2076
2077   $cd->cd_to_producer->find_or_new({ producer => $producer },
2078                                    { key => 'primary });
2079
2080 Find an existing record from this resultset, based on its primary
2081 key, or a unique constraint. If none exists, instantiate a new result
2082 object and return it. The object will not be saved into your storage
2083 until you call L<DBIx::Class::Row/insert> on it.
2084
2085 You most likely want this method when looking for existing rows using
2086 a unique constraint that is not the primary key, or looking for
2087 related rows.
2088
2089 If you want objects to be saved immediately, use L</find_or_create> instead.
2090
2091 B<Note>: C<find_or_new> is probably not what you want when creating a
2092 new row in a table that uses primary keys supplied by the
2093 database. Passing in a primary key column with a value of I<undef>
2094 will cause L</find> to attempt to search for a row with a value of
2095 I<NULL>.
2096
2097 =cut
2098
2099 sub find_or_new {
2100   my $self     = shift;
2101   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2102   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2103   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2104     return $row;
2105   }
2106   return $self->new_result($hash);
2107 }
2108
2109 =head2 create
2110
2111 =over 4
2112
2113 =item Arguments: \%vals
2114
2115 =item Return Value: a L<DBIx::Class::Row> $object
2116
2117 =back
2118
2119 Attempt to create a single new row or a row with multiple related rows
2120 in the table represented by the resultset (and related tables). This
2121 will not check for duplicate rows before inserting, use
2122 L</find_or_create> to do that.
2123
2124 To create one row for this resultset, pass a hashref of key/value
2125 pairs representing the columns of the table and the values you wish to
2126 store. If the appropriate relationships are set up, foreign key fields
2127 can also be passed an object representing the foreign row, and the
2128 value will be set to its primary key.
2129
2130 To create related objects, pass a hashref for the value if the related
2131 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2132 and use the name of the relationship as the key. (NOT the name of the field,
2133 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2134 of hashrefs containing the data for each of the rows to create in the foreign
2135 tables, again using the relationship name as the key.
2136
2137 Instead of hashrefs of plain related data (key/value pairs), you may
2138 also pass new or inserted objects. New objects (not inserted yet, see
2139 L</new>), will be inserted into their appropriate tables.
2140
2141 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2142
2143 Example of creating a new row.
2144
2145   $person_rs->create({
2146     name=>"Some Person",
2147     email=>"somebody@someplace.com"
2148   });
2149
2150 Example of creating a new row and also creating rows in a related C<has_many>
2151 or C<has_one> resultset.  Note Arrayref.
2152
2153   $artist_rs->create(
2154      { artistid => 4, name => 'Manufactured Crap', cds => [
2155         { title => 'My First CD', year => 2006 },
2156         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2157       ],
2158      },
2159   );
2160
2161 Example of creating a new row and also creating a row in a related
2162 C<belongs_to>resultset. Note Hashref.
2163
2164   $cd_rs->create({
2165     title=>"Music for Silly Walks",
2166     year=>2000,
2167     artist => {
2168       name=>"Silly Musician",
2169     }
2170   });
2171
2172 =cut
2173
2174 sub create {
2175   my ($self, $attrs) = @_;
2176   $self->throw_exception( "create needs a hashref" )
2177     unless ref $attrs eq 'HASH';
2178   return $self->new_result($attrs)->insert;
2179 }
2180
2181 =head2 find_or_create
2182
2183 =over 4
2184
2185 =item Arguments: \%vals, \%attrs?
2186
2187 =item Return Value: $rowobject
2188
2189 =back
2190
2191   $cd->cd_to_producer->find_or_create({ producer => $producer },
2192                                       { key => 'primary });
2193
2194 Tries to find a record based on its primary key or unique constraints; if none
2195 is found, creates one and returns that instead.
2196
2197   my $cd = $schema->resultset('CD')->find_or_create({
2198     cdid   => 5,
2199     artist => 'Massive Attack',
2200     title  => 'Mezzanine',
2201     year   => 2005,
2202   });
2203
2204 Also takes an optional C<key> attribute, to search by a specific key or unique
2205 constraint. For example:
2206
2207   my $cd = $schema->resultset('CD')->find_or_create(
2208     {
2209       artist => 'Massive Attack',
2210       title  => 'Mezzanine',
2211     },
2212     { key => 'cd_artist_title' }
2213   );
2214
2215 B<Note>: Because find_or_create() reads from the database and then
2216 possibly inserts based on the result, this method is subject to a race
2217 condition. Another process could create a record in the table after
2218 the find has completed and before the create has started. To avoid
2219 this problem, use find_or_create() inside a transaction.
2220
2221 B<Note>: C<find_or_create> is probably not what you want when creating
2222 a new row in a table that uses primary keys supplied by the
2223 database. Passing in a primary key column with a value of I<undef>
2224 will cause L</find> to attempt to search for a row with a value of
2225 I<NULL>.
2226
2227 See also L</find> and L</update_or_create>. For information on how to declare
2228 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2229
2230 =cut
2231
2232 sub find_or_create {
2233   my $self     = shift;
2234   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2235   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2236   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2237     return $row;
2238   }
2239   return $self->create($hash);
2240 }
2241
2242 =head2 update_or_create
2243
2244 =over 4
2245
2246 =item Arguments: \%col_values, { key => $unique_constraint }?
2247
2248 =item Return Value: $rowobject
2249
2250 =back
2251
2252   $resultset->update_or_create({ col => $val, ... });
2253
2254 First, searches for an existing row matching one of the unique constraints
2255 (including the primary key) on the source of this resultset. If a row is
2256 found, updates it with the other given column values. Otherwise, creates a new
2257 row.
2258
2259 Takes an optional C<key> attribute to search on a specific unique constraint.
2260 For example:
2261
2262   # In your application
2263   my $cd = $schema->resultset('CD')->update_or_create(
2264     {
2265       artist => 'Massive Attack',
2266       title  => 'Mezzanine',
2267       year   => 1998,
2268     },
2269     { key => 'cd_artist_title' }
2270   );
2271
2272   $cd->cd_to_producer->update_or_create({
2273     producer => $producer,
2274     name => 'harry',
2275   }, {
2276     key => 'primary,
2277   });
2278
2279
2280 If no C<key> is specified, it searches on all unique constraints defined on the
2281 source, including the primary key.
2282
2283 If the C<key> is specified as C<primary>, it searches only on the primary key.
2284
2285 See also L</find> and L</find_or_create>. For information on how to declare
2286 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2287
2288 B<Note>: C<update_or_create> is probably not what you want when
2289 looking for a row in a table that uses primary keys supplied by the
2290 database, unless you actually have a key value. Passing in a primary
2291 key column with a value of I<undef> will cause L</find> to attempt to
2292 search for a row with a value of I<NULL>.
2293
2294 =cut
2295
2296 sub update_or_create {
2297   my $self = shift;
2298   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2299   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2300
2301   my $row = $self->find($cond, $attrs);
2302   if (defined $row) {
2303     $row->update($cond);
2304     return $row;
2305   }
2306
2307   return $self->create($cond);
2308 }
2309
2310 =head2 update_or_new
2311
2312 =over 4
2313
2314 =item Arguments: \%col_values, { key => $unique_constraint }?
2315
2316 =item Return Value: $rowobject
2317
2318 =back
2319
2320   $resultset->update_or_new({ col => $val, ... });
2321
2322 First, searches for an existing row matching one of the unique constraints
2323 (including the primary key) on the source of this resultset. If a row is
2324 found, updates it with the other given column values. Otherwise, instantiate
2325 a new result object and return it. The object will not be saved into your storage
2326 until you call L<DBIx::Class::Row/insert> on it.
2327
2328 Takes an optional C<key> attribute to search on a specific unique constraint.
2329 For example:
2330
2331   # In your application
2332   my $cd = $schema->resultset('CD')->update_or_new(
2333     {
2334       artist => 'Massive Attack',
2335       title  => 'Mezzanine',
2336       year   => 1998,
2337     },
2338     { key => 'cd_artist_title' }
2339   );
2340
2341   if ($cd->in_storage) {
2342       # the cd was updated
2343   }
2344   else {
2345       # the cd is not yet in the database, let's insert it
2346       $cd->insert;
2347   }
2348
2349 See also L</find>, L</find_or_create> and L<find_or_new>.
2350
2351 =cut
2352
2353 sub update_or_new {
2354     my $self  = shift;
2355     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2356     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2357
2358     my $row = $self->find( $cond, $attrs );
2359     if ( defined $row ) {
2360         $row->update($cond);
2361         return $row;
2362     }
2363
2364     return $self->new_result($cond);
2365 }
2366
2367 =head2 get_cache
2368
2369 =over 4
2370
2371 =item Arguments: none
2372
2373 =item Return Value: \@cache_objects?
2374
2375 =back
2376
2377 Gets the contents of the cache for the resultset, if the cache is set.
2378
2379 The cache is populated either by using the L</prefetch> attribute to
2380 L</search> or by calling L</set_cache>.
2381
2382 =cut
2383
2384 sub get_cache {
2385   shift->{all_cache};
2386 }
2387
2388 =head2 set_cache
2389
2390 =over 4
2391
2392 =item Arguments: \@cache_objects
2393
2394 =item Return Value: \@cache_objects
2395
2396 =back
2397
2398 Sets the contents of the cache for the resultset. Expects an arrayref
2399 of objects of the same class as those produced by the resultset. Note that
2400 if the cache is set the resultset will return the cached objects rather
2401 than re-querying the database even if the cache attr is not set.
2402
2403 The contents of the cache can also be populated by using the
2404 L</prefetch> attribute to L</search>.
2405
2406 =cut
2407
2408 sub set_cache {
2409   my ( $self, $data ) = @_;
2410   $self->throw_exception("set_cache requires an arrayref")
2411       if defined($data) && (ref $data ne 'ARRAY');
2412   $self->{all_cache} = $data;
2413 }
2414
2415 =head2 clear_cache
2416
2417 =over 4
2418
2419 =item Arguments: none
2420
2421 =item Return Value: []
2422
2423 =back
2424
2425 Clears the cache for the resultset.
2426
2427 =cut
2428
2429 sub clear_cache {
2430   shift->set_cache(undef);
2431 }
2432
2433 =head2 related_resultset
2434
2435 =over 4
2436
2437 =item Arguments: $relationship_name
2438
2439 =item Return Value: $resultset
2440
2441 =back
2442
2443 Returns a related resultset for the supplied relationship name.
2444
2445   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2446
2447 =cut
2448
2449 sub related_resultset {
2450   my ($self, $rel) = @_;
2451
2452   $self->{related_resultsets} ||= {};
2453   return $self->{related_resultsets}{$rel} ||= do {
2454     my $rel_obj = $self->result_source->relationship_info($rel);
2455
2456     $self->throw_exception(
2457       "search_related: result source '" . $self->result_source->source_name .
2458         "' has no such relationship $rel")
2459       unless $rel_obj;
2460
2461     my ($from,$seen) = $self->_resolve_from($rel);
2462
2463     my $join_count = $seen->{$rel};
2464     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2465
2466     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2467     my %attrs = %{$self->{attrs}||{}};
2468     delete @attrs{qw(result_class alias)};
2469
2470     my $new_cache;
2471
2472     if (my $cache = $self->get_cache) {
2473       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2474         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2475                         @$cache ];
2476       }
2477     }
2478
2479     my $rel_source = $self->result_source->related_source($rel);
2480
2481     my $new = do {
2482
2483       # The reason we do this now instead of passing the alias to the
2484       # search_rs below is that if you wrap/overload resultset on the
2485       # source you need to know what alias it's -going- to have for things
2486       # to work sanely (e.g. RestrictWithObject wants to be able to add
2487       # extra query restrictions, and these may need to be $alias.)
2488
2489       my $attrs = $rel_source->resultset_attributes;
2490       local $attrs->{alias} = $alias;
2491
2492       $rel_source->resultset
2493                  ->search_rs(
2494                      undef, {
2495                        %attrs,
2496                        join => undef,
2497                        prefetch => undef,
2498                        select => undef,
2499                        as => undef,
2500                        where => $self->{cond},
2501                        seen_join => $seen,
2502                        from => $from,
2503                    });
2504     };
2505     $new->set_cache($new_cache) if $new_cache;
2506     $new;
2507   };
2508 }
2509
2510 =head2 current_source_alias
2511
2512 =over 4
2513
2514 =item Arguments: none
2515
2516 =item Return Value: $source_alias
2517
2518 =back
2519
2520 Returns the current table alias for the result source this resultset is built
2521 on, that will be used in the SQL query. Usually it is C<me>.
2522
2523 Currently the source alias that refers to the result set returned by a
2524 L</search>/L</find> family method depends on how you got to the resultset: it's
2525 C<me> by default, but eg. L</search_related> aliases it to the related result
2526 source name (and keeps C<me> referring to the original result set). The long
2527 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2528 (and make this method unnecessary).
2529
2530 Thus it's currently necessary to use this method in predefined queries (see
2531 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2532 source alias of the current result set:
2533
2534   # in a result set class
2535   sub modified_by {
2536     my ($self, $user) = @_;
2537
2538     my $me = $self->current_source_alias;
2539
2540     return $self->search(
2541       "$me.modified" => $user->id,
2542     );
2543   }
2544
2545 =cut
2546
2547 sub current_source_alias {
2548   my ($self) = @_;
2549
2550   return ($self->{attrs} || {})->{alias} || 'me';
2551 }
2552
2553 # This code is called by search_related, and makes sure there
2554 # is clear separation between the joins before, during, and
2555 # after the relationship. This information is needed later
2556 # in order to properly resolve prefetch aliases (any alias
2557 # with a relation_chain_depth less than the depth of the
2558 # current prefetch is not considered)
2559 sub _resolve_from {
2560   my ($self, $extra_join) = @_;
2561   my $source = $self->result_source;
2562   my $attrs = $self->{attrs};
2563
2564   my $from = [ @{
2565       $attrs->{from}
2566         ||
2567       [{
2568         -source_handle => $source->handle,
2569         -alias => $attrs->{alias},
2570         $attrs->{alias} => $source->from,
2571       }]
2572   }];
2573
2574   my $seen = { %{$attrs->{seen_join} || {} } };
2575
2576   # we need to take the prefetch the attrs into account before we
2577   # ->_resolve_join as otherwise they get lost - captainL
2578   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2579
2580   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2581
2582   ++$seen->{-relation_chain_depth};
2583
2584   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2585
2586   ++$seen->{-relation_chain_depth};
2587
2588   return ($from,$seen);
2589 }
2590
2591 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2592 sub _resolved_attrs_copy {
2593   my $self = shift;
2594   return { %{$self->_resolved_attrs (@_)} };
2595 }
2596
2597 sub _resolved_attrs {
2598   my $self = shift;
2599   return $self->{_attrs} if $self->{_attrs};
2600
2601   my $attrs  = { %{ $self->{attrs} || {} } };
2602   my $source = $self->result_source;
2603   my $alias  = $attrs->{alias};
2604
2605   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2606   my @colbits;
2607
2608   # build columns (as long as select isn't set) into a set of as/select hashes
2609   unless ( $attrs->{select} ) {
2610       @colbits = map {
2611           ( ref($_) eq 'HASH' )
2612               ? $_
2613               : {
2614                   (
2615                     /^\Q${alias}.\E(.+)$/
2616                       ? "$1"
2617                       : "$_"
2618                   )
2619                 =>
2620                   (
2621                     /\./
2622                       ? "$_"
2623                       : "${alias}.$_"
2624                   )
2625             }
2626       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2627   }
2628   # add the additional columns on
2629   foreach ( 'include_columns', '+columns' ) {
2630       push @colbits, map {
2631           ( ref($_) eq 'HASH' )
2632             ? $_
2633             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2634       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2635   }
2636
2637   # start with initial select items
2638   if ( $attrs->{select} ) {
2639     $attrs->{select} =
2640         ( ref $attrs->{select} eq 'ARRAY' )
2641       ? [ @{ $attrs->{select} } ]
2642       : [ $attrs->{select} ];
2643     $attrs->{as} = (
2644       $attrs->{as}
2645       ? (
2646         ref $attrs->{as} eq 'ARRAY'
2647         ? [ @{ $attrs->{as} } ]
2648         : [ $attrs->{as} ]
2649         )
2650       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2651     );
2652   }
2653   else {
2654
2655     # otherwise we intialise select & as to empty
2656     $attrs->{select} = [];
2657     $attrs->{as}     = [];
2658   }
2659
2660   # now add colbits to select/as
2661   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2662   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2663
2664   my $adds;
2665   if ( $adds = delete $attrs->{'+select'} ) {
2666     $adds = [$adds] unless ref $adds eq 'ARRAY';
2667     push(
2668       @{ $attrs->{select} },
2669       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2670     );
2671   }
2672   if ( $adds = delete $attrs->{'+as'} ) {
2673     $adds = [$adds] unless ref $adds eq 'ARRAY';
2674     push( @{ $attrs->{as} }, @$adds );
2675   }
2676
2677   $attrs->{from} ||= [ {
2678     -source_handle => $source->handle,
2679     -alias => $self->{attrs}{alias},
2680     $self->{attrs}{alias} => $source->from,
2681   } ];
2682
2683   if ( $attrs->{join} || $attrs->{prefetch} ) {
2684
2685     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2686       if ref $attrs->{from} ne 'ARRAY';
2687
2688     my $join = delete $attrs->{join} || {};
2689
2690     if ( defined $attrs->{prefetch} ) {
2691       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2692     }
2693
2694     $attrs->{from} =    # have to copy here to avoid corrupting the original
2695       [
2696         @{ $attrs->{from} },
2697         $source->_resolve_join(
2698           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2699         )
2700       ];
2701   }
2702
2703   if ( $attrs->{order_by} ) {
2704     $attrs->{order_by} = (
2705       ref( $attrs->{order_by} ) eq 'ARRAY'
2706       ? [ @{ $attrs->{order_by} } ]
2707       : [ $attrs->{order_by} ]
2708     );
2709   }
2710   else {
2711     $attrs->{order_by} = [];
2712   }
2713
2714   # If the order_by is otherwise empty - we will use this for TOP limit
2715   # emulation and the like.
2716   # Although this is needed only if the order_by is not defined, it is
2717   # actually cheaper to just populate this rather than properly examining
2718   # order_by (stuf like [ {} ] and the like)
2719   my $prefix = $alias . ($source->schema->storage->sql_maker->{name_sep} || '.');
2720   $attrs->{_virtual_order_by} = [
2721     map { $prefix . $_ } ($source->primary_columns)
2722   ];
2723
2724   $attrs->{collapse} ||= {};
2725   if ( my $prefetch = delete $attrs->{prefetch} ) {
2726     $prefetch = $self->_merge_attr( {}, $prefetch );
2727
2728     my $prefetch_ordering = [];
2729
2730     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2731
2732     my @prefetch =
2733       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2734
2735     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2736     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2737
2738     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2739     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2740   }
2741
2742
2743   if (delete $attrs->{distinct}) {
2744     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2745   }
2746
2747   # if both page and offset are specified, produce a combined offset
2748   # even though it doesn't make much sense, this is what pre 081xx has
2749   # been doing
2750   if (my $page = delete $attrs->{page}) {
2751     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2752       ($attrs->{offset} || 0);
2753   }
2754
2755   return $self->{_attrs} = $attrs;
2756 }
2757
2758 sub _joinpath_aliases {
2759   my ($self, $fromspec, $seen) = @_;
2760
2761   my $paths = {};
2762   return $paths unless ref $fromspec eq 'ARRAY';
2763
2764   for my $j (@$fromspec) {
2765
2766     next if ref $j ne 'ARRAY';
2767     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2768
2769     my $p = $paths;
2770     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2771     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2772   }
2773
2774   return $paths;
2775 }
2776
2777 sub _rollout_attr {
2778   my ($self, $attr) = @_;
2779
2780   if (ref $attr eq 'HASH') {
2781     return $self->_rollout_hash($attr);
2782   } elsif (ref $attr eq 'ARRAY') {
2783     return $self->_rollout_array($attr);
2784   } else {
2785     return [$attr];
2786   }
2787 }
2788
2789 sub _rollout_array {
2790   my ($self, $attr) = @_;
2791
2792   my @rolled_array;
2793   foreach my $element (@{$attr}) {
2794     if (ref $element eq 'HASH') {
2795       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2796     } elsif (ref $element eq 'ARRAY') {
2797       #  XXX - should probably recurse here
2798       push( @rolled_array, @{$self->_rollout_array($element)} );
2799     } else {
2800       push( @rolled_array, $element );
2801     }
2802   }
2803   return \@rolled_array;
2804 }
2805
2806 sub _rollout_hash {
2807   my ($self, $attr) = @_;
2808
2809   my @rolled_array;
2810   foreach my $key (keys %{$attr}) {
2811     push( @rolled_array, { $key => $attr->{$key} } );
2812   }
2813   return \@rolled_array;
2814 }
2815
2816 sub _calculate_score {
2817   my ($self, $a, $b) = @_;
2818
2819   if (ref $b eq 'HASH') {
2820     my ($b_key) = keys %{$b};
2821     if (ref $a eq 'HASH') {
2822       my ($a_key) = keys %{$a};
2823       if ($a_key eq $b_key) {
2824         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2825       } else {
2826         return 0;
2827       }
2828     } else {
2829       return ($a eq $b_key) ? 1 : 0;
2830     }
2831   } else {
2832     if (ref $a eq 'HASH') {
2833       my ($a_key) = keys %{$a};
2834       return ($b eq $a_key) ? 1 : 0;
2835     } else {
2836       return ($b eq $a) ? 1 : 0;
2837     }
2838   }
2839 }
2840
2841 sub _merge_attr {
2842   my ($self, $orig, $import) = @_;
2843
2844   return $import unless defined($orig);
2845   return $orig unless defined($import);
2846
2847   $orig = $self->_rollout_attr($orig);
2848   $import = $self->_rollout_attr($import);
2849
2850   my $seen_keys;
2851   foreach my $import_element ( @{$import} ) {
2852     # find best candidate from $orig to merge $b_element into
2853     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2854     foreach my $orig_element ( @{$orig} ) {
2855       my $score = $self->_calculate_score( $orig_element, $import_element );
2856       if ($score > $best_candidate->{score}) {
2857         $best_candidate->{position} = $position;
2858         $best_candidate->{score} = $score;
2859       }
2860       $position++;
2861     }
2862     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2863
2864     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2865       push( @{$orig}, $import_element );
2866     } else {
2867       my $orig_best = $orig->[$best_candidate->{position}];
2868       # merge orig_best and b_element together and replace original with merged
2869       if (ref $orig_best ne 'HASH') {
2870         $orig->[$best_candidate->{position}] = $import_element;
2871       } elsif (ref $import_element eq 'HASH') {
2872         my ($key) = keys %{$orig_best};
2873         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2874       }
2875     }
2876     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2877   }
2878
2879   return $orig;
2880 }
2881
2882 sub result_source {
2883     my $self = shift;
2884
2885     if (@_) {
2886         $self->_source_handle($_[0]->handle);
2887     } else {
2888         $self->_source_handle->resolve;
2889     }
2890 }
2891
2892 =head2 throw_exception
2893
2894 See L<DBIx::Class::Schema/throw_exception> for details.
2895
2896 =cut
2897
2898 sub throw_exception {
2899   my $self=shift;
2900   if (ref $self && $self->_source_handle->schema) {
2901     $self->_source_handle->schema->throw_exception(@_)
2902   } else {
2903     croak(@_);
2904   }
2905
2906 }
2907
2908 # XXX: FIXME: Attributes docs need clearing up
2909
2910 =head1 ATTRIBUTES
2911
2912 Attributes are used to refine a ResultSet in various ways when
2913 searching for data. They can be passed to any method which takes an
2914 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2915 L</count>.
2916
2917 These are in no particular order:
2918
2919 =head2 order_by
2920
2921 =over 4
2922
2923 =item Value: ( $order_by | \@order_by | \%order_by )
2924
2925 =back
2926
2927 Which column(s) to order the results by. If a single column name, or
2928 an arrayref of names is supplied, the argument is passed through
2929 directly to SQL. The hashref syntax allows for connection-agnostic
2930 specification of ordering direction:
2931
2932  For descending order:
2933
2934   order_by => { -desc => [qw/col1 col2 col3/] }
2935
2936  For explicit ascending order:
2937
2938   order_by => { -asc => 'col' }
2939
2940 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2941 supported, although you are strongly encouraged to use the hashref
2942 syntax as outlined above.
2943
2944 =head2 columns
2945
2946 =over 4
2947
2948 =item Value: \@columns
2949
2950 =back
2951
2952 Shortcut to request a particular set of columns to be retrieved. Each
2953 column spec may be a string (a table column name), or a hash (in which
2954 case the key is the C<as> value, and the value is used as the C<select>
2955 expression). Adds C<me.> onto the start of any column without a C<.> in
2956 it and sets C<select> from that, then auto-populates C<as> from
2957 C<select> as normal. (You may also use the C<cols> attribute, as in
2958 earlier versions of DBIC.)
2959
2960 =head2 +columns
2961
2962 =over 4
2963
2964 =item Value: \@columns
2965
2966 =back
2967
2968 Indicates additional columns to be selected from storage. Works the same
2969 as L</columns> but adds columns to the selection. (You may also use the
2970 C<include_columns> attribute, as in earlier versions of DBIC). For
2971 example:-
2972
2973   $schema->resultset('CD')->search(undef, {
2974     '+columns' => ['artist.name'],
2975     join => ['artist']
2976   });
2977
2978 would return all CDs and include a 'name' column to the information
2979 passed to object inflation. Note that the 'artist' is the name of the
2980 column (or relationship) accessor, and 'name' is the name of the column
2981 accessor in the related table.
2982
2983 =head2 include_columns
2984
2985 =over 4
2986
2987 =item Value: \@columns
2988
2989 =back
2990
2991 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2992
2993 =head2 select
2994
2995 =over 4
2996
2997 =item Value: \@select_columns
2998
2999 =back
3000
3001 Indicates which columns should be selected from the storage. You can use
3002 column names, or in the case of RDBMS back ends, function or stored procedure
3003 names:
3004
3005   $rs = $schema->resultset('Employee')->search(undef, {
3006     select => [
3007       'name',
3008       { count => 'employeeid' },
3009       { sum => 'salary' }
3010     ]
3011   });
3012
3013 When you use function/stored procedure names and do not supply an C<as>
3014 attribute, the column names returned are storage-dependent. E.g. MySQL would
3015 return a column named C<count(employeeid)> in the above example.
3016
3017 =head2 +select
3018
3019 =over 4
3020
3021 Indicates additional columns to be selected from storage.  Works the same as
3022 L</select> but adds columns to the selection.
3023
3024 =back
3025
3026 =head2 +as
3027
3028 =over 4
3029
3030 Indicates additional column names for those added via L</+select>. See L</as>.
3031
3032 =back
3033
3034 =head2 as
3035
3036 =over 4
3037
3038 =item Value: \@inflation_names
3039
3040 =back
3041
3042 Indicates column names for object inflation. That is, C<as>
3043 indicates the name that the column can be accessed as via the
3044 C<get_column> method (or via the object accessor, B<if one already
3045 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3046
3047 The C<as> attribute is used in conjunction with C<select>,
3048 usually when C<select> contains one or more function or stored
3049 procedure names:
3050
3051   $rs = $schema->resultset('Employee')->search(undef, {
3052     select => [
3053       'name',
3054       { count => 'employeeid' }
3055     ],
3056     as => ['name', 'employee_count'],
3057   });
3058
3059   my $employee = $rs->first(); # get the first Employee
3060
3061 If the object against which the search is performed already has an accessor
3062 matching a column name specified in C<as>, the value can be retrieved using
3063 the accessor as normal:
3064
3065   my $name = $employee->name();
3066
3067 If on the other hand an accessor does not exist in the object, you need to
3068 use C<get_column> instead:
3069
3070   my $employee_count = $employee->get_column('employee_count');
3071
3072 You can create your own accessors if required - see
3073 L<DBIx::Class::Manual::Cookbook> for details.
3074
3075 Please note: This will NOT insert an C<AS employee_count> into the SQL
3076 statement produced, it is used for internal access only. Thus
3077 attempting to use the accessor in an C<order_by> clause or similar
3078 will fail miserably.
3079
3080 To get around this limitation, you can supply literal SQL to your
3081 C<select> attibute that contains the C<AS alias> text, eg:
3082
3083   select => [\'myfield AS alias']
3084
3085 =head2 join
3086
3087 =over 4
3088
3089 =item Value: ($rel_name | \@rel_names | \%rel_names)
3090
3091 =back
3092
3093 Contains a list of relationships that should be joined for this query.  For
3094 example:
3095
3096   # Get CDs by Nine Inch Nails
3097   my $rs = $schema->resultset('CD')->search(
3098     { 'artist.name' => 'Nine Inch Nails' },
3099     { join => 'artist' }
3100   );
3101
3102 Can also contain a hash reference to refer to the other relation's relations.
3103 For example:
3104
3105   package MyApp::Schema::Track;
3106   use base qw/DBIx::Class/;
3107   __PACKAGE__->table('track');
3108   __PACKAGE__->add_columns(qw/trackid cd position title/);
3109   __PACKAGE__->set_primary_key('trackid');
3110   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3111   1;
3112
3113   # In your application
3114   my $rs = $schema->resultset('Artist')->search(
3115     { 'track.title' => 'Teardrop' },
3116     {
3117       join     => { cd => 'track' },
3118       order_by => 'artist.name',
3119     }
3120   );
3121
3122 You need to use the relationship (not the table) name in  conditions,
3123 because they are aliased as such. The current table is aliased as "me", so
3124 you need to use me.column_name in order to avoid ambiguity. For example:
3125
3126   # Get CDs from 1984 with a 'Foo' track
3127   my $rs = $schema->resultset('CD')->search(
3128     {
3129       'me.year' => 1984,
3130       'tracks.name' => 'Foo'
3131     },
3132     { join => 'tracks' }
3133   );
3134
3135 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3136 similarly for a third time). For e.g.
3137
3138   my $rs = $schema->resultset('Artist')->search({
3139     'cds.title'   => 'Down to Earth',
3140     'cds_2.title' => 'Popular',
3141   }, {
3142     join => [ qw/cds cds/ ],
3143   });
3144
3145 will return a set of all artists that have both a cd with title 'Down
3146 to Earth' and a cd with title 'Popular'.
3147
3148 If you want to fetch related objects from other tables as well, see C<prefetch>
3149 below.
3150
3151 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3152
3153 =head2 prefetch
3154
3155 =over 4
3156
3157 =item Value: ($rel_name | \@rel_names | \%rel_names)
3158
3159 =back
3160
3161 Contains one or more relationships that should be fetched along with
3162 the main query (when they are accessed afterwards the data will
3163 already be available, without extra queries to the database).  This is
3164 useful for when you know you will need the related objects, because it
3165 saves at least one query:
3166
3167   my $rs = $schema->resultset('Tag')->search(
3168     undef,
3169     {
3170       prefetch => {
3171         cd => 'artist'
3172       }
3173     }
3174   );
3175
3176 The initial search results in SQL like the following:
3177
3178   SELECT tag.*, cd.*, artist.* FROM tag
3179   JOIN cd ON tag.cd = cd.cdid
3180   JOIN artist ON cd.artist = artist.artistid
3181
3182 L<DBIx::Class> has no need to go back to the database when we access the
3183 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3184 case.
3185
3186 Simple prefetches will be joined automatically, so there is no need
3187 for a C<join> attribute in the above search.
3188
3189 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3190 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3191 with an accessor type of 'single' or 'filter'). A more complex example that
3192 prefetches an artists cds, the tracks on those cds, and the tags associted
3193 with that artist is given below (assuming many-to-many from artists to tags):
3194
3195  my $rs = $schema->resultset('Artist')->search(
3196    undef,
3197    {
3198      prefetch => [
3199        { cds => 'tracks' },
3200        { artist_tags => 'tags' }
3201      ]
3202    }
3203  );
3204
3205
3206 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3207 attributes will be ignored.
3208
3209 =head2 page
3210
3211 =over 4
3212
3213 =item Value: $page
3214
3215 =back
3216
3217 Makes the resultset paged and specifies the page to retrieve. Effectively
3218 identical to creating a non-pages resultset and then calling ->page($page)
3219 on it.
3220
3221 If L<rows> attribute is not specified it defualts to 10 rows per page.
3222
3223 When you have a paged resultset, L</count> will only return the number
3224 of rows in the page. To get the total, use the L</pager> and call
3225 C<total_entries> on it.
3226
3227 =head2 rows
3228
3229 =over 4
3230
3231 =item Value: $rows
3232
3233 =back
3234
3235 Specifes the maximum number of rows for direct retrieval or the number of
3236 rows per page if the page attribute or method is used.
3237
3238 =head2 offset
3239
3240 =over 4
3241
3242 =item Value: $offset
3243
3244 =back
3245
3246 Specifies the (zero-based) row number for the  first row to be returned, or the
3247 of the first row of the first page if paging is used.
3248
3249 =head2 group_by
3250
3251 =over 4
3252
3253 =item Value: \@columns
3254
3255 =back
3256
3257 A arrayref of columns to group by. Can include columns of joined tables.
3258
3259   group_by => [qw/ column1 column2 ... /]
3260
3261 =head2 having
3262
3263 =over 4
3264
3265 =item Value: $condition
3266
3267 =back
3268
3269 HAVING is a select statement attribute that is applied between GROUP BY and
3270 ORDER BY. It is applied to the after the grouping calculations have been
3271 done.
3272
3273   having => { 'count(employee)' => { '>=', 100 } }
3274
3275 =head2 distinct
3276
3277 =over 4
3278
3279 =item Value: (0 | 1)
3280
3281 =back
3282
3283 Set to 1 to group by all columns.
3284
3285 =head2 where
3286
3287 =over 4
3288
3289 Adds to the WHERE clause.
3290
3291   # only return rows WHERE deleted IS NULL for all searches
3292   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3293
3294 Can be overridden by passing C<{ where => undef }> as an attribute
3295 to a resulset.
3296
3297 =back
3298
3299 =head2 cache
3300
3301 Set to 1 to cache search results. This prevents extra SQL queries if you
3302 revisit rows in your ResultSet:
3303
3304   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3305
3306   while( my $artist = $resultset->next ) {
3307     ... do stuff ...
3308   }
3309
3310   $rs->first; # without cache, this would issue a query
3311
3312 By default, searches are not cached.
3313
3314 For more examples of using these attributes, see
3315 L<DBIx::Class::Manual::Cookbook>.
3316
3317 =head2 from
3318
3319 =over 4
3320
3321 =item Value: \@from_clause
3322
3323 =back
3324
3325 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3326 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3327 clauses.
3328
3329 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3330
3331 C<join> will usually do what you need and it is strongly recommended that you
3332 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3333 And we really do mean "cannot", not just tried and failed. Attempting to use
3334 this because you're having problems with C<join> is like trying to use x86
3335 ASM because you've got a syntax error in your C. Trust us on this.
3336
3337 Now, if you're still really, really sure you need to use this (and if you're
3338 not 100% sure, ask the mailing list first), here's an explanation of how this
3339 works.
3340
3341 The syntax is as follows -
3342
3343   [
3344     { <alias1> => <table1> },
3345     [
3346       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3347       [], # nested JOIN (optional)
3348       { <table1.column1> => <table2.column2>, ... (more conditions) },
3349     ],
3350     # More of the above [ ] may follow for additional joins
3351   ]
3352
3353   <table1> <alias1>
3354   JOIN
3355     <table2> <alias2>
3356     [JOIN ...]
3357   ON <table1.column1> = <table2.column2>
3358   <more joins may follow>
3359
3360 An easy way to follow the examples below is to remember the following:
3361
3362     Anything inside "[]" is a JOIN
3363     Anything inside "{}" is a condition for the enclosing JOIN
3364
3365 The following examples utilize a "person" table in a family tree application.
3366 In order to express parent->child relationships, this table is self-joined:
3367
3368     # Person->belongs_to('father' => 'Person');
3369     # Person->belongs_to('mother' => 'Person');
3370
3371 C<from> can be used to nest joins. Here we return all children with a father,
3372 then search against all mothers of those children:
3373
3374   $rs = $schema->resultset('Person')->search(
3375       undef,
3376       {
3377           alias => 'mother', # alias columns in accordance with "from"
3378           from => [
3379               { mother => 'person' },
3380               [
3381                   [
3382                       { child => 'person' },
3383                       [
3384                           { father => 'person' },
3385                           { 'father.person_id' => 'child.father_id' }
3386                       ]
3387                   ],
3388                   { 'mother.person_id' => 'child.mother_id' }
3389               ],
3390           ]
3391       },
3392   );
3393
3394   # Equivalent SQL:
3395   # SELECT mother.* FROM person mother
3396   # JOIN (
3397   #   person child
3398   #   JOIN person father
3399   #   ON ( father.person_id = child.father_id )
3400   # )
3401   # ON ( mother.person_id = child.mother_id )
3402
3403 The type of any join can be controlled manually. To search against only people
3404 with a father in the person table, we could explicitly use C<INNER JOIN>:
3405
3406     $rs = $schema->resultset('Person')->search(
3407         undef,
3408         {
3409             alias => 'child', # alias columns in accordance with "from"
3410             from => [
3411                 { child => 'person' },
3412                 [
3413                     { father => 'person', -join_type => 'inner' },
3414                     { 'father.id' => 'child.father_id' }
3415                 ],
3416             ]
3417         },
3418     );
3419
3420     # Equivalent SQL:
3421     # SELECT child.* FROM person child
3422     # INNER JOIN person father ON child.father_id = father.id
3423
3424 You can select from a subquery by passing a resultset to from as follows.
3425
3426     $schema->resultset('Artist')->search(
3427         undef,
3428         {   alias => 'artist2',
3429             from  => [ { artist2 => $artist_rs->as_query } ],
3430         } );
3431
3432     # and you'll get sql like this..
3433     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3434     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3435
3436 If you need to express really complex joins, you
3437 can supply literal SQL to C<from> via a scalar reference. In this case
3438 the contents of the scalar will replace the table name associated with the
3439 resultsource.
3440
3441 WARNING: This technique might very well not work as expected on chained
3442 searches - you have been warned.
3443
3444     # Assuming the Event resultsource is defined as:
3445
3446         MySchema::Event->add_columns (
3447             sequence => {
3448                 data_type => 'INT',
3449                 is_auto_increment => 1,
3450             },
3451             location => {
3452                 data_type => 'INT',
3453             },
3454             type => {
3455                 data_type => 'INT',
3456             },
3457         );
3458         MySchema::Event->set_primary_key ('sequence');
3459
3460     # This will get back the latest event for every location. The column
3461     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3462     # combo to limit the resultset
3463
3464     $rs = $schema->resultset('Event');
3465     $table = $rs->result_source->name;
3466     $latest = $rs->search (
3467         undef,
3468         { from => \ "
3469             (SELECT e1.* FROM $table e1
3470                 JOIN $table e2
3471                     ON e1.location = e2.location
3472                     AND e1.sequence < e2.sequence
3473                 WHERE e2.sequence is NULL
3474             ) me",
3475         },
3476     );
3477
3478     # Equivalent SQL (with the DBIC chunks added):
3479
3480     SELECT me.sequence, me.location, me.type FROM
3481        (SELECT e1.* FROM events e1
3482            JOIN events e2
3483                ON e1.location = e2.location
3484                AND e1.sequence < e2.sequence
3485            WHERE e2.sequence is NULL
3486        ) me;
3487
3488 =head2 for
3489
3490 =over 4
3491
3492 =item Value: ( 'update' | 'shared' )
3493
3494 =back
3495
3496 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3497 ... FOR SHARED.
3498
3499 =cut
3500
3501 1;