lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util qw(
  10   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  11 );
  12 use Try::Tiny;
  13 use Data::Compare (); # no imports!!! guard against insane architecture
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _related_results_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either on of the two undef or both undef
 660   if ( ( (defined $left) xor (defined $right) ) or ! defined $left ) {
 661     return defined $left ? $left : $right;
 662   }
 663
 664   my $cond = $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 665
 666   for my $c (grep { ref $cond->{$_} eq 'ARRAY' and ($cond->{$_}[0]||'') eq '-and' } keys %$cond) {
 667
 668     my @vals = sort @{$cond->{$c}}[ 1..$#{$cond->{$c}} ];
 669     my @fin = shift @vals;
 670
 671     for my $v (@vals) {
 672       push @fin, $v unless Data::Compare::Compare( $fin[-1], $v );
 673     }
 674
 675     $cond->{$c} = (@fin == 1) ? $fin[0] : [-and => @fin ];
 676   }
 677
 678   $cond;
 679 }
 680
 681 =head2 search_literal
 682
 683 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 684 should only be used in that context. C<search_literal> is a convenience
 685 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 686 want to ensure columns are bound correctly, use L</search>.
 687
 688 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 689 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 690 require C<search_literal>.
 691
 692 =over 4
 693
 694 =item Arguments: $sql_fragment, @standalone_bind_values
 695
 696 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 697
 698 =back
 699
 700   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 701   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 702
 703 Pass a literal chunk of SQL to be added to the conditional part of the
 704 resultset query.
 705
 706 Example of how to use C<search> instead of C<search_literal>
 707
 708   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 709   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 710
 711 =cut
 712
 713 sub search_literal {
 714   my ($self, $sql, @bind) = @_;
 715   my $attr;
 716   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 717     $attr = pop @bind;
 718   }
 719   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 720 }
 721
 722 =head2 find
 723
 724 =over 4
 725
 726 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 727
 728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 729
 730 =back
 731
 732 Finds and returns a single row based on supplied criteria. Takes either a
 733 hashref with the same format as L</create> (including inference of foreign
 734 keys from related objects), or a list of primary key values in the same
 735 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 736 declaration on the L</result_source>.
 737
 738 In either case an attempt is made to combine conditions already existing on
 739 the resultset with the condition passed to this method.
 740
 741 To aid with preparing the correct query for the storage you may supply the
 742 C<key> attribute, which is the name of a
 743 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 744 unique constraint corresponding to the
 745 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 746 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 747 to construct a query that satisfies the named unique constraint fully (
 748 non-NULL values for each column member of the constraint) an exception is
 749 thrown.
 750
 751 If no C<key> is specified, the search is carried over all unique constraints
 752 which are fully defined by the available condition.
 753
 754 If no such constraint is found, C<find> currently defaults to a simple
 755 C<< search->(\%column_values) >> which may or may not do what you expect.
 756 Note that this fallback behavior may be deprecated in further versions. If
 757 you need to search with arbitrary conditions - use L</search>. If the query
 758 resulting from this fallback produces more than one row, a warning to the
 759 effect is issued, though only the first row is constructed and returned as
 760 C<$result_object>.
 761
 762 In addition to C<key>, L</find> recognizes and applies standard
 763 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 764
 765 Note that if you have extra concerns about the correctness of the resulting
 766 query you need to specify the C<key> attribute and supply the entire condition
 767 as an argument to find (since it is not always possible to perform the
 768 combination of the resultset condition with the supplied one, especially if
 769 the resultset condition contains literal sql).
 770
 771 For example, to find a row by its primary key:
 772
 773   my $cd = $schema->resultset('CD')->find(5);
 774
 775 You can also find a row by a specific unique constraint:
 776
 777   my $cd = $schema->resultset('CD')->find(
 778     {
 779       artist => 'Massive Attack',
 780       title  => 'Mezzanine',
 781     },
 782     { key => 'cd_artist_title' }
 783   );
 784
 785 See also L</find_or_create> and L</update_or_create>.
 786
 787 =cut
 788
 789 sub find {
 790   my $self = shift;
 791   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 792
 793   my $rsrc = $self->result_source;
 794
 795   my $constraint_name;
 796   if (exists $attrs->{key}) {
 797     $constraint_name = defined $attrs->{key}
 798       ? $attrs->{key}
 799       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 800     ;
 801   }
 802
 803   # Parse out the condition from input
 804   my $call_cond;
 805
 806   if (ref $_[0] eq 'HASH') {
 807     $call_cond = { %{$_[0]} };
 808   }
 809   else {
 810     # if only values are supplied we need to default to 'primary'
 811     $constraint_name = 'primary' unless defined $constraint_name;
 812
 813     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 814
 815     $self->throw_exception(
 816       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 817     ) unless @c_cols;
 818
 819     $self->throw_exception (
 820       'find() expects either a column/value hashref, or a list of values '
 821     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 822     ) unless @c_cols == @_;
 823
 824     $call_cond = {};
 825     @{$call_cond}{@c_cols} = @_;
 826   }
 827
 828   my %related;
 829   for my $key (keys %$call_cond) {
 830     if (
 831       my $keyref = ref($call_cond->{$key})
 832         and
 833       my $relinfo = $rsrc->relationship_info($key)
 834     ) {
 835       my $val = delete $call_cond->{$key};
 836
 837       next if $keyref eq 'ARRAY'; # has_many for multi_create
 838
 839       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 840         $relinfo->{cond}, $val, $key, $key
 841       );
 842
 843       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 844          if $crosstable or ref($rel_cond) ne 'HASH';
 845
 846       # supplement
 847       @related{keys %$rel_cond} = values %$rel_cond;
 848     }
 849   }
 850
 851   # relationship conditions take precedence (?)
 852   @{$call_cond}{keys %related} = values %related;
 853
 854   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 855   my $final_cond;
 856   if (defined $constraint_name) {
 857     $final_cond = $self->_qualify_cond_columns (
 858
 859       $self->_build_unique_cond (
 860         $constraint_name,
 861         $call_cond,
 862       ),
 863
 864       $alias,
 865     );
 866   }
 867   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 868     # This means that we got here after a merger of relationship conditions
 869     # in ::Relationship::Base::search_related (the row method), and furthermore
 870     # the relationship is of the 'single' type. This means that the condition
 871     # provided by the relationship (already attached to $self) is sufficient,
 872     # as there can be only one row in the database that would satisfy the
 873     # relationship
 874   }
 875   else {
 876     # no key was specified - fall down to heuristics mode:
 877     # run through all unique queries registered on the resultset, and
 878     # 'OR' all qualifying queries together
 879     my (@unique_queries, %seen_column_combinations);
 880     for my $c_name ($rsrc->unique_constraint_names) {
 881       next if $seen_column_combinations{
 882         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 883       }++;
 884
 885       push @unique_queries, try {
 886         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 887       } || ();
 888     }
 889
 890     $final_cond = @unique_queries
 891       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 892       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 893     ;
 894   }
 895
 896   # Run the query, passing the result_class since it should propagate for find
 897   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 898   if ($rs->_resolved_attrs->{collapse}) {
 899     my $row = $rs->next;
 900     carp "Query returned more than one row" if $rs->next;
 901     return $row;
 902   }
 903   else {
 904     return $rs->single;
 905   }
 906 }
 907
 908 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 909 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 910 #
 911 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 912 # condition. It is provided for overrides until a saner way forward is devised
 913 #
 914 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 915 # the road. Please adjust your tests accordingly to catch this situation early
 916 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 917 #
 918 # The method will not be removed without an adequately complete replacement
 919 # for strict-mode enforcement
 920 sub _non_unique_find_fallback {
 921   my ($self, $cond, $attrs) = @_;
 922
 923   return $self->_qualify_cond_columns(
 924     $cond,
 925     exists $attrs->{alias}
 926       ? $attrs->{alias}
 927       : $self->{attrs}{alias}
 928   );
 929 }
 930
 931
 932 sub _qualify_cond_columns {
 933   my ($self, $cond, $alias) = @_;
 934
 935   my %aliased = %$cond;
 936   for (keys %aliased) {
 937     $aliased{"$alias.$_"} = delete $aliased{$_}
 938       if $_ !~ /\./;
 939   }
 940
 941   return \%aliased;
 942 }
 943
 944 sub _build_unique_cond {
 945   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 946
 947   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 948
 949   # combination may fail if $self->{cond} is non-trivial
 950   my ($final_cond) = try {
 951     $self->_merge_with_rscond ($extra_cond)
 952   } catch {
 953     +{ %$extra_cond }
 954   };
 955
 956   # trim out everything not in $columns
 957   $final_cond = { map {
 958     exists $final_cond->{$_}
 959       ? ( $_ => $final_cond->{$_} )
 960       : ()
 961   } @c_cols };
 962
 963   if (my @missing = grep
 964     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 965     (@c_cols)
 966   ) {
 967     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 968       $constraint_name,
 969       join (', ', map { "'$_'" } @missing),
 970     ) );
 971   }
 972
 973   if (
 974     !$croak_on_null
 975       and
 976     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 977       and
 978     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 979   ) {
 980     carp_unique ( sprintf (
 981       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 982     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 983     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 984       $constraint_name,
 985       join (', ', map { "'$_'" } @undefs),
 986     ));
 987   }
 988
 989   return $final_cond;
 990 }
 991
 992 =head2 search_related
 993
 994 =over 4
 995
 996 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 997
 998 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 999
