lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp join ("\n",
 877     'search_like() is deprecated and will be removed in 0.09.',
 878     'Instead use ->search({ x => { -like => "y%" } })',
 879     '(note the outer pair of {}s - they are important!)'
 880   );
 881   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 882   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 883   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 884   return $class->search($query, { %$attrs });
 885 }
 886
 887 =head2 slice
 888
 889 =over 4
 890
 891 =item Arguments: $first, $last
 892
 893 =item Return Value: $resultset (scalar context), @row_objs (list context)
 894
 895 =back
 896
 897 Returns a resultset or object list representing a subset of elements from the
 898 resultset slice is called on. Indexes are from 0, i.e., to get the first
 899 three records, call:
 900
 901   my ($one, $two, $three) = $rs->slice(0, 2);
 902
 903 =cut
 904
 905 sub slice {
 906   my ($self, $min, $max) = @_;
 907   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 908   $attrs->{offset} = $self->{attrs}{offset} || 0;
 909   $attrs->{offset} += $min;
 910   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 911   return $self->search(undef(), $attrs);
 912   #my $slice = (ref $self)->new($self->result_source, $attrs);
 913   #return (wantarray ? $slice->all : $slice);
 914 }
 915
 916 =head2 next
 917
 918 =over 4
 919
 920 =item Arguments: none
 921
 922 =item Return Value: $result?
 923
 924 =back
 925
 926 Returns the next element in the resultset (C<undef> is there is none).
 927
 928 Can be used to efficiently iterate over records in the resultset:
 929
 930   my $rs = $schema->resultset('CD')->search;
 931   while (my $cd = $rs->next) {
 932     print $cd->title;
 933   }
 934
 935 Note that you need to store the resultset object, and call C<next> on it.
 936 Calling C<< resultset('Table')->next >> repeatedly will always return the
 937 first record from the resultset.
 938
 939 =cut
 940
 941 sub next {
 942   my ($self) = @_;
 943   if (my $cache = $self->get_cache) {
 944     $self->{all_cache_position} ||= 0;
 945     return $cache->[$self->{all_cache_position}++];
 946   }
 947   if ($self->{attrs}{cache}) {
 948     $self->{all_cache_position} = 1;
 949     return ($self->all)[0];
 950   }
 951   if ($self->{stashed_objects}) {
 952     my $obj = shift(@{$self->{stashed_objects}});
 953     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 954     return $obj;
 955   }
 956   my @row = (
 957     exists $self->{stashed_row}
 958       ? @{delete $self->{stashed_row}}
 959       : $self->cursor->next
 960   );
 961   return undef unless (@row);
 962   my ($row, @more) = $self->_construct_object(@row);
 963   $self->{stashed_objects} = \@more if @more;
 964   return $row;
 965 }
 966
 967 sub _construct_object {
 968   my ($self, @row) = @_;
 969   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 970   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 971   @new = $self->{_attrs}{record_filter}->(@new)
 972     if exists $self->{_attrs}{record_filter};
 973   return @new;
 974 }
 975
 976 sub _collapse_result {
 977   my ($self, $as_proto, $row) = @_;
 978
 979   my @copy = @$row;
 980
 981   # 'foo'         => [ undef, 'foo' ]
 982   # 'foo.bar'     => [ 'foo', 'bar' ]
 983   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 984
 985   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 986
 987   my %collapse = %{$self->{_attrs}{collapse}||{}};
 988
 989   my @pri_index;
 990
 991   # if we're doing collapsing (has_many prefetch) we need to grab records
 992   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 993   # we know we don't have to bother.
 994
 995   # the reason for not using the collapse stuff directly is because if you
 996   # had for e.g. two artists in a row with no cds, the collapse info for
 997   # both would be NULL (undef) so you'd lose the second artist
 998
 999   # store just the index so we can check the array positions from the row
1000   # without having to contruct the full hash
1001
1002   if (keys %collapse) {
1003     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1004     foreach my $i (0 .. $#construct_as) {
1005       next if defined($construct_as[$i][0]); # only self table
1006       if (delete $pri{$construct_as[$i][1]}) {
1007         push(@pri_index, $i);
1008       }
1009       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1010     }
1011   }
1012
1013   # no need to do an if, it'll be empty if @pri_index is empty anyway
1014
1015   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1016
1017   my @const_rows;
1018
1019   do { # no need to check anything at the front, we always want the first row
1020
1021     my %const;
1022
1023     foreach my $this_as (@construct_as) {
1024       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1025     }
1026
1027     push(@const_rows, \%const);
1028
1029   } until ( # no pri_index => no collapse => drop straight out
1030       !@pri_index
1031     or
1032       do { # get another row, stash it, drop out if different PK
1033
1034         @copy = $self->cursor->next;
1035         $self->{stashed_row} = \@copy;
1036
1037         # last thing in do block, counts as true if anything doesn't match
1038
1039         # check xor defined first for NULL vs. NOT NULL then if one is
1040         # defined the other must be so check string equality
1041
1042         grep {
1043           (defined $pri_vals{$_} ^ defined $copy[$_])
1044           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1045         } @pri_index;
1046       }
1047   );
1048
1049   my $alias = $self->{attrs}{alias};
1050   my $info = [];
1051
1052   my %collapse_pos;
1053
1054   my @const_keys;
1055
1056   foreach my $const (@const_rows) {
1057     scalar @const_keys or do {
1058       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1059     };
1060     foreach my $key (@const_keys) {
1061       if (length $key) {
1062         my $target = $info;
1063         my @parts = split(/\./, $key);
1064         my $cur = '';
1065         my $data = $const->{$key};
1066         foreach my $p (@parts) {
1067           $target = $target->[1]->{$p} ||= [];
1068           $cur .= ".${p}";
1069           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1070             # collapsing at this point and on final part
1071             my $pos = $collapse_pos{$cur};
1072             CK: foreach my $ck (@ckey) {
1073               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1074                 $collapse_pos{$cur} = $data;
1075                 delete @collapse_pos{ # clear all positioning for sub-entries
1076                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1077                 };
1078                 push(@$target, []);
1079                 last CK;
1080               }
1081             }
1082           }
1083           if (exists $collapse{$cur}) {
1084             $target = $target->[-1];
1085           }
1086         }
1087         $target->[0] = $data;
1088       } else {
1089         $info->[0] = $const->{$key};
1090       }
1091     }
1092   }
1093
1094   return $info;
1095 }
1096
1097 =head2 result_source
1098
1099 =over 4
1100
1101 =item Arguments: $result_source?
1102
1103 =item Return Value: $result_source
1104
1105 =back
1106
1107 An accessor for the primary ResultSource object from which this ResultSet
1108 is derived.
1109
1110 =head2 result_class
1111
1112 =over 4
1113
1114 =item Arguments: $result_class?
1115
1116 =item Return Value: $result_class
1117
1118 =back
1119
1120 An accessor for the class to use when creating row objects. Defaults to
1121 C<< result_source->result_class >> - which in most cases is the name of the
1122 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1123
1124 Note that changing the result_class will also remove any components
1125 that were originally loaded in the source class via
1126 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1127 in the original source class will not run.
1128
1129 =cut
1130
1131 sub result_class {
1132   my ($self, $result_class) = @_;
1133   if ($result_class) {
1134     $self->ensure_class_loaded($result_class);
1135     $self->_result_class($result_class);
1136   }
1137   $self->_result_class;
1138 }
1139
1140 =head2 count
1141
1142 =over 4
1143
1144 =item Arguments: $cond, \%attrs??
1145
1146 =item Return Value: $count
1147
1148 =back
1149
1150 Performs an SQL C<COUNT> with the same query as the resultset was built
1151 with to find the number of elements. If passed arguments, does a search
1152 on the resultset and counts the results of that.
1153
1154 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1155 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1156 not support C<DISTINCT> with multiple columns. If you are using such a
1157 database, you should only use columns from the main table in your C<group_by>
1158 clause.
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166   my $count = $self->_count;
1167   return 0 unless $count;
1168
1169   # need to take offset from resolved attrs
1170
1171   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1172   $count = $self->{attrs}{rows} if
1173     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1174   $count = 0 if ($count < 0);
1175   return $count;
1176 }
1177
1178 sub _count { # Separated out so pager can get the full count
1179   my $self = shift;
1180   my $select = { count => '*' };
1181
1182   my $attrs = { %{$self->_resolved_attrs} };
1183   if (my $group_by = delete $attrs->{group_by}) {
1184     delete $attrs->{having};
1185     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1186     # todo: try CONCAT for multi-column pk
1187     my @pk = $self->result_source->primary_columns;
1188     if (@pk == 1) {
1189       my $alias = $attrs->{alias};
1190       foreach my $column (@distinct) {
1191         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1192           @distinct = ($column);
1193           last;
1194         }
1195       }
1196     }
1197
1198     $select = { count => { distinct => \@distinct } };
1199   }
1200
1201   $attrs->{select} = $select;
1202   $attrs->{as} = [qw/count/];
1203
1204   # offset, order by and page are not needed to count. record_filter is cdbi
1205   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1206
1207   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1208   my ($count) = $tmp_rs->cursor->next;
1209   return $count;
1210 }
1211
1212 sub _bool {
1213   return 1;
1214 }
1215
1216 =head2 count_literal
1217
1218 =over 4
1219
1220 =item Arguments: $sql_fragment, @bind_values
1221
1222 =item Return Value: $count
1223
1224 =back
1225
1226 Counts the results in a literal query. Equivalent to calling L</search_literal>
1227 with the passed arguments, then L</count>.
1228
1229 =cut
1230
1231 sub count_literal { shift->search_literal(@_)->count; }
1232
1233 =head2 all
1234
1235 =over 4
1236
1237 =item Arguments: none
1238
1239 =item Return Value: @objects
1240
1241 =back
1242
1243 Returns all elements in the resultset. Called implicitly if the resultset
1244 is returned in list context.
1245
1246 =cut
1247
1248 sub all {
1249   my $self = shift;
1250   if(@_) {
1251       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1252   }
1253
1254   return @{ $self->get_cache } if $self->get_cache;
1255
1256   my @obj;
1257
1258   # TODO: don't call resolve here
1259   if (keys %{$self->_resolved_attrs->{collapse}}) {
1260 #  if ($self->{attrs}{prefetch}) {
1261       # Using $self->cursor->all is really just an optimisation.
1262       # If we're collapsing has_many prefetches it probably makes
1263       # very little difference, and this is cleaner than hacking
1264       # _construct_object to survive the approach
1265     my @row = $self->cursor->next;
1266     while (@row) {
1267       push(@obj, $self->_construct_object(@row));
1268       @row = (exists $self->{stashed_row}
1269                ? @{delete $self->{stashed_row}}
1270                : $self->cursor->next);
1271     }
1272   } else {
1273     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1274   }
1275
1276   $self->set_cache(\@obj) if $self->{attrs}{cache};
1277   return @obj;
1278 }
1279
1280 =head2 reset
1281
1282 =over 4
1283
1284 =item Arguments: none
1285
1286 =item Return Value: $self
1287
1288 =back
1289
1290 Resets the resultset's cursor, so you can iterate through the elements again.
1291
1292 =cut
1293
1294 sub reset {
1295   my ($self) = @_;
1296   delete $self->{_attrs} if exists $self->{_attrs};
1297   $self->{all_cache_position} = 0;
1298   $self->cursor->reset;
1299   return $self;
1300 }
1301
1302 =head2 first
1303
1304 =over 4
1305
1306 =item Arguments: none
1307
1308 =item Return Value: $object?
1309
1310 =back
1311
1312 Resets the resultset and returns an object for the first result (if the
1313 resultset returns anything).
1314
1315 =cut
1316
1317 sub first {
1318   return $_[0]->reset->next;
1319 }
1320
1321 # _cond_for_update_delete
1322 #
1323 # update/delete require the condition to be modified to handle
1324 # the differing SQL syntax available.  This transforms the $self->{cond}
1325 # appropriately, returning the new condition.
1326
1327 sub _cond_for_update_delete {
1328   my ($self, $full_cond) = @_;
1329   my $cond = {};
1330
1331   $full_cond ||= $self->{cond};
1332   # No-op. No condition, we're updating/deleting everything
1333   return $cond unless ref $full_cond;
1334
1335   foreach my $pk ($self->result_source->primary_columns) {
1336       $cond->{$pk} = { IN => $self->get_column($pk)->as_query({ skip_parens => 1 }) };
1337   }
1338
1339   return $cond;
1340 }
1341
1342
1343 =head2 update
1344
1345 =over 4
1346
1347 =item Arguments: \%values
1348
1349 =item Return Value: $storage_rv
1350
1351 =back
1352
1353 Sets the specified columns in the resultset to the supplied values in a
1354 single query. Return value will be true if the update succeeded or false
1355 if no records were updated; exact type of success value is storage-dependent.
1356
1357 =cut
1358
1359 sub update {
1360   my ($self, $values) = @_;
1361   $self->throw_exception("Values for update must be a hash")
1362     unless ref $values eq 'HASH';
1363
1364   my $cond = $self->_cond_for_update_delete;
1365
1366   return $self->result_source->storage->update(
1367     $self->result_source, $values, $cond
1368   );
1369 }
1370
1371 =head2 update_all
1372
1373 =over 4
1374
1375 =item Arguments: \%values
1376
1377 =item Return Value: 1
1378
1379 =back
1380
1381 Fetches all objects and updates them one at a time. Note that C<update_all>
1382 will run DBIC cascade triggers, while L</update> will not.
1383
1384 =cut
1385
1386 sub update_all {
1387   my ($self, $values) = @_;
1388   $self->throw_exception("Values for update must be a hash")
1389     unless ref $values eq 'HASH';
1390   foreach my $obj ($self->all) {
1391     $obj->set_columns($values)->update;
1392   }
1393   return 1;
1394 }
1395
1396 =head2 delete
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: 1
1403
1404 =back
1405
1406 Deletes the contents of the resultset from its result source. Note that this
1407 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1408 to run. See also L<DBIx::Class::Row/delete>.
1409
1410 delete may not generate correct SQL for a query with joins or a resultset
1411 chained from a related resultset.  In this case it will generate a warning:-
1412
1413 In these cases you may find that delete_all is more appropriate, or you
1414 need to respecify your query in a way that can be expressed without a join.
1415
1416 =cut
1417
1418 sub delete {
1419   my ($self) = @_;
1420   $self->throw_exception("Delete should not be passed any arguments")
1421     if $_[1];
1422
1423   my $cond = $self->_cond_for_update_delete;
1424
1425   $self->result_source->storage->delete($self->result_source, $cond);
1426   return 1;
1427 }
1428
1429 =head2 delete_all
1430
1431 =over 4
1432
1433 =item Arguments: none
1434
1435 =item Return Value: 1
1436
1437 =back
1438
1439 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1440 will run DBIC cascade triggers, while L</delete> will not.
1441
1442 =cut
1443
1444 sub delete_all {
1445   my ($self) = @_;
1446   $_->delete for $self->all;
1447   return 1;
1448 }
1449
1450 =head2 populate
1451
1452 =over 4
1453
1454 =item Arguments: \@data;
1455
1456 =back
1457
1458 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1459 For the arrayref of hashrefs style each hashref should be a structure suitable
1460 forsubmitting to a $resultset->create(...) method.
1461
1462 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1463 to insert the data, as this is a faster method.
1464
1465 Otherwise, each set of data is inserted into the database using
1466 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1467 objects is returned.
1468
1469 Example:  Assuming an Artist Class that has many CDs Classes relating:
1470
1471   my $Artist_rs = $schema->resultset("Artist");
1472
1473   ## Void Context Example
1474   $Artist_rs->populate([
1475      { artistid => 4, name => 'Manufactured Crap', cds => [
1476         { title => 'My First CD', year => 2006 },
1477         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1478       ],
1479      },
1480      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1481         { title => 'My parents sold me to a record company' ,year => 2005 },
1482         { title => 'Why Am I So Ugly?', year => 2006 },
1483         { title => 'I Got Surgery and am now Popular', year => 2007 }
1484       ],
1485      },
1486   ]);
1487
1488   ## Array Context Example
1489   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1490     { name => "Artist One"},
1491     { name => "Artist Two"},
1492     { name => "Artist Three", cds=> [
1493     { title => "First CD", year => 2007},
1494     { title => "Second CD", year => 2008},
1495   ]}
1496   ]);
1497
1498   print $ArtistOne->name; ## response is 'Artist One'
1499   print $ArtistThree->cds->count ## reponse is '2'
1500
1501 For the arrayref of arrayrefs style,  the first element should be a list of the
1502 fieldsnames to which the remaining elements are rows being inserted.  For
1503 example:
1504
1505   $Arstist_rs->populate([
1506     [qw/artistid name/],
1507     [100, 'A Formally Unknown Singer'],
1508     [101, 'A singer that jumped the shark two albums ago'],
1509     [102, 'An actually cool singer.'],
1510   ]);
1511
1512 Please note an important effect on your data when choosing between void and
1513 wantarray context. Since void context goes straight to C<insert_bulk> in
1514 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1515 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1516 create primary keys for you, you will find that your PKs are empty.  In this
1517 case you will have to use the wantarray context in order to create those
1518 values.
1519
1520 =cut
1521
1522 sub populate {
1523   my $self = shift @_;
1524   my $data = ref $_[0][0] eq 'HASH'
1525     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1526     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1527
1528   if(defined wantarray) {
1529     my @created;
1530     foreach my $item (@$data) {
1531       push(@created, $self->create($item));
1532     }
1533     return @created;
1534   } else {
1535     my ($first, @rest) = @$data;
1536
1537     my @names = grep {!ref $first->{$_}} keys %$first;
1538     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1539     my @pks = $self->result_source->primary_columns;
1540
1541     ## do the belongs_to relationships
1542     foreach my $index (0..$#$data) {
1543       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1544         my @ret = $self->populate($data);
1545         return;
1546       }
1547
1548       foreach my $rel (@rels) {
1549         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1550         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1551         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1552         my $related = $result->result_source->resolve_condition(
1553           $result->result_source->relationship_info($reverse)->{cond},
1554           $self,
1555           $result,
1556         );
1557
1558         delete $data->[$index]->{$rel};
1559         $data->[$index] = {%{$data->[$index]}, %$related};
1560
1561         push @names, keys %$related if $index == 0;
1562       }
1563     }
1564
1565     ## do bulk insert on current row
1566     my @values = map { [ @$_{@names} ] } @$data;
1567
1568     $self->result_source->storage->insert_bulk(
1569       $self->result_source,
1570       \@names,
1571       \@values,
1572     );
1573
1574     ## do the has_many relationships
1575     foreach my $item (@$data) {
1576
1577       foreach my $rel (@rels) {
1578         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1579
1580         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1581      || $self->throw_exception('Cannot find the relating object.');
1582
1583         my $child = $parent->$rel;
1584
1585         my $related = $child->result_source->resolve_condition(
1586           $parent->result_source->relationship_info($rel)->{cond},
1587           $child,
1588           $parent,
1589         );
1590
1591         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1592         my @populate = map { {%$_, %$related} } @rows_to_add;
1593
1594         $child->populate( \@populate );
1595       }
1596     }
1597   }
1598 }
1599
1600 =head2 _normalize_populate_args ($args)
1601
1602 Private method used by L</populate> to normalize its incoming arguments.  Factored
1603 out in case you want to subclass and accept new argument structures to the
1604 L</populate> method.
1605
1606 =cut
1607
1608 sub _normalize_populate_args {
1609   my ($self, $data) = @_;
1610   my @names = @{shift(@$data)};
1611   my @results_to_create;
1612   foreach my $datum (@$data) {
1613     my %result_to_create;
1614     foreach my $index (0..$#names) {
1615       $result_to_create{$names[$index]} = $$datum[$index];
1616     }
1617     push @results_to_create, \%result_to_create;
1618   }
1619   return \@results_to_create;
1620 }
1621
1622 =head2 pager
1623
1624 =over 4
1625
1626 =item Arguments: none
1627
1628 =item Return Value: $pager
1629
1630 =back
1631
1632 Return Value a L<Data::Page> object for the current resultset. Only makes
1633 sense for queries with a C<page> attribute.
1634
1635 To get the full count of entries for a paged resultset, call
1636 C<total_entries> on the L<Data::Page> object.
1637
1638 =cut
1639
1640 sub pager {
1641   my ($self) = @_;
1642   my $attrs = $self->{attrs};
1643   $self->throw_exception("Can't create pager for non-paged rs")
1644     unless $self->{attrs}{page};
1645   $attrs->{rows} ||= 10;
1646   return $self->{pager} ||= Data::Page->new(
1647     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1648 }
1649
1650 =head2 page
1651
1652 =over 4
1653
1654 =item Arguments: $page_number
1655
1656 =item Return Value: $rs
1657
1658 =back
1659
1660 Returns a resultset for the $page_number page of the resultset on which page
1661 is called, where each page contains a number of rows equal to the 'rows'
1662 attribute set on the resultset (10 by default).
1663
1664 =cut
1665
1666 sub page {
1667   my ($self, $page) = @_;
1668   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1669 }
1670
1671 =head2 new_result
1672
1673 =over 4
1674
1675 =item Arguments: \%vals
1676
1677 =item Return Value: $rowobject
1678
1679 =back
1680
1681 Creates a new row object in the resultset's result class and returns
1682 it. The row is not inserted into the database at this point, call
1683 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1684 will tell you whether the row object has been inserted or not.
1685
1686 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1687
1688 =cut
1689
1690 sub new_result {
1691   my ($self, $values) = @_;
1692   $self->throw_exception( "new_result needs a hash" )
1693     unless (ref $values eq 'HASH');
1694
1695   my %new;
1696   my $alias = $self->{attrs}{alias};
1697
1698   if (
1699     defined $self->{cond}
1700     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1701   ) {
1702     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1703     $new{-from_resultset} = [ keys %new ] if keys %new;
1704   } else {
1705     $self->throw_exception(
1706       "Can't abstract implicit construct, condition not a hash"
1707     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1708
1709     my $collapsed_cond = (
1710       $self->{cond}
1711         ? $self->_collapse_cond($self->{cond})
1712         : {}
1713     );
1714
1715     # precendence must be given to passed values over values inherited from
1716     # the cond, so the order here is important.
1717     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1718     while( my($col,$value) = each %implied ){
1719       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1720         $new{$col} = $value->{'='};
1721         next;
1722       }
1723       $new{$col} = $value if $self->_is_deterministic_value($value);
1724     }
1725   }
1726
1727   %new = (
1728     %new,
1729     %{ $self->_remove_alias($values, $alias) },
1730     -source_handle => $self->_source_handle,
1731     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1732   );
1733
1734   return $self->result_class->new(\%new);
1735 }
1736
1737 # _is_deterministic_value
1738 #
1739 # Make an effor to strip non-deterministic values from the condition,
1740 # to make sure new_result chokes less
1741
1742 sub _is_deterministic_value {
1743   my $self = shift;
1744   my $value = shift;
1745   my $ref_type = ref $value;
1746   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1747   return 1 if Scalar::Util::blessed($value);
1748   return 0;
1749 }
1750
1751 # _collapse_cond
1752 #
1753 # Recursively collapse the condition.
1754
1755 sub _collapse_cond {
1756   my ($self, $cond, $collapsed) = @_;
1757
1758   $collapsed ||= {};
1759
1760   if (ref $cond eq 'ARRAY') {
1761     foreach my $subcond (@$cond) {
1762       next unless ref $subcond;  # -or
1763 #      warn "ARRAY: " . Dumper $subcond;
1764       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1765     }
1766   }
1767   elsif (ref $cond eq 'HASH') {
1768     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1769       foreach my $subcond (@{$cond->{-and}}) {
1770 #        warn "HASH: " . Dumper $subcond;
1771         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1772       }
1773     }
1774     else {
1775 #      warn "LEAF: " . Dumper $cond;
1776       foreach my $col (keys %$cond) {
1777         my $value = $cond->{$col};
1778         $collapsed->{$col} = $value;
1779       }
1780     }
1781   }
1782
1783   return $collapsed;
1784 }
1785
1786 # _remove_alias
1787 #
1788 # Remove the specified alias from the specified query hash. A copy is made so
1789 # the original query is not modified.
1790
1791 sub _remove_alias {
1792   my ($self, $query, $alias) = @_;
1793
1794   my %orig = %{ $query || {} };
1795   my %unaliased;
1796
1797   foreach my $key (keys %orig) {
1798     if ($key !~ /\./) {
1799       $unaliased{$key} = $orig{$key};
1800       next;
1801     }
1802     $unaliased{$1} = $orig{$key}
1803       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1804   }
1805
1806   return \%unaliased;
1807 }
1808
1809 =head2 as_query (EXPERIMENTAL)
1810
1811 =over 4
1812
1813 =item Arguments: \%opts
1814
1815 =item Return Value: \[ $sql, @bind ]
1816
1817 =back
1818
1819 Returns the SQL query and bind vars associated with the invocant.
1820
1821 This is generally used as the RHS for a subquery.
1822
1823 B<NOTE>: This feature is still experimental.
1824
1825 The query returned will be surrounded by parentheses, e.g:
1826
1827   ( SELECT cdid FROM cd WHERE title LIKE '%Hits%' )
1828
1829 This behaviour can be changed by passing special options:
1830
1831   $rs->get_column('cdid')->as_query({ skip_parens => 1 });
1832
1833 =cut
1834
1835 sub as_query { return shift->cursor->as_query(@_) }
1836
1837 =head2 find_or_new
1838
1839 =over 4
1840
1841 =item Arguments: \%vals, \%attrs?
1842
1843 =item Return Value: $rowobject
1844
1845 =back
1846
1847   my $artist = $schema->resultset('Artist')->find_or_new(
1848     { artist => 'fred' }, { key => 'artists' });
1849
1850   $cd->cd_to_producer->find_or_new({ producer => $producer },
1851                                    { key => 'primary });
1852
1853 Find an existing record from this resultset, based on its primary
1854 key, or a unique constraint. If none exists, instantiate a new result
1855 object and return it. The object will not be saved into your storage
1856 until you call L<DBIx::Class::Row/insert> on it.
1857
1858 You most likely want this method when looking for existing rows using
1859 a unique constraint that is not the primary key, or looking for
1860 related rows.
1861
1862 If you want objects to be saved immediately, use L</find_or_create> instead.
1863
1864 B<Note>: C<find_or_new> is probably not what you want when creating a
1865 new row in a table that uses primary keys supplied by the
1866 database. Passing in a primary key column with a value of I<undef>
1867 will cause L</find> to attempt to search for a row with a value of
1868 I<NULL>.
1869
1870 =cut
1871
1872 sub find_or_new {
1873   my $self     = shift;
1874   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1875   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1876   my $exists   = $self->find($hash, $attrs);
1877   return defined $exists ? $exists : $self->new_result($hash);
1878 }
1879
1880 =head2 create
1881
1882 =over 4
1883
1884 =item Arguments: \%vals
1885
1886 =item Return Value: a L<DBIx::Class::Row> $object
1887
1888 =back
1889
1890 Attempt to create a single new row or a row with multiple related rows
1891 in the table represented by the resultset (and related tables). This
1892 will not check for duplicate rows before inserting, use
1893 L</find_or_create> to do that.
1894
1895 To create one row for this resultset, pass a hashref of key/value
1896 pairs representing the columns of the table and the values you wish to
1897 store. If the appropriate relationships are set up, foreign key fields
1898 can also be passed an object representing the foreign row, and the
1899 value will be set to its primary key.
1900
1901 To create related objects, pass a hashref for the value if the related
1902 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1903 and use the name of the relationship as the key. (NOT the name of the field,
1904 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1905 of hashrefs containing the data for each of the rows to create in the foreign
1906 tables, again using the relationship name as the key.
1907
1908 Instead of hashrefs of plain related data (key/value pairs), you may
1909 also pass new or inserted objects. New objects (not inserted yet, see
1910 L</new>), will be inserted into their appropriate tables.
1911
1912 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1913
1914 Example of creating a new row.
1915
1916   $person_rs->create({
1917     name=>"Some Person",
1918     email=>"somebody@someplace.com"
1919   });
1920
1921 Example of creating a new row and also creating rows in a related C<has_many>
1922 or C<has_one> resultset.  Note Arrayref.
1923
1924   $artist_rs->create(
1925      { artistid => 4, name => 'Manufactured Crap', cds => [
1926         { title => 'My First CD', year => 2006 },
1927         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1928       ],
1929      },
1930   );
1931
1932 Example of creating a new row and also creating a row in a related
1933 C<belongs_to>resultset. Note Hashref.
1934
1935   $cd_rs->create({
1936     title=>"Music for Silly Walks",
1937     year=>2000,
1938     artist => {
1939       name=>"Silly Musician",
1940     }
1941   });
1942
1943 =cut
1944
1945 sub create {
1946   my ($self, $attrs) = @_;
1947   $self->throw_exception( "create needs a hashref" )
1948     unless ref $attrs eq 'HASH';
1949   return $self->new_result($attrs)->insert;
1950 }
1951
1952 =head2 find_or_create
1953
1954 =over 4
1955
1956 =item Arguments: \%vals, \%attrs?
1957
1958 =item Return Value: $rowobject
1959
1960 =back
1961
1962   $cd->cd_to_producer->find_or_create({ producer => $producer },
1963                                       { key => 'primary });
1964
1965 Tries to find a record based on its primary key or unique constraints; if none
1966 is found, creates one and returns that instead.
1967
1968   my $cd = $schema->resultset('CD')->find_or_create({
1969     cdid   => 5,
1970     artist => 'Massive Attack',
1971     title  => 'Mezzanine',
1972     year   => 2005,
1973   });
1974
1975 Also takes an optional C<key> attribute, to search by a specific key or unique
1976 constraint. For example:
1977
1978   my $cd = $schema->resultset('CD')->find_or_create(
1979     {
1980       artist => 'Massive Attack',
1981       title  => 'Mezzanine',
1982     },
1983     { key => 'cd_artist_title' }
1984   );
1985
1986 B<Note>: Because find_or_create() reads from the database and then
1987 possibly inserts based on the result, this method is subject to a race
1988 condition. Another process could create a record in the table after
1989 the find has completed and before the create has started. To avoid
1990 this problem, use find_or_create() inside a transaction.
1991
1992 B<Note>: C<find_or_create> is probably not what you want when creating
1993 a new row in a table that uses primary keys supplied by the
1994 database. Passing in a primary key column with a value of I<undef>
1995 will cause L</find> to attempt to search for a row with a value of
1996 I<NULL>.
1997
1998 See also L</find> and L</update_or_create>. For information on how to declare
1999 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2000
2001 =cut
2002
2003 sub find_or_create {
2004   my $self     = shift;
2005   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2006   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2007   my $exists   = $self->find($hash, $attrs);
2008   return defined $exists ? $exists : $self->create($hash);
2009 }
2010
2011 =head2 update_or_create
2012
2013 =over 4
2014
2015 =item Arguments: \%col_values, { key => $unique_constraint }?
2016
2017 =item Return Value: $rowobject
2018
2019 =back
2020
2021   $resultset->update_or_create({ col => $val, ... });
2022
2023 First, searches for an existing row matching one of the unique constraints
2024 (including the primary key) on the source of this resultset. If a row is
2025 found, updates it with the other given column values. Otherwise, creates a new
2026 row.
2027
2028 Takes an optional C<key> attribute to search on a specific unique constraint.
2029 For example:
2030
2031   # In your application
2032   my $cd = $schema->resultset('CD')->update_or_create(
2033     {
2034       artist => 'Massive Attack',
2035       title  => 'Mezzanine',
2036       year   => 1998,
2037     },
2038     { key => 'cd_artist_title' }
2039   );
2040
2041   $cd->cd_to_producer->update_or_create({
2042     producer => $producer,
2043     name => 'harry',
2044   }, {
2045     key => 'primary,
2046   });
2047
2048
2049 If no C<key> is specified, it searches on all unique constraints defined on the
2050 source, including the primary key.
2051
2052 If the C<key> is specified as C<primary>, it searches only on the primary key.
2053
2054 See also L</find> and L</find_or_create>. For information on how to declare
2055 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2056
2057 B<Note>: C<update_or_create> is probably not what you want when
2058 looking for a row in a table that uses primary keys supplied by the
2059 database, unless you actually have a key value. Passing in a primary
2060 key column with a value of I<undef> will cause L</find> to attempt to
2061 search for a row with a value of I<NULL>.
2062
2063 =cut
2064
2065 sub update_or_create {
2066   my $self = shift;
2067   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2068   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2069
2070   my $row = $self->find($cond, $attrs);
2071   if (defined $row) {
2072     $row->update($cond);
2073     return $row;
2074   }
2075
2076   return $self->create($cond);
2077 }
2078
2079 =head2 update_or_new
2080
2081 =over 4
2082
2083 =item Arguments: \%col_values, { key => $unique_constraint }?
2084
2085 =item Return Value: $rowobject
2086
2087 =back
2088
2089   $resultset->update_or_new({ col => $val, ... });
2090
2091 First, searches for an existing row matching one of the unique constraints
2092 (including the primary key) on the source of this resultset. If a row is
2093 found, updates it with the other given column values. Otherwise, instantiate
2094 a new result object and return it. The object will not be saved into your storage
2095 until you call L<DBIx::Class::Row/insert> on it.
2096
2097 Takes an optional C<key> attribute to search on a specific unique constraint.
2098 For example:
2099
2100   # In your application
2101   my $cd = $schema->resultset('CD')->update_or_new(
2102     {
2103       artist => 'Massive Attack',
2104       title  => 'Mezzanine',
2105       year   => 1998,
2106     },
2107     { key => 'cd_artist_title' }
2108   );
2109
2110   if ($cd->in_storage) {
2111       # the cd was updated
2112   }
2113   else {
2114       # the cd is not yet in the database, let's insert it
2115       $cd->insert;
2116   }
2117
2118 See also L</find>, L</find_or_create> and L<find_or_new>.
2119
2120 =cut
2121
2122 sub update_or_new {
2123     my $self  = shift;
2124     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2125     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2126
2127     my $row = $self->find( $cond, $attrs );
2128     if ( defined $row ) {
2129         $row->update($cond);
2130         return $row;
2131     }
2132
2133     return $self->new_result($cond);
2134 }
2135
2136 =head2 get_cache
2137
2138 =over 4
2139
2140 =item Arguments: none
2141
2142 =item Return Value: \@cache_objects?
2143
2144 =back
2145
2146 Gets the contents of the cache for the resultset, if the cache is set.
2147
2148 The cache is populated either by using the L</prefetch> attribute to
2149 L</search> or by calling L</set_cache>.
2150
2151 =cut
2152
2153 sub get_cache {
2154   shift->{all_cache};
2155 }
2156
2157 =head2 set_cache
2158
2159 =over 4
2160
2161 =item Arguments: \@cache_objects
2162
2163 =item Return Value: \@cache_objects
2164
2165 =back
2166
2167 Sets the contents of the cache for the resultset. Expects an arrayref
2168 of objects of the same class as those produced by the resultset. Note that
2169 if the cache is set the resultset will return the cached objects rather
2170 than re-querying the database even if the cache attr is not set.
2171
2172 The contents of the cache can also be populated by using the
2173 L</prefetch> attribute to L</search>.
2174
2175 =cut
2176
2177 sub set_cache {
2178   my ( $self, $data ) = @_;
2179   $self->throw_exception("set_cache requires an arrayref")
2180       if defined($data) && (ref $data ne 'ARRAY');
2181   $self->{all_cache} = $data;
2182 }
2183
2184 =head2 clear_cache
2185
2186 =over 4
2187
2188 =item Arguments: none
2189
2190 =item Return Value: []
2191
2192 =back
2193
2194 Clears the cache for the resultset.
2195
2196 =cut
2197
2198 sub clear_cache {
2199   shift->set_cache(undef);
2200 }
2201
2202 =head2 related_resultset
2203
2204 =over 4
2205
2206 =item Arguments: $relationship_name
2207
2208 =item Return Value: $resultset
2209
2210 =back
2211
2212 Returns a related resultset for the supplied relationship name.
2213
2214   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2215
2216 =cut
2217
2218 sub related_resultset {
2219   my ($self, $rel) = @_;
2220
2221   $self->{related_resultsets} ||= {};
2222   return $self->{related_resultsets}{$rel} ||= do {
2223     my $rel_obj = $self->result_source->relationship_info($rel);
2224
2225     $self->throw_exception(
2226       "search_related: result source '" . $self->result_source->source_name .
2227         "' has no such relationship $rel")
2228       unless $rel_obj;
2229
2230     my ($from,$seen) = $self->_resolve_from($rel);
2231
2232     my $join_count = $seen->{$rel};
2233     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2234
2235     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2236     my %attrs = %{$self->{attrs}||{}};
2237     delete @attrs{qw(result_class alias)};
2238
2239     my $new_cache;
2240
2241     if (my $cache = $self->get_cache) {
2242       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2243         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2244                         @$cache ];
2245       }
2246     }
2247
2248     my $rel_source = $self->result_source->related_source($rel);
2249
2250     my $new = do {
2251
2252       # The reason we do this now instead of passing the alias to the
2253       # search_rs below is that if you wrap/overload resultset on the
2254       # source you need to know what alias it's -going- to have for things
2255       # to work sanely (e.g. RestrictWithObject wants to be able to add
2256       # extra query restrictions, and these may need to be $alias.)
2257
2258       my $attrs = $rel_source->resultset_attributes;
2259       local $attrs->{alias} = $alias;
2260
2261       $rel_source->resultset
2262                  ->search_rs(
2263                      undef, {
2264                        %attrs,
2265                        join => undef,
2266                        prefetch => undef,
2267                        select => undef,
2268                        as => undef,
2269                        where => $self->{cond},
2270                        seen_join => $seen,
2271                        from => $from,
2272                    });
2273     };
2274     $new->set_cache($new_cache) if $new_cache;
2275     $new;
2276   };
2277 }
2278
2279 =head2 current_source_alias
2280
2281 =over 4
2282
2283 =item Arguments: none
2284
2285 =item Return Value: $source_alias
2286
2287 =back
2288
2289 Returns the current table alias for the result source this resultset is built
2290 on, that will be used in the SQL query. Usually it is C<me>.
2291
2292 Currently the source alias that refers to the result set returned by a
2293 L</search>/L</find> family method depends on how you got to the resultset: it's
2294 C<me> by default, but eg. L</search_related> aliases it to the related result
2295 source name (and keeps C<me> referring to the original result set). The long
2296 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2297 (and make this method unnecessary).
2298
2299 Thus it's currently necessary to use this method in predefined queries (see
2300 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2301 source alias of the current result set:
2302
2303   # in a result set class
2304   sub modified_by {
2305     my ($self, $user) = @_;
2306
2307     my $me = $self->current_source_alias;
2308
2309     return $self->search(
2310       "$me.modified" => $user->id,
2311     );
2312   }
2313
2314 =cut
2315
2316 sub current_source_alias {
2317   my ($self) = @_;
2318
2319   return ($self->{attrs} || {})->{alias} || 'me';
2320 }
2321
2322 sub _resolve_from {
2323   my ($self, $extra_join) = @_;
2324   my $source = $self->result_source;
2325   my $attrs = $self->{attrs};
2326
2327   my $from = $attrs->{from}
2328     || [ { $attrs->{alias} => $source->from } ];
2329
2330   my $seen = { %{$attrs->{seen_join}||{}} };
2331
2332   my $join = ($attrs->{join}
2333                ? [ $attrs->{join}, $extra_join ]
2334                : $extra_join);
2335
2336   # we need to take the prefetch the attrs into account before we
2337   # ->resolve_join as otherwise they get lost - captainL
2338   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2339
2340   $from = [
2341     @$from,
2342     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2343   ];
2344
2345   return ($from,$seen);
2346 }
2347
2348 sub _resolved_attrs {
2349   my $self = shift;
2350   return $self->{_attrs} if $self->{_attrs};
2351
2352   my $attrs  = { %{ $self->{attrs} || {} } };
2353   my $source = $self->result_source;
2354   my $alias  = $attrs->{alias};
2355
2356   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2357   my @colbits;
2358
2359   # build columns (as long as select isn't set) into a set of as/select hashes
2360   unless ( $attrs->{select} ) {
2361       @colbits = map {
2362           ( ref($_) eq 'HASH' )
2363               ? $_
2364               : {
2365                   (
2366                     /^\Q${alias}.\E(.+)$/
2367                       ? "$1"
2368                       : "$_"
2369                   )
2370                 =>
2371                   (
2372                     /\./
2373                       ? "$_"
2374                       : "${alias}.$_"
2375                   )
2376             }
2377       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2378   }
2379   # add the additional columns on
2380   foreach ( 'include_columns', '+columns' ) {
2381       push @colbits, map {
2382           ( ref($_) eq 'HASH' )
2383             ? $_
2384             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2385       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2386   }
2387
2388   # start with initial select items
2389   if ( $attrs->{select} ) {
2390     $attrs->{select} =
2391         ( ref $attrs->{select} eq 'ARRAY' )
2392       ? [ @{ $attrs->{select} } ]
2393       : [ $attrs->{select} ];
2394     $attrs->{as} = (
2395       $attrs->{as}
2396       ? (
2397         ref $attrs->{as} eq 'ARRAY'
2398         ? [ @{ $attrs->{as} } ]
2399         : [ $attrs->{as} ]
2400         )
2401       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2402     );
2403   }
2404   else {
2405
2406     # otherwise we intialise select & as to empty
2407     $attrs->{select} = [];
2408     $attrs->{as}     = [];
2409   }
2410
2411   # now add colbits to select/as
2412   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2413   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2414
2415   my $adds;
2416   if ( $adds = delete $attrs->{'+select'} ) {
2417     $adds = [$adds] unless ref $adds eq 'ARRAY';
2418     push(
2419       @{ $attrs->{select} },
2420       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2421     );
2422   }
2423   if ( $adds = delete $attrs->{'+as'} ) {
2424     $adds = [$adds] unless ref $adds eq 'ARRAY';
2425     push( @{ $attrs->{as} }, @$adds );
2426   }
2427
2428   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2429
2430   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2431     my $join = delete $attrs->{join} || {};
2432
2433     if ( defined $attrs->{prefetch} ) {
2434       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2435
2436     }
2437
2438     $attrs->{from} =    # have to copy here to avoid corrupting the original
2439       [
2440       @{ $attrs->{from} },
2441       $source->resolve_join(
2442         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2443       )
2444       ];
2445
2446   }
2447
2448   $attrs->{group_by} ||= $attrs->{select}
2449     if delete $attrs->{distinct};
2450   if ( $attrs->{order_by} ) {
2451     $attrs->{order_by} = (
2452       ref( $attrs->{order_by} ) eq 'ARRAY'
2453       ? [ @{ $attrs->{order_by} } ]
2454       : [ $attrs->{order_by} ]
2455     );
2456   }
2457   else {
2458     $attrs->{order_by} = [];
2459   }
2460
2461   my $collapse = $attrs->{collapse} || {};
2462   if ( my $prefetch = delete $attrs->{prefetch} ) {
2463     $prefetch = $self->_merge_attr( {}, $prefetch );
2464     my @pre_order;
2465     my $seen = { %{ $attrs->{seen_join} || {} } };
2466     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2467
2468       # bring joins back to level of current class
2469       my @prefetch =
2470         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2471       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2472       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2473     }
2474     push( @{ $attrs->{order_by} }, @pre_order );
2475   }
2476   $attrs->{collapse} = $collapse;
2477
2478   if ( $attrs->{page} ) {
2479     $attrs->{offset} ||= 0;
2480     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2481   }
2482
2483   return $self->{_attrs} = $attrs;
2484 }
2485
2486 sub _rollout_attr {
2487   my ($self, $attr) = @_;
2488
2489   if (ref $attr eq 'HASH') {
2490     return $self->_rollout_hash($attr);
2491   } elsif (ref $attr eq 'ARRAY') {
2492     return $self->_rollout_array($attr);
2493   } else {
2494     return [$attr];
2495   }
2496 }
2497
2498 sub _rollout_array {
2499   my ($self, $attr) = @_;
2500
2501   my @rolled_array;
2502   foreach my $element (@{$attr}) {
2503     if (ref $element eq 'HASH') {
2504       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2505     } elsif (ref $element eq 'ARRAY') {
2506       #  XXX - should probably recurse here
2507       push( @rolled_array, @{$self->_rollout_array($element)} );
2508     } else {
2509       push( @rolled_array, $element );
2510     }
2511   }
2512   return \@rolled_array;
2513 }
2514
2515 sub _rollout_hash {
2516   my ($self, $attr) = @_;
2517
2518   my @rolled_array;
2519   foreach my $key (keys %{$attr}) {
2520     push( @rolled_array, { $key => $attr->{$key} } );
2521   }
2522   return \@rolled_array;
2523 }
2524
2525 sub _calculate_score {
2526   my ($self, $a, $b) = @_;
2527
2528   if (ref $b eq 'HASH') {
2529     my ($b_key) = keys %{$b};
2530     if (ref $a eq 'HASH') {
2531       my ($a_key) = keys %{$a};
2532       if ($a_key eq $b_key) {
2533         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2534       } else {
2535         return 0;
2536       }
2537     } else {
2538       return ($a eq $b_key) ? 1 : 0;
2539     }
2540   } else {
2541     if (ref $a eq 'HASH') {
2542       my ($a_key) = keys %{$a};
2543       return ($b eq $a_key) ? 1 : 0;
2544     } else {
2545       return ($b eq $a) ? 1 : 0;
2546     }
2547   }
2548 }
2549
2550 sub _merge_attr {
2551   my ($self, $orig, $import) = @_;
2552
2553   return $import unless defined($orig);
2554   return $orig unless defined($import);
2555
2556   $orig = $self->_rollout_attr($orig);
2557   $import = $self->_rollout_attr($import);
2558
2559   my $seen_keys;
2560   foreach my $import_element ( @{$import} ) {
2561     # find best candidate from $orig to merge $b_element into
2562     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2563     foreach my $orig_element ( @{$orig} ) {
2564       my $score = $self->_calculate_score( $orig_element, $import_element );
2565       if ($score > $best_candidate->{score}) {
2566         $best_candidate->{position} = $position;
2567         $best_candidate->{score} = $score;
2568       }
2569       $position++;
2570     }
2571     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2572
2573     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2574       push( @{$orig}, $import_element );
2575     } else {
2576       my $orig_best = $orig->[$best_candidate->{position}];
2577       # merge orig_best and b_element together and replace original with merged
2578       if (ref $orig_best ne 'HASH') {
2579         $orig->[$best_candidate->{position}] = $import_element;
2580       } elsif (ref $import_element eq 'HASH') {
2581         my ($key) = keys %{$orig_best};
2582         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2583       }
2584     }
2585     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2586   }
2587
2588   return $orig;
2589 }
2590
2591 sub result_source {
2592     my $self = shift;
2593
2594     if (@_) {
2595         $self->_source_handle($_[0]->handle);
2596     } else {
2597         $self->_source_handle->resolve;
2598     }
2599 }
2600
2601 =head2 throw_exception
2602
2603 See L<DBIx::Class::Schema/throw_exception> for details.
2604
2605 =cut
2606
2607 sub throw_exception {
2608   my $self=shift;
2609   if (ref $self && $self->_source_handle->schema) {
2610     $self->_source_handle->schema->throw_exception(@_)
2611   } else {
2612     croak(@_);
2613   }
2614
2615 }
2616
2617 # XXX: FIXME: Attributes docs need clearing up
2618
2619 =head1 ATTRIBUTES
2620
2621 Attributes are used to refine a ResultSet in various ways when
2622 searching for data. They can be passed to any method which takes an
2623 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2624 L</count>.
2625
2626 These are in no particular order:
2627
2628 =head2 order_by
2629
2630 =over 4
2631
2632 =item Value: ( $order_by | \@order_by | \%order_by )
2633
2634 =back
2635
2636 Which column(s) to order the results by. If a single column name, or
2637 an arrayref of names is supplied, the argument is passed through
2638 directly to SQL. The hashref syntax allows for connection-agnostic
2639 specification of ordering direction:
2640
2641  For descending order:
2642
2643   order_by => { -desc => [qw/col1 col2 col3/] }
2644
2645  For explicit ascending order:
2646
2647   order_by => { -asc => 'col' }
2648
2649 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2650 supported, although you are strongly encouraged to use the hashref
2651 syntax as outlined above.
2652
2653 =head2 columns
2654
2655 =over 4
2656
2657 =item Value: \@columns
2658
2659 =back
2660
2661 Shortcut to request a particular set of columns to be retrieved. Each
2662 column spec may be a string (a table column name), or a hash (in which
2663 case the key is the C<as> value, and the value is used as the C<select>
2664 expression). Adds C<me.> onto the start of any column without a C<.> in
2665 it and sets C<select> from that, then auto-populates C<as> from
2666 C<select> as normal. (You may also use the C<cols> attribute, as in
2667 earlier versions of DBIC.)
2668
2669 =head2 +columns
2670
2671 =over 4
2672
2673 =item Value: \@columns
2674
2675 =back
2676
2677 Indicates additional columns to be selected from storage. Works the same
2678 as L</columns> but adds columns to the selection. (You may also use the
2679 C<include_columns> attribute, as in earlier versions of DBIC). For
2680 example:-
2681
2682   $schema->resultset('CD')->search(undef, {
2683     '+columns' => ['artist.name'],
2684     join => ['artist']
2685   });
2686
2687 would return all CDs and include a 'name' column to the information
2688 passed to object inflation. Note that the 'artist' is the name of the
2689 column (or relationship) accessor, and 'name' is the name of the column
2690 accessor in the related table.
2691
2692 =head2 include_columns
2693
2694 =over 4
2695
2696 =item Value: \@columns
2697
2698 =back
2699
2700 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2701
2702 =head2 select
2703
2704 =over 4
2705
2706 =item Value: \@select_columns
2707
2708 =back
2709
2710 Indicates which columns should be selected from the storage. You can use
2711 column names, or in the case of RDBMS back ends, function or stored procedure
2712 names:
2713
2714   $rs = $schema->resultset('Employee')->search(undef, {
2715     select => [
2716       'name',
2717       { count => 'employeeid' },
2718       { sum => 'salary' }
2719     ]
2720   });
2721
2722 When you use function/stored procedure names and do not supply an C<as>
2723 attribute, the column names returned are storage-dependent. E.g. MySQL would
2724 return a column named C<count(employeeid)> in the above example.
2725
2726 =head2 +select
2727
2728 =over 4
2729
2730 Indicates additional columns to be selected from storage.  Works the same as
2731 L</select> but adds columns to the selection.
2732
2733 =back
2734
2735 =head2 +as
2736
2737 =over 4
2738
2739 Indicates additional column names for those added via L</+select>. See L</as>.
2740
2741 =back
2742
2743 =head2 as
2744
2745 =over 4
2746
2747 =item Value: \@inflation_names
2748
2749 =back
2750
2751 Indicates column names for object inflation. That is, C<as>
2752 indicates the name that the column can be accessed as via the
2753 C<get_column> method (or via the object accessor, B<if one already
2754 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2755
2756 The C<as> attribute is used in conjunction with C<select>,
2757 usually when C<select> contains one or more function or stored
2758 procedure names:
2759
2760   $rs = $schema->resultset('Employee')->search(undef, {
2761     select => [
2762       'name',
2763       { count => 'employeeid' }
2764     ],
2765     as => ['name', 'employee_count'],
2766   });
2767
2768   my $employee = $rs->first(); # get the first Employee
2769
2770 If the object against which the search is performed already has an accessor
2771 matching a column name specified in C<as>, the value can be retrieved using
2772 the accessor as normal:
2773
2774   my $name = $employee->name();
2775
2776 If on the other hand an accessor does not exist in the object, you need to
2777 use C<get_column> instead:
2778
2779   my $employee_count = $employee->get_column('employee_count');
2780
2781 You can create your own accessors if required - see
2782 L<DBIx::Class::Manual::Cookbook> for details.
2783
2784 Please note: This will NOT insert an C<AS employee_count> into the SQL
2785 statement produced, it is used for internal access only. Thus
2786 attempting to use the accessor in an C<order_by> clause or similar
2787 will fail miserably.
2788
2789 To get around this limitation, you can supply literal SQL to your
2790 C<select> attibute that contains the C<AS alias> text, eg:
2791
2792   select => [\'myfield AS alias']
2793
2794 =head2 join
2795
2796 =over 4
2797
2798 =item Value: ($rel_name | \@rel_names | \%rel_names)
2799
2800 =back
2801
2802 Contains a list of relationships that should be joined for this query.  For
2803 example:
2804
2805   # Get CDs by Nine Inch Nails
2806   my $rs = $schema->resultset('CD')->search(
2807     { 'artist.name' => 'Nine Inch Nails' },
2808     { join => 'artist' }
2809   );
2810
2811 Can also contain a hash reference to refer to the other relation's relations.
2812 For example:
2813
2814   package MyApp::Schema::Track;
2815   use base qw/DBIx::Class/;
2816   __PACKAGE__->table('track');
2817   __PACKAGE__->add_columns(qw/trackid cd position title/);
2818   __PACKAGE__->set_primary_key('trackid');
2819   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2820   1;
2821
2822   # In your application
2823   my $rs = $schema->resultset('Artist')->search(
2824     { 'track.title' => 'Teardrop' },
2825     {
2826       join     => { cd => 'track' },
2827       order_by => 'artist.name',
2828     }
2829   );
2830
2831 You need to use the relationship (not the table) name in  conditions,
2832 because they are aliased as such. The current table is aliased as "me", so
2833 you need to use me.column_name in order to avoid ambiguity. For example:
2834
2835   # Get CDs from 1984 with a 'Foo' track
2836   my $rs = $schema->resultset('CD')->search(
2837     {
2838       'me.year' => 1984,
2839       'tracks.name' => 'Foo'
2840     },
2841     { join => 'tracks' }
2842   );
2843
2844 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2845 similarly for a third time). For e.g.
2846
2847   my $rs = $schema->resultset('Artist')->search({
2848     'cds.title'   => 'Down to Earth',
2849     'cds_2.title' => 'Popular',
2850   }, {
2851     join => [ qw/cds cds/ ],
2852   });
2853
2854 will return a set of all artists that have both a cd with title 'Down
2855 to Earth' and a cd with title 'Popular'.
2856
2857 If you want to fetch related objects from other tables as well, see C<prefetch>
2858 below.
2859
2860 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2861
2862 =head2 prefetch
2863
2864 =over 4
2865
2866 =item Value: ($rel_name | \@rel_names | \%rel_names)
2867
2868 =back
2869
2870 Contains one or more relationships that should be fetched along with
2871 the main query (when they are accessed afterwards the data will
2872 already be available, without extra queries to the database).  This is
2873 useful for when you know you will need the related objects, because it
2874 saves at least one query:
2875
2876   my $rs = $schema->resultset('Tag')->search(
2877     undef,
2878     {
2879       prefetch => {
2880         cd => 'artist'
2881       }
2882     }
2883   );
2884
2885 The initial search results in SQL like the following:
2886
2887   SELECT tag.*, cd.*, artist.* FROM tag
2888   JOIN cd ON tag.cd = cd.cdid
2889   JOIN artist ON cd.artist = artist.artistid
2890
2891 L<DBIx::Class> has no need to go back to the database when we access the
2892 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2893 case.
2894
2895 Simple prefetches will be joined automatically, so there is no need
2896 for a C<join> attribute in the above search.
2897
2898 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2899 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2900 with an accessor type of 'single' or 'filter'). A more complex example that
2901 prefetches an artists cds, the tracks on those cds, and the tags associted
2902 with that artist is given below (assuming many-to-many from artists to tags):
2903
2904  my $rs = $schema->resultset('Artist')->search(
2905    undef,
2906    {
2907      prefetch => [
2908        { cds => 'tracks' },
2909        { artist_tags => 'tags' }
2910      ]
2911    }
2912  );
2913
2914
2915 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2916 attributes will be ignored.
2917
2918 =head2 page
2919
2920 =over 4
2921
2922 =item Value: $page
2923
2924 =back
2925
2926 Makes the resultset paged and specifies the page to retrieve. Effectively
2927 identical to creating a non-pages resultset and then calling ->page($page)
2928 on it.
2929
2930 If L<rows> attribute is not specified it defualts to 10 rows per page.
2931
2932 When you have a paged resultset, L</count> will only return the number
2933 of rows in the page. To get the total, use the L</pager> and call
2934 C<total_entries> on it.
2935
2936 =head2 rows
2937
2938 =over 4
2939
2940 =item Value: $rows
2941
2942 =back
2943
2944 Specifes the maximum number of rows for direct retrieval or the number of
2945 rows per page if the page attribute or method is used.
2946
2947 =head2 offset
2948
2949 =over 4
2950
2951 =item Value: $offset
2952
2953 =back
2954
2955 Specifies the (zero-based) row number for the  first row to be returned, or the
2956 of the first row of the first page if paging is used.
2957
2958 =head2 group_by
2959
2960 =over 4
2961
2962 =item Value: \@columns
2963
2964 =back
2965
2966 A arrayref of columns to group by. Can include columns of joined tables.
2967
2968   group_by => [qw/ column1 column2 ... /]
2969
2970 =head2 having
2971
2972 =over 4
2973
2974 =item Value: $condition
2975
2976 =back
2977
2978 HAVING is a select statement attribute that is applied between GROUP BY and
2979 ORDER BY. It is applied to the after the grouping calculations have been
2980 done.
2981
2982   having => { 'count(employee)' => { '>=', 100 } }
2983
2984 =head2 distinct
2985
2986 =over 4
2987
2988 =item Value: (0 | 1)
2989
2990 =back
2991
2992 Set to 1 to group by all columns.
2993
2994 =head2 where
2995
2996 =over 4
2997
2998 Adds to the WHERE clause.
2999
3000   # only return rows WHERE deleted IS NULL for all searches
3001   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3002
3003 Can be overridden by passing C<{ where => undef }> as an attribute
3004 to a resulset.
3005
3006 =back
3007
3008 =head2 cache
3009
3010 Set to 1 to cache search results. This prevents extra SQL queries if you
3011 revisit rows in your ResultSet:
3012
3013   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3014
3015   while( my $artist = $resultset->next ) {
3016     ... do stuff ...
3017   }
3018
3019   $rs->first; # without cache, this would issue a query
3020
3021 By default, searches are not cached.
3022
3023 For more examples of using these attributes, see
3024 L<DBIx::Class::Manual::Cookbook>.
3025
3026 =head2 from
3027
3028 =over 4
3029
3030 =item Value: \@from_clause
3031
3032 =back
3033
3034 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3035 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3036 clauses.
3037
3038 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3039
3040 C<join> will usually do what you need and it is strongly recommended that you
3041 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3042 And we really do mean "cannot", not just tried and failed. Attempting to use
3043 this because you're having problems with C<join> is like trying to use x86
3044 ASM because you've got a syntax error in your C. Trust us on this.
3045
3046 Now, if you're still really, really sure you need to use this (and if you're
3047 not 100% sure, ask the mailing list first), here's an explanation of how this
3048 works.
3049
3050 The syntax is as follows -
3051
3052   [
3053     { <alias1> => <table1> },
3054     [
3055       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3056       [], # nested JOIN (optional)
3057       { <table1.column1> => <table2.column2>, ... (more conditions) },
3058     ],
3059     # More of the above [ ] may follow for additional joins
3060   ]
3061
3062   <table1> <alias1>
3063   JOIN
3064     <table2> <alias2>
3065     [JOIN ...]
3066   ON <table1.column1> = <table2.column2>
3067   <more joins may follow>
3068
3069 An easy way to follow the examples below is to remember the following:
3070
3071     Anything inside "[]" is a JOIN
3072     Anything inside "{}" is a condition for the enclosing JOIN
3073
3074 The following examples utilize a "person" table in a family tree application.
3075 In order to express parent->child relationships, this table is self-joined:
3076
3077     # Person->belongs_to('father' => 'Person');
3078     # Person->belongs_to('mother' => 'Person');
3079
3080 C<from> can be used to nest joins. Here we return all children with a father,
3081 then search against all mothers of those children:
3082
3083   $rs = $schema->resultset('Person')->search(
3084       undef,
3085       {
3086           alias => 'mother', # alias columns in accordance with "from"
3087           from => [
3088               { mother => 'person' },
3089               [
3090                   [
3091                       { child => 'person' },
3092                       [
3093                           { father => 'person' },
3094                           { 'father.person_id' => 'child.father_id' }
3095                       ]
3096                   ],
3097                   { 'mother.person_id' => 'child.mother_id' }
3098               ],
3099           ]
3100       },
3101   );
3102
3103   # Equivalent SQL:
3104   # SELECT mother.* FROM person mother
3105   # JOIN (
3106   #   person child
3107   #   JOIN person father
3108   #   ON ( father.person_id = child.father_id )
3109   # )
3110   # ON ( mother.person_id = child.mother_id )
3111
3112 The type of any join can be controlled manually. To search against only people
3113 with a father in the person table, we could explicitly use C<INNER JOIN>:
3114
3115     $rs = $schema->resultset('Person')->search(
3116         undef,
3117         {
3118             alias => 'child', # alias columns in accordance with "from"
3119             from => [
3120                 { child => 'person' },
3121                 [
3122                     { father => 'person', -join_type => 'inner' },
3123                     { 'father.id' => 'child.father_id' }
3124                 ],
3125             ]
3126         },
3127     );
3128
3129     # Equivalent SQL:
3130     # SELECT child.* FROM person child
3131     # INNER JOIN person father ON child.father_id = father.id
3132
3133 If you need to express really complex joins or you need a subselect, you
3134 can supply literal SQL to C<from> via a scalar reference. In this case
3135 the contents of the scalar will replace the table name asscoiated with the
3136 resultsource.
3137
3138 WARNING: This technique might very well not work as expected on chained
3139 searches - you have been warned.
3140
3141     # Assuming the Event resultsource is defined as:
3142
3143         MySchema::Event->add_columns (
3144             sequence => {
3145                 data_type => 'INT',
3146                 is_auto_increment => 1,
3147             },
3148             location => {
3149                 data_type => 'INT',
3150             },
3151             type => {
3152                 data_type => 'INT',
3153             },
3154         );
3155         MySchema::Event->set_primary_key ('sequence');
3156
3157     # This will get back the latest event for every location. The column
3158     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3159     # combo to limit the resultset
3160
3161     $rs = $schema->resultset('Event');
3162     $table = $rs->result_source->name;
3163     $latest = $rs->search (
3164         undef,
3165         { from => \ "
3166             (SELECT e1.* FROM $table e1
3167                 JOIN $table e2
3168                     ON e1.location = e2.location
3169                     AND e1.sequence < e2.sequence
3170                 WHERE e2.sequence is NULL
3171             ) me",
3172         },
3173     );
3174
3175     # Equivalent SQL (with the DBIC chunks added):
3176
3177     SELECT me.sequence, me.location, me.type FROM
3178        (SELECT e1.* FROM events e1
3179            JOIN events e2
3180                ON e1.location = e2.location
3181                AND e1.sequence < e2.sequence
3182            WHERE e2.sequence is NULL
3183        ) me;
3184
3185 =head2 for
3186
3187 =over 4
3188
3189 =item Value: ( 'update' | 'shared' )
3190
3191 =back
3192
3193 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3194 ... FOR SHARED.
3195
3196 =cut
3197
3198 1;