lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'DBIx::Class';
   7 use mro 'c3';
   8
   9 use DBIx::Class::Carp;
  10 use DBIx::Class::ResultSetColumn;
  11 use DBIx::Class::ResultClass::HashRefInflator;
  12 use Scalar::Util qw( blessed reftype );
  13 use DBIx::Class::_Util qw(
  14   dbic_internal_try dump_value
  15   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  16 );
  17 use Try::Tiny;
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! grep { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     delete @{$old_attrs}{(@selector_attrs, '_dark_selector')}
 494       if grep { exists $call_attrs->{$_} } qw(columns cols select as);
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 sub _normalize_selection {
 557   my ($self, $attrs) = @_;
 558
 559   # legacy syntax
 560   if ( exists $attrs->{include_columns} ) {
 561     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 562     $attrs->{'+columns'} = $self->_merge_attr(
 563       $attrs->{'+columns'}, delete $attrs->{include_columns}
 564     );
 565   }
 566
 567   # columns are always placed first, however
 568
 569   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 570   # delay the decision on whether to use a default select list ($rsrc->columns)
 571   # allowing stuff like the remove_columns helper to work
 572   #
 573   # select/as +select/+as pairs need special handling - the amount of select/as
 574   # elements in each pair does *not* have to be equal (think multicolumn
 575   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 576   # supplied at all) - try to infer the alias, either from the -as parameter
 577   # of the selector spec, or use the parameter whole if it looks like a column
 578   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 579   # is ok as well), but make sure no more additions to the 'as' chain take place
 580   for my $pref ('', '+') {
 581
 582     my ($sel, $as) = map {
 583       my $key = "${pref}${_}";
 584
 585       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 586         ? @{$attrs->{$key}}
 587         : $attrs->{$key} || ()
 588       ];
 589       delete $attrs->{$key};
 590       $val;
 591     } qw/select as/;
 592
 593     if (! @$as and ! @$sel ) {
 594       next;
 595     }
 596     elsif (@$as and ! @$sel) {
 597       $self->throw_exception(
 598         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 599       );
 600     }
 601     elsif( ! @$as ) {
 602       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 603       # if any @$as has been supplied we assume the user knows what (s)he is doing
 604       # and blindly keep stacking up pieces
 605       unless ($attrs->{_dark_selector}) {
 606         SELECTOR:
 607         for (@$sel) {
 608           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 609             push @$as, $_->{-as};
 610           }
 611           # assume any plain no-space, no-parenthesis string to be a column spec
 612           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 613           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 614             push @$as, $_;
 615           }
 616           # if all else fails - raise a flag that no more aliasing will be allowed
 617           else {
 618             $attrs->{_dark_selector} = {
 619               plus_stage => $pref,
 620               string => do {
 621                 local $Data::Dumper::Indent = 0;
 622                 dump_value $_;
 623               },
 624             };
 625             last SELECTOR;
 626           }
 627         }
 628       }
 629     }
 630     elsif (@$as < @$sel) {
 631       $self->throw_exception(
 632         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 633       );
 634     }
 635     elsif ($pref and $attrs->{_dark_selector}) {
 636       $self->throw_exception(
 637         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 638       );
 639     }
 640
 641
 642     # merge result
 643     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 644     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 645   }
 646 }
 647
 648 sub _stack_cond {
 649   my ($self, $left, $right) = @_;
 650
 651   (
 652     (ref $_ eq 'ARRAY' and !@$_)
 653       or
 654     (ref $_ eq 'HASH' and ! keys %$_)
 655   ) and $_ = undef for ($left, $right);
 656
 657   # either one of the two undef
 658   if ( (defined $left) xor (defined $right) ) {
 659     return defined $left ? $left : $right;
 660   }
 661   # both undef
 662   elsif ( ! defined $left ) {
 663     return undef
 664   }
 665   else {
 666     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 667   }
 668 }
 669
 670 =head2 search_literal
 671
 672 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 673 should only be used in that context. C<search_literal> is a convenience
 674 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 675 want to ensure columns are bound correctly, use L</search>.
 676
 677 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 678 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 679 require C<search_literal>.
 680
 681 =over 4
 682
 683 =item Arguments: $sql_fragment, @standalone_bind_values
 684
 685 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 686
 687 =back
 688
 689   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 690   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 691
 692 Pass a literal chunk of SQL to be added to the conditional part of the
 693 resultset query.
 694
 695 Example of how to use C<search> instead of C<search_literal>
 696
 697   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 698   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 699
 700 =cut
 701
 702 sub search_literal {
 703   my ($self, $sql, @bind) = @_;
 704   my $attr;
 705   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 706     $attr = pop @bind;
 707   }
 708   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 709 }
 710
 711 =head2 find
 712
 713 =over 4
 714
 715 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 716
 717 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 718
 719 =back
 720
 721 Finds and returns a single row based on supplied criteria. Takes either a
 722 hashref with the same format as L</create> (including inference of foreign
 723 keys from related objects), or a list of primary key values in the same
 724 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 725 declaration on the L</result_source>.
 726
 727 In either case an attempt is made to combine conditions already existing on
 728 the resultset with the condition passed to this method.
 729
 730 To aid with preparing the correct query for the storage you may supply the
 731 C<key> attribute, which is the name of a
 732 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 733 unique constraint corresponding to the
 734 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 735 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 736 to construct a query that satisfies the named unique constraint fully (
 737 non-NULL values for each column member of the constraint) an exception is
 738 thrown.
 739
 740 If no C<key> is specified, the search is carried over all unique constraints
 741 which are fully defined by the available condition.
 742
 743 If no such constraint is found, C<find> currently defaults to a simple
 744 C<< search->(\%column_values) >> which may or may not do what you expect.
 745 Note that this fallback behavior may be deprecated in further versions. If
 746 you need to search with arbitrary conditions - use L</search>. If the query
 747 resulting from this fallback produces more than one row, a warning to the
 748 effect is issued, though only the first row is constructed and returned as
 749 C<$result_object>.
 750
 751 In addition to C<key>, L</find> recognizes and applies standard
 752 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 753
 754 Note that if you have extra concerns about the correctness of the resulting
 755 query you need to specify the C<key> attribute and supply the entire condition
 756 as an argument to find (since it is not always possible to perform the
 757 combination of the resultset condition with the supplied one, especially if
 758 the resultset condition contains literal sql).
 759
 760 For example, to find a row by its primary key:
 761
 762   my $cd = $schema->resultset('CD')->find(5);
 763
 764 You can also find a row by a specific unique constraint:
 765
 766   my $cd = $schema->resultset('CD')->find(
 767     {
 768       artist => 'Massive Attack',
 769       title  => 'Mezzanine',
 770     },
 771     { key => 'cd_artist_title' }
 772   );
 773
 774 See also L</find_or_create> and L</update_or_create>.
 775
 776 =cut
 777
 778 sub find {
 779   my $self = shift;
 780   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 781
 782   my $rsrc = $self->result_source;
 783
 784   my $constraint_name;
 785   if (exists $attrs->{key}) {
 786     $constraint_name = defined $attrs->{key}
 787       ? $attrs->{key}
 788       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 789     ;
 790   }
 791
 792   # Parse out the condition from input
 793   my $call_cond;
 794
 795   if (ref $_[0] eq 'HASH') {
 796     $call_cond = { %{$_[0]} };
 797   }
 798   else {
 799     # if only values are supplied we need to default to 'primary'
 800     $constraint_name = 'primary' unless defined $constraint_name;
 801
 802     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 803
 804     $self->throw_exception(
 805       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 806     ) unless @c_cols;
 807
 808     $self->throw_exception (
 809       'find() expects either a column/value hashref, or a list of values '
 810     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 811     ) unless @c_cols == @_;
 812
 813     @{$call_cond}{@c_cols} = @_;
 814   }
 815
 816   # process relationship data if any
 817   for my $key (keys %$call_cond) {
 818     if (
 819       length ref($call_cond->{$key})
 820         and
 821       my $relinfo = $rsrc->relationship_info($key)
 822         and
 823       # implicitly skip has_many's (likely MC)
 824       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 825     ) {
 826       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 827         $relinfo->{cond}, $val, $key, $key
 828       );
 829
 830       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 831          if $crosstable or ref($rel_cond) ne 'HASH';
 832
 833       # supplement condition
 834       # relationship conditions take precedence (?)
 835       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 836     }
 837   }
 838
 839   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 840   my $final_cond;
 841   if (defined $constraint_name) {
 842     $final_cond = $self->_qualify_cond_columns (
 843
 844       $rsrc->_minimal_valueset_satisfying_constraint(
 845         constraint_name => $constraint_name,
 846         values => ($self->_merge_with_rscond($call_cond))[0],
 847         carp_on_nulls => 1,
 848       ),
 849
 850       $alias,
 851     );
 852   }
 853   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 854     # This means that we got here after a merger of relationship conditions
 855     # in ::Relationship::Base::search_related (the row method), and furthermore
 856     # the relationship is of the 'single' type. This means that the condition
 857     # provided by the relationship (already attached to $self) is sufficient,
 858     # as there can be only one row in the database that would satisfy the
 859     # relationship
 860   }
 861   else {
 862     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 863
 864     # no key was specified - fall down to heuristics mode:
 865     # run through all unique queries registered on the resultset, and
 866     # 'OR' all qualifying queries together
 867     #
 868     # always start from 'primary' if it exists at all
 869     for my $c_name ( sort {
 870         $a eq 'primary' ? -1
 871       : $b eq 'primary' ? 1
 872       : $a cmp $b
 873     } $rsrc->unique_constraint_names) {
 874
 875       next if $seen_column_combinations{
 876         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 877       }++;
 878
 879       dbic_internal_try {
 880         push @unique_queries, $self->_qualify_cond_columns(
 881           $rsrc->_minimal_valueset_satisfying_constraint(
 882             constraint_name => $c_name,
 883             values => ($self->_merge_with_rscond($call_cond))[0],
 884             columns_info => ($ci ||= $rsrc->columns_info),
 885           ),
 886           $alias
 887         );
 888       }
 889       catch {
 890         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 891       };
 892     }
 893
 894     $final_cond =
 895         @unique_queries   ? \@unique_queries
 896       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 897       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 898     ;
 899   }
 900
 901   # Run the query, passing the result_class since it should propagate for find
 902   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 903   if ($rs->_resolved_attrs->{collapse}) {
 904     my $row = $rs->next;
 905     carp "Query returned more than one row" if $rs->next;
 906     return $row;
 907   }
 908   else {
 909     return $rs->single;
 910   }
 911 }
 912
 913 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 914 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 915 #
 916 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 917 # condition. It is provided for overrides until a saner way forward is devised
 918 #
 919 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 920 # the road. Please adjust your tests accordingly to catch this situation early
 921 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 922 #
 923 # The method will not be removed without an adequately complete replacement
 924 # for strict-mode enforcement
 925 sub _non_unique_find_fallback {
 926   my ($self, $cond, $attrs) = @_;
 927
 928   return $self->_qualify_cond_columns(
 929     $cond,
 930     exists $attrs->{alias}
 931       ? $attrs->{alias}
 932       : $self->{attrs}{alias}
 933   );
 934 }
 935
 936
 937 sub _qualify_cond_columns {
 938   my ($self, $cond, $alias) = @_;
 939
 940   my %aliased = %$cond;
 941   for (keys %aliased) {
 942     $aliased{"$alias.$_"} = delete $aliased{$_}
 943       if $_ !~ /\./;
 944   }
 945
 946   return \%aliased;
 947 }
 948
 949 sub _build_unique_cond {
 950   carp_unique sprintf
 951     '_build_unique_cond is a private method, and moreover is about to go '
 952   . 'away. Please contact the development team at %s if you believe you '
 953   . 'have a genuine use for this method, in order to discuss alternatives.',
 954     DBIx::Class::_ENV_::HELP_URL,
 955   ;
 956
 957   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 958
 959   $self->result_source->_minimal_valueset_satisfying_constraint(
 960     constraint_name => $constraint_name,
 961     values => $cond,
 962     carp_on_nulls => !$croak_on_null
 963   );
 964 }
 965
 966 =head2 search_related
 967
 968 =over 4
 969
 970 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 971
 972 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 973
 974 =back
 975
 976   $new_rs = $cd_rs->search_related('artist', {
 977     name => 'Emo-R-Us',
 978   });
 979
 980 Searches the specified relationship, optionally specifying a condition and
 981 attributes for matching records. See L</ATTRIBUTES> for more information.
 982
 983 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 984 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 985
 986 See also L</search_related_rs>.
 987
 988 =cut
 989
 990 sub search_related {
 991   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 992   return shift->related_resultset(shift)->search(@_);
 993 }
 994
 995 =head2 search_related_rs
 996
 997 This method works exactly the same as search_related, except that
 998 it guarantees a resultset, even in list context.
 999