1000 =back
1001
1002   $new_rs = $cd_rs->search_related('artist', {
1003     name => 'Emo-R-Us',
1004   });
1005
1006 Searches the specified relationship, optionally specifying a condition and
1007 attributes for matching records. See L</ATTRIBUTES> for more information.
1008
1009 In list context, C<< ->all() >> is called implicitly on the resultset, thus
1010 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
1011
1012 See also L</search_related_rs>.
1013
1014 =cut
1015
1016 sub search_related {
1017   return shift->related_resultset(shift)->search(@_);
1018 }
1019
1020 =head2 search_related_rs
1021
1022 This method works exactly the same as search_related, except that
1023 it guarantees a resultset, even in list context.
1024
1025 =cut
1026
1027 sub search_related_rs {
1028   return shift->related_resultset(shift)->search_rs(@_);
1029 }
1030
1031 =head2 cursor
1032
1033 =over 4
1034
1035 =item Arguments: none
1036
1037 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1038
1039 =back
1040
1041 Returns a storage-driven cursor to the given resultset. See
1042 L<DBIx::Class::Cursor> for more information.
1043
1044 =cut
1045
1046 sub cursor {
1047   my $self = shift;
1048
1049   return $self->{cursor} ||= do {
1050     my $attrs = $self->_resolved_attrs;
1051     $self->result_source->storage->select(
1052       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1053     );
1054   };
1055 }
1056
1057 =head2 single
1058
1059 =over 4
1060
1061 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1062
1063 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1064
1065 =back
1066
1067   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1068
1069 Inflates the first result without creating a cursor if the resultset has
1070 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1071 of L</search>.
1072
1073 While this method can take an optional search condition (just like L</search>)
1074 being a fast-code-path it does not recognize search attributes. If you need to
1075 add extra joins or similar, call L</search> and then chain-call L</single> on the
1076 L<DBIx::Class::ResultSet> returned.
1077
1078 =over
1079
1080 =item B<Note>
1081
1082 As of 0.08100, this method enforces the assumption that the preceding
1083 query returns only one row. If more than one row is returned, you will receive
1084 a warning:
1085
1086   Query returned more than one row
1087
1088 In this case, you should be using L</next> or L</find> instead, or if you really
1089 know what you are doing, use the L</rows> attribute to explicitly limit the size
1090 of the resultset.
1091
1092 This method will also throw an exception if it is called on a resultset prefetching
1093 has_many, as such a prefetch implies fetching multiple rows from the database in
1094 order to assemble the resulting object.
1095
1096 =back
1097
1098 =cut
1099
1100 sub single {
1101   my ($self, $where) = @_;
1102   if(@_ > 2) {
1103       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1104   }
1105
1106   my $attrs = { %{$self->_resolved_attrs} };
1107
1108   $self->throw_exception(
1109     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1110   ) if $attrs->{collapse};
1111
1112   if ($where) {
1113     if (defined $attrs->{where}) {
1114       $attrs->{where} = {
1115         '-and' =>
1116             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1117                $where, delete $attrs->{where} ]
1118       };
1119     } else {
1120       $attrs->{where} = $where;
1121     }
1122   }
1123
1124   my $data = [ $self->result_source->storage->select_single(
1125     $attrs->{from}, $attrs->{select},
1126     $attrs->{where}, $attrs
1127   )];
1128
1129   return undef unless @$data;
1130   $self->{_stashed_rows} = [ $data ];
1131   $self->_construct_results->[0];
1132 }
1133
1134 =head2 get_column
1135
1136 =over 4
1137
1138 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1139
1140 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1141
1142 =back
1143
1144   my $max_length = $rs->get_column('length')->max;
1145
1146 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1147
1148 =cut
1149
1150 sub get_column {
1151   my ($self, $column) = @_;
1152   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1153   return $new;
1154 }
1155
1156 =head2 search_like
1157
1158 =over 4
1159
1160 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1161
1162 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1163
1164 =back
1165
1166   # WHERE title LIKE '%blue%'
1167   $cd_rs = $rs->search_like({ title => '%blue%'});
1168
1169 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1170 that this is simply a convenience method retained for ex Class::DBI users.
1171 You most likely want to use L</search> with specific operators.
1172
1173 For more information, see L<DBIx::Class::Manual::Cookbook>.
1174
1175 This method is deprecated and will be removed in 0.09. Use L</search()>
1176 instead. An example conversion is:
1177
1178   ->search_like({ foo => 'bar' });
1179
1180   # Becomes
1181
1182   ->search({ foo => { like => 'bar' } });
1183
1184 =cut
1185
1186 sub search_like {
1187   my $class = shift;
1188   carp_unique (
1189     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1190    .' Instead use ->search({ x => { -like => "y%" } })'
1191    .' (note the outer pair of {}s - they are important!)'
1192   );
1193   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1194   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1195   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1196   return $class->search($query, { %$attrs });
1197 }
1198
1199 =head2 slice
1200
1201 =over 4
1202
1203 =item Arguments: $first, $last
1204
1205 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1206
1207 =back
1208
1209 Returns a resultset or object list representing a subset of elements from the
1210 resultset slice is called on. Indexes are from 0, i.e., to get the first
1211 three records, call:
1212
1213   my ($one, $two, $three) = $rs->slice(0, 2);
1214
1215 =cut
1216
1217 sub slice {
1218   my ($self, $min, $max) = @_;
1219   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1220   $attrs->{offset} = $self->{attrs}{offset} || 0;
1221   $attrs->{offset} += $min;
1222   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1223   return $self->search(undef, $attrs);
1224 }
1225
1226 =head2 next
1227
1228 =over 4
1229
1230 =item Arguments: none
1231
1232 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1233
1234 =back
1235
1236 Returns the next element in the resultset (C<undef> is there is none).
1237
1238 Can be used to efficiently iterate over records in the resultset:
1239
1240   my $rs = $schema->resultset('CD')->search;
1241   while (my $cd = $rs->next) {
1242     print $cd->title;
1243   }
1244
1245 Note that you need to store the resultset object, and call C<next> on it.
1246 Calling C<< resultset('Table')->next >> repeatedly will always return the
1247 first record from the resultset.
1248
1249 =cut
1250
1251 sub next {
1252   my ($self) = @_;
1253
1254   if (my $cache = $self->get_cache) {
1255     $self->{all_cache_position} ||= 0;
1256     return $cache->[$self->{all_cache_position}++];
1257   }
1258
1259   if ($self->{attrs}{cache}) {
1260     delete $self->{pager};
1261     $self->{all_cache_position} = 1;
1262     return ($self->all)[0];
1263   }
1264
1265   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1266
1267   $self->{_stashed_results} = $self->_construct_results
1268     or return undef;
1269
1270   return shift @{$self->{_stashed_results}};
1271 }
1272
1273 # Constructs as many results as it can in one pass while respecting
1274 # cursor laziness. Several modes of operation:
1275 #
1276 # * Always builds everything present in @{$self->{_stashed_rows}}
1277 # * If called with $fetch_all true - pulls everything off the cursor and
1278 #   builds all result structures (or objects) in one pass
1279 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1280 #   and if the resultset is ordered properly by the left side:
1281 #   * Fetches stuff off the cursor until the "master object" changes,
1282 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1283 #   OR
1284 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1285 #     was requested (there is no other way to collapse except for an
1286 #     eager cursor)
1287 # * If no collapse is requested - just get the next row, construct and
1288 #   return
1289 sub _construct_results {
1290   my ($self, $fetch_all) = @_;
1291
1292   my $rsrc = $self->result_source;
1293   my $attrs = $self->_resolved_attrs;
1294
1295   if (
1296     ! $fetch_all
1297       and
1298     ! $attrs->{order_by}
1299       and
1300     $attrs->{collapse}
1301       and
1302     my @pcols = $rsrc->primary_columns
1303   ) {
1304     # default order for collapsing unless the user asked for something
1305     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1306     $attrs->{_ordered_for_collapse} = 1;
1307     $attrs->{_order_is_artificial} = 1;
1308   }
1309
1310   # this will be used as both initial raw-row collector AND as a RV of
1311   # _construct_results. Not regrowing the array twice matters a lot...
1312   # a surprising amount actually
1313   my $rows = delete $self->{_stashed_rows};
1314
1315   my $cursor; # we may not need one at all
1316
1317   my $did_fetch_all = $fetch_all;
1318
1319   if ($fetch_all) {
1320     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1321     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1322   }
1323   elsif( $attrs->{collapse} ) {
1324
1325     # a cursor will need to be closed over in case of collapse
1326     $cursor = $self->cursor;
1327
1328     $attrs->{_ordered_for_collapse} = (
1329       (
1330         $attrs->{order_by}
1331           and
1332         $rsrc->schema
1333               ->storage
1334                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1335       ) ? 1 : 0
1336     ) unless defined $attrs->{_ordered_for_collapse};
1337
1338     if (! $attrs->{_ordered_for_collapse}) {
1339       $did_fetch_all = 1;
1340
1341       # instead of looping over ->next, use ->all in stealth mode
1342       # *without* calling a ->reset afterwards
1343       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1344       if (! $cursor->{_done}) {
1345         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1346         $cursor->{_done} = 1;
1347       }
1348     }
1349   }
1350
1351   if (! $did_fetch_all and ! @{$rows||[]} ) {
1352     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1353     $cursor ||= $self->cursor;
1354     if (scalar (my @r = $cursor->next) ) {
1355       $rows = [ \@r ];
1356     }
1357   }
1358
1359   return undef unless @{$rows||[]};
1360
1361   # sanity check - people are too clever for their own good
1362   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1363
1364     my $multiplied_selectors;
1365     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1366       if (
1367         $aliastypes->{multiplying}{$sel_alias}
1368           or
1369         $aliastypes->{premultiplied}{$sel_alias}
1370       ) {
1371         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1372       }
1373     }
1374
1375     for my $i (0 .. $#{$attrs->{as}} ) {
1376       my $sel = $attrs->{select}[$i];
1377
1378       if (ref $sel eq 'SCALAR') {
1379         $sel = $$sel;
1380       }
1381       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1382         $sel = $$sel->[0];
1383       }
1384
1385       $self->throw_exception(
1386         'Result collapse not possible - selection from a has_many source redirected to the main object'
1387       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1388     }
1389   }
1390
1391   # hotspot - skip the setter
1392   my $res_class = $self->_result_class;
1393
1394   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1395     $res_class->can ('inflate_result')
1396       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1397   };
1398
1399   my $infmap = $attrs->{as};
1400
1401   $self->{_result_inflator}{is_core_row} = ( (
1402     $inflator_cref
1403       ==
1404     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1405   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1406
1407   $self->{_result_inflator}{is_hri} = ( (
1408     ! $self->{_result_inflator}{is_core_row}
1409       and
1410     $inflator_cref == (
1411       require DBIx::Class::ResultClass::HashRefInflator
1412         &&
1413       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1414     )
1415   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1416
1417
1418   if (! $attrs->{_related_results_construction}) {
1419     # construct a much simpler array->hash folder for the one-table cases right here
1420     if ($self->{_result_inflator}{is_hri}) {
1421       for my $r (@$rows) {
1422         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1423       }
1424     }
1425     # FIXME SUBOPTIMAL this is a very very very hot spot
1426     # while rather optimal we can *still* do much better, by
1427     # building a smarter Row::inflate_result(), and
1428     # switch to feeding it data via a much leaner interface
1429     #
1430     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1431     # this particular resultset size
1432     elsif (@$rows < 60) {
1433       for my $r (@$rows) {
1434         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1435       }
1436     }
1437     else {
1438       eval sprintf (
1439         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1440         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1441       );
1442     }
1443   }
1444   else {
1445     my $parser_type =
1446         $self->{_result_inflator}{is_hri}       ? 'hri'
1447       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1448       :                                           'classic_nonpruning'
1449     ;
1450
1451     # $args and $attrs to _mk_row_parser are separated to delineate what is
1452     # core collapser stuff and what is dbic $rs specific
1453     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1454       eval => 1,
1455       inflate_map => $infmap,
1456       collapse => $attrs->{collapse},
1457       premultiplied => $attrs->{_main_source_premultiplied},
1458       hri_style => $self->{_result_inflator}{is_hri},
1459       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1460     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1461
1462     # column_info metadata historically hasn't been too reliable.
1463     # We need to start fixing this somehow (the collapse resolver
1464     # can't work without it). Add an explicit check for the *main*
1465     # result, hopefully this will gradually weed out such errors
1466     #
1467     # FIXME - this is a temporary kludge that reduces performance
1468     # It is however necessary for the time being
1469     my ($unrolled_non_null_cols_to_check, $err);
1470
1471     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1472
1473       $err =
1474         'Collapse aborted due to invalid ResultSource metadata - the following '
1475       . 'selections are declared non-nullable but NULLs were retrieved: '
1476       ;
1477
1478       my @violating_idx;
1479       COL: for my $i (@$check_non_null_cols) {
1480         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1481       }
1482
1483       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1484         if @violating_idx;
1485
1486       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1487     }
1488
1489     my $next_cref =
1490       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1491     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1492 sub {
1493   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1494   my @r = $cursor->next or return;
1495   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1496     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1497   }
1498   \@r
1499 }
1500 EOS
1501     : sub {
1502         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1503         my @r = $cursor->next or return;
1504         \@r
1505       }
1506     ;
1507
1508     $self->{_row_parser}{$parser_type}{cref}->(
1509       $rows,
1510       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1511     );
1512
1513     # Special-case multi-object HRI - there is no $inflator_cref pass
1514     unless ($self->{_result_inflator}{is_hri}) {
1515       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1516     }
1517   }
1518
1519   # The @$rows check seems odd at first - why wouldn't we want to warn
1520   # regardless? The issue is things like find() etc, where the user
1521   # *knows* only one result will come back. In these cases the ->all
1522   # is not a pessimization, but rather something we actually want
1523   carp_unique(
1524     'Unable to properly collapse has_many results in iterator mode due '
1525   . 'to order criteria - performed an eager cursor slurp underneath. '
1526   . 'Consider using ->all() instead'
1527   ) if ( ! $fetch_all and @$rows > 1 );
1528
1529   return $rows;
1530 }
1531
1532 =head2 result_source
1533
1534 =over 4
1535
1536 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1537
1538 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1539
1540 =back
1541
1542 An accessor for the primary ResultSource object from which this ResultSet
1543 is derived.
1544
1545 =head2 result_class
1546
1547 =over 4
1548
1549 =item Arguments: $result_class?
1550
1551 =item Return Value: $result_class
1552
1553 =back
1554
1555 An accessor for the class to use when creating result objects. Defaults to
1556 C<< result_source->result_class >> - which in most cases is the name of the
1557 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1558
1559 Note that changing the result_class will also remove any components
1560 that were originally loaded in the source class via
1561 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1562 in the original source class will not run.
1563
1564 =cut
1565
1566 sub result_class {
1567   my ($self, $result_class) = @_;
1568   if ($result_class) {
1569
1570     # don't fire this for an object
1571     $self->ensure_class_loaded($result_class)
1572       unless ref($result_class);
1573
1574     if ($self->get_cache) {
1575       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1576     }
1577     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1578     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1579       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1580     }
1581
1582     $self->_result_class($result_class);
1583
1584     delete $self->{_result_inflator};
1585   }
1586   $self->_result_class;
1587 }
1588
1589 =head2 count
1590
1591 =over 4
1592
1593 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1594
1595 =item Return Value: $count
1596
1597 =back
1598
1599 Performs an SQL C<COUNT> with the same query as the resultset was built
1600 with to find the number of elements. Passing arguments is equivalent to
1601 C<< $rs->search ($cond, \%attrs)->count >>
1602
1603 =cut
1604
1605 sub count {
1606   my $self = shift;
1607   return $self->search(@_)->count if @_ and defined $_[0];
1608   return scalar @{ $self->get_cache } if $self->get_cache;
1609
1610   my $attrs = { %{ $self->_resolved_attrs } };
1611
1612   # this is a little optimization - it is faster to do the limit
1613   # adjustments in software, instead of a subquery
1614   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1615
1616   my $crs;
1617   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1618     $crs = $self->_count_subq_rs ($attrs);
1619   }
1620   else {
1621     $crs = $self->_count_rs ($attrs);
1622   }
1623   my $count = $crs->next;
1624
1625   $count -= $offset if $offset;
1626   $count = $rows if $rows and $rows < $count;
1627   $count = 0 if ($count < 0);
1628
1629   return $count;
1630 }
1631
1632 =head2 count_rs
1633
1634 =over 4
1635
1636 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1637
1638 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1639
1640 =back
1641
1642 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1643 This can be very handy for subqueries:
1644
1645   ->search( { amount => $some_rs->count_rs->as_query } )
1646
1647 As with regular resultsets the SQL query will be executed only after
1648 the resultset is accessed via L</next> or L</all>. That would return
1649 the same single value obtainable via L</count>.
1650
1651 =cut
1652
1653 sub count_rs {
1654   my $self = shift;
1655   return $self->search(@_)->count_rs if @_;
1656
1657   # this may look like a lack of abstraction (count() does about the same)
1658   # but in fact an _rs *must* use a subquery for the limits, as the
1659   # software based limiting can not be ported if this $rs is to be used
1660   # in a subquery itself (i.e. ->as_query)
1661   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1662     return $self->_count_subq_rs($self->{_attrs});
1663   }
1664   else {
1665     return $self->_count_rs($self->{_attrs});
1666   }
1667 }
1668
1669 #
1670 # returns a ResultSetColumn object tied to the count query
1671 #
1672 sub _count_rs {
1673   my ($self, $attrs) = @_;
1674
1675   my $rsrc = $self->result_source;
1676
1677   my $tmp_attrs = { %$attrs };
1678   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1679   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1680
1681   # overwrite the selector (supplied by the storage)
1682   $rsrc->resultset_class->new($rsrc, {
1683     %$tmp_attrs,
1684     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1685     as => 'count',
1686   })->get_column ('count');
1687 }
1688
1689 #
1690 # same as above but uses a subquery
1691 #
1692 sub _count_subq_rs {
1693   my ($self, $attrs) = @_;
1694
1695   my $rsrc = $self->result_source;
1696
1697   my $sub_attrs = { %$attrs };
1698   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1699   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1700
1701   # if we multi-prefetch we group_by something unique, as this is what we would
1702   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1703   if ( $attrs->{collapse}  ) {
1704     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1705       $rsrc->_identifying_column_set || $self->throw_exception(
1706         'Unable to construct a unique group_by criteria properly collapsing the '
1707       . 'has_many prefetch before count()'
1708       );
1709     } ]
1710   }
1711
1712   # Calculate subquery selector
1713   if (my $g = $sub_attrs->{group_by}) {
1714
1715     my $sql_maker = $rsrc->storage->sql_maker;
1716
1717     # necessary as the group_by may refer to aliased functions
1718     my $sel_index;
1719     for my $sel (@{$attrs->{select}}) {
1720       $sel_index->{$sel->{-as}} = $sel
1721         if (ref $sel eq 'HASH' and $sel->{-as});
1722     }
1723
1724     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1725     # also look for named aggregates referred in the having clause
1726     # having often contains scalarrefs - thus parse it out entirely
1727     my @parts = @$g;
1728     if ($attrs->{having}) {
1729       local $sql_maker->{having_bind};
1730       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1731       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1732       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1733         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1734         # if we don't unset it we screw up retarded but unfortunately working
1735         # 'MAX(foo.bar)' => { '>', 3 }
1736         $sql_maker->{name_sep} = '';
1737       }
1738
1739       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1740
1741       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1742       my %seen_having;
1743
1744       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1745       # and if all fails for an utterly naive quoted scalar-with-function
1746       while ($having_sql =~ /
1747         $rquote $sep $lquote (.+?) $rquote
1748           |
1749         [\s,] \w+ \. (\w+) [\s,]
1750           |
1751         [\s,] $lquote (.+?) $rquote [\s,]
1752       /gx) {
1753         my $part = $1 || $2 || $3;  # one of them matched if we got here
1754         unless ($seen_having{$part}++) {
1755           push @parts, $part;
1756         }
1757       }
1758     }
1759
1760     for (@parts) {
1761       my $colpiece = $sel_index->{$_} || $_;
1762
1763       # unqualify join-based group_by's. Arcane but possible query
1764       # also horrible horrible hack to alias a column (not a func.)
1765       # (probably need to introduce SQLA syntax)
1766       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1767         my $as = $colpiece;
1768         $as =~ s/\./__/;
1769         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1770       }
1771       push @{$sub_attrs->{select}}, $colpiece;
1772     }
1773   }
1774   else {
1775     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1776     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1777   }
1778
1779   return $rsrc->resultset_class
1780                ->new ($rsrc, $sub_attrs)
1781                 ->as_subselect_rs
1782                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1783                   ->get_column ('count');
1784 }
1785
1786
1787 =head2 count_literal
1788
1789 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1790 should only be used in that context. See L</search_literal> for further info.
1791
1792 =over 4
1793
1794 =item Arguments: $sql_fragment, @standalone_bind_values
1795
1796 =item Return Value: $count
1797
1798 =back
1799
1800 Counts the results in a literal query. Equivalent to calling L</search_literal>
1801 with the passed arguments, then L</count>.
1802
1803 =cut
1804
1805 sub count_literal { shift->search_literal(@_)->count; }
1806
1807 =head2 all
1808
1809 =over 4
1810
1811 =item Arguments: none
1812
1813 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1814
1815 =back
1816
1817 Returns all elements in the resultset.
1818
1819 =cut
1820
1821 sub all {
1822   my $self = shift;
1823   if(@_) {
1824     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1825   }
1826
1827   delete @{$self}{qw/_stashed_rows _stashed_results/};
1828
1829   if (my $c = $self->get_cache) {
1830     return @$c;
1831   }
1832
1833   $self->cursor->reset;
1834
1835   my $objs = $self->_construct_results('fetch_all') || [];
1836
1837   $self->set_cache($objs) if $self->{attrs}{cache};
1838
1839   return @$objs;
1840 }
1841
1842 =head2 reset
1843
1844 =over 4
1845
1846 =item Arguments: none
1847
1848 =item Return Value: $self
1849
1850 =back
1851
1852 Resets the resultset's cursor, so you can iterate through the elements again.
1853 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1854 another query.
1855
1856 =cut
1857
1858 sub reset {
1859   my ($self) = @_;
1860
1861   delete @{$self}{qw/_stashed_rows _stashed_results/};
1862   $self->{all_cache_position} = 0;
1863   $self->cursor->reset;
1864   return $self;
1865 }
1866
1867 =head2 first
1868
1869 =over 4
1870
1871 =item Arguments: none
1872
1873 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1874
1875 =back
1876
1877 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1878 an object for the first result (or C<undef> if the resultset is empty).
1879
1880 =cut
1881
1882 sub first {
1883   return $_[0]->reset->next;
1884 }
1885
1886
1887 # _rs_update_delete
1888 #
1889 # Determines whether and what type of subquery is required for the $rs operation.
1890 # If grouping is necessary either supplies its own, or verifies the current one
1891 # After all is done delegates to the proper storage method.
1892
1893 sub _rs_update_delete {
1894   my ($self, $op, $values) = @_;
1895
1896   my $rsrc = $self->result_source;
1897   my $storage = $rsrc->schema->storage;
1898
1899   my $attrs = { %{$self->_resolved_attrs} };
1900
1901   my $join_classifications;
1902   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1903
1904   # do we need a subquery for any reason?
1905   my $needs_subq = (
1906     defined $existing_group_by
1907       or
1908     # if {from} is unparseable wrap a subq
1909     ref($attrs->{from}) ne 'ARRAY'
1910       or
1911     # limits call for a subq
1912     $self->_has_resolved_attr(qw/rows offset/)
1913   );
1914
1915   # simplify the joinmap, so we can further decide if a subq is necessary
1916   if (!$needs_subq and @{$attrs->{from}} > 1) {
1917
1918     ($attrs->{from}, $join_classifications) =
1919       $storage->_prune_unused_joins ($attrs);
1920
1921     # any non-pruneable non-local restricting joins imply subq
1922     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1923   }
1924
1925   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1926   $needs_subq ||= (
1927     (ref $attrs->{from}[0]) ne 'HASH'
1928       or
1929     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1930   );
1931
1932   my ($cond, $guard);
1933   # do we need anything like a subquery?
1934   if (! $needs_subq) {
1935     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1936     # a condition containing 'me' or other table prefixes will not work
1937     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1938     $cond = do {
1939       my $sqla = $rsrc->storage->sql_maker;
1940       local $sqla->{_dequalify_idents} = 1;
1941       \[ $sqla->_recurse_where($self->{cond}) ];
1942     };
1943   }
1944   else {
1945     # we got this far - means it is time to wrap a subquery
1946     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1947       sprintf(
1948         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1949         $op,
1950         $rsrc->source_name,
1951       )
1952     );
1953
1954     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1955     delete $attrs->{$_} for qw/select as collapse/;
1956     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1957
1958     # this will be consumed by the pruner waaaaay down the stack
1959     $attrs->{_force_prune_multiplying_joins} = 1;
1960
1961     my $subrs = (ref $self)->new($rsrc, $attrs);
1962
1963     if (@$idcols == 1) {
1964       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1965     }
1966     elsif ($storage->_use_multicolumn_in) {
1967       # no syntax for calling this properly yet
1968       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1969       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1970         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1971         $subrs->as_query
1972       ),
1973     }
1974     else {
1975       # if all else fails - get all primary keys and operate over a ORed set
1976       # wrap in a transaction for consistency
1977       # this is where the group_by/multiplication starts to matter
1978       if (
1979         $existing_group_by
1980           or
1981         # we do not need to check pre-multipliers, since if the premulti is there, its
1982         # parent (who is multi) will be there too
1983         keys %{ $join_classifications->{multiplying} || {} }
1984       ) {
1985         # make sure if there is a supplied group_by it matches the columns compiled above
1986         # perfectly. Anything else can not be sanely executed on most databases so croak
1987         # right then and there
1988         if ($existing_group_by) {
1989           my @current_group_by = map
1990             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1991             @$existing_group_by
1992           ;
1993
1994           if (
1995             join ("\x00", sort @current_group_by)
1996               ne
1997             join ("\x00", sort @{$attrs->{columns}} )
1998           ) {
1999             $self->throw_exception (
2000               "You have just attempted a $op operation on a resultset which does group_by"
2001               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
2002               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
2003               . ' kind of queries. Please retry the operation with a modified group_by or'
2004               . ' without using one at all.'
2005             );
2006           }
2007         }
2008
2009         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2010       }
2011
2012       $guard = $storage->txn_scope_guard;
2013
2014       for my $row ($subrs->cursor->all) {
2015         push @$cond, { map
2016           { $idcols->[$_] => $row->[$_] }
2017           (0 .. $#$idcols)
2018         };
2019       }
2020     }
2021   }
2022
2023   my $res = $cond ? $storage->$op (
2024     $rsrc,
2025     $op eq 'update' ? $values : (),
2026     $cond,
2027   ) : '0E0';
2028
2029   $guard->commit if $guard;
2030
2031   return $res;
2032 }
2033
2034 =head2 update
2035
2036 =over 4
2037
2038 =item Arguments: \%values
2039
2040 =item Return Value: $underlying_storage_rv
2041
2042 =back
2043
2044 Sets the specified columns in the resultset to the supplied values in a
2045 single query. Note that this will not run any accessor/set_column/update
2046 triggers, nor will it update any result object instances derived from this
2047 resultset (this includes the contents of the L<resultset cache|/set_cache>
2048 if any). See L</update_all> if you need to execute any on-update
2049 triggers or cascades defined either by you or a
2050 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2051
2052 The return value is a pass through of what the underlying
2053 storage backend returned, and may vary. See L<DBI/execute> for the most
2054 common case.
2055
2056 =head3 CAVEAT
2057
2058 Note that L</update> does not process/deflate any of the values passed in.
2059 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2060 ensure manually that any value passed to this method will stringify to
2061 something the RDBMS knows how to deal with. A notable example is the
2062 handling of L<DateTime> objects, for more info see:
2063 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2064
2065 =cut
2066
2067 sub update {
2068   my ($self, $values) = @_;
2069   $self->throw_exception('Values for update must be a hash')
2070     unless ref $values eq 'HASH';
2071
2072   return $self->_rs_update_delete ('update', $values);
2073 }
2074
2075 =head2 update_all
2076
2077 =over 4
2078
2079 =item Arguments: \%values
2080
2081 =item Return Value: 1
2082
2083 =back
2084
2085 Fetches all objects and updates them one at a time via
2086 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2087 triggers, while L</update> will not.
2088
2089 =cut
2090
2091 sub update_all {
2092   my ($self, $values) = @_;
2093   $self->throw_exception('Values for update_all must be a hash')
2094     unless ref $values eq 'HASH';
2095
2096   my $guard = $self->result_source->schema->txn_scope_guard;
2097   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2098   $guard->commit;
2099   return 1;
2100 }
2101
2102 =head2 delete
2103
2104 =over 4
2105
2106 =item Arguments: none
2107
2108 =item Return Value: $underlying_storage_rv
2109
2110 =back
2111
2112 Deletes the rows matching this resultset in a single query. Note that this
2113 will not run any delete triggers, nor will it alter the
2114 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2115 derived from this resultset (this includes the contents of the
2116 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2117 execute any on-delete triggers or cascades defined either by you or a
2118 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2119
2120 The return value is a pass through of what the underlying storage backend
2121 returned, and may vary. See L<DBI/execute> for the most common case.
2122
2123 =cut
2124
2125 sub delete {
2126   my $self = shift;
2127   $self->throw_exception('delete does not accept any arguments')
2128     if @_;
2129
2130   return $self->_rs_update_delete ('delete');
2131 }
2132
2133 =head2 delete_all
2134
2135 =over 4
2136
2137 =item Arguments: none
2138
2139 =item Return Value: 1
2140
2141 =back
2142
2143 Fetches all objects and deletes them one at a time via
2144 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2145 triggers, while L</delete> will not.
2146
2147 =cut
2148
2149 sub delete_all {
2150   my $self = shift;
2151   $self->throw_exception('delete_all does not accept any arguments')
2152     if @_;
2153
2154   my $guard = $self->result_source->schema->txn_scope_guard;
2155   $_->delete for $self->all;
2156   $guard->commit;
2157   return 1;
2158 }
2159
2160 =head2 populate
2161
2162 =over 4
2163
2164 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2165
2166 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2167
2168 =back
2169
2170 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2171 arrayrefs.
2172
2173 =over
2174
2175 =item NOTE
2176
2177 The context of this method call has an important effect on what is
2178 submitted to storage. In void context data is fed directly to fastpath
2179 insertion routines provided by the underlying storage (most often
2180 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2181 L<insert|DBIx::Class::Row/insert> calls on the
2182 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2183 augmentation of these methods provided by components. For example if you
2184 are using something like L<DBIx::Class::UUIDColumns> to create primary
2185 keys for you, you will find that your PKs are empty.  In this case you
2186 will have to explicitly force scalar or list context in order to create
2187 those values.
2188
2189 =back
2190
2191 In non-void (scalar or list) context, this method is simply a wrapper
2192 for L</create>. Depending on list or scalar context either a list of
2193 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2194 containing these objects is returned.
2195
2196 When supplying data in "arrayref of arrayrefs" invocation style, the
2197 first element should be a list of column names and each subsequent
2198 element should be a data value in the earlier specified column order.
2199 For example:
2200
2201   $schema->resultset("Artist")->populate([
2202     [ qw( artistid name ) ],
2203     [ 100, 'A Formally Unknown Singer' ],
2204     [ 101, 'A singer that jumped the shark two albums ago' ],
2205     [ 102, 'An actually cool singer' ],
2206   ]);
2207
2208 For the arrayref of hashrefs style each hashref should be a structure
2209 suitable for passing to L</create>. Multi-create is also permitted with
2210 this syntax.
2211
2212   $schema->resultset("Artist")->populate([
2213      { artistid => 4, name => 'Manufactured Crap', cds => [
2214         { title => 'My First CD', year => 2006 },
2215         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2216       ],
2217      },
2218      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2219         { title => 'My parents sold me to a record company', year => 2005 },
2220         { title => 'Why Am I So Ugly?', year => 2006 },
2221         { title => 'I Got Surgery and am now Popular', year => 2007 }
2222       ],
2223      },
2224   ]);
2225
2226 If you attempt a void-context multi-create as in the example above (each
2227 Artist also has the related list of CDs), and B<do not> supply the
2228 necessary autoinc foreign key information, this method will proxy to the
2229 less efficient L</create>, and then throw the Result objects away. In this
2230 case there are obviously no benefits to using this method over L</create>.
2231
2232 =cut
2233
2234 sub populate {
2235   my $self = shift;
2236
2237   my ($data, $guard);
2238
2239   # this is naive and just a quick check
2240   # the types will need to be checked more thoroughly when the
2241   # multi-source populate gets added
2242   if (ref $_[0] eq 'ARRAY') {
2243     return unless @{$_[0]};
2244
2245     $data = $_[0] if (ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY');
2246   }
2247
2248   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs')
2249     unless $data;
2250
2251   # FIXME - no cref handling
2252   # At this point assume either hashes or arrays
2253
2254   if(defined wantarray) {
2255     my @results;
2256
2257     $guard = $self->result_source->schema->storage->txn_scope_guard
2258       if ( @$data > 2 or ( @$data == 2 and ref $data->[0] eq 'ARRAY' ) );
2259
2260     if (ref $data->[0] eq 'ARRAY') {
2261       @results = map
2262         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2263         @{$data}[1 .. $#$data]
2264       ;
2265     }
2266     else {
2267       @results = map { $self->new_result($_)->insert } @$data;
2268     }
2269
2270     $guard->commit if $guard;
2271     return wantarray ? @results : \@results;
2272   }
2273
2274   # we have to deal with *possibly incomplete* related data
2275   # this means we have to walk the data structure twice
2276   # whether we want this or not
2277   # jnap, I hate you ;)
2278   my $rsrc = $self->result_source;
2279   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2280
2281   my ($colinfo, $colnames, $slices_with_rels);
2282   my $data_start = 0;
2283
2284   DATA_SLICE:
2285   for my $i (0 .. $#$data) {
2286
2287     my $current_slice_seen_rel_infos;
2288
2289 ### Determine/Supplement collists
2290 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2291     if( ref $data->[$i] eq 'ARRAY' ) {
2292
2293       # positional(!) explicit column list
2294       if ($i == 0) {
2295
2296         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2297           for 0 .. $#{$data->[0]};
2298
2299         $data_start = 1;
2300
2301         next DATA_SLICE;
2302       }
2303       else {
2304         for (values %$colinfo) {
2305           if ($_->{is_rel} ||= (
2306             $rel_info->{$_->{name}}
2307               and
2308             (
2309               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2310                 or
2311               ref $data->[$i][$_->{pos}] eq 'HASH'
2312                 or
2313               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2314             )
2315               and
2316             1
2317           )) {
2318
2319             # moar sanity check... sigh
2320             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2321               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2322                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2323                 return my $throwaway = $self->populate(@_);
2324               }
2325             }
2326
2327             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2328           }
2329         }
2330       }
2331
2332      if ($current_slice_seen_rel_infos) {
2333         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2334
2335         # this is needed further down to decide whether or not to fallback to create()
2336         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2337           for 0 .. $#$colnames;
2338       }
2339     }
2340     elsif( ref $data->[$i] eq 'HASH' ) {
2341
2342       for ( sort keys %{$data->[$i]} ) {
2343
2344         $colinfo->{$_} ||= do {
2345
2346           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2347             if $data_start; # it will be 0 on AoH, 1 on AoA
2348
2349           push @$colnames, $_;
2350
2351           # RV
2352           { pos => $#$colnames, name => $_ }
2353         };
2354
2355         if ($colinfo->{$_}{is_rel} ||= (
2356           $rel_info->{$_}
2357             and
2358           (
2359             ref $data->[$i]{$_} eq 'ARRAY'
2360               or
2361             ref $data->[$i]{$_} eq 'HASH'
2362               or
2363             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2364           )
2365             and
2366           1
2367         )) {
2368
2369           # moar sanity check... sigh
2370           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2371             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2372               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2373               return my $throwaway = $self->populate(@_);
2374             }
2375           }
2376
2377           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2378         }
2379       }
2380
2381       if ($current_slice_seen_rel_infos) {
2382         push @$slices_with_rels, $data->[$i];
2383
2384         # this is needed further down to decide whether or not to fallback to create()
2385         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2386           for keys %{$data->[$i]};
2387       }
2388     }
2389     else {
2390       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2391     }
2392
2393     if ( grep
2394       { $_->{attrs}{is_depends_on} }
2395       @{ $current_slice_seen_rel_infos || [] }
2396     ) {
2397       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2398       return my $throwaway = $self->populate(@_);
2399     }
2400   }
2401
2402   if( $slices_with_rels ) {
2403
2404     # need to exclude the rel "columns"
2405     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2406
2407     # extra sanity check - ensure the main source is in fact identifiable
2408     # the localizing of nullability is insane, but oh well... the use-case is legit
2409     my $ci = $rsrc->columns_info($colnames);
2410
2411     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2412       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2413
2414     unless( $rsrc->_identifying_column_set($ci) ) {
2415       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2416       return my $throwaway = $self->populate(@_);
2417     }
2418   }
2419
2420 ### inherit the data locked in the conditions of the resultset
2421   my ($rs_data) = $self->_merge_with_rscond({});
2422   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2423
2424   # if anything left - decompose rs_data
2425   my $rs_data_vals;
2426   if (keys %$rs_data) {
2427      push @$rs_data_vals, $rs_data->{$_}
2428       for sort keys %$rs_data;
2429   }
2430
2431 ### start work
2432   $guard = $rsrc->schema->storage->txn_scope_guard
2433     if $slices_with_rels;
2434
2435 ### main source data
2436   # FIXME - need to switch entirely to a coderef-based thing,
2437   # so that large sets aren't copied several times... I think
2438   $rsrc->storage->insert_bulk(
2439     $rsrc,
2440     [ @$colnames, sort keys %$rs_data ],
2441     [ map {
2442       ref $data->[$_] eq 'ARRAY'
2443       ? (
2444           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2445         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2446         :                     $data->[$_]
2447       )
2448       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2449     } $data_start .. $#$data ],
2450   );
2451
2452 ### do the children relationships
2453   if ( $slices_with_rels ) {
2454     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2455       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2456
2457     for my $sl (@$slices_with_rels) {
2458
2459       my ($main_proto, $main_proto_rs);
2460       for my $rel (@rels) {
2461         next unless defined $sl->{$rel};
2462
2463         $main_proto ||= {
2464           %$rs_data,
2465           (map { $_ => $sl->{$_} } @$colnames),
2466         };
2467
2468         unless (defined $colinfo->{$rel}{rs}) {
2469
2470           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2471
2472           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2473             rel_name => $rel,
2474             self_alias => "\xFE", # irrelevant
2475             foreign_alias => "\xFF", # irrelevant
2476           )->{identity_map} || {} } };
2477
2478         }
2479
2480         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2481           {
2482             $_ => { '=' =>
2483               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2484                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2485                  ->as_query
2486             }
2487           }
2488           keys %{$colinfo->{$rel}{fk_map}}
2489         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2490
2491         1;
2492       }
2493     }
2494   }
2495
2496   $guard->commit if $guard;
2497 }
2498
2499 =head2 pager
2500
2501 =over 4
2502
2503 =item Arguments: none
2504
2505 =item Return Value: L<$pager|Data::Page>
2506
2507 =back
2508
2509 Returns a L<Data::Page> object for the current resultset. Only makes
2510 sense for queries with a C<page> attribute.
2511
2512 To get the full count of entries for a paged resultset, call
2513 C<total_entries> on the L<Data::Page> object.
2514
2515 =cut
2516
2517 sub pager {
2518   my ($self) = @_;
2519
2520   return $self->{pager} if $self->{pager};
2521
2522   my $attrs = $self->{attrs};
2523   if (!defined $attrs->{page}) {
2524     $self->throw_exception("Can't create pager for non-paged rs");
2525   }
2526   elsif ($attrs->{page} <= 0) {
2527     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2528   }
2529   $attrs->{rows} ||= 10;
2530
2531   # throw away the paging flags and re-run the count (possibly
2532   # with a subselect) to get the real total count
2533   my $count_attrs = { %$attrs };
2534   delete @{$count_attrs}{qw/rows offset page pager/};
2535
2536   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2537
2538   require DBIx::Class::ResultSet::Pager;
2539   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2540     sub { $total_rs->count },  #lazy-get the total
2541     $attrs->{rows},
2542     $self->{attrs}{page},
2543   );
2544 }
2545
2546 =head2 page
2547
2548 =over 4
2549
2550 =item Arguments: $page_number
2551
2552 =item Return Value: L<$resultset|/search>
2553
2554 =back
2555
2556 Returns a resultset for the $page_number page of the resultset on which page
2557 is called, where each page contains a number of rows equal to the 'rows'
2558 attribute set on the resultset (10 by default).
2559
2560 =cut
2561
2562 sub page {
2563   my ($self, $page) = @_;
2564   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2565 }
2566
2567 =head2 new_result
2568
2569 =over 4
2570
2571 =item Arguments: \%col_data
2572
2573 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2574
2575 =back
2576
2577 Creates a new result object in the resultset's result class and returns
2578 it. The row is not inserted into the database at this point, call
2579 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2580 will tell you whether the result object has been inserted or not.
2581
2582 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2583
2584 =cut
2585
2586 sub new_result {
2587   my ($self, $values) = @_;
2588
2589   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2590     if @_ > 2;
2591
2592   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2593     unless (ref $values eq 'HASH');
2594
2595   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2596
2597   my $new = $self->result_class->new({
2598     %$merged_cond,
2599     ( @$cols_from_relations
2600       ? (-cols_from_relations => $cols_from_relations)
2601       : ()
2602     ),
2603     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2604   });
2605
2606   if (
2607     reftype($new) eq 'HASH'
2608       and
2609     ! keys %$new
2610       and
2611     blessed($new)
2612   ) {
2613     carp_unique (sprintf (
2614       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2615       $self->result_class,
2616     ));
2617   }
2618
2619   $new;
2620 }
2621
2622 # _merge_with_rscond
2623 #
2624 # Takes a simple hash of K/V data and returns its copy merged with the
2625 # condition already present on the resultset. Additionally returns an
2626 # arrayref of value/condition names, which were inferred from related
2627 # objects (this is needed for in-memory related objects)
2628 sub _merge_with_rscond {
2629   my ($self, $data) = @_;
2630
2631   my ($implied_data, @cols_from_relations);
2632
2633   my $alias = $self->{attrs}{alias};
2634
2635   if (! defined $self->{cond}) {
2636     # just massage $data below
2637   }
2638   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2639     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2640     @cols_from_relations = keys %{ $implied_data || {} };
2641   }
2642   else {
2643     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2644     $implied_data = { map {
2645       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2646     } keys %$eqs };
2647   }
2648
2649   return (
2650     { map
2651       { %{ $self->_remove_alias($_, $alias) } }
2652       # precedence must be given to passed values over values inherited from
2653       # the cond, so the order here is important.
2654       ( $implied_data||(), $data)
2655     },
2656     \@cols_from_relations
2657   );
2658 }
2659
2660 # _has_resolved_attr
2661 #
2662 # determines if the resultset defines at least one
2663 # of the attributes supplied
2664 #
2665 # used to determine if a subquery is necessary
2666 #
2667 # supports some virtual attributes:
2668 #   -join
2669 #     This will scan for any joins being present on the resultset.
2670 #     It is not a mere key-search but a deep inspection of {from}
2671 #
2672
2673 sub _has_resolved_attr {
2674   my ($self, @attr_names) = @_;
2675
2676   my $attrs = $self->_resolved_attrs;
2677
2678   my %extra_checks;
2679
2680   for my $n (@attr_names) {
2681     if (grep { $n eq $_ } (qw/-join/) ) {
2682       $extra_checks{$n}++;
2683       next;
2684     }
2685
2686     my $attr =  $attrs->{$n};
2687
2688     next if not defined $attr;
2689
2690     if (ref $attr eq 'HASH') {
2691       return 1 if keys %$attr;
2692     }
2693     elsif (ref $attr eq 'ARRAY') {
2694       return 1 if @$attr;
2695     }
2696     else {
2697       return 1 if $attr;
2698     }
2699   }
2700
2701   # a resolved join is expressed as a multi-level from
2702   return 1 if (
2703     $extra_checks{-join}
2704       and
2705     ref $attrs->{from} eq 'ARRAY'
2706       and
2707     @{$attrs->{from}} > 1
2708   );
2709
2710   return 0;
2711 }
2712
2713 # _remove_alias
2714 #
2715 # Remove the specified alias from the specified query hash. A copy is made so
2716 # the original query is not modified.
2717
2718 sub _remove_alias {
2719   my ($self, $query, $alias) = @_;
2720
2721   my %orig = %{ $query || {} };
2722   my %unaliased;
2723
2724   foreach my $key (keys %orig) {
2725     if ($key !~ /\./) {
2726       $unaliased{$key} = $orig{$key};
2727       next;
2728     }
2729     $unaliased{$1} = $orig{$key}
2730       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2731   }
2732
2733   return \%unaliased;
2734 }
2735
2736 =head2 as_query
2737
2738 =over 4
2739
2740 =item Arguments: none
2741
2742 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2743
2744 =back
2745
2746 Returns the SQL query and bind vars associated with the invocant.
2747
2748 This is generally used as the RHS for a subquery.
2749
2750 =cut
2751
2752 sub as_query {
2753   my $self = shift;
2754
2755   my $attrs = { %{ $self->_resolved_attrs } };
2756
2757   my $aq = $self->result_source->storage->_select_args_to_query (
2758     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2759   );
2760
2761   $aq;
2762 }
2763
2764 =head2 find_or_new
2765
2766 =over 4
2767
2768 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2769
2770 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2771
2772 =back
2773
2774   my $artist = $schema->resultset('Artist')->find_or_new(
2775     { artist => 'fred' }, { key => 'artists' });
2776
2777   $cd->cd_to_producer->find_or_new({ producer => $producer },
2778                                    { key => 'primary' });
2779
2780 Find an existing record from this resultset using L</find>. if none exists,
2781 instantiate a new result object and return it. The object will not be saved
2782 into your storage until you call L<DBIx::Class::Row/insert> on it.
2783
2784 You most likely want this method when looking for existing rows using a unique
2785 constraint that is not the primary key, or looking for related rows.
2786
2787 If you want objects to be saved immediately, use L</find_or_create> instead.
2788
2789 B<Note>: Make sure to read the documentation of L</find> and understand the
2790 significance of the C<key> attribute, as its lack may skew your search, and
2791 subsequently result in spurious new objects.
2792
2793 B<Note>: Take care when using C<find_or_new> with a table having
2794 columns with default values that you intend to be automatically
2795 supplied by the database (e.g. an auto_increment primary key column).
2796 In normal usage, the value of such columns should NOT be included at
2797 all in the call to C<find_or_new>, even when set to C<undef>.
2798
2799 =cut
2800
2801 sub find_or_new {
2802   my $self     = shift;
2803   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2804   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2805   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2806     return $row;
2807   }
2808   return $self->new_result($hash);
2809 }
2810
2811 =head2 create
2812
2813 =over 4
2814
2815 =item Arguments: \%col_data
2816
2817 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2818
2819 =back
2820
2821 Attempt to create a single new row or a row with multiple related rows
2822 in the table represented by the resultset (and related tables). This
2823 will not check for duplicate rows before inserting, use
2824 L</find_or_create> to do that.
2825
2826 To create one row for this resultset, pass a hashref of key/value
2827 pairs representing the columns of the table and the values you wish to
2828 store. If the appropriate relationships are set up, foreign key fields
2829 can also be passed an object representing the foreign row, and the
2830 value will be set to its primary key.
2831
2832 To create related objects, pass a hashref of related-object column values
2833 B<keyed on the relationship name>. If the relationship is of type C<multi>
2834 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2835 The process will correctly identify columns holding foreign keys, and will
2836 transparently populate them from the keys of the corresponding relation.
2837 This can be applied recursively, and will work correctly for a structure
2838 with an arbitrary depth and width, as long as the relationships actually
2839 exists and the correct column data has been supplied.
2840
2841 Instead of hashrefs of plain related data (key/value pairs), you may
2842 also pass new or inserted objects. New objects (not inserted yet, see
2843 L</new_result>), will be inserted into their appropriate tables.
2844
2845 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2846
2847 Example of creating a new row.
2848
2849   $person_rs->create({
2850     name=>"Some Person",
2851     email=>"somebody@someplace.com"
2852   });
2853
2854 Example of creating a new row and also creating rows in a related C<has_many>
2855 or C<has_one> resultset.  Note Arrayref.
2856
2857   $artist_rs->create(
2858      { artistid => 4, name => 'Manufactured Crap', cds => [
2859         { title => 'My First CD', year => 2006 },
2860         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2861       ],
2862      },
2863   );
2864
2865 Example of creating a new row and also creating a row in a related
2866 C<belongs_to> resultset. Note Hashref.
2867
2868   $cd_rs->create({
2869     title=>"Music for Silly Walks",
2870     year=>2000,
2871     artist => {
2872       name=>"Silly Musician",
2873     }
2874   });
2875
2876 =over
2877
2878 =item WARNING
2879
2880 When subclassing ResultSet never attempt to override this method. Since
2881 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2882 lot of the internals simply never call it, so your override will be
2883 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2884 or L<DBIx::Class::Row/insert> depending on how early in the
2885 L</create> process you need to intervene. See also warning pertaining to
2886 L</new>.
2887
2888 =back
2889
2890 =cut
2891
2892 sub create {
2893   #my ($self, $col_data) = @_;
2894   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2895   return shift->new_result(shift)->insert;
2896 }
2897
2898 =head2 find_or_create
2899
2900 =over 4
2901
2902 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2903
2904 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2905
2906 =back
2907
2908   $cd->cd_to_producer->find_or_create({ producer => $producer },
2909                                       { key => 'primary' });
2910
2911 Tries to find a record based on its primary key or unique constraints; if none
2912 is found, creates one and returns that instead.
2913
2914   my $cd = $schema->resultset('CD')->find_or_create({
2915     cdid   => 5,
2916     artist => 'Massive Attack',
2917     title  => 'Mezzanine',
2918     year   => 2005,
2919   });
2920
2921 Also takes an optional C<key> attribute, to search by a specific key or unique
2922 constraint. For example:
2923
2924   my $cd = $schema->resultset('CD')->find_or_create(
2925     {
2926       artist => 'Massive Attack',
2927       title  => 'Mezzanine',
2928     },
2929     { key => 'cd_artist_title' }
2930   );
2931
2932 B<Note>: Make sure to read the documentation of L</find> and understand the
2933 significance of the C<key> attribute, as its lack may skew your search, and
2934 subsequently result in spurious row creation.
2935
2936 B<Note>: Because find_or_create() reads from the database and then
2937 possibly inserts based on the result, this method is subject to a race
2938 condition. Another process could create a record in the table after
2939 the find has completed and before the create has started. To avoid
2940 this problem, use find_or_create() inside a transaction.
2941
2942 B<Note>: Take care when using C<find_or_create> with a table having
2943 columns with default values that you intend to be automatically
2944 supplied by the database (e.g. an auto_increment primary key column).
2945 In normal usage, the value of such columns should NOT be included at
2946 all in the call to C<find_or_create>, even when set to C<undef>.
2947
2948 See also L</find> and L</update_or_create>. For information on how to declare
2949 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2950
2951 If you need to know if an existing row was found or a new one created use
2952 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2953 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2954 database!
2955
2956   my $cd = $schema->resultset('CD')->find_or_new({
2957     cdid   => 5,
2958     artist => 'Massive Attack',
2959     title  => 'Mezzanine',
2960     year   => 2005,
2961   });
2962
2963   if( !$cd->in_storage ) {
2964       # do some stuff
2965       $cd->insert;
2966   }
2967
2968 =cut
2969
2970 sub find_or_create {
2971   my $self     = shift;
2972   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2973   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2974   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2975     return $row;
2976   }
2977   return $self->new_result($hash)->insert;
2978 }
2979
2980 =head2 update_or_create
2981
2982 =over 4
2983
2984 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2985
2986 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2987
2988 =back
2989
2990   $resultset->update_or_create({ col => $val, ... });
2991
2992 Like L</find_or_create>, but if a row is found it is immediately updated via
2993 C<< $found_row->update (\%col_data) >>.
2994
2995
2996 Takes an optional C<key> attribute to search on a specific unique constraint.
2997 For example:
2998
2999   # In your application
3000   my $cd = $schema->resultset('CD')->update_or_create(
3001     {
3002       artist => 'Massive Attack',
3003       title  => 'Mezzanine',
3004       year   => 1998,
3005     },
3006     { key => 'cd_artist_title' }
3007   );
3008
3009   $cd->cd_to_producer->update_or_create({
3010     producer => $producer,
3011     name => 'harry',
3012   }, {
3013     key => 'primary',
3014   });
3015
3016 B<Note>: Make sure to read the documentation of L</find> and understand the
3017 significance of the C<key> attribute, as its lack may skew your search, and
3018 subsequently result in spurious row creation.
3019
3020 B<Note>: Take care when using C<update_or_create> with a table having
3021 columns with default values that you intend to be automatically
3022 supplied by the database (e.g. an auto_increment primary key column).
3023 In normal usage, the value of such columns should NOT be included at
3024 all in the call to C<update_or_create>, even when set to C<undef>.
3025
3026 See also L</find> and L</find_or_create>. For information on how to declare
3027 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3028
3029 If you need to know if an existing row was updated or a new one created use
3030 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3031 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3032 database!
3033
3034 =cut
3035
3036 sub update_or_create {
3037   my $self = shift;
3038   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3039   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3040
3041   my $row = $self->find($cond, $attrs);
3042   if (defined $row) {
3043     $row->update($cond);
3044     return $row;
3045   }
3046
3047   return $self->new_result($cond)->insert;
3048 }
3049
3050 =head2 update_or_new
3051
3052 =over 4
3053
3054 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3055
3056 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3057
3058 =back
3059
3060   $resultset->update_or_new({ col => $val, ... });
3061
3062 Like L</find_or_new> but if a row is found it is immediately updated via
3063 C<< $found_row->update (\%col_data) >>.
3064
3065 For example:
3066
3067   # In your application
3068   my $cd = $schema->resultset('CD')->update_or_new(
3069     {
3070       artist => 'Massive Attack',
3071       title  => 'Mezzanine',
3072       year   => 1998,
3073     },
3074     { key => 'cd_artist_title' }
3075   );
3076
3077   if ($cd->in_storage) {
3078       # the cd was updated
3079   }
3080   else {
3081       # the cd is not yet in the database, let's insert it
3082       $cd->insert;
3083   }
3084
3085 B<Note>: Make sure to read the documentation of L</find> and understand the
3086 significance of the C<key> attribute, as its lack may skew your search, and
3087 subsequently result in spurious new objects.
3088
3089 B<Note>: Take care when using C<update_or_new> with a table having
3090 columns with default values that you intend to be automatically
3091 supplied by the database (e.g. an auto_increment primary key column).
3092 In normal usage, the value of such columns should NOT be included at
3093 all in the call to C<update_or_new>, even when set to C<undef>.
3094
3095 See also L</find>, L</find_or_create> and L</find_or_new>.
3096
3097 =cut
3098
3099 sub update_or_new {
3100     my $self  = shift;
3101     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3102     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3103
3104     my $row = $self->find( $cond, $attrs );
3105     if ( defined $row ) {
3106         $row->update($cond);
3107         return $row;
3108     }
3109
3110     return $self->new_result($cond);
3111 }
3112
3113 =head2 get_cache
3114
3115 =over 4
3116
3117 =item Arguments: none
3118
3119 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3120
3121 =back
3122
3123 Gets the contents of the cache for the resultset, if the cache is set.
3124
3125 The cache is populated either by using the L</prefetch> attribute to
3126 L</search> or by calling L</set_cache>.
3127
3128 =cut
3129
3130 sub get_cache {
3131   shift->{all_cache};
3132 }
3133
3134 =head2 set_cache
3135
3136 =over 4
3137
3138 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3139
3140 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3141
3142 =back
3143
3144 Sets the contents of the cache for the resultset. Expects an arrayref
3145 of objects of the same class as those produced by the resultset. Note that
3146 if the cache is set, the resultset will return the cached objects rather
3147 than re-querying the database even if the cache attr is not set.
3148
3149 The contents of the cache can also be populated by using the
3150 L</prefetch> attribute to L</search>.
3151
3152 =cut
3153
3154 sub set_cache {
3155   my ( $self, $data ) = @_;
3156   $self->throw_exception("set_cache requires an arrayref")
3157       if defined($data) && (ref $data ne 'ARRAY');
3158   $self->{all_cache} = $data;
3159 }
3160
3161 =head2 clear_cache
3162
3163 =over 4
3164
3165 =item Arguments: none
3166
3167 =item Return Value: undef
3168
3169 =back
3170
3171 Clears the cache for the resultset.
3172
3173 =cut
3174
3175 sub clear_cache {
3176   shift->set_cache(undef);
3177 }
3178
3179 =head2 is_paged
3180
3181 =over 4
3182
3183 =item Arguments: none
3184
3185 =item Return Value: true, if the resultset has been paginated
3186
3187 =back
3188
3189 =cut
3190
3191 sub is_paged {
3192   my ($self) = @_;
3193   return !!$self->{attrs}{page};
3194 }
3195
3196 =head2 is_ordered
3197
3198 =over 4
3199
3200 =item Arguments: none
3201
3202 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3203
3204 =back
3205
3206 =cut
3207
3208 sub is_ordered {
3209   my ($self) = @_;
3210   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3211 }
3212
3213 =head2 related_resultset
3214
3215 =over 4
3216
3217 =item Arguments: $rel_name
3218
3219 =item Return Value: L<$resultset|/search>
3220
3221 =back
3222
3223 Returns a related resultset for the supplied relationship name.
3224
3225   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3226
3227 =cut
3228
3229 sub related_resultset {
3230   my ($self, $rel) = @_;
3231
3232   return $self->{related_resultsets}{$rel}
3233     if defined $self->{related_resultsets}{$rel};
3234
3235   return $self->{related_resultsets}{$rel} = do {
3236     my $rsrc = $self->result_source;
3237     my $rel_info = $rsrc->relationship_info($rel);
3238
3239     $self->throw_exception(
3240       "search_related: result source '" . $rsrc->source_name .
3241         "' has no such relationship $rel")
3242       unless $rel_info;
3243
3244     my $attrs = $self->_chain_relationship($rel);
3245
3246     my $join_count = $attrs->{seen_join}{$rel};
3247
3248     my $alias = $self->result_source->storage
3249         ->relname_to_table_alias($rel, $join_count);
3250
3251     # since this is search_related, and we already slid the select window inwards
3252     # (the select/as attrs were deleted in the beginning), we need to flip all
3253     # left joins to inner, so we get the expected results
3254     # read the comment on top of the actual function to see what this does
3255     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3256
3257
3258     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3259     delete @{$attrs}{qw(result_class alias)};
3260
3261     my $rel_source = $rsrc->related_source($rel);
3262
3263     my $new = do {
3264
3265       # The reason we do this now instead of passing the alias to the
3266       # search_rs below is that if you wrap/overload resultset on the
3267       # source you need to know what alias it's -going- to have for things
3268       # to work sanely (e.g. RestrictWithObject wants to be able to add
3269       # extra query restrictions, and these may need to be $alias.)
3270
3271       my $rel_attrs = $rel_source->resultset_attributes;
3272       local $rel_attrs->{alias} = $alias;
3273
3274       $rel_source->resultset
3275                  ->search_rs(
3276                      undef, {
3277                        %$attrs,
3278                        where => $attrs->{where},
3279                    });
3280     };
3281
3282     if (my $cache = $self->get_cache) {
3283       my @related_cache = map
3284         { $_->related_resultset($rel)->get_cache || () }
3285         @$cache
3286       ;
3287
3288       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3289     }
3290
3291     $new;
3292   };
3293 }
3294
3295 =head2 current_source_alias
3296
3297 =over 4
3298
3299 =item Arguments: none
3300
3301 =item Return Value: $source_alias
3302
3303 =back
3304
3305 Returns the current table alias for the result source this resultset is built
3306 on, that will be used in the SQL query. Usually it is C<me>.
3307
3308 Currently the source alias that refers to the result set returned by a
3309 L</search>/L</find> family method depends on how you got to the resultset: it's
3310 C<me> by default, but eg. L</search_related> aliases it to the related result
3311 source name (and keeps C<me> referring to the original result set). The long
3312 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3313 (and make this method unnecessary).
3314
3315 Thus it's currently necessary to use this method in predefined queries (see
3316 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3317 source alias of the current result set:
3318
3319   # in a result set class
3320   sub modified_by {
3321     my ($self, $user) = @_;
3322
3323     my $me = $self->current_source_alias;
3324
3325     return $self->search({
3326       "$me.modified" => $user->id,
3327     });
3328   }
3329
3330 =cut
3331
3332 sub current_source_alias {
3333   return (shift->{attrs} || {})->{alias} || 'me';
3334 }
3335
3336 =head2 as_subselect_rs
3337
3338 =over 4
3339
3340 =item Arguments: none
3341
3342 =item Return Value: L<$resultset|/search>
3343
3344 =back
3345
3346 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3347 "virtual view" by including it as a subquery within the from clause.  From this
3348 point on, any joined tables are inaccessible to ->search on the resultset (as if
3349 it were simply where-filtered without joins).  For example:
3350
3351  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3352
3353  # 'x' now pollutes the query namespace
3354
3355  # So the following works as expected
3356  my $ok_rs = $rs->search({'x.other' => 1});
3357
3358  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3359  # def) we look for one row with contradictory terms and join in another table
3360  # (aliased 'x_2') which we never use
3361  my $broken_rs = $rs->search({'x.name' => 'def'});
3362
3363  my $rs2 = $rs->as_subselect_rs;
3364
3365  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3366  my $not_joined_rs = $rs2->search({'x.other' => 1});
3367
3368  # works as expected: finds a 'table' row related to two x rows (abc and def)
3369  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3370
3371 Another example of when one might use this would be to select a subset of
3372 columns in a group by clause:
3373
3374  my $rs = $schema->resultset('Bar')->search(undef, {
3375    group_by => [qw{ id foo_id baz_id }],
3376  })->as_subselect_rs->search(undef, {
3377    columns => [qw{ id foo_id }]
3378  });
3379
3380 In the above example normally columns would have to be equal to the group by,
3381 but because we isolated the group by into a subselect the above works.
3382
3383 =cut
3384
3385 sub as_subselect_rs {
3386   my $self = shift;
3387
3388   my $attrs = $self->_resolved_attrs;
3389
3390   my $fresh_rs = (ref $self)->new (
3391     $self->result_source
3392   );
3393
3394   # these pieces will be locked in the subquery
3395   delete $fresh_rs->{cond};
3396   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3397
3398   return $fresh_rs->search( {}, {
3399     from => [{
3400       $attrs->{alias} => $self->as_query,
3401       -alias  => $attrs->{alias},
3402       -rsrc   => $self->result_source,
3403     }],
3404     alias => $attrs->{alias},
3405   });
3406 }
3407
3408 # This code is called by search_related, and makes sure there
3409 # is clear separation between the joins before, during, and
3410 # after the relationship. This information is needed later
3411 # in order to properly resolve prefetch aliases (any alias
3412 # with a relation_chain_depth less than the depth of the
3413 # current prefetch is not considered)
3414 #
3415 # The increments happen twice per join. An even number means a
3416 # relationship specified via a search_related, whereas an odd
3417 # number indicates a join/prefetch added via attributes
3418 #
3419 # Also this code will wrap the current resultset (the one we
3420 # chain to) in a subselect IFF it contains limiting attributes
3421 sub _chain_relationship {
3422   my ($self, $rel) = @_;
3423   my $source = $self->result_source;
3424   my $attrs = { %{$self->{attrs}||{}} };
3425
3426   # we need to take the prefetch the attrs into account before we
3427   # ->_resolve_join as otherwise they get lost - captainL
3428   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3429
3430   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3431
3432   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3433
3434   my $from;
3435   my @force_subq_attrs = qw/offset rows group_by having/;
3436
3437   if (
3438     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3439       ||
3440     $self->_has_resolved_attr (@force_subq_attrs)
3441   ) {
3442     # Nuke the prefetch (if any) before the new $rs attrs
3443     # are resolved (prefetch is useless - we are wrapping
3444     # a subquery anyway).
3445     my $rs_copy = $self->search;
3446     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3447       $rs_copy->{attrs}{join},
3448       delete $rs_copy->{attrs}{prefetch},
3449     );
3450
3451     $from = [{
3452       -rsrc   => $source,
3453       -alias  => $attrs->{alias},
3454       $attrs->{alias} => $rs_copy->as_query,
3455     }];
3456     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3457     $seen->{-relation_chain_depth} = 0;
3458   }
3459   elsif ($attrs->{from}) {  #shallow copy suffices
3460     $from = [ @{$attrs->{from}} ];
3461   }
3462   else {
3463     $from = [{
3464       -rsrc  => $source,
3465       -alias => $attrs->{alias},
3466       $attrs->{alias} => $source->from,
3467     }];
3468   }
3469
3470   my $jpath = ($seen->{-relation_chain_depth})
3471     ? $from->[-1][0]{-join_path}
3472     : [];
3473
3474   my @requested_joins = $source->_resolve_join(
3475     $join,
3476     $attrs->{alias},
3477     $seen,
3478     $jpath,
3479   );
3480
3481   push @$from, @requested_joins;
3482
3483   $seen->{-relation_chain_depth}++;
3484
3485   # if $self already had a join/prefetch specified on it, the requested
3486   # $rel might very well be already included. What we do in this case
3487   # is effectively a no-op (except that we bump up the chain_depth on
3488   # the join in question so we could tell it *is* the search_related)
3489   my $already_joined;
3490
3491   # we consider the last one thus reverse
3492   for my $j (reverse @requested_joins) {
3493     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3494     if ($rel eq $last_j) {
3495       $j->[0]{-relation_chain_depth}++;
3496       $already_joined++;
3497       last;
3498     }
3499   }
3500
3501   unless ($already_joined) {
3502     push @$from, $source->_resolve_join(
3503       $rel,
3504       $attrs->{alias},
3505       $seen,
3506       $jpath,
3507     );
3508   }
3509
3510   $seen->{-relation_chain_depth}++;
3511
3512   return {%$attrs, from => $from, seen_join => $seen};
3513 }
3514
3515 sub _resolved_attrs {
3516   my $self = shift;
3517   return $self->{_attrs} if $self->{_attrs};
3518
3519   my $attrs  = { %{ $self->{attrs} || {} } };
3520   my $source = $attrs->{result_source} = $self->result_source;
3521   my $alias  = $attrs->{alias};
3522
3523   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3524     if $attrs->{collapse} and $attrs->{distinct};
3525
3526   # default selection list
3527   $attrs->{columns} = [ $source->columns ]
3528     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3529
3530   # merge selectors together
3531   for (qw/columns select as/) {
3532     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3533       if $attrs->{$_} or $attrs->{"+$_"};
3534   }
3535
3536   # disassemble columns
3537   my (@sel, @as);
3538   if (my $cols = delete $attrs->{columns}) {
3539     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3540       if (ref $c eq 'HASH') {
3541         for my $as (sort keys %$c) {
3542           push @sel, $c->{$as};
3543           push @as, $as;
3544         }
3545       }
3546       else {
3547         push @sel, $c;
3548         push @as, $c;
3549       }
3550     }
3551   }
3552
3553   # when trying to weed off duplicates later do not go past this point -
3554   # everything added from here on is unbalanced "anyone's guess" stuff
3555   my $dedup_stop_idx = $#as;
3556
3557   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3558     if $attrs->{as};
3559   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3560     if $attrs->{select};
3561
3562   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3563   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3564
3565   # disqualify all $alias.col as-bits (inflate-map mandated)
3566   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3567
3568   # de-duplicate the result (remove *identical* select/as pairs)
3569   # and also die on duplicate {as} pointing to different {select}s
3570   # not using a c-style for as the condition is prone to shrinkage
3571   my $seen;
3572   my $i = 0;
3573   while ($i <= $dedup_stop_idx) {
3574     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3575       splice @sel, $i, 1;
3576       splice @as, $i, 1;
3577       $dedup_stop_idx--;
3578     }
3579     elsif ($seen->{$as[$i]}++) {
3580       $self->throw_exception(
3581         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3582       );
3583     }
3584     else {
3585       $i++;
3586     }
3587   }
3588
3589   $attrs->{select} = \@sel;
3590   $attrs->{as} = \@as;
3591
3592   $attrs->{from} ||= [{
3593     -rsrc   => $source,
3594     -alias  => $self->{attrs}{alias},
3595     $self->{attrs}{alias} => $source->from,
3596   }];
3597
3598   if ( $attrs->{join} || $attrs->{prefetch} ) {
3599
3600     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3601       if ref $attrs->{from} ne 'ARRAY';
3602
3603     my $join = (delete $attrs->{join}) || {};
3604
3605     if ( defined $attrs->{prefetch} ) {
3606       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3607     }
3608
3609     $attrs->{from} =    # have to copy here to avoid corrupting the original
3610       [
3611         @{ $attrs->{from} },
3612         $source->_resolve_join(
3613           $join,
3614           $alias,
3615           { %{ $attrs->{seen_join} || {} } },
3616           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3617             ? $attrs->{from}[-1][0]{-join_path}
3618             : []
3619           ,
3620         )
3621       ];
3622   }
3623
3624   if ( defined $attrs->{order_by} ) {
3625     $attrs->{order_by} = (
3626       ref( $attrs->{order_by} ) eq 'ARRAY'
3627       ? [ @{ $attrs->{order_by} } ]
3628       : [ $attrs->{order_by} || () ]
3629     );
3630   }
3631
3632   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3633     $attrs->{group_by} = [ $attrs->{group_by} ];
3634   }
3635
3636
3637   # generate selections based on the prefetch helper
3638   my ($prefetch, @prefetch_select, @prefetch_as);
3639   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3640     if defined $attrs->{prefetch};
3641
3642   if ($prefetch) {
3643
3644     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3645       if $attrs->{_dark_selector};
3646
3647     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3648       if defined $attrs->{collapse} and ! $attrs->{collapse};
3649
3650     $attrs->{collapse} = 1;
3651
3652     # this is a separate structure (we don't look in {from} directly)
3653     # as the resolver needs to shift things off the lists to work
3654     # properly (identical-prefetches on different branches)
3655     my $join_map = {};
3656     if (ref $attrs->{from} eq 'ARRAY') {
3657
3658       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3659
3660       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3661         next unless $j->[0]{-alias};
3662         next unless $j->[0]{-join_path};
3663         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3664
3665         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3666
3667         my $p = $join_map;
3668         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3669         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3670       }
3671     }
3672
3673     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3674
3675     # save these for after distinct resolution
3676     @prefetch_select = map { $_->[0] } @prefetch;
3677     @prefetch_as = map { $_->[1] } @prefetch;
3678   }
3679
3680   # run through the resulting joinstructure (starting from our current slot)
3681   # and unset collapse if proven unnecessary
3682   #
3683   # also while we are at it find out if the current root source has
3684   # been premultiplied by previous related_source chaining
3685   #
3686   # this allows to predict whether a root object with all other relation
3687   # data set to NULL is in fact unique
3688   if ($attrs->{collapse}) {
3689
3690     if (ref $attrs->{from} eq 'ARRAY') {
3691
3692       if (@{$attrs->{from}} == 1) {
3693         # no joins - no collapse
3694         $attrs->{collapse} = 0;
3695       }
3696       else {
3697         # find where our table-spec starts
3698         my @fromlist = @{$attrs->{from}};
3699         while (@fromlist) {
3700           my $t = shift @fromlist;
3701
3702           my $is_multi;
3703           # me vs join from-spec distinction - a ref means non-root
3704           if (ref $t eq 'ARRAY') {
3705             $t = $t->[0];
3706             $is_multi ||= ! $t->{-is_single};
3707           }
3708           last if ($t->{-alias} && $t->{-alias} eq $alias);
3709           $attrs->{_main_source_premultiplied} ||= $is_multi;
3710         }
3711
3712         # no non-singles remaining, nor any premultiplication - nothing to collapse
3713         if (
3714           ! $attrs->{_main_source_premultiplied}
3715             and
3716           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3717         ) {
3718           $attrs->{collapse} = 0;
3719         }
3720       }
3721     }
3722
3723     else {
3724       # if we can not analyze the from - err on the side of safety
3725       $attrs->{_main_source_premultiplied} = 1;
3726     }
3727   }
3728
3729   # generate the distinct induced group_by before injecting the prefetched select/as parts
3730   if (delete $attrs->{distinct}) {
3731     if ($attrs->{group_by}) {
3732       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3733     }
3734     else {
3735       $attrs->{_grouped_by_distinct} = 1;
3736       # distinct affects only the main selection part, not what prefetch may add below
3737       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3738
3739       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3740       # The thinking is: if we are collapsing the subquerying prefetch engine will
3741       # rip stuff apart for us anyway, and we do not want to have a potentially
3742       # function-converted external order_by
3743       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3744       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3745     }
3746   }
3747
3748   # inject prefetch-bound selection (if any)
3749   push @{$attrs->{select}}, @prefetch_select;
3750   push @{$attrs->{as}}, @prefetch_as;
3751
3752   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3753   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3754     $attrs->{_related_results_construction} = 1;
3755   }
3756
3757   # if both page and offset are specified, produce a combined offset
3758   # even though it doesn't make much sense, this is what pre 081xx has
3759   # been doing
3760   if (my $page = delete $attrs->{page}) {
3761     $attrs->{offset} =
3762       ($attrs->{rows} * ($page - 1))
3763             +
3764       ($attrs->{offset} || 0)
3765     ;
3766   }
3767
3768   return $self->{_attrs} = $attrs;
3769 }
3770
3771 sub _rollout_attr {
3772   my ($self, $attr) = @_;
3773
3774   if (ref $attr eq 'HASH') {
3775     return $self->_rollout_hash($attr);
3776   } elsif (ref $attr eq 'ARRAY') {
3777     return $self->_rollout_array($attr);
3778   } else {
3779     return [$attr];
3780   }
3781 }
3782
3783 sub _rollout_array {
3784   my ($self, $attr) = @_;
3785
3786   my @rolled_array;
3787   foreach my $element (@{$attr}) {
3788     if (ref $element eq 'HASH') {
3789       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3790     } elsif (ref $element eq 'ARRAY') {
3791       #  XXX - should probably recurse here
3792       push( @rolled_array, @{$self->_rollout_array($element)} );
3793     } else {
3794       push( @rolled_array, $element );
3795     }
3796   }
3797   return \@rolled_array;
3798 }
3799
3800 sub _rollout_hash {
3801   my ($self, $attr) = @_;
3802
3803   my @rolled_array;
3804   foreach my $key (keys %{$attr}) {
3805     push( @rolled_array, { $key => $attr->{$key} } );
3806   }
3807   return \@rolled_array;
3808 }
3809
3810 sub _calculate_score {
3811   my ($self, $a, $b) = @_;
3812
3813   if (defined $a xor defined $b) {
3814     return 0;
3815   }
3816   elsif (not defined $a) {
3817     return 1;
3818   }
3819
3820   if (ref $b eq 'HASH') {
3821     my ($b_key) = keys %{$b};
3822     if (ref $a eq 'HASH') {
3823       my ($a_key) = keys %{$a};
3824       if ($a_key eq $b_key) {
3825         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3826       } else {
3827         return 0;
3828       }
3829     } else {
3830       return ($a eq $b_key) ? 1 : 0;
3831     }
3832   } else {
3833     if (ref $a eq 'HASH') {
3834       my ($a_key) = keys %{$a};
3835       return ($b eq $a_key) ? 1 : 0;
3836     } else {
3837       return ($b eq $a) ? 1 : 0;
3838     }
3839   }
3840 }
3841
3842 sub _merge_joinpref_attr {
3843   my ($self, $orig, $import) = @_;
3844
3845   return $import unless defined($orig);
3846   return $orig unless defined($import);
3847
3848   $orig = $self->_rollout_attr($orig);
3849   $import = $self->_rollout_attr($import);
3850
3851   my $seen_keys;
3852   foreach my $import_element ( @{$import} ) {
3853     # find best candidate from $orig to merge $b_element into
3854     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3855     foreach my $orig_element ( @{$orig} ) {
3856       my $score = $self->_calculate_score( $orig_element, $import_element );
3857       if ($score > $best_candidate->{score}) {
3858         $best_candidate->{position} = $position;
3859         $best_candidate->{score} = $score;
3860       }
3861       $position++;
3862     }
3863     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3864     $import_key = '' if not defined $import_key;
3865
3866     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3867       push( @{$orig}, $import_element );
3868     } else {
3869       my $orig_best = $orig->[$best_candidate->{position}];
3870       # merge orig_best and b_element together and replace original with merged
3871       if (ref $orig_best ne 'HASH') {
3872         $orig->[$best_candidate->{position}] = $import_element;
3873       } elsif (ref $import_element eq 'HASH') {
3874         my ($key) = keys %{$orig_best};
3875         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3876       }
3877     }
3878     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3879   }
3880
3881   return @$orig ? $orig : ();
3882 }
3883
3884 {
3885   my $hm;
3886
3887   sub _merge_attr {
3888     $hm ||= do {
3889       require Hash::Merge;
3890       my $hm = Hash::Merge->new;
3891
3892       $hm->specify_behavior({
3893         SCALAR => {
3894           SCALAR => sub {
3895             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3896
3897             if ($defl xor $defr) {
3898               return [ $defl ? $_[0] : $_[1] ];
3899             }
3900             elsif (! $defl) {
3901               return [];
3902             }
3903             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3904               return [ $_[0] ];
3905             }
3906             else {
3907               return [$_[0], $_[1]];
3908             }
3909           },
3910           ARRAY => sub {
3911             return $_[1] if !defined $_[0];
3912             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3913             return [$_[0], @{$_[1]}]
3914           },
3915           HASH  => sub {
3916             return [] if !defined $_[0] and !keys %{$_[1]};
3917             return [ $_[1] ] if !defined $_[0];
3918             return [ $_[0] ] if !keys %{$_[1]};
3919             return [$_[0], $_[1]]
3920           },
3921         },
3922         ARRAY => {
3923           SCALAR => sub {
3924             return $_[0] if !defined $_[1];
3925             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3926             return [@{$_[0]}, $_[1]]
3927           },
3928           ARRAY => sub {
3929             my @ret = @{$_[0]} or return $_[1];
3930             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3931             my %idx = map { $_ => 1 } @ret;
3932             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3933             \@ret;
3934           },
3935           HASH => sub {
3936             return [ $_[1] ] if ! @{$_[0]};
3937             return $_[0] if !keys %{$_[1]};
3938             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3939             return [ @{$_[0]}, $_[1] ];
3940           },
3941         },
3942         HASH => {
3943           SCALAR => sub {
3944             return [] if !keys %{$_[0]} and !defined $_[1];
3945             return [ $_[0] ] if !defined $_[1];
3946             return [ $_[1] ] if !keys %{$_[0]};
3947             return [$_[0], $_[1]]
3948           },
3949           ARRAY => sub {
3950             return [] if !keys %{$_[0]} and !@{$_[1]};
3951             return [ $_[0] ] if !@{$_[1]};
3952             return $_[1] if !keys %{$_[0]};
3953             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3954             return [ $_[0], @{$_[1]} ];
3955           },
3956           HASH => sub {
3957             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3958             return [ $_[0] ] if !keys %{$_[1]};
3959             return [ $_[1] ] if !keys %{$_[0]};
3960             return [ $_[0] ] if $_[0] eq $_[1];
3961             return [ $_[0], $_[1] ];
3962           },
3963         }
3964       } => 'DBIC_RS_ATTR_MERGER');
3965       $hm;
3966     };
3967
3968     return $hm->merge ($_[1], $_[2]);
3969   }
3970 }
3971
3972 sub STORABLE_freeze {
3973   my ($self, $cloning) = @_;
3974   my $to_serialize = { %$self };
3975
3976   # A cursor in progress can't be serialized (and would make little sense anyway)
3977   # the parser can be regenerated (and can't be serialized)
3978   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3979
3980   # nor is it sensical to store a not-yet-fired-count pager
3981   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3982     delete $to_serialize->{pager};
3983   }
3984
3985   Storable::nfreeze($to_serialize);
3986 }
3987
3988 # need this hook for symmetry
3989 sub STORABLE_thaw {
3990   my ($self, $cloning, $serialized) = @_;
3991
3992   %$self = %{ Storable::thaw($serialized) };
3993
3994   $self;
3995 }
3996
3997
3998 =head2 throw_exception
3999
4000 See L<DBIx::Class::Schema/throw_exception> for details.
4001
4002 =cut
4003
4004 sub throw_exception {
4005   my $self=shift;
4006
4007   if (ref $self and my $rsrc = $self->result_source) {
4008     $rsrc->throw_exception(@_)
4009   }
4010   else {
4011     DBIx::Class::Exception->throw(@_);
4012   }
4013 }
4014
4015 1;
4016
4017 __END__
4018
4019 # XXX: FIXME: Attributes docs need clearing up
4020
4021 =head1 ATTRIBUTES
4022
4023 Attributes are used to refine a ResultSet in various ways when
4024 searching for data. They can be passed to any method which takes an
4025 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4026 L</count>.
4027
4028 Default attributes can be set on the result class using
4029 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4030 the CAVEATS on that feature before using it!)
4031
4032 These are in no particular order:
4033
4034 =head2 order_by
4035
4036 =over 4
4037
4038 =item Value: ( $order_by | \@order_by | \%order_by )
4039
4040 =back
4041
4042 Which column(s) to order the results by.
4043
4044 [The full list of suitable values is documented in
4045 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4046 common options.]
4047
4048 If a single column name, or an arrayref of names is supplied, the
4049 argument is passed through directly to SQL. The hashref syntax allows
4050 for connection-agnostic specification of ordering direction:
4051
4052  For descending order:
4053
4054   order_by => { -desc => [qw/col1 col2 col3/] }
4055
4056  For explicit ascending order:
4057
4058   order_by => { -asc => 'col' }
4059
4060 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4061 supported, although you are strongly encouraged to use the hashref
4062 syntax as outlined above.
4063
4064 =head2 columns
4065
4066 =over 4
4067
4068 =item Value: \@columns | \%columns | $column
4069
4070 =back
4071
4072 Shortcut to request a particular set of columns to be retrieved. Each
4073 column spec may be a string (a table column name), or a hash (in which
4074 case the key is the C<as> value, and the value is used as the C<select>
4075 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4076 it and sets C<select> from that, then auto-populates C<as> from
4077 C<select> as normal. (You may also use the C<cols> attribute, as in
4078 earlier versions of DBIC, but this is deprecated)
4079
4080 Essentially C<columns> does the same as L</select> and L</as>.
4081
4082     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4083
4084 is the same as
4085
4086     select => [qw(some_column another_column)],
4087     as     => [qw(some_column dbic_slot)]
4088
4089 If you want to individually retrieve related columns (in essence perform
4090 manual prefetch) you have to make sure to specify the correct inflation slot
4091 chain such that it matches existing relationships:
4092
4093     my $rs = $schema->resultset('Artist')->search({}, {
4094         # required to tell DBIC to collapse has_many relationships
4095         collapse => 1,
4096         join     => { cds => 'tracks'},
4097         '+columns'  => {
4098           'cds.cdid'         => 'cds.cdid',
4099           'cds.tracks.title' => 'tracks.title',
4100         },
4101     });
4102
4103 =head2 +columns
4104
4105 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4106 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4107 with a unary plus operator before it, which is the same as simply C<columns>.
4108
4109 =over 4
4110
4111 =item Value: \@extra_columns
4112
4113 =back
4114
4115 Indicates additional columns to be selected from storage. Works the same as
4116 L</columns> but adds columns to the current selection. (You may also use the
4117 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4118 deprecated)
4119
4120   $schema->resultset('CD')->search(undef, {
4121     '+columns' => ['artist.name'],
4122     join => ['artist']
4123   });
4124
4125 would return all CDs and include a 'name' column to the information
4126 passed to object inflation. Note that the 'artist' is the name of the
4127 column (or relationship) accessor, and 'name' is the name of the column
4128 accessor in the related table.
4129
4130 =head2 select
4131
4132 =over 4
4133
4134 =item Value: \@select_columns
4135
4136 =back
4137
4138 Indicates which columns should be selected from the storage. You can use
4139 column names, or in the case of RDBMS back ends, function or stored procedure
4140 names:
4141
4142   $rs = $schema->resultset('Employee')->search(undef, {
4143     select => [
4144       'name',
4145       { count => 'employeeid' },
4146       { max => { length => 'name' }, -as => 'longest_name' }
4147     ]
4148   });
4149
4150   # Equivalent SQL
4151   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4152
4153 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4154 use L</select>, to instruct DBIx::Class how to store the result of the column.
4155 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4156 identifier aliasing. You can however alias a function, so you can use it in
4157 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4158 attribute> supplied as shown in the example above.
4159
4160 =head2 +select
4161
4162 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4163 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4164 with a unary plus operator before it, which is the same as simply C<select>.
4165
4166 =over 4
4167
4168 =item Value: \@extra_select_columns
4169
4170 =back
4171
4172 Indicates additional columns to be selected from storage.  Works the same as
4173 L</select> but adds columns to the current selection, instead of specifying
4174 a new explicit list.
4175
4176 =head2 as
4177
4178 =over 4
4179
4180 =item Value: \@inflation_names
4181
4182 =back
4183
4184 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4185 slot name in which the column value will be stored within the
4186 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4187 identifier by the C<get_column> method (or via the object accessor B<if one
4188 with the same name already exists>) as shown below. The L</as> attribute has
4189 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4190
4191   $rs = $schema->resultset('Employee')->search(undef, {
4192     select => [
4193       'name',
4194       { count => 'employeeid' },
4195       { max => { length => 'name' }, -as => 'longest_name' }
4196     ],
4197     as => [qw/
4198       name
4199       employee_count
4200       max_name_length
4201     /],
4202   });
4203
4204 If the object against which the search is performed already has an accessor
4205 matching a column name specified in C<as>, the value can be retrieved using
4206 the accessor as normal:
4207
4208   my $name = $employee->name();
4209
4210 If on the other hand an accessor does not exist in the object, you need to
4211 use C<get_column> instead:
4212
4213   my $employee_count = $employee->get_column('employee_count');
4214
4215 You can create your own accessors if required - see
4216 L<DBIx::Class::Manual::Cookbook> for details.
4217
4218 =head2 +as
4219
4220 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4221 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4222 with a unary plus operator before it, which is the same as simply C<as>.
4223
4224 =over 4
4225
4226 =item Value: \@extra_inflation_names
4227
4228 =back
4229
4230 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4231
4232 =head2 join
4233
4234 =over 4
4235
4236 =item Value: ($rel_name | \@rel_names | \%rel_names)
4237
4238 =back
4239
4240 Contains a list of relationships that should be joined for this query.  For
4241 example:
4242
4243   # Get CDs by Nine Inch Nails
4244   my $rs = $schema->resultset('CD')->search(
4245     { 'artist.name' => 'Nine Inch Nails' },
4246     { join => 'artist' }
4247   );
4248
4249 Can also contain a hash reference to refer to the other relation's relations.
4250 For example:
4251
4252   package MyApp::Schema::Track;
4253   use base qw/DBIx::Class/;
4254   __PACKAGE__->table('track');
4255   __PACKAGE__->add_columns(qw/trackid cd position title/);
4256   __PACKAGE__->set_primary_key('trackid');
4257   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4258   1;
4259
4260   # In your application
4261   my $rs = $schema->resultset('Artist')->search(
4262     { 'track.title' => 'Teardrop' },
4263     {
4264       join     => { cd => 'track' },
4265       order_by => 'artist.name',
4266     }
4267   );
4268
4269 You need to use the relationship (not the table) name in  conditions,
4270 because they are aliased as such. The current table is aliased as "me", so
4271 you need to use me.column_name in order to avoid ambiguity. For example:
4272
4273   # Get CDs from 1984 with a 'Foo' track
4274   my $rs = $schema->resultset('CD')->search(
4275     {
4276       'me.year' => 1984,
4277       'tracks.name' => 'Foo'
4278     },
4279     { join => 'tracks' }
4280   );
4281
4282 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4283 similarly for a third time). For e.g.
4284
4285   my $rs = $schema->resultset('Artist')->search({
4286     'cds.title'   => 'Down to Earth',
4287     'cds_2.title' => 'Popular',
4288   }, {
4289     join => [ qw/cds cds/ ],
4290   });
4291
4292 will return a set of all artists that have both a cd with title 'Down
4293 to Earth' and a cd with title 'Popular'.
4294
4295 If you want to fetch related objects from other tables as well, see L</prefetch>
4296 below.
4297
4298  NOTE: An internal join-chain pruner will discard certain joins while
4299  constructing the actual SQL query, as long as the joins in question do not
4300  affect the retrieved result. This for example includes 1:1 left joins
4301  that are not part of the restriction specification (WHERE/HAVING) nor are
4302  a part of the query selection.
4303
4304 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4305
4306 =head2 collapse
4307
4308 =over 4
4309
4310 =item Value: (0 | 1)
4311
4312 =back
4313
4314 When set to a true value, indicates that any rows fetched from joined has_many
4315 relationships are to be aggregated into the corresponding "parent" object. For
4316 example, the resultset:
4317
4318   my $rs = $schema->resultset('CD')->search({}, {
4319     '+columns' => [ qw/ tracks.title tracks.position / ],
4320     join => 'tracks',
4321     collapse => 1,
4322   });
4323
4324 While executing the following query:
4325
4326   SELECT me.*, tracks.title, tracks.position
4327     FROM cd me
4328     LEFT JOIN track tracks
4329       ON tracks.cdid = me.cdid
4330
4331 Will return only as many objects as there are rows in the CD source, even
4332 though the result of the query may span many rows. Each of these CD objects
4333 will in turn have multiple "Track" objects hidden behind the has_many
4334 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4335 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4336 product"), with each CD object containing exactly one of all fetched Track data.
4337
4338 When a collapse is requested on a non-ordered resultset, an order by some
4339 unique part of the main source (the left-most table) is inserted automatically.
4340 This is done so that the resultset is allowed to be "lazy" - calling
4341 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4342 object with all of its related data.
4343
4344 If an L</order_by> is already declared, and orders the resultset in a way that
4345 makes collapsing as described above impossible (e.g. C<< ORDER BY
4346 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4347 switch to "eager" mode and slurp the entire resultset before constructing the
4348 first object returned by L</next>.
4349
4350 Setting this attribute on a resultset that does not join any has_many
4351 relations is a no-op.
4352
4353 For a more in-depth discussion, see L</PREFETCHING>.
4354
4355 =head2 prefetch
4356
4357 =over 4
4358
4359 =item Value: ($rel_name | \@rel_names | \%rel_names)
4360
4361 =back
4362
4363 This attribute is a shorthand for specifying a L</join> spec, adding all
4364 columns from the joined related sources as L</+columns> and setting
4365 L</collapse> to a true value. For example, the following two queries are
4366 equivalent:
4367
4368   my $rs = $schema->resultset('Artist')->search({}, {
4369     prefetch => { cds => ['genre', 'tracks' ] },
4370   });
4371
4372 and
4373
4374   my $rs = $schema->resultset('Artist')->search({}, {
4375     join => { cds => ['genre', 'tracks' ] },
4376     collapse => 1,
4377     '+columns' => [
4378       (map
4379         { +{ "cds.$_" => "cds.$_" } }
4380         $schema->source('Artist')->related_source('cds')->columns
4381       ),
4382       (map
4383         { +{ "cds.genre.$_" => "genre.$_" } }
4384         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4385       ),
4386       (map
4387         { +{ "cds.tracks.$_" => "tracks.$_" } }
4388         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4389       ),
4390     ],
4391   });
4392
4393 Both producing the following SQL:
4394
4395   SELECT  me.artistid, me.name, me.rank, me.charfield,
4396           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4397           genre.genreid, genre.name,
4398           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4399     FROM artist me
4400     LEFT JOIN cd cds
4401       ON cds.artist = me.artistid
4402     LEFT JOIN genre genre
4403       ON genre.genreid = cds.genreid
4404     LEFT JOIN track tracks
4405       ON tracks.cd = cds.cdid
4406   ORDER BY me.artistid
4407
4408 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4409 the arguments are properly merged and generally do the right thing. For
4410 example, you may want to do the following:
4411
4412   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4413     { 'genre.genreid' => undef },
4414     {
4415       join => { cds => 'genre' },
4416       prefetch => 'cds',
4417     }
4418   );
4419
4420 Which generates the following SQL:
4421
4422   SELECT  me.artistid, me.name, me.rank, me.charfield,
4423           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4424     FROM artist me
4425     LEFT JOIN cd cds
4426       ON cds.artist = me.artistid
4427     LEFT JOIN genre genre
4428       ON genre.genreid = cds.genreid
4429   WHERE genre.genreid IS NULL
4430   ORDER BY me.artistid
4431
4432 For a more in-depth discussion, see L</PREFETCHING>.
4433
4434 =head2 alias
4435
4436 =over 4
4437
4438 =item Value: $source_alias
4439
4440 =back
4441
4442 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4443 nested search queries (sub-SELECTs) might need specific aliases set to
4444 reference inner queries.  For example:
4445
4446    my $q = $rs
4447       ->related_resultset('CDs')
4448       ->related_resultset('Tracks')
4449       ->search({
4450          'track.id' => { -ident => 'none_search.id' },
4451       })
4452       ->as_query;
4453
4454    my $ids = $self->search({
4455       -not_exists => $q,
4456    }, {
4457       alias    => 'none_search',
4458       group_by => 'none_search.id',
4459    })->get_column('id')->as_query;
4460
4461    $self->search({ id => { -in => $ids } })
4462
4463 This attribute is directly tied to L</current_source_alias>.
4464
4465 =head2 page
4466
4467 =over 4
4468
4469 =item Value: $page
4470
4471 =back
4472
4473 Makes the resultset paged and specifies the page to retrieve. Effectively
4474 identical to creating a non-pages resultset and then calling ->page($page)
4475 on it.
4476
4477 If L</rows> attribute is not specified it defaults to 10 rows per page.
4478
4479 When you have a paged resultset, L</count> will only return the number
4480 of rows in the page. To get the total, use the L</pager> and call
4481 C<total_entries> on it.
4482
4483 =head2 rows
4484
4485 =over 4
4486
4487 =item Value: $rows
4488
4489 =back
4490
4491 Specifies the maximum number of rows for direct retrieval or the number of
4492 rows per page if the page attribute or method is used.
4493
4494 =head2 offset
4495
4496 =over 4
4497
4498 =item Value: $offset
4499
4500 =back
4501
4502 Specifies the (zero-based) row number for the  first row to be returned, or the
4503 of the first row of the first page if paging is used.
4504
4505 =head2 software_limit
4506
4507 =over 4
4508
4509 =item Value: (0 | 1)
4510
4511 =back
4512
4513 When combined with L</rows> and/or L</offset> the generated SQL will not
4514 include any limit dialect stanzas. Instead the entire result will be selected
4515 as if no limits were specified, and DBIC will perform the limit locally, by
4516 artificially advancing and finishing the resulting L</cursor>.
4517
4518 This is the recommended way of performing resultset limiting when no sane RDBMS
4519 implementation is available (e.g.
4520 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4521 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4522
4523 =head2 group_by
4524
4525 =over 4
4526
4527 =item Value: \@columns
4528
4529 =back
4530
4531 A arrayref of columns to group by. Can include columns of joined tables.
4532
4533   group_by => [qw/ column1 column2 ... /]
4534
4535 =head2 having
4536
4537 =over 4
4538
4539 =item Value: $condition
4540
4541 =back
4542
4543 HAVING is a select statement attribute that is applied between GROUP BY and
4544 ORDER BY. It is applied to the after the grouping calculations have been
4545 done.
4546
4547   having => { 'count_employee' => { '>=', 100 } }
4548
4549 or with an in-place function in which case literal SQL is required:
4550
4551   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4552
4553 =head2 distinct
4554
4555 =over 4
4556
4557 =item Value: (0 | 1)
4558
4559 =back
4560
4561 Set to 1 to automatically generate a L</group_by> clause based on the selection
4562 (including intelligent handling of L</order_by> contents). Note that the group
4563 criteria calculation takes place over the B<final> selection. This includes
4564 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4565 L</search> calls, and standalone columns selected via
4566 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4567 extra selections specified via L</prefetch> - such selections are explicitly
4568 excluded from group criteria calculations.
4569
4570 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4571 setting is ignored and an appropriate warning is issued.
4572
4573 =head2 where
4574
4575 =over 4
4576
4577 Adds to the WHERE clause.
4578
4579   # only return rows WHERE deleted IS NULL for all searches
4580   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4581
4582 Can be overridden by passing C<< { where => undef } >> as an attribute
4583 to a resultset.
4584
4585 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4586
4587 =back
4588
4589 =head2 cache
4590
4591 Set to 1 to cache search results. This prevents extra SQL queries if you
4592 revisit rows in your ResultSet:
4593
4594   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4595
4596   while( my $artist = $resultset->next ) {
4597     ... do stuff ...
4598   }
4599
4600   $rs->first; # without cache, this would issue a query
4601
4602 By default, searches are not cached.
4603
4604 For more examples of using these attributes, see
4605 L<DBIx::Class::Manual::Cookbook>.
4606
4607 =head2 for
4608
4609 =over 4
4610
4611 =item Value: ( 'update' | 'shared' | \$scalar )
4612
4613 =back
4614
4615 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4616 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4617 query.
4618
4619 =head1 PREFETCHING
4620
4621 DBIx::Class supports arbitrary related data prefetching from multiple related
4622 sources. Any combination of relationship types and column sets are supported.
4623 If L<collapsing|/collapse> is requested, there is an additional requirement of
4624 selecting enough data to make every individual object uniquely identifiable.
4625
4626 Here are some more involved examples, based on the following relationship map:
4627
4628   # Assuming:
4629   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4630   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4631   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4632
4633   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4634
4635   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4636
4637
4638
4639   my $rs = $schema->resultset('Tag')->search(
4640     undef,
4641     {
4642       prefetch => {
4643         cd => 'artist'
4644       }
4645     }
4646   );
4647
4648 The initial search results in SQL like the following:
4649
4650   SELECT tag.*, cd.*, artist.* FROM tag
4651   JOIN cd ON tag.cd = cd.cdid
4652   JOIN artist ON cd.artist = artist.artistid
4653
4654 L<DBIx::Class> has no need to go back to the database when we access the
4655 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4656 case.
4657
4658 Simple prefetches will be joined automatically, so there is no need
4659 for a C<join> attribute in the above search.
4660
4661 The L</prefetch> attribute can be used with any of the relationship types
4662 and multiple prefetches can be specified together. Below is a more complex
4663 example that prefetches a CD's artist, its liner notes (if present),
4664 the cover image, the tracks on that CD, and the guests on those
4665 tracks.
4666
4667   my $rs = $schema->resultset('CD')->search(
4668     undef,
4669     {
4670       prefetch => [
4671         { artist => 'record_label'},  # belongs_to => belongs_to
4672         'liner_note',                 # might_have
4673         'cover_image',                # has_one
4674         { tracks => 'guests' },       # has_many => has_many
4675       ]
4676     }
4677   );
4678
4679 This will produce SQL like the following:
4680
4681   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4682          tracks.*, guests.*
4683     FROM cd me
4684     JOIN artist artist
4685       ON artist.artistid = me.artistid
4686     JOIN record_label record_label
4687       ON record_label.labelid = artist.labelid
4688     LEFT JOIN track tracks
4689       ON tracks.cdid = me.cdid
4690     LEFT JOIN guest guests
4691       ON guests.trackid = track.trackid
4692     LEFT JOIN liner_notes liner_note
4693       ON liner_note.cdid = me.cdid
4694     JOIN cd_artwork cover_image
4695       ON cover_image.cdid = me.cdid
4696   ORDER BY tracks.cd
4697
4698 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4699 C<tracks>, and C<guests> of the CD will all be available through the
4700 relationship accessors without the need for additional queries to the
4701 database.
4702
4703 =head3 CAVEATS
4704
4705 Prefetch does a lot of deep magic. As such, it may not behave exactly
4706 as you might expect.
4707
4708 =over 4
4709
4710 =item *
4711
4712 Prefetch uses the L</cache> to populate the prefetched relationships. This
4713 may or may not be what you want.
4714
4715 =item *
4716
4717 If you specify a condition on a prefetched relationship, ONLY those
4718 rows that match the prefetched condition will be fetched into that relationship.
4719 This means that adding prefetch to a search() B<may alter> what is returned by
4720 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4721
4722   my $artist_rs = $schema->resultset('Artist')->search({
4723       'cds.year' => 2008,
4724   }, {
4725       join => 'cds',
4726   });
4727
4728   my $count = $artist_rs->first->cds->count;
4729
4730   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4731
4732   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4733
4734   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4735
4736 That cmp_ok() may or may not pass depending on the datasets involved. In other
4737 words the C<WHERE> condition would apply to the entire dataset, just like
4738 it would in regular SQL. If you want to add a condition only to the "right side"
4739 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4740 condition|DBIx::Class::Relationship::Base/condition>
4741
4742 =back
4743
4744 =head1 DBIC BIND VALUES
4745
4746 Because DBIC may need more information to bind values than just the column name
4747 and value itself, it uses a special format for both passing and receiving bind
4748 values.  Each bind value should be composed of an arrayref of
4749 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4750
4751 =over 4
4752
4753 =item dbd_attrs
4754
4755 If present (in any form), this is what is being passed directly to bind_param.
4756 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4757 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4758
4759 If this is specified, all other bind options described below are ignored.
4760
4761 =item sqlt_datatype
4762
4763 If present, this is used to infer the actual bind attribute by passing to
4764 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4765 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4766
4767 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4768 currently drivers are expected to "Do the Right Thing" when given a common
4769 datatype name.  (Not ideal, but that's what we got at this point.)
4770
4771 =item sqlt_size
4772
4773 Currently used to correctly allocate buffers for bind_param_inout().
4774 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4775 or to a sensible value based on the "data_type".
4776
4777 =item dbic_colname
4778
4779 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4780 explicitly specified they are never overridden).  Also used by some weird DBDs,
4781 where the column name should be available at bind_param time (e.g. Oracle).
4782
4783 =back
4784
4785 For backwards compatibility and convenience, the following shortcuts are
4786 supported:
4787
4788   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4789   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4790   [ undef,   $val ] === [ {}, $val ]
4791   $val              === [ {}, $val ]
4792
4793 =head1 AUTHOR AND CONTRIBUTORS
4794
4795 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4796
4797 =head1 LICENSE
4798
4799 You may distribute this code under the same terms as Perl itself.
4800