lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => 'count',
   7         fallback => 1;
   8 use Data::Page;
   9
  10 =head1 NAME
  11
  12 DBIX::Class::ResultSet - Responsible for fetching and creating resultset.
  13
  14 =head1 SYNOPSIS;
  15
  16 $rs=MyApp::DB::Class->search(registered=>1);
  17
  18 =head1 DESCRIPTION
  19
  20 The resultset is also known as an iterator.
  21
  22 =head1 METHODS
  23
  24 =over 4
  25
  26 =item new  <db_class> <attrs>
  27
  28 The resultset constructor. Takes a db class and an
  29 attribute hash (see below for more info on attributes)
  30
  31 =cut
  32
  33 sub new {
  34   my ($class, $db_class, $attrs) = @_;
  35   #use Data::Dumper; warn Dumper(@_);
  36   $class = ref $class if ref $class;
  37   $attrs = { %{ $attrs || {} } };
  38   my %seen;
  39   $attrs->{cols} ||= [ map { "me.$_" } $db_class->_select_columns ];
  40   $attrs->{from} ||= [ { 'me' => $db_class->_table_name } ];
  41   if ($attrs->{join}) {
  42     foreach my $j (ref $attrs->{join} eq 'ARRAY'
  43               ? (@{$attrs->{join}}) : ($attrs->{join})) {
  44       if (ref $j eq 'HASH') {
  45         $seen{$_} = 1 foreach keys %$j;
  46       } else {
  47         $seen{$j} = 1;
  48       }
  49     }
  50     push(@{$attrs->{from}}, $db_class->_resolve_join($attrs->{join}, 'me'));
  51   }
  52   foreach my $pre (@{$attrs->{prefetch} || []}) {
  53     push(@{$attrs->{from}}, $db_class->_resolve_join($pre, 'me'))
  54       unless $seen{$pre};
  55     push(@{$attrs->{cols}},
  56       map { "$pre.$_" }
  57       $db_class->_relationships->{$pre}->{class}->_select_columns);
  58   }
  59   my $new = {
  60     source => $db_class,
  61     cols => $attrs->{cols} || [ $db_class->_select_columns ],
  62     cond => $attrs->{where},
  63     from => $attrs->{from} || $db_class->_table_name,
  64     count => undef,
  65     pager => undef,
  66     attrs => $attrs };
  67   bless ($new, $class);
  68   $new->pager if ($attrs->{page});
  69   return $new;
  70 }
  71
  72 =item cursor
  73
  74 Return a storage driven cursor to the given resultset.
  75
  76 =cut
  77
  78 sub cursor {
  79   my ($self) = @_;
  80   my ($source, $attrs) = @{$self}{qw/source attrs/};
  81   if ($attrs->{page}) {
  82     $attrs->{rows} = $self->pager->entries_per_page;
  83     $attrs->{offset} = $self->pager->skipped;
  84   }
  85   return $self->{cursor}
  86     ||= $source->storage->select($self->{from}, $self->{cols},
  87           $attrs->{where},$attrs);
  88 }
  89
  90 =item slice <first> <last>
  91
  92 return a number of elements from the given resultset.
  93
  94 =cut
  95
  96 sub slice {
  97   my ($self, $min, $max) = @_;
  98   my $attrs = { %{ $self->{attrs} || {} } };
  99   $self->{source}->throw("Can't slice without where") unless $attrs->{where};
 100   $attrs->{offset} = $min;
 101   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 102   my $slice = $self->new($self->{source}, $attrs);
 103   return (wantarray ? $slice->all : $slice);
 104 }
 105
 106 =item next
 107
 108 Returns the next element in this resultset.
 109
 110 =cut
 111
 112 sub next {
 113   my ($self) = @_;
 114   my @row = $self->cursor->next;
 115   return unless (@row);
 116   return $self->_construct_object(@row);
 117 }
 118
 119 sub _construct_object {
 120   my ($self, @row) = @_;
 121   my @cols = @{ $self->{attrs}{cols} };
 122   s/^me\.// for @cols;
 123   @cols = grep { /\(/ or ! /\./ } @cols;
 124   my $new;
 125   unless ($self->{attrs}{prefetch}) {
 126     $new = $self->{source}->_row_to_object(\@cols, \@row);
 127   } else {
 128     my @main = splice(@row, 0, scalar @cols);
 129     $new = $self->{source}->_row_to_object(\@cols, \@main);
 130     PRE: foreach my $pre (@{$self->{attrs}{prefetch}}) {
 131       my $rel_obj = $self->{source}->_relationships->{$pre};
 132       my $pre_class = $self->{source}->resolve_class($rel_obj->{class});
 133       my @pre_cols = $pre_class->_select_columns;
 134       my @vals = splice(@row, 0, scalar @pre_cols);
 135       my $fetched = $pre_class->_row_to_object(\@pre_cols, \@vals);
 136       $self->{source}->throw("No accessor for prefetched $pre")
 137         unless defined $rel_obj->{attrs}{accessor};
 138       if ($rel_obj->{attrs}{accessor} eq 'single') {
 139         foreach my $pri ($rel_obj->{class}->primary_columns) {
 140           unless (defined $fetched->get_column($pri)) {
 141             undef $fetched;
 142             last;
 143           }
 144         }
 145         $new->{_relationship_data}{$pre} = $fetched;
 146       } elsif ($rel_obj->{attrs}{accessor} eq 'filter') {
 147         $new->{_inflated_column}{$pre} = $fetched;
 148       } else {
 149         $self->{source}->throw("Don't know how to store prefetched $pre");
 150       }
 151     }
 152   }
 153   $new = $self->{attrs}{record_filter}->($new)
 154     if exists $self->{attrs}{record_filter};
 155   return $new;
 156 }
 157
 158 =item count
 159
 160 Performs an SQL count with the same query as the resultset was built
 161 with to find the number of elements.
 162
 163 =cut
 164
 165
 166 sub count {
 167   my ($self) = @_;
 168   my $attrs = { %{ $self->{attrs} } };
 169   unless ($self->{count}) {
 170     # offset and order by are not needed to count
 171     delete $attrs->{$_} for qw/offset order_by/;
 172
 173     my @cols = 'COUNT(*)';
 174     $self->{count} = $self->{source}->storage->select_single(
 175         $self->{from}, \@cols, $self->{cond}, $attrs);
 176   }
 177   return 0 unless $self->{count};
 178   return $self->{pager}->entries_on_this_page if ($self->{pager});
 179   return ( $attrs->{rows} && $attrs->{rows} < $self->{count} )
 180     ? $attrs->{rows}
 181     : $self->{count};
 182 }
 183
 184 =item all
 185
 186 Returns all elements in the resultset. Is called implictly if the search
 187 method is used in list context.
 188
 189 =cut
 190
 191 sub all {
 192   my ($self) = @_;
 193   return map { $self->_construct_object(@$_); }
 194            $self->cursor->all;
 195 }
 196
 197 =item reset
 198
 199 Reset this resultset's cursor, so you can iterate through the elements again.
 200
 201 =cut
 202
 203 sub reset {
 204   my ($self) = @_;
 205   $self->cursor->reset;
 206   return $self;
 207 }
 208
 209 =item first
 210
 211 resets the resultset and returns the first element.
 212
 213 =cut
 214
 215 sub first {
 216   return $_[0]->reset->next;
 217 }
 218
 219 =item delete
 220
 221 Deletes all elements in the resultset.
 222
 223 =cut
 224
 225 sub delete {
 226   my ($self) = @_;
 227   $_->delete for $self->all;
 228   return 1;
 229 }
 230
 231 *delete_all = \&delete; # Yeah, yeah, yeah ...
 232
 233 =item pager
 234
 235 Returns a L<Data::Page> object for the current resultset. Only makes
 236 sense for queries with page turned on.
 237
 238 =cut
 239
 240 sub pager {
 241   my ($self) = @_;
 242   my $attrs = $self->{attrs};
 243   delete $attrs->{offset};
 244   my $rows_per_page = delete $attrs->{rows} || 10;
 245   $self->{pager} ||= Data::Page->new(
 246     $self->count, $rows_per_page, $attrs->{page} || 1);
 247   $attrs->{rows} = $rows_per_page;
 248   return $self->{pager};
 249 }
 250
 251 =item page <page>
 252
 253 Returns a new resultset representing a given page.
 254
 255 =cut
 256
 257 sub page {
 258   my ($self, $page) = @_;
 259   my $attrs = $self->{attrs};
 260   $attrs->{page} = $page;
 261   return $self->new($self->{source}, $attrs);
 262 }
 263
 264 =back
 265
 266 =head1 Attributes
 267
 268 The resultset is responsible for handling the various attributes that
 269 can be passed in with the search functions. Here's an overview of them:
 270
 271 =over 4
 272
 273 =item order_by
 274
 275 Which column to order the results by.
 276
 277 =item cols
 278
 279 Which cols should be retrieved on the first search.
 280
 281 =item join
 282
 283 Contains a list of relations that should be joined for this query. Can also
 284 contain a hash referece to refer to that relation's relations.
 285
 286 =item from
 287
 288 This attribute can contain a arrayref of  elements. each element can be another
 289 arrayref, to nest joins, or it can be a hash which represents the two sides
 290 of the join.
 291
 292 *NOTE* Use this on your own risk. This allows you to shoot your foot off!
 293
 294 =item page
 295
 296 Should the resultset be paged? This can also be enabled by using the
 297 'page' option.
 298
 299 =item rows
 300
 301 For paged resultsset, how  many rows per page
 302
 303 =item  offset
 304
 305 For paged resultsset, which page to start on.
 306
 307 =back
 308
 309 1;