1000 =cut
1001
1002 sub search_related_rs {
1003   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1004   return shift->related_resultset(shift)->search_rs(@_);
1005 }
1006
1007 =head2 cursor
1008
1009 =over 4
1010
1011 =item Arguments: none
1012
1013 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1014
1015 =back
1016
1017 Returns a storage-driven cursor to the given resultset. See
1018 L<DBIx::Class::Cursor> for more information.
1019
1020 =cut
1021
1022 sub cursor {
1023   my $self = shift;
1024
1025   return $self->{cursor} ||= do {
1026     my $attrs = $self->_resolved_attrs;
1027     $self->result_source->schema->storage->select(
1028       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1029     );
1030   };
1031 }
1032
1033 =head2 single
1034
1035 =over 4
1036
1037 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1038
1039 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1040
1041 =back
1042
1043   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1044
1045 Inflates the first result without creating a cursor if the resultset has
1046 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1047 of L</search>.
1048
1049 While this method can take an optional search condition (just like L</search>)
1050 being a fast-code-path it does not recognize search attributes. If you need to
1051 add extra joins or similar, call L</search> and then chain-call L</single> on the
1052 L<DBIx::Class::ResultSet> returned.
1053
1054 =over
1055
1056 =item B<Note>
1057
1058 As of 0.08100, this method enforces the assumption that the preceding
1059 query returns only one row. If more than one row is returned, you will receive
1060 a warning:
1061
1062   Query returned more than one row
1063
1064 In this case, you should be using L</next> or L</find> instead, or if you really
1065 know what you are doing, use the L</rows> attribute to explicitly limit the size
1066 of the resultset.
1067
1068 This method will also throw an exception if it is called on a resultset prefetching
1069 has_many, as such a prefetch implies fetching multiple rows from the database in
1070 order to assemble the resulting object.
1071
1072 =back
1073
1074 =cut
1075
1076 sub single {
1077   my ($self, $where) = @_;
1078   if(@_ > 2) {
1079       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1080   }
1081
1082   my $attrs = { %{$self->_resolved_attrs} };
1083
1084   $self->throw_exception(
1085     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1086   ) if $attrs->{collapse};
1087
1088   if ($where) {
1089     if (defined $attrs->{where}) {
1090       $attrs->{where} = {
1091         '-and' =>
1092             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1093                $where, delete $attrs->{where} ]
1094       };
1095     } else {
1096       $attrs->{where} = $where;
1097     }
1098   }
1099
1100   my $data = [ $self->result_source->schema->storage->select_single(
1101     $attrs->{from}, $attrs->{select},
1102     $attrs->{where}, $attrs
1103   )];
1104
1105   return undef unless @$data;
1106   $self->{_stashed_rows} = [ $data ];
1107   $self->_construct_results->[0];
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   DBIx::Class::ResultSetColumn->new(@_);
1128 }
1129
1130 =head2 search_like
1131
1132 =over 4
1133
1134 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1135
1136 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1137
1138 =back
1139
1140   # WHERE title LIKE '%blue%'
1141   $cd_rs = $rs->search_like({ title => '%blue%'});
1142
1143 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1144 that this is simply a convenience method retained for ex Class::DBI users.
1145 You most likely want to use L</search> with specific operators.
1146
1147 For more information, see L<DBIx::Class::Manual::Cookbook>.
1148
1149 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1150 instead. An example conversion is:
1151
1152   ->search_like({ foo => 'bar' });
1153
1154   # Becomes
1155
1156   ->search({ foo => { like => 'bar' } });
1157
1158 =cut
1159
1160 sub search_like {
1161   my $class = shift;
1162   carp_unique (
1163     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1164    .' Instead use ->search({ x => { -like => "y%" } })'
1165    .' (note the outer pair of {}s - they are important!)'
1166   );
1167   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1168   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1169   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1170   return $class->search($query, { %$attrs });
1171 }
1172
1173 =head2 slice
1174
1175 =over 4
1176
1177 =item Arguments: $first, $last
1178
1179 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1180
1181 =back
1182
1183 Returns a resultset or object list representing a subset of elements from the
1184 resultset slice is called on. Indexes are from 0, i.e., to get the first
1185 three records, call:
1186
1187   my ($one, $two, $three) = $rs->slice(0, 2);
1188
1189 =cut
1190
1191 sub slice {
1192   my ($self, $min, $max) = @_;
1193   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1194   $attrs->{offset} = $self->{attrs}{offset} || 0;
1195   $attrs->{offset} += $min;
1196   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1197   return $self->search(undef, $attrs);
1198 }
1199
1200 =head2 next
1201
1202 =over 4
1203
1204 =item Arguments: none
1205
1206 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1207
1208 =back
1209
1210 Returns the next element in the resultset (C<undef> is there is none).
1211
1212 Can be used to efficiently iterate over records in the resultset:
1213
1214   my $rs = $schema->resultset('CD')->search;
1215   while (my $cd = $rs->next) {
1216     print $cd->title;
1217   }
1218
1219 Note that you need to store the resultset object, and call C<next> on it.
1220 Calling C<< resultset('Table')->next >> repeatedly will always return the
1221 first record from the resultset.
1222
1223 =cut
1224
1225 sub next {
1226   my ($self) = @_;
1227
1228   if (my $cache = $self->get_cache) {
1229     $self->{all_cache_position} ||= 0;
1230     return $cache->[$self->{all_cache_position}++];
1231   }
1232
1233   if ($self->{attrs}{cache}) {
1234     delete $self->{pager};
1235     $self->{all_cache_position} = 1;
1236     return ($self->all)[0];
1237   }
1238
1239   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1240
1241   $self->{_stashed_results} = $self->_construct_results
1242     or return undef;
1243
1244   return shift @{$self->{_stashed_results}};
1245 }
1246
1247 # Constructs as many results as it can in one pass while respecting
1248 # cursor laziness. Several modes of operation:
1249 #
1250 # * Always builds everything present in @{$self->{_stashed_rows}}
1251 # * If called with $fetch_all true - pulls everything off the cursor and
1252 #   builds all result structures (or objects) in one pass
1253 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1254 #   and if the resultset is ordered properly by the left side:
1255 #   * Fetches stuff off the cursor until the "master object" changes,
1256 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1257 #   OR
1258 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1259 #     was requested (there is no other way to collapse except for an
1260 #     eager cursor)
1261 # * If no collapse is requested - just get the next row, construct and
1262 #   return
1263 sub _construct_results {
1264   my ($self, $fetch_all) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   my $attrs = $self->_resolved_attrs;
1268
1269   if (
1270     ! $fetch_all
1271       and
1272     ! $attrs->{order_by}
1273       and
1274     $attrs->{collapse}
1275       and
1276     my @pcols = $rsrc->primary_columns
1277   ) {
1278     # default order for collapsing unless the user asked for something
1279     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1280     $attrs->{_ordered_for_collapse} = 1;
1281     $attrs->{_order_is_artificial} = 1;
1282   }
1283
1284   # this will be used as both initial raw-row collector AND as a RV of
1285   # _construct_results. Not regrowing the array twice matters a lot...
1286   # a surprising amount actually
1287   my $rows = delete $self->{_stashed_rows};
1288
1289   my $cursor; # we may not need one at all
1290
1291   my $did_fetch_all = $fetch_all;
1292
1293   if ($fetch_all) {
1294     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1295     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1296   }
1297   elsif( $attrs->{collapse} ) {
1298
1299     # a cursor will need to be closed over in case of collapse
1300     $cursor = $self->cursor;
1301
1302     $attrs->{_ordered_for_collapse} = (
1303       (
1304         $attrs->{order_by}
1305           and
1306         $rsrc->schema
1307               ->storage
1308                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1309       ) ? 1 : 0
1310     ) unless defined $attrs->{_ordered_for_collapse};
1311
1312     if (! $attrs->{_ordered_for_collapse}) {
1313       $did_fetch_all = 1;
1314
1315       # instead of looping over ->next, use ->all in stealth mode
1316       # *without* calling a ->reset afterwards
1317       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1318       if (! $cursor->{_done}) {
1319         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1320         $cursor->{_done} = 1;
1321       }
1322     }
1323   }
1324
1325   if (! $did_fetch_all and ! @{$rows||[]} ) {
1326     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1327     $cursor ||= $self->cursor;
1328     if (scalar (my @r = $cursor->next) ) {
1329       $rows = [ \@r ];
1330     }
1331   }
1332
1333   return undef unless @{$rows||[]};
1334
1335   # sanity check - people are too clever for their own good
1336   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1337
1338     my $multiplied_selectors;
1339     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1340       if (
1341         $aliastypes->{multiplying}{$sel_alias}
1342           or
1343         $aliastypes->{premultiplied}{$sel_alias}
1344       ) {
1345         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1346       }
1347     }
1348
1349     for my $i (0 .. $#{$attrs->{as}} ) {
1350       my $sel = $attrs->{select}[$i];
1351
1352       if (ref $sel eq 'SCALAR') {
1353         $sel = $$sel;
1354       }
1355       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1356         $sel = $$sel->[0];
1357       }
1358
1359       $self->throw_exception(
1360         'Result collapse not possible - selection from a has_many source redirected to the main object'
1361       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1362     }
1363   }
1364
1365   # hotspot - skip the setter
1366   my $res_class = $self->_result_class;
1367
1368   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1369     $res_class->can ('inflate_result')
1370       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1371   };
1372
1373   my $infmap = $attrs->{as};
1374
1375   $self->{_result_inflator}{is_core_row} = ( (
1376     $inflator_cref
1377       ==
1378     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1379   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1380
1381   $self->{_result_inflator}{is_hri} = ( (
1382     ! $self->{_result_inflator}{is_core_row}
1383       and
1384     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1385   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1386
1387
1388   if ($attrs->{_simple_passthrough_construction}) {
1389     # construct a much simpler array->hash folder for the one-table HRI cases right here
1390     if ($self->{_result_inflator}{is_hri}) {
1391       for my $r (@$rows) {
1392         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1393       }
1394     }
1395     # FIXME SUBOPTIMAL this is a very very very hot spot
1396     # while rather optimal we can *still* do much better, by
1397     # building a smarter Row::inflate_result(), and
1398     # switch to feeding it data via a much leaner interface
1399     #
1400     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1401     # this particular resultset size
1402     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1403       for my $r (@$rows) {
1404         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1405       }
1406     }
1407     else {
1408       eval sprintf (
1409         ( $self->{_result_inflator}{is_core_row}
1410           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1411           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1412           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1413         ),
1414         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1415       ) . '; 1' or die;
1416     }
1417   }
1418   else {
1419     my $parser_type =
1420         $self->{_result_inflator}{is_hri}       ? 'hri'
1421       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1422       :                                           'classic_nonpruning'
1423     ;
1424
1425     unless( $self->{_row_parser}{$parser_type}{cref} ) {
1426
1427       # $args and $attrs to _mk_row_parser are separated to delineate what is
1428       # core collapser stuff and what is dbic $rs specific
1429       $self->{_row_parser}{$parser_type}{src} = $rsrc->_mk_row_parser({
1430         inflate_map => $infmap,
1431         collapse => $attrs->{collapse},
1432         premultiplied => $attrs->{_main_source_premultiplied},
1433         hri_style => $self->{_result_inflator}{is_hri},
1434         prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1435       }, $attrs);
1436
1437       $self->{_row_parser}{$parser_type}{cref} = do {
1438         package # hide form PAUSE
1439           DBIx::Class::__GENERATED_ROW_PARSER__;
1440
1441         eval $self->{_row_parser}{$parser_type}{src};
1442       } || die $@;
1443     }
1444
1445     # this needs to close over the *current* cursor, hence why it is not cached above
1446     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1447       ? undef
1448       : sub {
1449         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1450         my @r = $cursor->next or return;
1451         \@r
1452       }
1453     ;
1454
1455     $self->{_row_parser}{$parser_type}{cref}->(
1456       $rows,
1457       $next_cref,
1458       ( $self->{_stashed_rows} = [] ),
1459       ( my $null_violations = {} ),
1460     );
1461
1462     $self->throw_exception(
1463       'Collapse aborted - the following columns are declared (or defaulted to) '
1464     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1465     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1466     . ' within data row ' . dump_value({
1467       map {
1468         $infmap->[$_] =>
1469           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1470             ? $self->{_stashed_rows}[0][$_]
1471             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1472       } 0 .. $#{$self->{_stashed_rows}[0]}
1473     })
1474     ) if keys %$null_violations;
1475
1476     # simple in-place substitution, does not regrow $rows
1477     if ($self->{_result_inflator}{is_core_row}) {
1478       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1479     }
1480     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1481     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1482       # the inflator may be a multiplier/reductor - put it in list ctx
1483       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1484     }
1485   }
1486
1487   # The @$rows check seems odd at first - why wouldn't we want to warn
1488   # regardless? The issue is things like find() etc, where the user
1489   # *knows* only one result will come back. In these cases the ->all
1490   # is not a pessimization, but rather something we actually want
1491   carp_unique(
1492     'Unable to properly collapse has_many results in iterator mode due '
1493   . 'to order criteria - performed an eager cursor slurp underneath. '
1494   . 'Consider using ->all() instead'
1495   ) if ( ! $fetch_all and @$rows > 1 );
1496
1497   return $rows;
1498 }
1499
1500 =head2 result_source
1501
1502 =over 4
1503
1504 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1505
1506 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1507
1508 =back
1509
1510 An accessor for the primary ResultSource object from which this ResultSet
1511 is derived.
1512
1513 =head2 result_class
1514
1515 =over 4
1516
1517 =item Arguments: $result_class?
1518
1519 =item Return Value: $result_class
1520
1521 =back
1522
1523 An accessor for the class to use when creating result objects. Defaults to
1524 C<< result_source->result_class >> - which in most cases is the name of the
1525 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1526
1527 Note that changing the result_class will also remove any components
1528 that were originally loaded in the source class via
1529 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1530 Any overloaded methods in the original source class will not run.
1531
1532 =cut
1533
1534 sub result_class {
1535   my ($self, $result_class) = @_;
1536   if ($result_class) {
1537
1538     # don't fire this for an object
1539     $self->ensure_class_loaded($result_class)
1540       unless ref($result_class);
1541
1542     if ($self->get_cache) {
1543       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1544     }
1545     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1546     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1547       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1548     }
1549
1550     $self->_result_class($result_class);
1551
1552     delete $self->{_result_inflator};
1553   }
1554   $self->_result_class;
1555 }
1556
1557 =head2 count
1558
1559 =over 4
1560
1561 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1562
1563 =item Return Value: $count
1564
1565 =back
1566
1567 Performs an SQL C<COUNT> with the same query as the resultset was built
1568 with to find the number of elements. Passing arguments is equivalent to
1569 C<< $rs->search ($cond, \%attrs)->count >>
1570
1571 =cut
1572
1573 sub count {
1574   my $self = shift;
1575   return $self->search(@_)->count if @_ and defined $_[0];
1576   return scalar @{ $self->get_cache } if $self->get_cache;
1577
1578   my $attrs = { %{ $self->_resolved_attrs } };
1579
1580   # this is a little optimization - it is faster to do the limit
1581   # adjustments in software, instead of a subquery
1582   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1583
1584   my $crs;
1585   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1586     $crs = $self->_count_subq_rs ($attrs);
1587   }
1588   else {
1589     $crs = $self->_count_rs ($attrs);
1590   }
1591   my $count = $crs->next;
1592
1593   $count -= $offset if $offset;
1594   $count = $rows if $rows and $rows < $count;
1595   $count = 0 if ($count < 0);
1596
1597   return $count;
1598 }
1599
1600 =head2 count_rs
1601
1602 =over 4
1603
1604 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1605
1606 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1607
1608 =back
1609
1610 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1611 This can be very handy for subqueries:
1612
1613   ->search( { amount => $some_rs->count_rs->as_query } )
1614
1615 As with regular resultsets the SQL query will be executed only after
1616 the resultset is accessed via L</next> or L</all>. That would return
1617 the same single value obtainable via L</count>.
1618
1619 =cut
1620
1621 sub count_rs {
1622   my $self = shift;
1623   return $self->search(@_)->count_rs if @_;
1624
1625   # this may look like a lack of abstraction (count() does about the same)
1626   # but in fact an _rs *must* use a subquery for the limits, as the
1627   # software based limiting can not be ported if this $rs is to be used
1628   # in a subquery itself (i.e. ->as_query)
1629   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1630     return $self->_count_subq_rs($self->{_attrs});
1631   }
1632   else {
1633     return $self->_count_rs($self->{_attrs});
1634   }
1635 }
1636
1637 #
1638 # returns a ResultSetColumn object tied to the count query
1639 #
1640 sub _count_rs {
1641   my ($self, $attrs) = @_;
1642
1643   my $rsrc = $self->result_source;
1644
1645   my $tmp_attrs = { %$attrs };
1646   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1647   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1648
1649   # overwrite the selector (supplied by the storage)
1650   $rsrc->resultset_class->new($rsrc, {
1651     %$tmp_attrs,
1652     select => $rsrc->schema->storage->_count_select ($rsrc, $attrs),
1653     as => 'count',
1654   })->get_column ('count');
1655 }
1656
1657 #
1658 # same as above but uses a subquery
1659 #
1660 sub _count_subq_rs {
1661   my ($self, $attrs) = @_;
1662
1663   my $rsrc = $self->result_source;
1664
1665   my $sub_attrs = { %$attrs };
1666   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1667   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1668
1669   # if we multi-prefetch we group_by something unique, as this is what we would
1670   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1671   if ( $attrs->{collapse}  ) {
1672     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1673       $rsrc->_identifying_column_set || $self->throw_exception(
1674         'Unable to construct a unique group_by criteria properly collapsing the '
1675       . 'has_many prefetch before count()'
1676       );
1677     } ]
1678   }
1679
1680   # Calculate subquery selector
1681   if (my $g = $sub_attrs->{group_by}) {
1682
1683     my $sql_maker = $rsrc->schema->storage->sql_maker;
1684
1685     # necessary as the group_by may refer to aliased functions
1686     my $sel_index;
1687     for my $sel (@{$attrs->{select}}) {
1688       $sel_index->{$sel->{-as}} = $sel
1689         if (ref $sel eq 'HASH' and $sel->{-as});
1690     }
1691
1692     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1693     # also look for named aggregates referred in the having clause
1694     # having often contains scalarrefs - thus parse it out entirely
1695     my @parts = @$g;
1696     if ($attrs->{having}) {
1697       local $sql_maker->{having_bind};
1698       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1699       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1700       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1701         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1702         # if we don't unset it we screw up retarded but unfortunately working
1703         # 'MAX(foo.bar)' => { '>', 3 }
1704         $sql_maker->{name_sep} = '';
1705       }
1706
1707       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1708
1709       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1710       my %seen_having;
1711
1712       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1713       # and if all fails for an utterly naive quoted scalar-with-function
1714       while ($having_sql =~ /
1715         $rquote $sep $lquote (.+?) $rquote
1716           |
1717         [\s,] \w+ \. (\w+) [\s,]
1718           |
1719         [\s,] $lquote (.+?) $rquote [\s,]
1720       /gx) {
1721         my $part = $1 || $2 || $3;  # one of them matched if we got here
1722         unless ($seen_having{$part}++) {
1723           push @parts, $part;
1724         }
1725       }
1726     }
1727
1728     for (@parts) {
1729       my $colpiece = $sel_index->{$_} || $_;
1730
1731       # unqualify join-based group_by's. Arcane but possible query
1732       # also horrible horrible hack to alias a column (not a func.)
1733       # (probably need to introduce SQLA syntax)
1734       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1735         my $as = $colpiece;
1736         $as =~ s/\./__/;
1737         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1738       }
1739       push @{$sub_attrs->{select}}, $colpiece;
1740     }
1741   }
1742   else {
1743     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1744     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1745   }
1746
1747   return $rsrc->resultset_class
1748                ->new ($rsrc, $sub_attrs)
1749                 ->as_subselect_rs
1750                  ->search ({}, { columns => { count => $rsrc->schema->storage->_count_select ($rsrc, $attrs) } })
1751                   ->get_column ('count');
1752 }
1753
1754
1755 =head2 count_literal
1756
1757 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1758 should only be used in that context. See L</search_literal> for further info.
1759
1760 =over 4
1761
1762 =item Arguments: $sql_fragment, @standalone_bind_values
1763
1764 =item Return Value: $count
1765
1766 =back
1767
1768 Counts the results in a literal query. Equivalent to calling L</search_literal>
1769 with the passed arguments, then L</count>.
1770
1771 =cut
1772
1773 sub count_literal {
1774   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1775   shift->search_literal(@_)->count
1776 }
1777
1778 =head2 all
1779
1780 =over 4
1781
1782 =item Arguments: none
1783
1784 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1785
1786 =back
1787
1788 Returns all elements in the resultset.
1789
1790 =cut
1791
1792 sub all {
1793   my $self = shift;
1794   if(@_) {
1795     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1796   }
1797
1798   delete @{$self}{qw/_stashed_rows _stashed_results/};
1799
1800   if (my $c = $self->get_cache) {
1801     return @$c;
1802   }
1803
1804   $self->cursor->reset;
1805
1806   my $objs = $self->_construct_results('fetch_all') || [];
1807
1808   $self->set_cache($objs) if $self->{attrs}{cache};
1809
1810   return @$objs;
1811 }
1812
1813 =head2 reset
1814
1815 =over 4
1816
1817 =item Arguments: none
1818
1819 =item Return Value: $self
1820
1821 =back
1822
1823 Resets the resultset's cursor, so you can iterate through the elements again.
1824 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1825 another query.
1826
1827 =cut
1828
1829 sub reset {
1830   my ($self) = @_;
1831
1832   delete @{$self}{qw/_stashed_rows _stashed_results/};
1833   $self->{all_cache_position} = 0;
1834   $self->cursor->reset;
1835   return $self;
1836 }
1837
1838 =head2 first
1839
1840 =over 4
1841
1842 =item Arguments: none
1843
1844 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1845
1846 =back
1847
1848 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1849 an object for the first result (or C<undef> if the resultset is empty).
1850
1851 =cut
1852
1853 sub first {
1854   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1855   return $_[0]->reset->next;
1856 }
1857
1858
1859 # _rs_update_delete
1860 #
1861 # Determines whether and what type of subquery is required for the $rs operation.
1862 # If grouping is necessary either supplies its own, or verifies the current one
1863 # After all is done delegates to the proper storage method.
1864
1865 sub _rs_update_delete {
1866   my ($self, $op, $values) = @_;
1867
1868   my $rsrc = $self->result_source;
1869   my $storage = $rsrc->schema->storage;
1870
1871   my $attrs = { %{$self->_resolved_attrs} };
1872
1873   my $join_classifications;
1874   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1875
1876   # do we need a subquery for any reason?
1877   my $needs_subq = (
1878     defined $existing_group_by
1879       or
1880     # if {from} is unparseable wrap a subq
1881     ref($attrs->{from}) ne 'ARRAY'
1882       or
1883     # limits call for a subq
1884     $self->_has_resolved_attr(qw/rows offset/)
1885   );
1886
1887   # simplify the joinmap, so we can further decide if a subq is necessary
1888   if (!$needs_subq and @{$attrs->{from}} > 1) {
1889
1890     ($attrs->{from}, $join_classifications) =
1891       $storage->_prune_unused_joins ($attrs);
1892
1893     # any non-pruneable non-local restricting joins imply subq
1894     $needs_subq = grep { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1895   }
1896
1897   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1898   $needs_subq ||= (
1899     (ref $attrs->{from}[0]) ne 'HASH'
1900       or
1901     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1902   );
1903
1904   my ($cond, $guard);
1905   # do we need anything like a subquery?
1906   if (! $needs_subq) {
1907     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1908     # a condition containing 'me' or other table prefixes will not work
1909     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1910     $cond = do {
1911       my $sqla = $rsrc->schema->storage->sql_maker;
1912       local $sqla->{_dequalify_idents} = 1;
1913       \[ $sqla->_recurse_where($self->{cond}) ];
1914     };
1915   }
1916   else {
1917     # we got this far - means it is time to wrap a subquery
1918     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1919       sprintf(
1920         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1921         $op,
1922         $rsrc->source_name,
1923       )
1924     );
1925
1926     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1927     delete $attrs->{$_} for qw/select as collapse/;
1928     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1929
1930     # this will be consumed by the pruner waaaaay down the stack
1931     $attrs->{_force_prune_multiplying_joins} = 1;
1932
1933     my $subrs = (ref $self)->new($rsrc, $attrs);
1934
1935     if (@$idcols == 1) {
1936       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1937     }
1938     elsif ($storage->_use_multicolumn_in) {
1939       # no syntax for calling this properly yet
1940       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1941       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1942         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1943         $subrs->as_query
1944       ),
1945     }
1946     else {
1947       # if all else fails - get all primary keys and operate over a ORed set
1948       # wrap in a transaction for consistency
1949       # this is where the group_by/multiplication starts to matter
1950       if (
1951         $existing_group_by
1952           or
1953         # we do not need to check pre-multipliers, since if the premulti is there, its
1954         # parent (who is multi) will be there too
1955         keys %{ $join_classifications->{multiplying} || {} }
1956       ) {
1957         # make sure if there is a supplied group_by it matches the columns compiled above
1958         # perfectly. Anything else can not be sanely executed on most databases so croak
1959         # right then and there
1960         if ($existing_group_by) {
1961           my @current_group_by = map
1962             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1963             @$existing_group_by
1964           ;
1965
1966           if (
1967             join ("\x00", sort @current_group_by)
1968               ne
1969             join ("\x00", sort @{$attrs->{columns}} )
1970           ) {
1971             $self->throw_exception (
1972               "You have just attempted a $op operation on a resultset which does group_by"
1973               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1974               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1975               . ' kind of queries. Please retry the operation with a modified group_by or'
1976               . ' without using one at all.'
1977             );
1978           }
1979         }
1980
1981         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1982       }
1983
1984       $guard = $storage->txn_scope_guard;
1985
1986       for my $row ($subrs->cursor->all) {
1987         push @$cond, { map
1988           { $idcols->[$_] => $row->[$_] }
1989           (0 .. $#$idcols)
1990         };
1991       }
1992     }
1993   }
1994
1995   my $res = $cond ? $storage->$op (
1996     $rsrc,
1997     $op eq 'update' ? $values : (),
1998     $cond,
1999   ) : '0E0';
2000
2001   $guard->commit if $guard;
2002
2003   return $res;
2004 }
2005
2006 =head2 update
2007
2008 =over 4
2009
2010 =item Arguments: \%values
2011
2012 =item Return Value: $underlying_storage_rv
2013
2014 =back
2015
2016 Sets the specified columns in the resultset to the supplied values in a
2017 single query. Note that this will not run any accessor/set_column/update
2018 triggers, nor will it update any result object instances derived from this
2019 resultset (this includes the contents of the L<resultset cache|/set_cache>
2020 if any). See L</update_all> if you need to execute any on-update
2021 triggers or cascades defined either by you or a
2022 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2023
2024 The return value is a pass through of what the underlying
2025 storage backend returned, and may vary. See L<DBI/execute> for the most
2026 common case.
2027
2028 =head3 CAVEAT
2029
2030 Note that L</update> does not process/deflate any of the values passed in.
2031 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2032 ensure manually that any value passed to this method will stringify to
2033 something the RDBMS knows how to deal with. A notable example is the
2034 handling of L<DateTime> objects, for more info see:
2035 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2036
2037 =cut
2038
2039 sub update {
2040   my ($self, $values) = @_;
2041   $self->throw_exception('Values for update must be a hash')
2042     unless ref $values eq 'HASH';
2043
2044   return $self->_rs_update_delete ('update', $values);
2045 }
2046
2047 =head2 update_all
2048
2049 =over 4
2050
2051 =item Arguments: \%values
2052
2053 =item Return Value: 1
2054
2055 =back
2056
2057 Fetches all objects and updates them one at a time via
2058 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2059 triggers, while L</update> will not.
2060
2061 =cut
2062
2063 sub update_all {
2064   my ($self, $values) = @_;
2065   $self->throw_exception('Values for update_all must be a hash')
2066     unless ref $values eq 'HASH';
2067
2068   my $guard = $self->result_source->schema->txn_scope_guard;
2069   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2070   $guard->commit;
2071   return 1;
2072 }
2073
2074 =head2 delete
2075
2076 =over 4
2077
2078 =item Arguments: none
2079
2080 =item Return Value: $underlying_storage_rv
2081
2082 =back
2083
2084 Deletes the rows matching this resultset in a single query. Note that this
2085 will not run any delete triggers, nor will it alter the
2086 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2087 derived from this resultset (this includes the contents of the
2088 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2089 execute any on-delete triggers or cascades defined either by you or a
2090 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2091
2092 The return value is a pass through of what the underlying storage backend
2093 returned, and may vary. See L<DBI/execute> for the most common case.
2094
2095 =cut
2096
2097 sub delete {
2098   my $self = shift;
2099   $self->throw_exception('delete does not accept any arguments')
2100     if @_;
2101
2102   return $self->_rs_update_delete ('delete');
2103 }
2104
2105 =head2 delete_all
2106
2107 =over 4
2108
2109 =item Arguments: none
2110
2111 =item Return Value: 1
2112
2113 =back
2114
2115 Fetches all objects and deletes them one at a time via
2116 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2117 triggers, while L</delete> will not.
2118
2119 =cut
2120
2121 sub delete_all {
2122   my $self = shift;
2123   $self->throw_exception('delete_all does not accept any arguments')
2124     if @_;
2125
2126   my $guard = $self->result_source->schema->txn_scope_guard;
2127   $_->delete for $self->all;
2128   $guard->commit;
2129   return 1;
2130 }
2131
2132 =head2 populate
2133
2134 =over 4
2135
2136 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2137
2138 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2139
2140 =back
2141
2142 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2143 arrayrefs.
2144
2145 =over
2146
2147 =item NOTE
2148
2149 The context of this method call has an important effect on what is
2150 submitted to storage. In void context data is fed directly to fastpath
2151 insertion routines provided by the underlying storage (most often
2152 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2153 L<insert|DBIx::Class::Row/insert> calls on the
2154 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2155 augmentation of these methods provided by components. For example if you
2156 are using something like L<DBIx::Class::UUIDColumns> to create primary
2157 keys for you, you will find that your PKs are empty.  In this case you
2158 will have to explicitly force scalar or list context in order to create
2159 those values.
2160
2161 =back
2162
2163 In non-void (scalar or list) context, this method is simply a wrapper
2164 for L</create>. Depending on list or scalar context either a list of
2165 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2166 containing these objects is returned.
2167
2168 When supplying data in "arrayref of arrayrefs" invocation style, the
2169 first element should be a list of column names and each subsequent
2170 element should be a data value in the earlier specified column order.
2171 For example:
2172
2173   $schema->resultset("Artist")->populate([
2174     [ qw( artistid name ) ],
2175     [ 100, 'A Formally Unknown Singer' ],
2176     [ 101, 'A singer that jumped the shark two albums ago' ],
2177     [ 102, 'An actually cool singer' ],
2178   ]);
2179
2180 For the arrayref of hashrefs style each hashref should be a structure
2181 suitable for passing to L</create>. Multi-create is also permitted with
2182 this syntax.
2183
2184   $schema->resultset("Artist")->populate([
2185      { artistid => 4, name => 'Manufactured Crap', cds => [
2186         { title => 'My First CD', year => 2006 },
2187         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2188       ],
2189      },
2190      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2191         { title => 'My parents sold me to a record company', year => 2005 },
2192         { title => 'Why Am I So Ugly?', year => 2006 },
2193         { title => 'I Got Surgery and am now Popular', year => 2007 }
2194       ],
2195      },
2196   ]);
2197
2198 If you attempt a void-context multi-create as in the example above (each
2199 Artist also has the related list of CDs), and B<do not> supply the
2200 necessary autoinc foreign key information, this method will proxy to the
2201 less efficient L</create>, and then throw the Result objects away. In this
2202 case there are obviously no benefits to using this method over L</create>.
2203
2204 =cut
2205
2206 sub populate {
2207   my $self = shift;
2208
2209   # this is naive and just a quick check
2210   # the types will need to be checked more thoroughly when the
2211   # multi-source populate gets added
2212   my $data = (
2213     ref $_[0] eq 'ARRAY'
2214       and
2215     ( @{$_[0]} or return )
2216       and
2217     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2218       and
2219     $_[0]
2220   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2221
2222   # FIXME - no cref handling
2223   # At this point assume either hashes or arrays
2224
2225   my $rsrc = $self->result_source;
2226
2227   if(defined wantarray) {
2228     my (@results, $guard);
2229
2230     if (ref $data->[0] eq 'ARRAY') {
2231       # column names only, nothing to do
2232       return if @$data == 1;
2233
2234       $guard = $rsrc->schema->storage->txn_scope_guard
2235         if @$data > 2;
2236
2237       @results = map
2238         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2239         @{$data}[1 .. $#$data]
2240       ;
2241     }
2242     else {
2243
2244       $guard = $rsrc->schema->storage->txn_scope_guard
2245         if @$data > 1;
2246
2247       @results = map { $self->new_result($_)->insert } @$data;
2248     }
2249
2250     $guard->commit if $guard;
2251     return wantarray ? @results : \@results;
2252   }
2253
2254   # we have to deal with *possibly incomplete* related data
2255   # this means we have to walk the data structure twice
2256   # whether we want this or not
2257   # jnap, I hate you ;)
2258   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2259
2260   my ($colinfo, $colnames, $slices_with_rels);
2261   my $data_start = 0;
2262
2263   DATA_SLICE:
2264   for my $i (0 .. $#$data) {
2265
2266     my $current_slice_seen_rel_infos;
2267
2268 ### Determine/Supplement collists
2269 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2270     if( ref $data->[$i] eq 'ARRAY' ) {
2271
2272       # positional(!) explicit column list
2273       if ($i == 0) {
2274         # column names only, nothing to do
2275         return if @$data == 1;
2276
2277         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2278           for 0 .. $#{$data->[0]};
2279
2280         $data_start = 1;
2281
2282         next DATA_SLICE;
2283       }
2284       else {
2285         for (values %$colinfo) {
2286           if ($_->{is_rel} ||= (
2287             $rel_info->{$_->{name}}
2288               and
2289             (
2290               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2291                 or
2292               ref $data->[$i][$_->{pos}] eq 'HASH'
2293                 or
2294               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2295             )
2296               and
2297             1
2298           )) {
2299
2300             # moar sanity check... sigh
2301             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2302               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2303                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2304                 return my $throwaway = $self->populate(@_);
2305               }
2306             }
2307
2308             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2309           }
2310         }
2311       }
2312
2313      if ($current_slice_seen_rel_infos) {
2314         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2315
2316         # this is needed further down to decide whether or not to fallback to create()
2317         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2318           for 0 .. $#$colnames;
2319       }
2320     }
2321     elsif( ref $data->[$i] eq 'HASH' ) {
2322
2323       for ( sort keys %{$data->[$i]} ) {
2324
2325         $colinfo->{$_} ||= do {
2326
2327           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2328             if $data_start; # it will be 0 on AoH, 1 on AoA
2329
2330           push @$colnames, $_;
2331
2332           # RV
2333           { pos => $#$colnames, name => $_ }
2334         };
2335
2336         if ($colinfo->{$_}{is_rel} ||= (
2337           $rel_info->{$_}
2338             and
2339           (
2340             ref $data->[$i]{$_} eq 'ARRAY'
2341               or
2342             ref $data->[$i]{$_} eq 'HASH'
2343               or
2344             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2345           )
2346             and
2347           1
2348         )) {
2349
2350           # moar sanity check... sigh
2351           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2352             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2353               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2354               return my $throwaway = $self->populate(@_);
2355             }
2356           }
2357
2358           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2359         }
2360       }
2361
2362       if ($current_slice_seen_rel_infos) {
2363         push @$slices_with_rels, $data->[$i];
2364
2365         # this is needed further down to decide whether or not to fallback to create()
2366         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2367           for keys %{$data->[$i]};
2368       }
2369     }
2370     else {
2371       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2372     }
2373
2374     if ( grep
2375       { $_->{attrs}{is_depends_on} }
2376       @{ $current_slice_seen_rel_infos || [] }
2377     ) {
2378       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2379       return my $throwaway = $self->populate(@_);
2380     }
2381   }
2382
2383   if( $slices_with_rels ) {
2384
2385     # need to exclude the rel "columns"
2386     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2387
2388     # extra sanity check - ensure the main source is in fact identifiable
2389     # the localizing of nullability is insane, but oh well... the use-case is legit
2390     my $ci = $rsrc->columns_info($colnames);
2391
2392     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2393       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2394
2395     unless( $rsrc->_identifying_column_set($ci) ) {
2396       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2397       return my $throwaway = $self->populate(@_);
2398     }
2399   }
2400
2401 ### inherit the data locked in the conditions of the resultset
2402   my ($rs_data) = $self->_merge_with_rscond({});
2403   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2404
2405   # if anything left - decompose rs_data
2406   my $rs_data_vals;
2407   if (keys %$rs_data) {
2408      push @$rs_data_vals, $rs_data->{$_}
2409       for sort keys %$rs_data;
2410   }
2411
2412 ### start work
2413   my $guard;
2414   $guard = $rsrc->schema->storage->txn_scope_guard
2415     if $slices_with_rels;
2416
2417 ### main source data
2418   # FIXME - need to switch entirely to a coderef-based thing,
2419   # so that large sets aren't copied several times... I think
2420   $rsrc->schema->storage->_insert_bulk(
2421     $rsrc,
2422     [ @$colnames, sort keys %$rs_data ],
2423     [ map {
2424       ref $data->[$_] eq 'ARRAY'
2425       ? (
2426           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2427         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2428         :                     $data->[$_]
2429       )
2430       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2431     } $data_start .. $#$data ],
2432   );
2433
2434 ### do the children relationships
2435   if ( $slices_with_rels ) {
2436     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2437       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2438
2439     for my $sl (@$slices_with_rels) {
2440
2441       my ($main_proto, $main_proto_rs);
2442       for my $rel (@rels) {
2443         next unless defined $sl->{$rel};
2444
2445         $main_proto ||= {
2446           %$rs_data,
2447           (map { $_ => $sl->{$_} } @$colnames),
2448         };
2449
2450         unless (defined $colinfo->{$rel}{rs}) {
2451
2452           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2453
2454           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2455             rel_name => $rel,
2456             self_alias => "\xFE", # irrelevant
2457             foreign_alias => "\xFF", # irrelevant
2458           )->{identity_map} || {} } };
2459
2460         }
2461
2462         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2463           {
2464             $_ => { '=' =>
2465               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2466                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2467                  ->as_query
2468             }
2469           }
2470           keys %{$colinfo->{$rel}{fk_map}}
2471         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2472
2473         1;
2474       }
2475     }
2476   }
2477
2478   $guard->commit if $guard;
2479 }
2480
2481 =head2 pager
2482
2483 =over 4
2484
2485 =item Arguments: none
2486
2487 =item Return Value: L<$pager|Data::Page>
2488
2489 =back
2490
2491 Returns a L<Data::Page> object for the current resultset. Only makes
2492 sense for queries with a C<page> attribute.
2493
2494 To get the full count of entries for a paged resultset, call
2495 C<total_entries> on the L<Data::Page> object.
2496
2497 =cut
2498
2499 sub pager {
2500   my ($self) = @_;
2501
2502   return $self->{pager} if $self->{pager};
2503
2504   my $attrs = $self->{attrs};
2505   if (!defined $attrs->{page}) {
2506     $self->throw_exception("Can't create pager for non-paged rs");
2507   }
2508   elsif ($attrs->{page} <= 0) {
2509     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2510   }
2511   $attrs->{rows} ||= 10;
2512
2513   # throw away the paging flags and re-run the count (possibly
2514   # with a subselect) to get the real total count
2515   my $count_attrs = { %$attrs };
2516   delete @{$count_attrs}{qw/rows offset page pager/};
2517
2518   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2519
2520   require DBIx::Class::ResultSet::Pager;
2521   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2522     sub { $total_rs->count },  #lazy-get the total
2523     $attrs->{rows},
2524     $self->{attrs}{page},
2525   );
2526 }
2527
2528 =head2 page
2529
2530 =over 4
2531
2532 =item Arguments: $page_number
2533
2534 =item Return Value: L<$resultset|/search>
2535
2536 =back
2537
2538 Returns a resultset for the $page_number page of the resultset on which page
2539 is called, where each page contains a number of rows equal to the 'rows'
2540 attribute set on the resultset (10 by default).
2541
2542 =cut
2543
2544 sub page {
2545   my ($self, $page) = @_;
2546   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2547 }
2548
2549 =head2 new_result
2550
2551 =over 4
2552
2553 =item Arguments: \%col_data
2554
2555 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2556
2557 =back
2558
2559 Creates a new result object in the resultset's result class and returns
2560 it. The row is not inserted into the database at this point, call
2561 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2562 will tell you whether the result object has been inserted or not.
2563
2564 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2565
2566 =cut
2567
2568 sub new_result {
2569   my ($self, $values) = @_;
2570
2571   $self->throw_exception( "Result object instantiation requires a single hashref argument" )
2572     if @_ > 2 or ref $values ne 'HASH';
2573
2574   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2575
2576   my $new = $self->result_class->new({
2577     %$merged_cond,
2578     ( @$cols_from_relations
2579       ? (-cols_from_relations => $cols_from_relations)
2580       : ()
2581     ),
2582     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2583   });
2584
2585   if (
2586     reftype($new) eq 'HASH'
2587       and
2588     ! keys %$new
2589       and
2590     blessed($new)
2591   ) {
2592     carp_unique (sprintf (
2593       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2594       $self->result_class,
2595     ));
2596   }
2597
2598   $new;
2599 }
2600
2601 # _merge_with_rscond
2602 #
2603 # Takes a simple hash of K/V data and returns its copy merged with the
2604 # condition already present on the resultset. Additionally returns an
2605 # arrayref of value/condition names, which were inferred from related
2606 # objects (this is needed for in-memory related objects)
2607 sub _merge_with_rscond {
2608   my ($self, $data) = @_;
2609
2610   my ($implied_data, @cols_from_relations);
2611
2612   my $alias = $self->{attrs}{alias};
2613
2614   if (! defined $self->{cond}) {
2615     # just massage $data below
2616   }
2617   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2618     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2619     @cols_from_relations = keys %{ $implied_data || {} };
2620   }
2621   else {
2622     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2623     $implied_data = { map {
2624       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2625     } keys %$eqs };
2626   }
2627
2628   return (
2629     { map
2630       { %{ $self->_remove_alias($_, $alias) } }
2631       # precedence must be given to passed values over values inherited from
2632       # the cond, so the order here is important.
2633       ( $implied_data||(), $data)
2634     },
2635     \@cols_from_relations
2636   );
2637 }
2638
2639 # _has_resolved_attr
2640 #
2641 # determines if the resultset defines at least one
2642 # of the attributes supplied
2643 #
2644 # used to determine if a subquery is necessary
2645 #
2646 # supports some virtual attributes:
2647 #   -join
2648 #     This will scan for any joins being present on the resultset.
2649 #     It is not a mere key-search but a deep inspection of {from}
2650 #
2651
2652 sub _has_resolved_attr {
2653   my ($self, @attr_names) = @_;
2654
2655   my $attrs = $self->_resolved_attrs;
2656
2657   my %extra_checks;
2658
2659   for my $n (@attr_names) {
2660     if (grep { $n eq $_ } (qw/-join/) ) {
2661       $extra_checks{$n}++;
2662       next;
2663     }
2664
2665     my $attr =  $attrs->{$n};
2666
2667     next if not defined $attr;
2668
2669     if (ref $attr eq 'HASH') {
2670       return 1 if keys %$attr;
2671     }
2672     elsif (ref $attr eq 'ARRAY') {
2673       return 1 if @$attr;
2674     }
2675     else {
2676       return 1 if $attr;
2677     }
2678   }
2679
2680   # a resolved join is expressed as a multi-level from
2681   return 1 if (
2682     $extra_checks{-join}
2683       and
2684     ref $attrs->{from} eq 'ARRAY'
2685       and
2686     @{$attrs->{from}} > 1
2687   );
2688
2689   return 0;
2690 }
2691
2692 # _remove_alias
2693 #
2694 # Remove the specified alias from the specified query hash. A copy is made so
2695 # the original query is not modified.
2696
2697 sub _remove_alias {
2698   my ($self, $query, $alias) = @_;
2699
2700   my %orig = %{ $query || {} };
2701   my %unaliased;
2702
2703   foreach my $key (keys %orig) {
2704     if ($key !~ /\./) {
2705       $unaliased{$key} = $orig{$key};
2706       next;
2707     }
2708     $unaliased{$1} = $orig{$key}
2709       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2710   }
2711
2712   return \%unaliased;
2713 }
2714
2715 =head2 as_query
2716
2717 =over 4
2718
2719 =item Arguments: none
2720
2721 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2722
2723 =back
2724
2725 Returns the SQL query and bind vars associated with the invocant.
2726
2727 This is generally used as the RHS for a subquery.
2728
2729 =cut
2730
2731 sub as_query {
2732   my $self = shift;
2733
2734   my $attrs = { %{ $self->_resolved_attrs } };
2735
2736   my $aq = $self->result_source->schema->storage->_select_args_to_query (
2737     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2738   );
2739
2740   $aq;
2741 }
2742
2743 =head2 find_or_new
2744
2745 =over 4
2746
2747 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2748
2749 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2750
2751 =back
2752
2753   my $artist = $schema->resultset('Artist')->find_or_new(
2754     { artist => 'fred' }, { key => 'artists' });
2755
2756   $cd->cd_to_producer->find_or_new({ producer => $producer },
2757                                    { key => 'primary' });
2758
2759 Find an existing record from this resultset using L</find>. if none exists,
2760 instantiate a new result object and return it. The object will not be saved
2761 into your storage until you call L<DBIx::Class::Row/insert> on it.
2762
2763 You most likely want this method when looking for existing rows using a unique
2764 constraint that is not the primary key, or looking for related rows.
2765
2766 If you want objects to be saved immediately, use L</find_or_create> instead.
2767
2768 B<Note>: Make sure to read the documentation of L</find> and understand the
2769 significance of the C<key> attribute, as its lack may skew your search, and
2770 subsequently result in spurious new objects.
2771
2772 B<Note>: Take care when using C<find_or_new> with a table having
2773 columns with default values that you intend to be automatically
2774 supplied by the database (e.g. an auto_increment primary key column).
2775 In normal usage, the value of such columns should NOT be included at
2776 all in the call to C<find_or_new>, even when set to C<undef>.
2777
2778 =cut
2779
2780 sub find_or_new {
2781   my $self     = shift;
2782   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2783   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2784   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2785     return $row;
2786   }
2787   return $self->new_result($hash);
2788 }
2789
2790 =head2 create
2791
2792 =over 4
2793
2794 =item Arguments: \%col_data
2795
2796 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2797
2798 =back
2799
2800 Attempt to create a single new row or a row with multiple related rows
2801 in the table represented by the resultset (and related tables). This
2802 will not check for duplicate rows before inserting, use
2803 L</find_or_create> to do that.
2804
2805 To create one row for this resultset, pass a hashref of key/value
2806 pairs representing the columns of the table and the values you wish to
2807 store. If the appropriate relationships are set up, foreign key fields
2808 can also be passed an object representing the foreign row, and the
2809 value will be set to its primary key.
2810
2811 To create related objects, pass a hashref of related-object column values
2812 B<keyed on the relationship name>. If the relationship is of type C<multi>
2813 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2814 The process will correctly identify columns holding foreign keys, and will
2815 transparently populate them from the keys of the corresponding relation.
2816 This can be applied recursively, and will work correctly for a structure
2817 with an arbitrary depth and width, as long as the relationships actually
2818 exists and the correct column data has been supplied.
2819
2820 Instead of hashrefs of plain related data (key/value pairs), you may
2821 also pass new or inserted objects. New objects (not inserted yet, see
2822 L</new_result>), will be inserted into their appropriate tables.
2823
2824 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2825
2826 Example of creating a new row.
2827
2828   $person_rs->create({
2829     name=>"Some Person",
2830     email=>"somebody@someplace.com"
2831   });
2832
2833 Example of creating a new row and also creating rows in a related C<has_many>
2834 or C<has_one> resultset.  Note Arrayref.
2835
2836   $artist_rs->create(
2837      { artistid => 4, name => 'Manufactured Crap', cds => [
2838         { title => 'My First CD', year => 2006 },
2839         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2840       ],
2841      },
2842   );
2843
2844 Example of creating a new row and also creating a row in a related
2845 C<belongs_to> resultset. Note Hashref.
2846
2847   $cd_rs->create({
2848     title=>"Music for Silly Walks",
2849     year=>2000,
2850     artist => {
2851       name=>"Silly Musician",
2852     }
2853   });
2854
2855 =over
2856
2857 =item WARNING
2858
2859 When subclassing ResultSet never attempt to override this method. Since
2860 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2861 lot of the internals simply never call it, so your override will be
2862 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2863 or L<DBIx::Class::Row/insert> depending on how early in the
2864 L</create> process you need to intervene. See also warning pertaining to
2865 L</new>.
2866
2867 =back
2868
2869 =cut
2870
2871 sub create {
2872   #my ($self, $col_data) = @_;
2873   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2874   return shift->new_result(shift)->insert;
2875 }
2876
2877 =head2 find_or_create
2878
2879 =over 4
2880
2881 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2882
2883 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2884
2885 =back
2886
2887   $cd->cd_to_producer->find_or_create({ producer => $producer },
2888                                       { key => 'primary' });
2889
2890 Tries to find a record based on its primary key or unique constraints; if none
2891 is found, creates one and returns that instead.
2892
2893   my $cd = $schema->resultset('CD')->find_or_create({
2894     cdid   => 5,
2895     artist => 'Massive Attack',
2896     title  => 'Mezzanine',
2897     year   => 2005,
2898   });
2899
2900 Also takes an optional C<key> attribute, to search by a specific key or unique
2901 constraint. For example:
2902
2903   my $cd = $schema->resultset('CD')->find_or_create(
2904     {
2905       artist => 'Massive Attack',
2906       title  => 'Mezzanine',
2907     },
2908     { key => 'cd_artist_title' }
2909   );
2910
2911 B<Note>: Make sure to read the documentation of L</find> and understand the
2912 significance of the C<key> attribute, as its lack may skew your search, and
2913 subsequently result in spurious row creation.
2914
2915 B<Note>: Because find_or_create() reads from the database and then
2916 possibly inserts based on the result, this method is subject to a race
2917 condition. Another process could create a record in the table after
2918 the find has completed and before the create has started. To avoid
2919 this problem, use find_or_create() inside a transaction.
2920
2921 B<Note>: Take care when using C<find_or_create> with a table having
2922 columns with default values that you intend to be automatically
2923 supplied by the database (e.g. an auto_increment primary key column).
2924 In normal usage, the value of such columns should NOT be included at
2925 all in the call to C<find_or_create>, even when set to C<undef>.
2926
2927 See also L</find> and L</update_or_create>. For information on how to declare
2928 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2929
2930 If you need to know if an existing row was found or a new one created use
2931 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2932 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2933 database!
2934
2935   my $cd = $schema->resultset('CD')->find_or_new({
2936     cdid   => 5,
2937     artist => 'Massive Attack',
2938     title  => 'Mezzanine',
2939     year   => 2005,
2940   });
2941
2942   if( !$cd->in_storage ) {
2943       # do some stuff
2944       $cd->insert;
2945   }
2946
2947 =cut
2948
2949 sub find_or_create {
2950   my $self     = shift;
2951   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2952   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2953   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2954     return $row;
2955   }
2956   return $self->new_result($hash)->insert;
2957 }
2958
2959 =head2 update_or_create
2960
2961 =over 4
2962
2963 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2964
2965 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2966
2967 =back
2968
2969   $resultset->update_or_create({ col => $val, ... });
2970
2971 Like L</find_or_create>, but if a row is found it is immediately updated via
2972 C<< $found_row->update (\%col_data) >>.
2973
2974
2975 Takes an optional C<key> attribute to search on a specific unique constraint.
2976 For example:
2977
2978   # In your application
2979   my $cd = $schema->resultset('CD')->update_or_create(
2980     {
2981       artist => 'Massive Attack',
2982       title  => 'Mezzanine',
2983       year   => 1998,
2984     },
2985     { key => 'cd_artist_title' }
2986   );
2987
2988   $cd->cd_to_producer->update_or_create({
2989     producer => $producer,
2990     name => 'harry',
2991   }, {
2992     key => 'primary',
2993   });
2994
2995 B<Note>: Make sure to read the documentation of L</find> and understand the
2996 significance of the C<key> attribute, as its lack may skew your search, and
2997 subsequently result in spurious row creation.
2998
2999 B<Note>: Take care when using C<update_or_create> with a table having
3000 columns with default values that you intend to be automatically
3001 supplied by the database (e.g. an auto_increment primary key column).
3002 In normal usage, the value of such columns should NOT be included at
3003 all in the call to C<update_or_create>, even when set to C<undef>.
3004
3005 See also L</find> and L</find_or_create>. For information on how to declare
3006 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3007
3008 If you need to know if an existing row was updated or a new one created use
3009 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3010 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3011 database!
3012
3013 =cut
3014
3015 sub update_or_create {
3016   my $self = shift;
3017   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3018   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3019
3020   my $row = $self->find($cond, $attrs);
3021   if (defined $row) {
3022     $row->update($cond);
3023     return $row;
3024   }
3025
3026   return $self->new_result($cond)->insert;
3027 }
3028
3029 =head2 update_or_new
3030
3031 =over 4
3032
3033 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3034
3035 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3036
3037 =back
3038
3039   $resultset->update_or_new({ col => $val, ... });
3040
3041 Like L</find_or_new> but if a row is found it is immediately updated via
3042 C<< $found_row->update (\%col_data) >>.
3043
3044 For example:
3045
3046   # In your application
3047   my $cd = $schema->resultset('CD')->update_or_new(
3048     {
3049       artist => 'Massive Attack',
3050       title  => 'Mezzanine',
3051       year   => 1998,
3052     },
3053     { key => 'cd_artist_title' }
3054   );
3055
3056   if ($cd->in_storage) {
3057       # the cd was updated
3058   }
3059   else {
3060       # the cd is not yet in the database, let's insert it
3061       $cd->insert;
3062   }
3063
3064 B<Note>: Make sure to read the documentation of L</find> and understand the
3065 significance of the C<key> attribute, as its lack may skew your search, and
3066 subsequently result in spurious new objects.
3067
3068 B<Note>: Take care when using C<update_or_new> with a table having
3069 columns with default values that you intend to be automatically
3070 supplied by the database (e.g. an auto_increment primary key column).
3071 In normal usage, the value of such columns should NOT be included at
3072 all in the call to C<update_or_new>, even when set to C<undef>.
3073
3074 See also L</find>, L</find_or_create> and L</find_or_new>.
3075
3076 =cut
3077
3078 sub update_or_new {
3079     my $self  = shift;
3080     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3081     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3082
3083     my $row = $self->find( $cond, $attrs );
3084     if ( defined $row ) {
3085         $row->update($cond);
3086         return $row;
3087     }
3088
3089     return $self->new_result($cond);
3090 }
3091
3092 =head2 get_cache
3093
3094 =over 4
3095
3096 =item Arguments: none
3097
3098 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3099
3100 =back
3101
3102 Gets the contents of the cache for the resultset, if the cache is set.
3103
3104 The cache is populated either by using the L</prefetch> attribute to
3105 L</search> or by calling L</set_cache>.
3106
3107 =cut
3108
3109 sub get_cache {
3110   shift->{all_cache};
3111 }
3112
3113 =head2 set_cache
3114
3115 =over 4
3116
3117 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3118
3119 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3120
3121 =back
3122
3123 Sets the contents of the cache for the resultset. Expects an arrayref
3124 of objects of the same class as those produced by the resultset. Note that
3125 if the cache is set, the resultset will return the cached objects rather
3126 than re-querying the database even if the cache attr is not set.
3127
3128 The contents of the cache can also be populated by using the
3129 L</prefetch> attribute to L</search>.
3130
3131 =cut
3132
3133 sub set_cache {
3134   my ( $self, $data ) = @_;
3135   $self->throw_exception("set_cache requires an arrayref")
3136       if defined($data) && (ref $data ne 'ARRAY');
3137   $self->{all_cache} = $data;
3138 }
3139
3140 =head2 clear_cache
3141
3142 =over 4
3143
3144 =item Arguments: none
3145
3146 =item Return Value: undef
3147
3148 =back
3149
3150 Clears the cache for the resultset.
3151
3152 =cut
3153
3154 sub clear_cache {
3155   shift->set_cache(undef);
3156 }
3157
3158 =head2 is_paged
3159
3160 =over 4
3161
3162 =item Arguments: none
3163
3164 =item Return Value: true, if the resultset has been paginated
3165
3166 =back
3167
3168 =cut
3169
3170 sub is_paged {
3171   my ($self) = @_;
3172   return !!$self->{attrs}{page};
3173 }
3174
3175 =head2 is_ordered
3176
3177 =over 4
3178
3179 =item Arguments: none
3180
3181 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3182
3183 =back
3184
3185 =cut
3186
3187 sub is_ordered {
3188   my ($self) = @_;
3189   return scalar $self->result_source->schema->storage->_extract_order_criteria($self->{attrs}{order_by});
3190 }
3191
3192 =head2 related_resultset
3193
3194 =over 4
3195
3196 =item Arguments: $rel_name
3197
3198 =item Return Value: L<$resultset|/search>
3199
3200 =back
3201
3202 Returns a related resultset for the supplied relationship name.
3203
3204   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3205
3206 =cut
3207
3208 sub related_resultset {
3209   $_[0]->throw_exception(
3210     'Extra arguments to $rs->related_resultset() were always quietly '
3211   . 'discarded without consideration, you need to switch to '
3212   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3213   ) if @_ > 2;
3214
3215   return $_[0]->{related_resultsets}{$_[1]}
3216     if defined $_[0]->{related_resultsets}{$_[1]};
3217
3218   my ($self, $rel) = @_;
3219
3220   return $self->{related_resultsets}{$rel} = do {
3221     my $rsrc = $self->result_source;
3222     my $rel_info = $rsrc->relationship_info($rel);
3223
3224     $self->throw_exception(
3225       "search_related: result source '" . $rsrc->source_name .
3226         "' has no such relationship $rel")
3227       unless $rel_info;
3228
3229     my $attrs = $self->_chain_relationship($rel);
3230
3231     my $storage = $rsrc->schema->storage;
3232
3233     # Previously this atribute was deleted (instead of being set as it is now)
3234     # Doing so seems to be harmless in all available test permutations
3235     # See also 01d59a6a6 and mst's comment below
3236     #
3237     $attrs->{alias} = $storage->relname_to_table_alias(
3238       $rel,
3239       $attrs->{seen_join}{$rel}
3240     );
3241
3242     # since this is search_related, and we already slid the select window inwards
3243     # (the select/as attrs were deleted in the beginning), we need to flip all
3244     # left joins to inner, so we get the expected results
3245     # read the comment on top of the actual function to see what this does
3246     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3247
3248     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3249     delete $attrs->{result_class};
3250
3251     my $new = do {
3252
3253       # The reason we do this now instead of passing the alias to the
3254       # search_rs below is that if you wrap/overload resultset on the
3255       # source you need to know what alias it's -going- to have for things
3256       # to work sanely (e.g. RestrictWithObject wants to be able to add
3257       # extra query restrictions, and these may need to be $alias.)
3258       #                                       -- mst ~ 2007 (01d59a6a6)
3259       #
3260       # FIXME - this seems to be no longer neccessary (perhaps due to the
3261       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3262       # dependent (as of Jun 2015 ) does not yield any difference with or
3263       # without this line. Nevertheless keep it as is for now, to minimize
3264       # churn, there is enough potential for breakage in 0.0829xx as it is
3265       #                                       -- ribasushi Jun 2015
3266       #
3267       my $rel_source = $rsrc->related_source($rel);
3268       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3269
3270       $rel_source->resultset->search_rs( undef, $attrs );
3271     };
3272
3273     if (my $cache = $self->get_cache) {
3274       my @related_cache = map
3275         { $_->related_resultset($rel)->get_cache || () }
3276         @$cache
3277       ;
3278
3279       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3280     }
3281
3282     $new;
3283   };
3284 }
3285
3286 =head2 current_source_alias
3287
3288 =over 4
3289
3290 =item Arguments: none
3291
3292 =item Return Value: $source_alias
3293
3294 =back
3295
3296 Returns the current table alias for the result source this resultset is built
3297 on, that will be used in the SQL query. Usually it is C<me>.
3298
3299 Currently the source alias that refers to the result set returned by a
3300 L</search>/L</find> family method depends on how you got to the resultset: it's
3301 C<me> by default, but eg. L</search_related> aliases it to the related result
3302 source name (and keeps C<me> referring to the original result set). The long
3303 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3304 (and make this method unnecessary).
3305
3306 Thus it's currently necessary to use this method in predefined queries (see
3307 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3308 source alias of the current result set:
3309
3310   # in a result set class
3311   sub modified_by {
3312     my ($self, $user) = @_;
3313
3314     my $me = $self->current_source_alias;
3315
3316     return $self->search({
3317       "$me.modified" => $user->id,
3318     });
3319   }
3320
3321 The alias of L<newly created resultsets|/search> can be altered by the
3322 L<alias attribute|/alias>.
3323
3324 =cut
3325
3326 sub current_source_alias {
3327   return (shift->{attrs} || {})->{alias} || 'me';
3328 }
3329
3330 =head2 as_subselect_rs
3331
3332 =over 4
3333
3334 =item Arguments: none
3335
3336 =item Return Value: L<$resultset|/search>
3337
3338 =back
3339
3340 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3341 "virtual view" by including it as a subquery within the from clause.  From this
3342 point on, any joined tables are inaccessible to ->search on the resultset (as if
3343 it were simply where-filtered without joins).  For example:
3344
3345  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3346
3347  # 'x' now pollutes the query namespace
3348
3349  # So the following works as expected
3350  my $ok_rs = $rs->search({'x.other' => 1});
3351
3352  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3353  # def) we look for one row with contradictory terms and join in another table
3354  # (aliased 'x_2') which we never use
3355  my $broken_rs = $rs->search({'x.name' => 'def'});
3356
3357  my $rs2 = $rs->as_subselect_rs;
3358
3359  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3360  my $not_joined_rs = $rs2->search({'x.other' => 1});
3361
3362  # works as expected: finds a 'table' row related to two x rows (abc and def)
3363  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3364
3365 Another example of when one might use this would be to select a subset of
3366 columns in a group by clause:
3367
3368  my $rs = $schema->resultset('Bar')->search(undef, {
3369    group_by => [qw{ id foo_id baz_id }],
3370  })->as_subselect_rs->search(undef, {
3371    columns => [qw{ id foo_id }]
3372  });
3373
3374 In the above example normally columns would have to be equal to the group by,
3375 but because we isolated the group by into a subselect the above works.
3376
3377 =cut
3378
3379 sub as_subselect_rs {
3380   my $self = shift;
3381
3382   my $attrs = $self->_resolved_attrs;
3383
3384   my $fresh_rs = (ref $self)->new (
3385     $self->result_source
3386   );
3387
3388   # these pieces will be locked in the subquery
3389   delete $fresh_rs->{cond};
3390   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3391
3392   return $fresh_rs->search( {}, {
3393     from => [{
3394       $attrs->{alias} => $self->as_query,
3395       -alias  => $attrs->{alias},
3396       -rsrc   => $self->result_source,
3397     }],
3398     alias => $attrs->{alias},
3399   });
3400 }
3401
3402 # This code is called by search_related, and makes sure there
3403 # is clear separation between the joins before, during, and
3404 # after the relationship. This information is needed later
3405 # in order to properly resolve prefetch aliases (any alias
3406 # with a relation_chain_depth less than the depth of the
3407 # current prefetch is not considered)
3408 #
3409 # The increments happen twice per join. An even number means a
3410 # relationship specified via a search_related, whereas an odd
3411 # number indicates a join/prefetch added via attributes
3412 #
3413 # Also this code will wrap the current resultset (the one we
3414 # chain to) in a subselect IFF it contains limiting attributes
3415 sub _chain_relationship {
3416   my ($self, $rel) = @_;
3417   my $source = $self->result_source;
3418   my $attrs = { %{$self->{attrs}||{}} };
3419
3420   # we need to take the prefetch the attrs into account before we
3421   # ->_resolve_join as otherwise they get lost - captainL
3422   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3423
3424   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3425
3426   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3427
3428   my $from;
3429   my @force_subq_attrs = qw/offset rows group_by having/;
3430
3431   if (
3432     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3433       ||
3434     $self->_has_resolved_attr (@force_subq_attrs)
3435   ) {
3436     # Nuke the prefetch (if any) before the new $rs attrs
3437     # are resolved (prefetch is useless - we are wrapping
3438     # a subquery anyway).
3439     my $rs_copy = $self->search;
3440     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3441       $rs_copy->{attrs}{join},
3442       delete $rs_copy->{attrs}{prefetch},
3443     );
3444
3445     $from = [{
3446       -rsrc   => $source,
3447       -alias  => $attrs->{alias},
3448       $attrs->{alias} => $rs_copy->as_query,
3449     }];
3450     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3451     $seen->{-relation_chain_depth} = 0;
3452   }
3453   elsif ($attrs->{from}) {  #shallow copy suffices
3454     $from = [ @{$attrs->{from}} ];
3455   }
3456   else {
3457     $from = [{
3458       -rsrc  => $source,
3459       -alias => $attrs->{alias},
3460       $attrs->{alias} => $source->from,
3461     }];
3462   }
3463
3464   my $jpath = ($seen->{-relation_chain_depth})
3465     ? $from->[-1][0]{-join_path}
3466     : [];
3467
3468   my @requested_joins = $source->_resolve_join(
3469     $join,
3470     $attrs->{alias},
3471     $seen,
3472     $jpath,
3473   );
3474
3475   push @$from, @requested_joins;
3476
3477   $seen->{-relation_chain_depth}++;
3478
3479   # if $self already had a join/prefetch specified on it, the requested
3480   # $rel might very well be already included. What we do in this case
3481   # is effectively a no-op (except that we bump up the chain_depth on
3482   # the join in question so we could tell it *is* the search_related)
3483   my $already_joined;
3484
3485   # we consider the last one thus reverse
3486   for my $j (reverse @requested_joins) {
3487     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3488     if ($rel eq $last_j) {
3489       $j->[0]{-relation_chain_depth}++;
3490       $already_joined++;
3491       last;
3492     }
3493   }
3494
3495   unless ($already_joined) {
3496     push @$from, $source->_resolve_join(
3497       $rel,
3498       $attrs->{alias},
3499       $seen,
3500       $jpath,
3501     );
3502   }
3503
3504   $seen->{-relation_chain_depth}++;
3505
3506   return {%$attrs, from => $from, seen_join => $seen};
3507 }
3508
3509 sub _resolved_attrs {
3510   my $self = shift;
3511   return $self->{_attrs} if $self->{_attrs};
3512
3513   my $attrs  = { %{ $self->{attrs} || {} } };
3514   my $source = $attrs->{result_source} = $self->result_source;
3515   my $alias  = $attrs->{alias};
3516
3517   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3518     if $attrs->{collapse} and $attrs->{distinct};
3519
3520
3521   # Sanity check the paging attributes
3522   # SQLMaker does it too, but in case of a software_limit we'll never get there
3523   if (defined $attrs->{offset}) {
3524     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3525       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3526   }
3527   if (defined $attrs->{rows}) {
3528     $self->throw_exception("The rows attribute must be a positive integer if present")
3529       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3530   }
3531
3532
3533   # default selection list
3534   $attrs->{columns} = [ $source->columns ]
3535     unless grep { exists $attrs->{$_} } qw/columns cols select as/;
3536
3537   # merge selectors together
3538   for (qw/columns select as/) {
3539     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3540       if $attrs->{$_} or $attrs->{"+$_"};
3541   }
3542
3543   # disassemble columns
3544   my (@sel, @as);
3545   if (my $cols = delete $attrs->{columns}) {
3546     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3547       if (ref $c eq 'HASH') {
3548         for my $as (sort keys %$c) {
3549           push @sel, $c->{$as};
3550           push @as, $as;
3551         }
3552       }
3553       else {
3554         push @sel, $c;
3555         push @as, $c;
3556       }
3557     }
3558   }
3559
3560   # when trying to weed off duplicates later do not go past this point -
3561   # everything added from here on is unbalanced "anyone's guess" stuff
3562   my $dedup_stop_idx = $#as;
3563
3564   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3565     if $attrs->{as};
3566   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3567     if $attrs->{select};
3568
3569   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3570   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3571
3572   # disqualify all $alias.col as-bits (inflate-map mandated)
3573   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3574
3575   # de-duplicate the result (remove *identical* select/as pairs)
3576   # and also die on duplicate {as} pointing to different {select}s
3577   # not using a c-style for as the condition is prone to shrinkage
3578   my $seen;
3579   my $i = 0;
3580   while ($i <= $dedup_stop_idx) {
3581     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3582       splice @sel, $i, 1;
3583       splice @as, $i, 1;
3584       $dedup_stop_idx--;
3585     }
3586     elsif ($seen->{$as[$i]}++) {
3587       $self->throw_exception(
3588         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3589       );
3590     }
3591     else {
3592       $i++;
3593     }
3594   }
3595
3596   $attrs->{select} = \@sel;
3597   $attrs->{as} = \@as;
3598
3599   $attrs->{from} ||= [{
3600     -rsrc   => $source,
3601     -alias  => $self->{attrs}{alias},
3602     $self->{attrs}{alias} => $source->from,
3603   }];
3604
3605   if ( $attrs->{join} || $attrs->{prefetch} ) {
3606
3607     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3608       if ref $attrs->{from} ne 'ARRAY';
3609
3610     my $join = (delete $attrs->{join}) || {};
3611
3612     if ( defined $attrs->{prefetch} ) {
3613       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3614     }
3615
3616     $attrs->{from} =    # have to copy here to avoid corrupting the original
3617       [
3618         @{ $attrs->{from} },
3619         $source->_resolve_join(
3620           $join,
3621           $alias,
3622           { %{ $attrs->{seen_join} || {} } },
3623           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3624             ? $attrs->{from}[-1][0]{-join_path}
3625             : []
3626           ,
3627         )
3628       ];
3629   }
3630
3631
3632   for my $attr (qw(order_by group_by)) {
3633
3634     if ( defined $attrs->{$attr} ) {
3635       $attrs->{$attr} = (
3636         ref( $attrs->{$attr} ) eq 'ARRAY'
3637         ? [ @{ $attrs->{$attr} } ]
3638         : [ $attrs->{$attr} || () ]
3639       );
3640
3641       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3642     }
3643   }
3644
3645
3646   # set collapse default based on presence of prefetch
3647   my $prefetch;
3648   if (
3649     defined $attrs->{prefetch}
3650       and
3651     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3652   ) {
3653     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3654       if defined $attrs->{collapse} and ! $attrs->{collapse};
3655
3656     $attrs->{collapse} = 1;
3657   }
3658
3659
3660   # run through the resulting joinstructure (starting from our current slot)
3661   # and unset collapse if proven unnecessary
3662   #
3663   # also while we are at it find out if the current root source has
3664   # been premultiplied by previous related_source chaining
3665   #
3666   # this allows to predict whether a root object with all other relation
3667   # data set to NULL is in fact unique
3668   if ($attrs->{collapse}) {
3669
3670     if (ref $attrs->{from} eq 'ARRAY') {
3671
3672       if (@{$attrs->{from}} == 1) {
3673         # no joins - no collapse
3674         $attrs->{collapse} = 0;
3675       }
3676       else {
3677         # find where our table-spec starts
3678         my @fromlist = @{$attrs->{from}};
3679         while (@fromlist) {
3680           my $t = shift @fromlist;
3681
3682           my $is_multi;
3683           # me vs join from-spec distinction - a ref means non-root
3684           if (ref $t eq 'ARRAY') {
3685             $t = $t->[0];
3686             $is_multi ||= ! $t->{-is_single};
3687           }
3688           last if ($t->{-alias} && $t->{-alias} eq $alias);
3689           $attrs->{_main_source_premultiplied} ||= $is_multi;
3690         }
3691
3692         # no non-singles remaining, nor any premultiplication - nothing to collapse
3693         if (
3694           ! $attrs->{_main_source_premultiplied}
3695             and
3696           ! grep { ! $_->[0]{-is_single} } @fromlist
3697         ) {
3698           $attrs->{collapse} = 0;
3699         }
3700       }
3701     }
3702
3703     else {
3704       # if we can not analyze the from - err on the side of safety
3705       $attrs->{_main_source_premultiplied} = 1;
3706     }
3707   }
3708
3709
3710   # generate the distinct induced group_by before injecting the prefetched select/as parts
3711   if (delete $attrs->{distinct}) {
3712     if ($attrs->{group_by}) {
3713       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3714     }
3715     else {
3716       $attrs->{_grouped_by_distinct} = 1;
3717       # distinct affects only the main selection part, not what prefetch may add below
3718       ($attrs->{group_by}, my $new_order) = $source->schema->storage->_group_over_selection($attrs);
3719
3720       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3721       # The thinking is: if we are collapsing the subquerying prefetch engine will
3722       # rip stuff apart for us anyway, and we do not want to have a potentially
3723       # function-converted external order_by
3724       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3725       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3726     }
3727   }
3728
3729
3730   # generate selections based on the prefetch helper
3731   if ($prefetch) {
3732
3733     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3734       if $attrs->{_dark_selector};
3735
3736     # this is a separate structure (we don't look in {from} directly)
3737     # as the resolver needs to shift things off the lists to work
3738     # properly (identical-prefetches on different branches)
3739     my $joined_node_aliases_map = {};
3740     if (ref $attrs->{from} eq 'ARRAY') {
3741
3742       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3743
3744       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3745         next unless $j->[0]{-alias};
3746         next unless $j->[0]{-join_path};
3747         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3748
3749         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3750
3751         my $p = $joined_node_aliases_map;
3752         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3753         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3754       }
3755     }
3756
3757     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3758       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3759   }
3760
3761
3762   $attrs->{_simple_passthrough_construction} = !(
3763     $attrs->{collapse}
3764       or
3765     grep { $_ =~ /\./ } @{$attrs->{as}}
3766   );
3767
3768
3769   # if both page and offset are specified, produce a combined offset
3770   # even though it doesn't make much sense, this is what pre 081xx has
3771   # been doing
3772   if (my $page = delete $attrs->{page}) {
3773     $attrs->{offset} =
3774       ($attrs->{rows} * ($page - 1))
3775             +
3776       ($attrs->{offset} || 0)
3777     ;
3778   }
3779
3780   return $self->{_attrs} = $attrs;
3781 }
3782
3783 sub _rollout_attr {
3784   my ($self, $attr) = @_;
3785
3786   if (ref $attr eq 'HASH') {
3787     return $self->_rollout_hash($attr);
3788   } elsif (ref $attr eq 'ARRAY') {
3789     return $self->_rollout_array($attr);
3790   } else {
3791     return [$attr];
3792   }
3793 }
3794
3795 sub _rollout_array {
3796   my ($self, $attr) = @_;
3797
3798   my @rolled_array;
3799   foreach my $element (@{$attr}) {
3800     if (ref $element eq 'HASH') {
3801       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3802     } elsif (ref $element eq 'ARRAY') {
3803       #  XXX - should probably recurse here
3804       push( @rolled_array, @{$self->_rollout_array($element)} );
3805     } else {
3806       push( @rolled_array, $element );
3807     }
3808   }
3809   return \@rolled_array;
3810 }
3811
3812 sub _rollout_hash {
3813   my ($self, $attr) = @_;
3814
3815   my @rolled_array;
3816   foreach my $key (keys %{$attr}) {
3817     push( @rolled_array, { $key => $attr->{$key} } );
3818   }
3819   return \@rolled_array;
3820 }
3821
3822 sub _calculate_score {
3823   my ($self, $a, $b) = @_;
3824
3825   if (defined $a xor defined $b) {
3826     return 0;
3827   }
3828   elsif (not defined $a) {
3829     return 1;
3830   }
3831
3832   if (ref $b eq 'HASH') {
3833     my ($b_key) = keys %{$b};
3834     $b_key = '' if ! defined $b_key;
3835     if (ref $a eq 'HASH') {
3836       my ($a_key) = keys %{$a};
3837       $a_key = '' if ! defined $a_key;
3838       if ($a_key eq $b_key) {
3839         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3840       } else {
3841         return 0;
3842       }
3843     } else {
3844       return ($a eq $b_key) ? 1 : 0;
3845     }
3846   } else {
3847     if (ref $a eq 'HASH') {
3848       my ($a_key) = keys %{$a};
3849       return ($b eq $a_key) ? 1 : 0;
3850     } else {
3851       return ($b eq $a) ? 1 : 0;
3852     }
3853   }
3854 }
3855
3856 sub _merge_joinpref_attr {
3857   my ($self, $orig, $import) = @_;
3858
3859   return $import unless defined($orig);
3860   return $orig unless defined($import);
3861
3862   $orig = $self->_rollout_attr($orig);
3863   $import = $self->_rollout_attr($import);
3864
3865   my $seen_keys;
3866   foreach my $import_element ( @{$import} ) {
3867     # find best candidate from $orig to merge $b_element into
3868     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3869     foreach my $orig_element ( @{$orig} ) {
3870       my $score = $self->_calculate_score( $orig_element, $import_element );
3871       if ($score > $best_candidate->{score}) {
3872         $best_candidate->{position} = $position;
3873         $best_candidate->{score} = $score;
3874       }
3875       $position++;
3876     }
3877     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3878     $import_key = '' if not defined $import_key;
3879
3880     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3881       push( @{$orig}, $import_element );
3882     } else {
3883       my $orig_best = $orig->[$best_candidate->{position}];
3884       # merge orig_best and b_element together and replace original with merged
3885       if (ref $orig_best ne 'HASH') {
3886         $orig->[$best_candidate->{position}] = $import_element;
3887       } elsif (ref $import_element eq 'HASH') {
3888         my ($key) = keys %{$orig_best};
3889         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3890       }
3891     }
3892     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3893   }
3894
3895   return @$orig ? $orig : ();
3896 }
3897
3898 {
3899   my $hm;
3900
3901   sub _merge_attr {
3902     $hm ||= do {
3903       require Hash::Merge;
3904       my $hm = Hash::Merge->new;
3905
3906       $hm->specify_behavior({
3907         SCALAR => {
3908           SCALAR => sub {
3909             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3910
3911             if ($defl xor $defr) {
3912               return [ $defl ? $_[0] : $_[1] ];
3913             }
3914             elsif (! $defl) {
3915               return [];
3916             }
3917             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3918               return [ $_[0] ];
3919             }
3920             else {
3921               return [$_[0], $_[1]];
3922             }
3923           },
3924           ARRAY => sub {
3925             return $_[1] if !defined $_[0];
3926             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3927             return [$_[0], @{$_[1]}]
3928           },
3929           HASH  => sub {
3930             return [] if !defined $_[0] and !keys %{$_[1]};
3931             return [ $_[1] ] if !defined $_[0];
3932             return [ $_[0] ] if !keys %{$_[1]};
3933             return [$_[0], $_[1]]
3934           },
3935         },
3936         ARRAY => {
3937           SCALAR => sub {
3938             return $_[0] if !defined $_[1];
3939             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3940             return [@{$_[0]}, $_[1]]
3941           },
3942           ARRAY => sub {
3943             my @ret = @{$_[0]} or return $_[1];
3944             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3945             my %idx = map { $_ => 1 } @ret;
3946             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3947             \@ret;
3948           },
3949           HASH => sub {
3950             return [ $_[1] ] if ! @{$_[0]};
3951             return $_[0] if !keys %{$_[1]};
3952             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3953             return [ @{$_[0]}, $_[1] ];
3954           },
3955         },
3956         HASH => {
3957           SCALAR => sub {
3958             return [] if !keys %{$_[0]} and !defined $_[1];
3959             return [ $_[0] ] if !defined $_[1];
3960             return [ $_[1] ] if !keys %{$_[0]};
3961             return [$_[0], $_[1]]
3962           },
3963           ARRAY => sub {
3964             return [] if !keys %{$_[0]} and !@{$_[1]};
3965             return [ $_[0] ] if !@{$_[1]};
3966             return $_[1] if !keys %{$_[0]};
3967             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3968             return [ $_[0], @{$_[1]} ];
3969           },
3970           HASH => sub {
3971             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3972             return [ $_[0] ] if !keys %{$_[1]};
3973             return [ $_[1] ] if !keys %{$_[0]};
3974             return [ $_[0] ] if $_[0] eq $_[1];
3975             return [ $_[0], $_[1] ];
3976           },
3977         }
3978       } => 'DBIC_RS_ATTR_MERGER');
3979       $hm;
3980     };
3981
3982     return $hm->merge ($_[1], $_[2]);
3983   }
3984 }
3985
3986 sub STORABLE_freeze {
3987   my ($self, $cloning) = @_;
3988   my $to_serialize = { %$self };
3989
3990   # A cursor in progress can't be serialized (and would make little sense anyway)
3991   # the parser can be regenerated (and can't be serialized)
3992   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3993
3994   # nor is it sensical to store a not-yet-fired-count pager
3995   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3996     delete $to_serialize->{pager};
3997   }
3998
3999   Storable::nfreeze($to_serialize);
4000 }
4001
4002 # need this hook for symmetry
4003 sub STORABLE_thaw {
4004   my ($self, $cloning, $serialized) = @_;
4005
4006   %$self = %{ Storable::thaw($serialized) };
4007
4008   $self;
4009 }
4010
4011
4012 =head2 throw_exception
4013
4014 See L<DBIx::Class::Schema/throw_exception> for details.
4015
4016 =cut
4017
4018 sub throw_exception {
4019   my $self=shift;
4020
4021   if (ref $self and my $rsrc = $self->result_source) {
4022     $rsrc->throw_exception(@_)
4023   }
4024   else {
4025     DBIx::Class::Exception->throw(@_);
4026   }
4027 }
4028
4029 1;
4030
4031 __END__
4032
4033 # XXX: FIXME: Attributes docs need clearing up
4034
4035 =head1 ATTRIBUTES
4036
4037 Attributes are used to refine a ResultSet in various ways when
4038 searching for data. They can be passed to any method which takes an
4039 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4040 L</count>.
4041
4042 Default attributes can be set on the result class using
4043 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4044 the CAVEATS on that feature before using it!)
4045
4046 These are in no particular order:
4047
4048 =head2 order_by
4049
4050 =over 4
4051
4052 =item Value: ( $order_by | \@order_by | \%order_by )
4053
4054 =back
4055
4056 Which column(s) to order the results by.
4057
4058 [The full list of suitable values is documented in
4059 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4060 common options.]
4061
4062 If a single column name, or an arrayref of names is supplied, the
4063 argument is passed through directly to SQL. The hashref syntax allows
4064 for connection-agnostic specification of ordering direction:
4065
4066  For descending order:
4067
4068   order_by => { -desc => [qw/col1 col2 col3/] }
4069
4070  For explicit ascending order:
4071
4072   order_by => { -asc => 'col' }
4073
4074 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4075 supported, although you are strongly encouraged to use the hashref
4076 syntax as outlined above.
4077
4078 =head2 columns
4079
4080 =over 4
4081
4082 =item Value: \@columns | \%columns | $column
4083
4084 =back
4085
4086 Shortcut to request a particular set of columns to be retrieved. Each
4087 column spec may be a string (a table column name), or a hash (in which
4088 case the key is the C<as> value, and the value is used as the C<select>
4089 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4090 it and sets C<select> from that, then auto-populates C<as> from
4091 C<select> as normal. (You may also use the C<cols> attribute, as in
4092 earlier versions of DBIC, but this is deprecated)
4093
4094 Essentially C<columns> does the same as L</select> and L</as>.
4095
4096     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4097
4098 is the same as
4099
4100     select => [qw(some_column another_column)],
4101     as     => [qw(some_column dbic_slot)]
4102
4103 If you want to individually retrieve related columns (in essence perform
4104 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4105 chain such that it matches existing relationships:
4106
4107     my $rs = $schema->resultset('Artist')->search({}, {
4108         # required to tell DBIC to collapse has_many relationships
4109         collapse => 1,
4110         join     => { cds => 'tracks' },
4111         '+columns'  => {
4112           'cds.cdid'         => 'cds.cdid',
4113           'cds.tracks.title' => 'tracks.title',
4114         },
4115     });
4116
4117 Like elsewhere, literal SQL or literal values can be included by using a
4118 scalar reference or a literal bind value, and these values will be available
4119 in the result with C<get_column> (see also
4120 L<SQL::Abstract/Literal SQL and value type operators>):
4121
4122     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4123     # bind values: $true_value, $false_value
4124     columns => [
4125         {
4126             foo => \1,
4127             bar => \q{'a string'},
4128             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4129         }
4130     ]
4131
4132 =head2 +columns
4133
4134 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4135 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4136 with a unary plus operator before it, which is the same as simply C<columns>.
4137
4138 =over 4
4139
4140 =item Value: \@extra_columns
4141
4142 =back
4143
4144 Indicates additional columns to be selected from storage. Works the same as
4145 L</columns> but adds columns to the current selection. (You may also use the
4146 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4147 deprecated)
4148
4149   $schema->resultset('CD')->search(undef, {
4150     '+columns' => ['artist.name'],
4151     join => ['artist']
4152   });
4153
4154 would return all CDs and include a 'name' column to the information
4155 passed to object inflation. Note that the 'artist' is the name of the
4156 column (or relationship) accessor, and 'name' is the name of the column
4157 accessor in the related table.
4158
4159 =head2 select
4160
4161 =over 4
4162
4163 =item Value: \@select_columns
4164
4165 =back
4166
4167 Indicates which columns should be selected from the storage. You can use
4168 column names, or in the case of RDBMS back ends, function or stored procedure
4169 names:
4170
4171   $rs = $schema->resultset('Employee')->search(undef, {
4172     select => [
4173       'name',
4174       { count => 'employeeid' },
4175       { max => { length => 'name' }, -as => 'longest_name' }
4176     ]
4177   });
4178
4179   # Equivalent SQL
4180   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4181
4182 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4183 use L</select>, to instruct DBIx::Class how to store the result of the column.
4184
4185 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4186 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4187 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4188 function attribute> supplied as shown in the example above.
4189
4190 =head2 +select
4191
4192 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4193 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4194 with a unary plus operator before it, which is the same as simply C<select>.
4195
4196 =over 4
4197
4198 =item Value: \@extra_select_columns
4199
4200 =back
4201
4202 Indicates additional columns to be selected from storage.  Works the same as
4203 L</select> but adds columns to the current selection, instead of specifying
4204 a new explicit list.
4205
4206 =head2 as
4207
4208 =over 4
4209
4210 =item Value: \@inflation_names
4211
4212 =back
4213
4214 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4215 slot name in which the column value will be stored within the
4216 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4217 identifier by the C<get_column> method (or via the object accessor B<if one
4218 with the same name already exists>) as shown below.
4219
4220 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4221 aliasing C<AS>. See L</select> for details.
4222
4223   $rs = $schema->resultset('Employee')->search(undef, {
4224     select => [
4225       'name',
4226       { count => 'employeeid' },
4227       { max => { length => 'name' }, -as => 'longest_name' }
4228     ],
4229     as => [qw/
4230       name
4231       employee_count
4232       max_name_length
4233     /],
4234   });
4235
4236 If the object against which the search is performed already has an accessor
4237 matching a column name specified in C<as>, the value can be retrieved using
4238 the accessor as normal:
4239
4240   my $name = $employee->name();
4241
4242 If on the other hand an accessor does not exist in the object, you need to
4243 use C<get_column> instead:
4244
4245   my $employee_count = $employee->get_column('employee_count');
4246
4247 You can create your own accessors if required - see
4248 L<DBIx::Class::Manual::Cookbook> for details.
4249
4250 =head2 +as
4251
4252 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4253 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4254 with a unary plus operator before it, which is the same as simply C<as>.
4255
4256 =over 4
4257
4258 =item Value: \@extra_inflation_names
4259
4260 =back
4261
4262 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4263
4264 =head2 join
4265
4266 =over 4
4267
4268 =item Value: ($rel_name | \@rel_names | \%rel_names)
4269
4270 =back
4271
4272 Contains a list of relationships that should be joined for this query.  For
4273 example:
4274
4275   # Get CDs by Nine Inch Nails
4276   my $rs = $schema->resultset('CD')->search(
4277     { 'artist.name' => 'Nine Inch Nails' },
4278     { join => 'artist' }
4279   );
4280
4281 Can also contain a hash reference to refer to the other relation's relations.
4282 For example:
4283
4284   package MyApp::Schema::Track;
4285   use base qw/DBIx::Class/;
4286   __PACKAGE__->table('track');
4287   __PACKAGE__->add_columns(qw/trackid cd position title/);
4288   __PACKAGE__->set_primary_key('trackid');
4289   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4290   1;
4291
4292   # In your application
4293   my $rs = $schema->resultset('Artist')->search(
4294     { 'track.title' => 'Teardrop' },
4295     {
4296       join     => { cd => 'track' },
4297       order_by => 'artist.name',
4298     }
4299   );
4300
4301 You need to use the relationship (not the table) name in  conditions,
4302 because they are aliased as such. The current table is aliased as "me", so
4303 you need to use me.column_name in order to avoid ambiguity. For example:
4304
4305   # Get CDs from 1984 with a 'Foo' track
4306   my $rs = $schema->resultset('CD')->search(
4307     {
4308       'me.year' => 1984,
4309       'tracks.name' => 'Foo'
4310     },
4311     { join => 'tracks' }
4312   );
4313
4314 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4315 similarly for a third time). For e.g.
4316
4317   my $rs = $schema->resultset('Artist')->search({
4318     'cds.title'   => 'Down to Earth',
4319     'cds_2.title' => 'Popular',
4320   }, {
4321     join => [ qw/cds cds/ ],
4322   });
4323
4324 will return a set of all artists that have both a cd with title 'Down
4325 to Earth' and a cd with title 'Popular'.
4326
4327 If you want to fetch related objects from other tables as well, see L</prefetch>
4328 below.
4329
4330  NOTE: An internal join-chain pruner will discard certain joins while
4331  constructing the actual SQL query, as long as the joins in question do not
4332  affect the retrieved result. This for example includes 1:1 left joins
4333  that are not part of the restriction specification (WHERE/HAVING) nor are
4334  a part of the query selection.
4335
4336 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4337
4338 =head2 collapse
4339
4340 =over 4
4341
4342 =item Value: (0 | 1)
4343
4344 =back
4345
4346 When set to a true value, indicates that any rows fetched from joined has_many
4347 relationships are to be aggregated into the corresponding "parent" object. For
4348 example, the resultset:
4349
4350   my $rs = $schema->resultset('CD')->search({}, {
4351     '+columns' => [ qw/ tracks.title tracks.position / ],
4352     join => 'tracks',
4353     collapse => 1,
4354   });
4355
4356 While executing the following query:
4357
4358   SELECT me.*, tracks.title, tracks.position
4359     FROM cd me
4360     LEFT JOIN track tracks
4361       ON tracks.cdid = me.cdid
4362
4363 Will return only as many objects as there are rows in the CD source, even
4364 though the result of the query may span many rows. Each of these CD objects
4365 will in turn have multiple "Track" objects hidden behind the has_many
4366 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4367 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4368 product"), with each CD object containing exactly one of all fetched Track data.
4369
4370 When a collapse is requested on a non-ordered resultset, an order by some
4371 unique part of the main source (the left-most table) is inserted automatically.
4372 This is done so that the resultset is allowed to be "lazy" - calling
4373 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4374 object with all of its related data.
4375
4376 If an L</order_by> is already declared, and orders the resultset in a way that
4377 makes collapsing as described above impossible (e.g. C<< ORDER BY
4378 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4379 switch to "eager" mode and slurp the entire resultset before constructing the
4380 first object returned by L</next>.
4381
4382 Setting this attribute on a resultset that does not join any has_many
4383 relations is a no-op.
4384
4385 For a more in-depth discussion, see L</PREFETCHING>.
4386
4387 =head2 prefetch
4388
4389 =over 4
4390
4391 =item Value: ($rel_name | \@rel_names | \%rel_names)
4392
4393 =back
4394
4395 This attribute is a shorthand for specifying a L</join> spec, adding all
4396 columns from the joined related sources as L</+columns> and setting
4397 L</collapse> to a true value. It can be thought of as a rough B<superset>
4398 of the L</join> attribute.
4399
4400 For example, the following two queries are equivalent:
4401
4402   my $rs = $schema->resultset('Artist')->search({}, {
4403     prefetch => { cds => ['genre', 'tracks' ] },
4404   });
4405
4406 and
4407
4408   my $rs = $schema->resultset('Artist')->search({}, {
4409     join => { cds => ['genre', 'tracks' ] },
4410     collapse => 1,
4411     '+columns' => [
4412       (map
4413         { +{ "cds.$_" => "cds.$_" } }
4414         $schema->source('Artist')->related_source('cds')->columns
4415       ),
4416       (map
4417         { +{ "cds.genre.$_" => "genre.$_" } }
4418         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4419       ),
4420       (map
4421         { +{ "cds.tracks.$_" => "tracks.$_" } }
4422         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4423       ),
4424     ],
4425   });
4426
4427 Both producing the following SQL:
4428
4429   SELECT  me.artistid, me.name, me.rank, me.charfield,
4430           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4431           genre.genreid, genre.name,
4432           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4433     FROM artist me
4434     LEFT JOIN cd cds
4435       ON cds.artist = me.artistid
4436     LEFT JOIN genre genre
4437       ON genre.genreid = cds.genreid
4438     LEFT JOIN track tracks
4439       ON tracks.cd = cds.cdid
4440   ORDER BY me.artistid
4441
4442 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4443 the arguments are properly merged and generally do the right thing. For
4444 example, you may want to do the following:
4445
4446   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4447     { 'genre.genreid' => undef },
4448     {
4449       join => { cds => 'genre' },
4450       prefetch => 'cds',
4451     }
4452   );
4453
4454 Which generates the following SQL:
4455
4456   SELECT  me.artistid, me.name, me.rank, me.charfield,
4457           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4458     FROM artist me
4459     LEFT JOIN cd cds
4460       ON cds.artist = me.artistid
4461     LEFT JOIN genre genre
4462       ON genre.genreid = cds.genreid
4463   WHERE genre.genreid IS NULL
4464   ORDER BY me.artistid
4465
4466 For a more in-depth discussion, see L</PREFETCHING>.
4467
4468 =head2 alias
4469
4470 =over 4
4471
4472 =item Value: $source_alias
4473
4474 =back
4475
4476 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4477 nested search queries (sub-SELECTs) might need specific aliases set to
4478 reference inner queries.  For example:
4479
4480    my $q = $rs
4481       ->related_resultset('CDs')
4482       ->related_resultset('Tracks')
4483       ->search({
4484          'track.id' => { -ident => 'none_search.id' },
4485       })
4486       ->as_query;
4487
4488    my $ids = $self->search({
4489       -not_exists => $q,
4490    }, {
4491       alias    => 'none_search',
4492       group_by => 'none_search.id',
4493    })->get_column('id')->as_query;
4494
4495    $self->search({ id => { -in => $ids } })
4496
4497 This attribute is directly tied to L</current_source_alias>.
4498
4499 =head2 page
4500
4501 =over 4
4502
4503 =item Value: $page
4504
4505 =back
4506
4507 Makes the resultset paged and specifies the page to retrieve. Effectively
4508 identical to creating a non-pages resultset and then calling ->page($page)
4509 on it.
4510
4511 If L</rows> attribute is not specified it defaults to 10 rows per page.
4512
4513 When you have a paged resultset, L</count> will only return the number
4514 of rows in the page. To get the total, use the L</pager> and call
4515 C<total_entries> on it.
4516
4517 =head2 rows
4518
4519 =over 4
4520
4521 =item Value: $rows
4522
4523 =back
4524
4525 Specifies the maximum number of rows for direct retrieval or the number of
4526 rows per page if the page attribute or method is used.
4527
4528 =head2 offset
4529
4530 =over 4
4531
4532 =item Value: $offset
4533
4534 =back
4535
4536 Specifies the (zero-based) row number for the  first row to be returned, or the
4537 of the first row of the first page if paging is used.
4538
4539 =head2 software_limit
4540
4541 =over 4
4542
4543 =item Value: (0 | 1)
4544
4545 =back
4546
4547 When combined with L</rows> and/or L</offset> the generated SQL will not
4548 include any limit dialect stanzas. Instead the entire result will be selected
4549 as if no limits were specified, and DBIC will perform the limit locally, by
4550 artificially advancing and finishing the resulting L</cursor>.
4551
4552 This is the recommended way of performing resultset limiting when no sane RDBMS
4553 implementation is available (e.g.
4554 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4555 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4556
4557 =head2 group_by
4558
4559 =over 4
4560
4561 =item Value: \@columns
4562
4563 =back
4564
4565 A arrayref of columns to group by. Can include columns of joined tables.
4566
4567   group_by => [qw/ column1 column2 ... /]
4568
4569 =head2 having
4570
4571 =over 4
4572
4573 =item Value: $condition
4574
4575 =back
4576
4577 The HAVING operator specifies a B<secondary> condition applied to the set
4578 after the grouping calculations have been done. In other words it is a
4579 constraint just like L</where> (and accepting the same
4580 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4581 as it exists after GROUP BY has taken place. Specifying L</having> without
4582 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4583
4584 E.g.
4585
4586   having => { 'count_employee' => { '>=', 100 } }
4587
4588 or with an in-place function in which case literal SQL is required:
4589
4590   having => \[ 'count(employee) >= ?', 100 ]
4591
4592 =head2 distinct
4593
4594 =over 4
4595
4596 =item Value: (0 | 1)
4597
4598 =back
4599
4600 Set to 1 to automatically generate a L</group_by> clause based on the selection
4601 (including intelligent handling of L</order_by> contents). Note that the group
4602 criteria calculation takes place over the B<final> selection. This includes
4603 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4604 L</search> calls, and standalone columns selected via
4605 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4606 extra selections specified via L</prefetch> - such selections are explicitly
4607 excluded from group criteria calculations.
4608
4609 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4610 setting is ignored and an appropriate warning is issued.
4611
4612 =head2 where
4613
4614 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4615 conditions, same as the B<first> argument to the L<search operator|/search>
4616
4617   # only return rows WHERE deleted IS NULL for all searches
4618   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4619
4620 Note that the above example is
4621 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4622
4623 =head2 cache
4624
4625 Set to 1 to cache search results. This prevents extra SQL queries if you
4626 revisit rows in your ResultSet:
4627
4628   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4629
4630   while( my $artist = $resultset->next ) {
4631     ... do stuff ...
4632   }
4633
4634   $resultset->first; # without cache, this would issue a query
4635
4636 By default, searches are not cached.
4637
4638 For more examples of using these attributes, see
4639 L<DBIx::Class::Manual::Cookbook>.
4640
4641 =head2 for
4642
4643 =over 4
4644
4645 =item Value: ( 'update' | 'shared' | \$scalar )
4646
4647 =back
4648
4649 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4650 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4651 query.
4652
4653 =head1 PREFETCHING
4654
4655 DBIx::Class supports arbitrary related data prefetching from multiple related
4656 sources. Any combination of relationship types and column sets are supported.
4657 If L<collapsing|/collapse> is requested, there is an additional requirement of
4658 selecting enough data to make every individual object uniquely identifiable.
4659
4660 Here are some more involved examples, based on the following relationship map:
4661
4662   # Assuming:
4663   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4664   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4665   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4666
4667   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4668
4669   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4670
4671
4672
4673   my $rs = $schema->resultset('Tag')->search(
4674     undef,
4675     {
4676       prefetch => {
4677         cd => 'artist'
4678       }
4679     }
4680   );
4681
4682 The initial search results in SQL like the following:
4683
4684   SELECT tag.*, cd.*, artist.* FROM tag
4685   JOIN cd ON tag.cd = cd.cdid
4686   JOIN artist ON cd.artist = artist.artistid
4687
4688 L<DBIx::Class> has no need to go back to the database when we access the
4689 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4690 case.
4691
4692 Simple prefetches will be joined automatically, so there is no need
4693 for a C<join> attribute in the above search.
4694
4695 The L</prefetch> attribute can be used with any of the relationship types
4696 and multiple prefetches can be specified together. Below is a more complex
4697 example that prefetches a CD's artist, its liner notes (if present),
4698 the cover image, the tracks on that CD, and the guests on those
4699 tracks.
4700
4701   my $rs = $schema->resultset('CD')->search(
4702     undef,
4703     {
4704       prefetch => [
4705         { artist => 'record_label'},  # belongs_to => belongs_to
4706         'liner_note',                 # might_have
4707         'cover_image',                # has_one
4708         { tracks => 'guests' },       # has_many => has_many
4709       ]
4710     }
4711   );
4712
4713 This will produce SQL like the following:
4714
4715   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4716          tracks.*, guests.*
4717     FROM cd me
4718     JOIN artist artist
4719       ON artist.artistid = me.artistid
4720     JOIN record_label record_label
4721       ON record_label.labelid = artist.labelid
4722     LEFT JOIN track tracks
4723       ON tracks.cdid = me.cdid
4724     LEFT JOIN guest guests
4725       ON guests.trackid = track.trackid
4726     LEFT JOIN liner_notes liner_note
4727       ON liner_note.cdid = me.cdid
4728     JOIN cd_artwork cover_image
4729       ON cover_image.cdid = me.cdid
4730   ORDER BY tracks.cd
4731
4732 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4733 C<tracks>, and C<guests> of the CD will all be available through the
4734 relationship accessors without the need for additional queries to the
4735 database.
4736
4737 =head3 CAVEATS
4738
4739 Prefetch does a lot of deep magic. As such, it may not behave exactly
4740 as you might expect.
4741
4742 =over 4
4743
4744 =item *
4745
4746 Prefetch uses the L</cache> to populate the prefetched relationships. This
4747 may or may not be what you want.
4748
4749 =item *
4750
4751 If you specify a condition on a prefetched relationship, ONLY those
4752 rows that match the prefetched condition will be fetched into that relationship.
4753 This means that adding prefetch to a search() B<may alter> what is returned by
4754 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4755
4756   my $artist_rs = $schema->resultset('Artist')->search({
4757       'cds.year' => 2008,
4758   }, {
4759       join => 'cds',
4760   });
4761
4762   my $count = $artist_rs->first->cds->count;
4763
4764   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4765
4766   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4767
4768   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4769
4770 That cmp_ok() may or may not pass depending on the datasets involved. In other
4771 words the C<WHERE> condition would apply to the entire dataset, just like
4772 it would in regular SQL. If you want to add a condition only to the "right side"
4773 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4774 condition|DBIx::Class::Relationship::Base/condition>
4775
4776 =back
4777
4778 =head1 DBIC BIND VALUES
4779
4780 Because DBIC may need more information to bind values than just the column name
4781 and value itself, it uses a special format for both passing and receiving bind
4782 values.  Each bind value should be composed of an arrayref of
4783 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4784
4785 =over 4
4786
4787 =item dbd_attrs
4788
4789 If present (in any form), this is what is being passed directly to bind_param.
4790 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4791 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4792
4793 If this is specified, all other bind options described below are ignored.
4794
4795 =item sqlt_datatype
4796
4797 If present, this is used to infer the actual bind attribute by passing to
4798 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4799 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4800
4801 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4802 currently drivers are expected to "Do the Right Thing" when given a common
4803 datatype name.  (Not ideal, but that's what we got at this point.)
4804
4805 =item sqlt_size
4806
4807 Currently used to correctly allocate buffers for bind_param_inout().
4808 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4809 or to a sensible value based on the "data_type".
4810
4811 =item dbic_colname
4812
4813 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4814 explicitly specified they are never overridden).  Also used by some weird DBDs,
4815 where the column name should be available at bind_param time (e.g. Oracle).
4816
4817 =back
4818
4819 For backwards compatibility and convenience, the following shortcuts are
4820 supported:
4821
4822   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4823   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4824   [ undef,   $val ] === [ {}, $val ]
4825   $val              === [ {}, $val ]
4826
4827 =head1 FURTHER QUESTIONS?
4828
4829 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4830
4831 =head1 COPYRIGHT AND LICENSE
4832
4833 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4834 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4835 redistribute it and/or modify it under the same terms as the
4836 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4837
4838 =cut