lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->_resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my @subq_attrs = qw/prefetch collapse distinct group_by having having_bind/;
1159   my $attrs = $self->_resolved_attrs;
1160
1161   # if we are not paged - we are simply asking for a limit
1162   if (not $attrs->{page} and not $attrs->{software_limit}) {
1163     push @subq_attrs, qw/rows offset/;
1164   }
1165
1166   return $self->_has_attr (@subq_attrs)
1167     ? $self->_count_subq
1168     : $self->_count_simple
1169 }
1170
1171 sub _count_subq {
1172   my $self = shift;
1173
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   # copy for the subquery, we need to do some adjustments to it too
1177   my $sub_attrs = { %$attrs };
1178
1179   # these can not go in the subquery either
1180   delete $sub_attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1181
1182   # force a group_by and the same set of columns (most databases require this)
1183   $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1184
1185   $attrs->{from} = [{
1186     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1187   }];
1188
1189   # the subquery replaces this
1190   delete $attrs->{$_} for qw/where bind prefetch collapse group_by having/;
1191
1192   return $self->__count ($attrs);
1193 }
1194
1195 sub _count_simple {
1196   my $self = shift;
1197
1198   my $count = $self->__count;
1199   return 0 unless $count;
1200
1201   # need to take offset from resolved attrs
1202
1203   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1204   $count = $self->{attrs}{rows} if
1205     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1206   $count = 0 if ($count < 0);
1207   return $count;
1208 }
1209
1210 sub __count {
1211   my ($self, $attrs) = @_;
1212
1213   $attrs ||= { %{$self->_resolved_attrs} };
1214
1215   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1216   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1217
1218   $attrs->{select} = { count => '*' };
1219   $attrs->{as} = [qw/count/];
1220
1221   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1222   my ($count) = $tmp_rs->cursor->next;
1223
1224   return $count;
1225 }
1226
1227 sub _bool {
1228   return 1;
1229 }
1230
1231 =head2 count_literal
1232
1233 =over 4
1234
1235 =item Arguments: $sql_fragment, @bind_values
1236
1237 =item Return Value: $count
1238
1239 =back
1240
1241 Counts the results in a literal query. Equivalent to calling L</search_literal>
1242 with the passed arguments, then L</count>.
1243
1244 =cut
1245
1246 sub count_literal { shift->search_literal(@_)->count; }
1247
1248 =head2 all
1249
1250 =over 4
1251
1252 =item Arguments: none
1253
1254 =item Return Value: @objects
1255
1256 =back
1257
1258 Returns all elements in the resultset. Called implicitly if the resultset
1259 is returned in list context.
1260
1261 =cut
1262
1263 sub all {
1264   my $self = shift;
1265   if(@_) {
1266       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1267   }
1268
1269   return @{ $self->get_cache } if $self->get_cache;
1270
1271   my @obj;
1272
1273   # TODO: don't call resolve here
1274   if (keys %{$self->_resolved_attrs->{collapse}}) {
1275 #  if ($self->{attrs}{prefetch}) {
1276       # Using $self->cursor->all is really just an optimisation.
1277       # If we're collapsing has_many prefetches it probably makes
1278       # very little difference, and this is cleaner than hacking
1279       # _construct_object to survive the approach
1280     my @row = $self->cursor->next;
1281     while (@row) {
1282       push(@obj, $self->_construct_object(@row));
1283       @row = (exists $self->{stashed_row}
1284                ? @{delete $self->{stashed_row}}
1285                : $self->cursor->next);
1286     }
1287   } else {
1288     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1289   }
1290
1291   $self->set_cache(\@obj) if $self->{attrs}{cache};
1292   return @obj;
1293 }
1294
1295 =head2 reset
1296
1297 =over 4
1298
1299 =item Arguments: none
1300
1301 =item Return Value: $self
1302
1303 =back
1304
1305 Resets the resultset's cursor, so you can iterate through the elements again.
1306
1307 =cut
1308
1309 sub reset {
1310   my ($self) = @_;
1311   delete $self->{_attrs} if exists $self->{_attrs};
1312   $self->{all_cache_position} = 0;
1313   $self->cursor->reset;
1314   return $self;
1315 }
1316
1317 =head2 first
1318
1319 =over 4
1320
1321 =item Arguments: none
1322
1323 =item Return Value: $object?
1324
1325 =back
1326
1327 Resets the resultset and returns an object for the first result (if the
1328 resultset returns anything).
1329
1330 =cut
1331
1332 sub first {
1333   return $_[0]->reset->next;
1334 }
1335
1336
1337 # _rs_update_delete
1338 #
1339 # Determines whether and what type of subquery is required for the $rs operation.
1340 # If grouping is necessary either supplies its own, or verifies the current one
1341 # After all is done delegates to the proper storage method.
1342
1343 sub _rs_update_delete {
1344   my ($self, $op, $values) = @_;
1345
1346   my $rsrc = $self->result_source;
1347
1348   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1349   my $needs_subq = $self->_has_attr (qw/row offset page/);
1350
1351   if ($needs_group_by_subq or $needs_subq) {
1352
1353     # make a new $rs selecting only the PKs (that's all we really need)
1354     my $attrs = $self->_resolved_attrs;
1355
1356     delete $attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1357     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1358
1359     if ($needs_group_by_subq) {
1360       # make sure no group_by was supplied, or if there is one - make sure it matches
1361       # the columns compiled above perfectly. Anything else can not be sanely executed
1362       # on most databases so croak right then and there
1363
1364       if (my $g = $attrs->{group_by}) {
1365         my @current_group_by = map
1366           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1367           (ref $g eq 'ARRAY' ? @$g : $g );
1368
1369         if (
1370           join ("\x00", sort @current_group_by)
1371             ne
1372           join ("\x00", sort @{$attrs->{columns}} )
1373         ) {
1374           $self->throw_exception (
1375             "You have just attempted a $op operation on a resultset which does group_by"
1376             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1377             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1378             . ' kind of queries. Please retry the operation with a modified group_by or'
1379             . ' without using one at all.'
1380           );
1381         }
1382       }
1383       else {
1384         $attrs->{group_by} = $attrs->{columns};
1385       }
1386     }
1387
1388     my $subrs = (ref $self)->new($rsrc, $attrs);
1389
1390     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1391   }
1392   else {
1393     return $rsrc->storage->$op(
1394       $rsrc,
1395       $op eq 'update' ? $values : (),
1396       $self->_cond_for_update_delete,
1397     );
1398   }
1399 }
1400
1401
1402 # _cond_for_update_delete
1403 #
1404 # update/delete require the condition to be modified to handle
1405 # the differing SQL syntax available.  This transforms the $self->{cond}
1406 # appropriately, returning the new condition.
1407
1408 sub _cond_for_update_delete {
1409   my ($self, $full_cond) = @_;
1410   my $cond = {};
1411
1412   $full_cond ||= $self->{cond};
1413   # No-op. No condition, we're updating/deleting everything
1414   return $cond unless ref $full_cond;
1415
1416   if (ref $full_cond eq 'ARRAY') {
1417     $cond = [
1418       map {
1419         my %hash;
1420         foreach my $key (keys %{$_}) {
1421           $key =~ /([^.]+)$/;
1422           $hash{$1} = $_->{$key};
1423         }
1424         \%hash;
1425       } @{$full_cond}
1426     ];
1427   }
1428   elsif (ref $full_cond eq 'HASH') {
1429     if ((keys %{$full_cond})[0] eq '-and') {
1430       $cond->{-and} = [];
1431       my @cond = @{$full_cond->{-and}};
1432        for (my $i = 0; $i < @cond; $i++) {
1433         my $entry = $cond[$i];
1434         my $hash;
1435         if (ref $entry eq 'HASH') {
1436           $hash = $self->_cond_for_update_delete($entry);
1437         }
1438         else {
1439           $entry =~ /([^.]+)$/;
1440           $hash->{$1} = $cond[++$i];
1441         }
1442         push @{$cond->{-and}}, $hash;
1443       }
1444     }
1445     else {
1446       foreach my $key (keys %{$full_cond}) {
1447         $key =~ /([^.]+)$/;
1448         $cond->{$1} = $full_cond->{$key};
1449       }
1450     }
1451   }
1452   else {
1453     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1454   }
1455
1456   return $cond;
1457 }
1458
1459
1460 =head2 update
1461
1462 =over 4
1463
1464 =item Arguments: \%values
1465
1466 =item Return Value: $storage_rv
1467
1468 =back
1469
1470 Sets the specified columns in the resultset to the supplied values in a
1471 single query. Return value will be true if the update succeeded or false
1472 if no records were updated; exact type of success value is storage-dependent.
1473
1474 =cut
1475
1476 sub update {
1477   my ($self, $values) = @_;
1478   $self->throw_exception('Values for update must be a hash')
1479     unless ref $values eq 'HASH';
1480
1481   return $self->_rs_update_delete ('update', $values);
1482 }
1483
1484 =head2 update_all
1485
1486 =over 4
1487
1488 =item Arguments: \%values
1489
1490 =item Return Value: 1
1491
1492 =back
1493
1494 Fetches all objects and updates them one at a time. Note that C<update_all>
1495 will run DBIC cascade triggers, while L</update> will not.
1496
1497 =cut
1498
1499 sub update_all {
1500   my ($self, $values) = @_;
1501   $self->throw_exception('Values for update_all must be a hash')
1502     unless ref $values eq 'HASH';
1503   foreach my $obj ($self->all) {
1504     $obj->set_columns($values)->update;
1505   }
1506   return 1;
1507 }
1508
1509 =head2 delete
1510
1511 =over 4
1512
1513 =item Arguments: none
1514
1515 =item Return Value: 1
1516
1517 =back
1518
1519 Deletes the contents of the resultset from its result source. Note that this
1520 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1521 to run. See also L<DBIx::Class::Row/delete>.
1522
1523 delete may not generate correct SQL for a query with joins or a resultset
1524 chained from a related resultset.  In this case it will generate a warning:-
1525
1526 In these cases you may find that delete_all is more appropriate, or you
1527 need to respecify your query in a way that can be expressed without a join.
1528
1529 =cut
1530
1531 sub delete {
1532   my $self = shift;
1533   $self->throw_exception('delete does not accept any arguments')
1534     if @_;
1535
1536   return $self->_rs_update_delete ('delete');
1537 }
1538
1539 =head2 delete_all
1540
1541 =over 4
1542
1543 =item Arguments: none
1544
1545 =item Return Value: 1
1546
1547 =back
1548
1549 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1550 will run DBIC cascade triggers, while L</delete> will not.
1551
1552 =cut
1553
1554 sub delete_all {
1555   my $self = shift;
1556   $self->throw_exception('delete_all does not accept any arguments')
1557     if @_;
1558
1559   $_->delete for $self->all;
1560   return 1;
1561 }
1562
1563 =head2 populate
1564
1565 =over 4
1566
1567 =item Arguments: \@data;
1568
1569 =back
1570
1571 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1572 For the arrayref of hashrefs style each hashref should be a structure suitable
1573 forsubmitting to a $resultset->create(...) method.
1574
1575 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1576 to insert the data, as this is a faster method.
1577
1578 Otherwise, each set of data is inserted into the database using
1579 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1580 objects is returned.
1581
1582 Example:  Assuming an Artist Class that has many CDs Classes relating:
1583
1584   my $Artist_rs = $schema->resultset("Artist");
1585
1586   ## Void Context Example
1587   $Artist_rs->populate([
1588      { artistid => 4, name => 'Manufactured Crap', cds => [
1589         { title => 'My First CD', year => 2006 },
1590         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1591       ],
1592      },
1593      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1594         { title => 'My parents sold me to a record company' ,year => 2005 },
1595         { title => 'Why Am I So Ugly?', year => 2006 },
1596         { title => 'I Got Surgery and am now Popular', year => 2007 }
1597       ],
1598      },
1599   ]);
1600
1601   ## Array Context Example
1602   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1603     { name => "Artist One"},
1604     { name => "Artist Two"},
1605     { name => "Artist Three", cds=> [
1606     { title => "First CD", year => 2007},
1607     { title => "Second CD", year => 2008},
1608   ]}
1609   ]);
1610
1611   print $ArtistOne->name; ## response is 'Artist One'
1612   print $ArtistThree->cds->count ## reponse is '2'
1613
1614 For the arrayref of arrayrefs style,  the first element should be a list of the
1615 fieldsnames to which the remaining elements are rows being inserted.  For
1616 example:
1617
1618   $Arstist_rs->populate([
1619     [qw/artistid name/],
1620     [100, 'A Formally Unknown Singer'],
1621     [101, 'A singer that jumped the shark two albums ago'],
1622     [102, 'An actually cool singer.'],
1623   ]);
1624
1625 Please note an important effect on your data when choosing between void and
1626 wantarray context. Since void context goes straight to C<insert_bulk> in
1627 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1628 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1629 create primary keys for you, you will find that your PKs are empty.  In this
1630 case you will have to use the wantarray context in order to create those
1631 values.
1632
1633 =cut
1634
1635 sub populate {
1636   my $self = shift @_;
1637   my $data = ref $_[0][0] eq 'HASH'
1638     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1639     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1640
1641   if(defined wantarray) {
1642     my @created;
1643     foreach my $item (@$data) {
1644       push(@created, $self->create($item));
1645     }
1646     return @created;
1647   } else {
1648     my ($first, @rest) = @$data;
1649
1650     my @names = grep {!ref $first->{$_}} keys %$first;
1651     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1652     my @pks = $self->result_source->primary_columns;
1653
1654     ## do the belongs_to relationships
1655     foreach my $index (0..$#$data) {
1656       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1657         my @ret = $self->populate($data);
1658         return;
1659       }
1660
1661       foreach my $rel (@rels) {
1662         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1663         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1664         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1665         my $related = $result->result_source->_resolve_condition(
1666           $result->result_source->relationship_info($reverse)->{cond},
1667           $self,
1668           $result,
1669         );
1670
1671         delete $data->[$index]->{$rel};
1672         $data->[$index] = {%{$data->[$index]}, %$related};
1673
1674         push @names, keys %$related if $index == 0;
1675       }
1676     }
1677
1678     ## do bulk insert on current row
1679     my @values = map { [ @$_{@names} ] } @$data;
1680
1681     $self->result_source->storage->insert_bulk(
1682       $self->result_source,
1683       \@names,
1684       \@values,
1685     );
1686
1687     ## do the has_many relationships
1688     foreach my $item (@$data) {
1689
1690       foreach my $rel (@rels) {
1691         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1692
1693         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1694      || $self->throw_exception('Cannot find the relating object.');
1695
1696         my $child = $parent->$rel;
1697
1698         my $related = $child->result_source->_resolve_condition(
1699           $parent->result_source->relationship_info($rel)->{cond},
1700           $child,
1701           $parent,
1702         );
1703
1704         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1705         my @populate = map { {%$_, %$related} } @rows_to_add;
1706
1707         $child->populate( \@populate );
1708       }
1709     }
1710   }
1711 }
1712
1713 =head2 _normalize_populate_args ($args)
1714
1715 Private method used by L</populate> to normalize its incoming arguments.  Factored
1716 out in case you want to subclass and accept new argument structures to the
1717 L</populate> method.
1718
1719 =cut
1720
1721 sub _normalize_populate_args {
1722   my ($self, $data) = @_;
1723   my @names = @{shift(@$data)};
1724   my @results_to_create;
1725   foreach my $datum (@$data) {
1726     my %result_to_create;
1727     foreach my $index (0..$#names) {
1728       $result_to_create{$names[$index]} = $$datum[$index];
1729     }
1730     push @results_to_create, \%result_to_create;
1731   }
1732   return \@results_to_create;
1733 }
1734
1735 =head2 pager
1736
1737 =over 4
1738
1739 =item Arguments: none
1740
1741 =item Return Value: $pager
1742
1743 =back
1744
1745 Return Value a L<Data::Page> object for the current resultset. Only makes
1746 sense for queries with a C<page> attribute.
1747
1748 To get the full count of entries for a paged resultset, call
1749 C<total_entries> on the L<Data::Page> object.
1750
1751 =cut
1752
1753 sub pager {
1754   my ($self) = @_;
1755
1756   return $self->{pager} if $self->{pager};
1757
1758   my $attrs = $self->{attrs};
1759   $self->throw_exception("Can't create pager for non-paged rs")
1760     unless $self->{attrs}{page};
1761   $attrs->{rows} ||= 10;
1762
1763   # throw away the paging flags and re-run the count (possibly
1764   # with a subselect) to get the real total count
1765   my $count_attrs = { %$attrs };
1766   delete $count_attrs->{$_} for qw/rows offset page pager/;
1767   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1768
1769   return $self->{pager} = Data::Page->new(
1770     $total_count,
1771     $attrs->{rows},
1772     $self->{attrs}{page}
1773   );
1774 }
1775
1776 =head2 page
1777
1778 =over 4
1779
1780 =item Arguments: $page_number
1781
1782 =item Return Value: $rs
1783
1784 =back
1785
1786 Returns a resultset for the $page_number page of the resultset on which page
1787 is called, where each page contains a number of rows equal to the 'rows'
1788 attribute set on the resultset (10 by default).
1789
1790 =cut
1791
1792 sub page {
1793   my ($self, $page) = @_;
1794   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1795 }
1796
1797 =head2 new_result
1798
1799 =over 4
1800
1801 =item Arguments: \%vals
1802
1803 =item Return Value: $rowobject
1804
1805 =back
1806
1807 Creates a new row object in the resultset's result class and returns
1808 it. The row is not inserted into the database at this point, call
1809 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1810 will tell you whether the row object has been inserted or not.
1811
1812 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1813
1814 =cut
1815
1816 sub new_result {
1817   my ($self, $values) = @_;
1818   $self->throw_exception( "new_result needs a hash" )
1819     unless (ref $values eq 'HASH');
1820
1821   my %new;
1822   my $alias = $self->{attrs}{alias};
1823
1824   if (
1825     defined $self->{cond}
1826     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1827   ) {
1828     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1829     $new{-from_resultset} = [ keys %new ] if keys %new;
1830   } else {
1831     $self->throw_exception(
1832       "Can't abstract implicit construct, condition not a hash"
1833     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1834
1835     my $collapsed_cond = (
1836       $self->{cond}
1837         ? $self->_collapse_cond($self->{cond})
1838         : {}
1839     );
1840
1841     # precendence must be given to passed values over values inherited from
1842     # the cond, so the order here is important.
1843     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1844     while( my($col,$value) = each %implied ){
1845       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1846         $new{$col} = $value->{'='};
1847         next;
1848       }
1849       $new{$col} = $value if $self->_is_deterministic_value($value);
1850     }
1851   }
1852
1853   %new = (
1854     %new,
1855     %{ $self->_remove_alias($values, $alias) },
1856     -source_handle => $self->_source_handle,
1857     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1858   );
1859
1860   return $self->result_class->new(\%new);
1861 }
1862
1863 # _is_deterministic_value
1864 #
1865 # Make an effor to strip non-deterministic values from the condition,
1866 # to make sure new_result chokes less
1867
1868 sub _is_deterministic_value {
1869   my $self = shift;
1870   my $value = shift;
1871   my $ref_type = ref $value;
1872   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1873   return 1 if Scalar::Util::blessed($value);
1874   return 0;
1875 }
1876
1877 # _has_attr
1878 #
1879 # determines if the resultset defines at least one
1880 # of the attributes supplied
1881 #
1882 # used to determine if a subquery is neccessary
1883
1884 sub _has_attr {
1885   my ($self, @attr_names) = @_;
1886
1887   my $attrs = $self->_resolved_attrs;
1888
1889   my $join_check_req;
1890
1891   for my $n (@attr_names) {
1892     ++$join_check_req if $n =~ /join/;
1893
1894     my $attr =  $attrs->{$n};
1895
1896     next if not defined $attr;
1897
1898     if (ref $attr eq 'HASH') {
1899       return 1 if keys %$attr;
1900     }
1901     elsif (ref $attr eq 'ARRAY') {
1902       return 1 if @$attr;
1903     }
1904     else {
1905       return 1 if $attr;
1906     }
1907   }
1908
1909   # a join can be expressed as a multi-level from
1910   return 1 if (
1911     $join_check_req
1912       and
1913     ref $attrs->{from} eq 'ARRAY'
1914       and
1915     @{$attrs->{from}} > 1
1916   );
1917
1918   return 0;
1919 }
1920
1921 # _collapse_cond
1922 #
1923 # Recursively collapse the condition.
1924
1925 sub _collapse_cond {
1926   my ($self, $cond, $collapsed) = @_;
1927
1928   $collapsed ||= {};
1929
1930   if (ref $cond eq 'ARRAY') {
1931     foreach my $subcond (@$cond) {
1932       next unless ref $subcond;  # -or
1933       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1934     }
1935   }
1936   elsif (ref $cond eq 'HASH') {
1937     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1938       foreach my $subcond (@{$cond->{-and}}) {
1939         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1940       }
1941     }
1942     else {
1943       foreach my $col (keys %$cond) {
1944         my $value = $cond->{$col};
1945         $collapsed->{$col} = $value;
1946       }
1947     }
1948   }
1949
1950   return $collapsed;
1951 }
1952
1953 # _remove_alias
1954 #
1955 # Remove the specified alias from the specified query hash. A copy is made so
1956 # the original query is not modified.
1957
1958 sub _remove_alias {
1959   my ($self, $query, $alias) = @_;
1960
1961   my %orig = %{ $query || {} };
1962   my %unaliased;
1963
1964   foreach my $key (keys %orig) {
1965     if ($key !~ /\./) {
1966       $unaliased{$key} = $orig{$key};
1967       next;
1968     }
1969     $unaliased{$1} = $orig{$key}
1970       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1971   }
1972
1973   return \%unaliased;
1974 }
1975
1976 =head2 as_query (EXPERIMENTAL)
1977
1978 =over 4
1979
1980 =item Arguments: none
1981
1982 =item Return Value: \[ $sql, @bind ]
1983
1984 =back
1985
1986 Returns the SQL query and bind vars associated with the invocant.
1987
1988 This is generally used as the RHS for a subquery.
1989
1990 B<NOTE>: This feature is still experimental.
1991
1992 =cut
1993
1994 sub as_query { return shift->cursor->as_query(@_) }
1995
1996 =head2 find_or_new
1997
1998 =over 4
1999
2000 =item Arguments: \%vals, \%attrs?
2001
2002 =item Return Value: $rowobject
2003
2004 =back
2005
2006   my $artist = $schema->resultset('Artist')->find_or_new(
2007     { artist => 'fred' }, { key => 'artists' });
2008
2009   $cd->cd_to_producer->find_or_new({ producer => $producer },
2010                                    { key => 'primary });
2011
2012 Find an existing record from this resultset, based on its primary
2013 key, or a unique constraint. If none exists, instantiate a new result
2014 object and return it. The object will not be saved into your storage
2015 until you call L<DBIx::Class::Row/insert> on it.
2016
2017 You most likely want this method when looking for existing rows using
2018 a unique constraint that is not the primary key, or looking for
2019 related rows.
2020
2021 If you want objects to be saved immediately, use L</find_or_create> instead.
2022
2023 B<Note>: C<find_or_new> is probably not what you want when creating a
2024 new row in a table that uses primary keys supplied by the
2025 database. Passing in a primary key column with a value of I<undef>
2026 will cause L</find> to attempt to search for a row with a value of
2027 I<NULL>.
2028
2029 =cut
2030
2031 sub find_or_new {
2032   my $self     = shift;
2033   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2034   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2035   my $exists   = $self->find($hash, $attrs);
2036   return defined $exists ? $exists : $self->new_result($hash);
2037 }
2038
2039 =head2 create
2040
2041 =over 4
2042
2043 =item Arguments: \%vals
2044
2045 =item Return Value: a L<DBIx::Class::Row> $object
2046
2047 =back
2048
2049 Attempt to create a single new row or a row with multiple related rows
2050 in the table represented by the resultset (and related tables). This
2051 will not check for duplicate rows before inserting, use
2052 L</find_or_create> to do that.
2053
2054 To create one row for this resultset, pass a hashref of key/value
2055 pairs representing the columns of the table and the values you wish to
2056 store. If the appropriate relationships are set up, foreign key fields
2057 can also be passed an object representing the foreign row, and the
2058 value will be set to its primary key.
2059
2060 To create related objects, pass a hashref for the value if the related
2061 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2062 and use the name of the relationship as the key. (NOT the name of the field,
2063 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2064 of hashrefs containing the data for each of the rows to create in the foreign
2065 tables, again using the relationship name as the key.
2066
2067 Instead of hashrefs of plain related data (key/value pairs), you may
2068 also pass new or inserted objects. New objects (not inserted yet, see
2069 L</new>), will be inserted into their appropriate tables.
2070
2071 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2072
2073 Example of creating a new row.
2074
2075   $person_rs->create({
2076     name=>"Some Person",
2077     email=>"somebody@someplace.com"
2078   });
2079
2080 Example of creating a new row and also creating rows in a related C<has_many>
2081 or C<has_one> resultset.  Note Arrayref.
2082
2083   $artist_rs->create(
2084      { artistid => 4, name => 'Manufactured Crap', cds => [
2085         { title => 'My First CD', year => 2006 },
2086         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2087       ],
2088      },
2089   );
2090
2091 Example of creating a new row and also creating a row in a related
2092 C<belongs_to>resultset. Note Hashref.
2093
2094   $cd_rs->create({
2095     title=>"Music for Silly Walks",
2096     year=>2000,
2097     artist => {
2098       name=>"Silly Musician",
2099     }
2100   });
2101
2102 =cut
2103
2104 sub create {
2105   my ($self, $attrs) = @_;
2106   $self->throw_exception( "create needs a hashref" )
2107     unless ref $attrs eq 'HASH';
2108   return $self->new_result($attrs)->insert;
2109 }
2110
2111 =head2 find_or_create
2112
2113 =over 4
2114
2115 =item Arguments: \%vals, \%attrs?
2116
2117 =item Return Value: $rowobject
2118
2119 =back
2120
2121   $cd->cd_to_producer->find_or_create({ producer => $producer },
2122                                       { key => 'primary });
2123
2124 Tries to find a record based on its primary key or unique constraints; if none
2125 is found, creates one and returns that instead.
2126
2127   my $cd = $schema->resultset('CD')->find_or_create({
2128     cdid   => 5,
2129     artist => 'Massive Attack',
2130     title  => 'Mezzanine',
2131     year   => 2005,
2132   });
2133
2134 Also takes an optional C<key> attribute, to search by a specific key or unique
2135 constraint. For example:
2136
2137   my $cd = $schema->resultset('CD')->find_or_create(
2138     {
2139       artist => 'Massive Attack',
2140       title  => 'Mezzanine',
2141     },
2142     { key => 'cd_artist_title' }
2143   );
2144
2145 B<Note>: Because find_or_create() reads from the database and then
2146 possibly inserts based on the result, this method is subject to a race
2147 condition. Another process could create a record in the table after
2148 the find has completed and before the create has started. To avoid
2149 this problem, use find_or_create() inside a transaction.
2150
2151 B<Note>: C<find_or_create> is probably not what you want when creating
2152 a new row in a table that uses primary keys supplied by the
2153 database. Passing in a primary key column with a value of I<undef>
2154 will cause L</find> to attempt to search for a row with a value of
2155 I<NULL>.
2156
2157 See also L</find> and L</update_or_create>. For information on how to declare
2158 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2159
2160 =cut
2161
2162 sub find_or_create {
2163   my $self     = shift;
2164   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2165   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2166   my $exists   = $self->find($hash, $attrs);
2167   return defined $exists ? $exists : $self->create($hash);
2168 }
2169
2170 =head2 update_or_create
2171
2172 =over 4
2173
2174 =item Arguments: \%col_values, { key => $unique_constraint }?
2175
2176 =item Return Value: $rowobject
2177
2178 =back
2179
2180   $resultset->update_or_create({ col => $val, ... });
2181
2182 First, searches for an existing row matching one of the unique constraints
2183 (including the primary key) on the source of this resultset. If a row is
2184 found, updates it with the other given column values. Otherwise, creates a new
2185 row.
2186
2187 Takes an optional C<key> attribute to search on a specific unique constraint.
2188 For example:
2189
2190   # In your application
2191   my $cd = $schema->resultset('CD')->update_or_create(
2192     {
2193       artist => 'Massive Attack',
2194       title  => 'Mezzanine',
2195       year   => 1998,
2196     },
2197     { key => 'cd_artist_title' }
2198   );
2199
2200   $cd->cd_to_producer->update_or_create({
2201     producer => $producer,
2202     name => 'harry',
2203   }, {
2204     key => 'primary,
2205   });
2206
2207
2208 If no C<key> is specified, it searches on all unique constraints defined on the
2209 source, including the primary key.
2210
2211 If the C<key> is specified as C<primary>, it searches only on the primary key.
2212
2213 See also L</find> and L</find_or_create>. For information on how to declare
2214 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2215
2216 B<Note>: C<update_or_create> is probably not what you want when
2217 looking for a row in a table that uses primary keys supplied by the
2218 database, unless you actually have a key value. Passing in a primary
2219 key column with a value of I<undef> will cause L</find> to attempt to
2220 search for a row with a value of I<NULL>.
2221
2222 =cut
2223
2224 sub update_or_create {
2225   my $self = shift;
2226   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2227   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2228
2229   my $row = $self->find($cond, $attrs);
2230   if (defined $row) {
2231     $row->update($cond);
2232     return $row;
2233   }
2234
2235   return $self->create($cond);
2236 }
2237
2238 =head2 update_or_new
2239
2240 =over 4
2241
2242 =item Arguments: \%col_values, { key => $unique_constraint }?
2243
2244 =item Return Value: $rowobject
2245
2246 =back
2247
2248   $resultset->update_or_new({ col => $val, ... });
2249
2250 First, searches for an existing row matching one of the unique constraints
2251 (including the primary key) on the source of this resultset. If a row is
2252 found, updates it with the other given column values. Otherwise, instantiate
2253 a new result object and return it. The object will not be saved into your storage
2254 until you call L<DBIx::Class::Row/insert> on it.
2255
2256 Takes an optional C<key> attribute to search on a specific unique constraint.
2257 For example:
2258
2259   # In your application
2260   my $cd = $schema->resultset('CD')->update_or_new(
2261     {
2262       artist => 'Massive Attack',
2263       title  => 'Mezzanine',
2264       year   => 1998,
2265     },
2266     { key => 'cd_artist_title' }
2267   );
2268
2269   if ($cd->in_storage) {
2270       # the cd was updated
2271   }
2272   else {
2273       # the cd is not yet in the database, let's insert it
2274       $cd->insert;
2275   }
2276
2277 See also L</find>, L</find_or_create> and L<find_or_new>.
2278
2279 =cut
2280
2281 sub update_or_new {
2282     my $self  = shift;
2283     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2284     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2285
2286     my $row = $self->find( $cond, $attrs );
2287     if ( defined $row ) {
2288         $row->update($cond);
2289         return $row;
2290     }
2291
2292     return $self->new_result($cond);
2293 }
2294
2295 =head2 get_cache
2296
2297 =over 4
2298
2299 =item Arguments: none
2300
2301 =item Return Value: \@cache_objects?
2302
2303 =back
2304
2305 Gets the contents of the cache for the resultset, if the cache is set.
2306
2307 The cache is populated either by using the L</prefetch> attribute to
2308 L</search> or by calling L</set_cache>.
2309
2310 =cut
2311
2312 sub get_cache {
2313   shift->{all_cache};
2314 }
2315
2316 =head2 set_cache
2317
2318 =over 4
2319
2320 =item Arguments: \@cache_objects
2321
2322 =item Return Value: \@cache_objects
2323
2324 =back
2325
2326 Sets the contents of the cache for the resultset. Expects an arrayref
2327 of objects of the same class as those produced by the resultset. Note that
2328 if the cache is set the resultset will return the cached objects rather
2329 than re-querying the database even if the cache attr is not set.
2330
2331 The contents of the cache can also be populated by using the
2332 L</prefetch> attribute to L</search>.
2333
2334 =cut
2335
2336 sub set_cache {
2337   my ( $self, $data ) = @_;
2338   $self->throw_exception("set_cache requires an arrayref")
2339       if defined($data) && (ref $data ne 'ARRAY');
2340   $self->{all_cache} = $data;
2341 }
2342
2343 =head2 clear_cache
2344
2345 =over 4
2346
2347 =item Arguments: none
2348
2349 =item Return Value: []
2350
2351 =back
2352
2353 Clears the cache for the resultset.
2354
2355 =cut
2356
2357 sub clear_cache {
2358   shift->set_cache(undef);
2359 }
2360
2361 =head2 related_resultset
2362
2363 =over 4
2364
2365 =item Arguments: $relationship_name
2366
2367 =item Return Value: $resultset
2368
2369 =back
2370
2371 Returns a related resultset for the supplied relationship name.
2372
2373   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2374
2375 =cut
2376
2377 sub related_resultset {
2378   my ($self, $rel) = @_;
2379
2380   $self->{related_resultsets} ||= {};
2381   return $self->{related_resultsets}{$rel} ||= do {
2382     my $rel_obj = $self->result_source->relationship_info($rel);
2383
2384     $self->throw_exception(
2385       "search_related: result source '" . $self->result_source->source_name .
2386         "' has no such relationship $rel")
2387       unless $rel_obj;
2388
2389     my ($from,$seen) = $self->_resolve_from($rel);
2390
2391     my $join_count = $seen->{$rel};
2392     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2393
2394     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2395     my %attrs = %{$self->{attrs}||{}};
2396     delete @attrs{qw(result_class alias)};
2397
2398     my $new_cache;
2399
2400     if (my $cache = $self->get_cache) {
2401       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2402         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2403                         @$cache ];
2404       }
2405     }
2406
2407     my $rel_source = $self->result_source->related_source($rel);
2408
2409     my $new = do {
2410
2411       # The reason we do this now instead of passing the alias to the
2412       # search_rs below is that if you wrap/overload resultset on the
2413       # source you need to know what alias it's -going- to have for things
2414       # to work sanely (e.g. RestrictWithObject wants to be able to add
2415       # extra query restrictions, and these may need to be $alias.)
2416
2417       my $attrs = $rel_source->resultset_attributes;
2418       local $attrs->{alias} = $alias;
2419
2420       $rel_source->resultset
2421                  ->search_rs(
2422                      undef, {
2423                        %attrs,
2424                        join => undef,
2425                        prefetch => undef,
2426                        select => undef,
2427                        as => undef,
2428                        where => $self->{cond},
2429                        seen_join => $seen,
2430                        from => $from,
2431                    });
2432     };
2433     $new->set_cache($new_cache) if $new_cache;
2434     $new;
2435   };
2436 }
2437
2438 =head2 current_source_alias
2439
2440 =over 4
2441
2442 =item Arguments: none
2443
2444 =item Return Value: $source_alias
2445
2446 =back
2447
2448 Returns the current table alias for the result source this resultset is built
2449 on, that will be used in the SQL query. Usually it is C<me>.
2450
2451 Currently the source alias that refers to the result set returned by a
2452 L</search>/L</find> family method depends on how you got to the resultset: it's
2453 C<me> by default, but eg. L</search_related> aliases it to the related result
2454 source name (and keeps C<me> referring to the original result set). The long
2455 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2456 (and make this method unnecessary).
2457
2458 Thus it's currently necessary to use this method in predefined queries (see
2459 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2460 source alias of the current result set:
2461
2462   # in a result set class
2463   sub modified_by {
2464     my ($self, $user) = @_;
2465
2466     my $me = $self->current_source_alias;
2467
2468     return $self->search(
2469       "$me.modified" => $user->id,
2470     );
2471   }
2472
2473 =cut
2474
2475 sub current_source_alias {
2476   my ($self) = @_;
2477
2478   return ($self->{attrs} || {})->{alias} || 'me';
2479 }
2480
2481 # This code is called by search_related, and makes sure there
2482 # is clear separation between the joins before, during, and
2483 # after the relationship. This information is needed later
2484 # in order to properly resolve prefetch aliases (any alias
2485 # with a relation_chain_depth less than the depth of the
2486 # current prefetch is not considered)
2487 sub _resolve_from {
2488   my ($self, $extra_join) = @_;
2489   my $source = $self->result_source;
2490   my $attrs = $self->{attrs};
2491
2492   my $from = $attrs->{from}
2493     || [ { $attrs->{alias} => $source->from } ];
2494
2495   my $seen = { %{$attrs->{seen_join}||{}} };
2496
2497   # we need to take the prefetch the attrs into account before we
2498   # ->_resolve_join as otherwise they get lost - captainL
2499   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2500
2501   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2502
2503   ++$seen->{-relation_chain_depth};
2504
2505   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2506
2507   ++$seen->{-relation_chain_depth};
2508
2509   return ($from,$seen);
2510 }
2511
2512 sub _resolved_attrs {
2513   my $self = shift;
2514   return $self->{_attrs} if $self->{_attrs};
2515
2516   my $attrs  = { %{ $self->{attrs} || {} } };
2517   my $source = $self->result_source;
2518   my $alias  = $attrs->{alias};
2519
2520   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2521   my @colbits;
2522
2523   # build columns (as long as select isn't set) into a set of as/select hashes
2524   unless ( $attrs->{select} ) {
2525       @colbits = map {
2526           ( ref($_) eq 'HASH' )
2527               ? $_
2528               : {
2529                   (
2530                     /^\Q${alias}.\E(.+)$/
2531                       ? "$1"
2532                       : "$_"
2533                   )
2534                 =>
2535                   (
2536                     /\./
2537                       ? "$_"
2538                       : "${alias}.$_"
2539                   )
2540             }
2541       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2542   }
2543   # add the additional columns on
2544   foreach ( 'include_columns', '+columns' ) {
2545       push @colbits, map {
2546           ( ref($_) eq 'HASH' )
2547             ? $_
2548             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2549       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2550   }
2551
2552   # start with initial select items
2553   if ( $attrs->{select} ) {
2554     $attrs->{select} =
2555         ( ref $attrs->{select} eq 'ARRAY' )
2556       ? [ @{ $attrs->{select} } ]
2557       : [ $attrs->{select} ];
2558     $attrs->{as} = (
2559       $attrs->{as}
2560       ? (
2561         ref $attrs->{as} eq 'ARRAY'
2562         ? [ @{ $attrs->{as} } ]
2563         : [ $attrs->{as} ]
2564         )
2565       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2566     );
2567   }
2568   else {
2569
2570     # otherwise we intialise select & as to empty
2571     $attrs->{select} = [];
2572     $attrs->{as}     = [];
2573   }
2574
2575   # now add colbits to select/as
2576   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2577   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2578
2579   my $adds;
2580   if ( $adds = delete $attrs->{'+select'} ) {
2581     $adds = [$adds] unless ref $adds eq 'ARRAY';
2582     push(
2583       @{ $attrs->{select} },
2584       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2585     );
2586   }
2587   if ( $adds = delete $attrs->{'+as'} ) {
2588     $adds = [$adds] unless ref $adds eq 'ARRAY';
2589     push( @{ $attrs->{as} }, @$adds );
2590   }
2591
2592   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2593
2594   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2595     my $join = delete $attrs->{join} || {};
2596
2597     if ( defined $attrs->{prefetch} ) {
2598       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2599
2600     }
2601
2602     $attrs->{from} =    # have to copy here to avoid corrupting the original
2603       [
2604       @{ $attrs->{from} },
2605       $source->_resolve_join(
2606         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2607       )
2608       ];
2609
2610   }
2611
2612   $attrs->{group_by} ||= $attrs->{select}
2613     if delete $attrs->{distinct};
2614   if ( $attrs->{order_by} ) {
2615     $attrs->{order_by} = (
2616       ref( $attrs->{order_by} ) eq 'ARRAY'
2617       ? [ @{ $attrs->{order_by} } ]
2618       : [ $attrs->{order_by} ]
2619     );
2620   }
2621   else {
2622     $attrs->{order_by} = [];
2623   }
2624
2625   my $collapse = $attrs->{collapse} || {};
2626   if ( my $prefetch = delete $attrs->{prefetch} ) {
2627     $prefetch = $self->_merge_attr( {}, $prefetch );
2628     my @pre_order;
2629     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2630
2631       # bring joins back to level of current class
2632       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2633       my @prefetch =
2634         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2635       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2636       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2637     }
2638     push( @{ $attrs->{order_by} }, @pre_order );
2639   }
2640   $attrs->{collapse} = $collapse;
2641
2642   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2643     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2644   }
2645
2646   return $self->{_attrs} = $attrs;
2647 }
2648
2649 sub _joinpath_aliases {
2650   my ($self, $fromspec, $seen) = @_;
2651
2652   my $paths = {};
2653   return $paths unless ref $fromspec eq 'ARRAY';
2654
2655   for my $j (@$fromspec) {
2656
2657     next if ref $j ne 'ARRAY';
2658     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2659
2660     my $p = $paths;
2661     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2662     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2663   }
2664
2665   return $paths;
2666 }
2667
2668 sub _rollout_attr {
2669   my ($self, $attr) = @_;
2670
2671   if (ref $attr eq 'HASH') {
2672     return $self->_rollout_hash($attr);
2673   } elsif (ref $attr eq 'ARRAY') {
2674     return $self->_rollout_array($attr);
2675   } else {
2676     return [$attr];
2677   }
2678 }
2679
2680 sub _rollout_array {
2681   my ($self, $attr) = @_;
2682
2683   my @rolled_array;
2684   foreach my $element (@{$attr}) {
2685     if (ref $element eq 'HASH') {
2686       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2687     } elsif (ref $element eq 'ARRAY') {
2688       #  XXX - should probably recurse here
2689       push( @rolled_array, @{$self->_rollout_array($element)} );
2690     } else {
2691       push( @rolled_array, $element );
2692     }
2693   }
2694   return \@rolled_array;
2695 }
2696
2697 sub _rollout_hash {
2698   my ($self, $attr) = @_;
2699
2700   my @rolled_array;
2701   foreach my $key (keys %{$attr}) {
2702     push( @rolled_array, { $key => $attr->{$key} } );
2703   }
2704   return \@rolled_array;
2705 }
2706
2707 sub _calculate_score {
2708   my ($self, $a, $b) = @_;
2709
2710   if (ref $b eq 'HASH') {
2711     my ($b_key) = keys %{$b};
2712     if (ref $a eq 'HASH') {
2713       my ($a_key) = keys %{$a};
2714       if ($a_key eq $b_key) {
2715         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2716       } else {
2717         return 0;
2718       }
2719     } else {
2720       return ($a eq $b_key) ? 1 : 0;
2721     }
2722   } else {
2723     if (ref $a eq 'HASH') {
2724       my ($a_key) = keys %{$a};
2725       return ($b eq $a_key) ? 1 : 0;
2726     } else {
2727       return ($b eq $a) ? 1 : 0;
2728     }
2729   }
2730 }
2731
2732 sub _merge_attr {
2733   my ($self, $orig, $import) = @_;
2734
2735   return $import unless defined($orig);
2736   return $orig unless defined($import);
2737
2738   $orig = $self->_rollout_attr($orig);
2739   $import = $self->_rollout_attr($import);
2740
2741   my $seen_keys;
2742   foreach my $import_element ( @{$import} ) {
2743     # find best candidate from $orig to merge $b_element into
2744     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2745     foreach my $orig_element ( @{$orig} ) {
2746       my $score = $self->_calculate_score( $orig_element, $import_element );
2747       if ($score > $best_candidate->{score}) {
2748         $best_candidate->{position} = $position;
2749         $best_candidate->{score} = $score;
2750       }
2751       $position++;
2752     }
2753     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2754
2755     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2756       push( @{$orig}, $import_element );
2757     } else {
2758       my $orig_best = $orig->[$best_candidate->{position}];
2759       # merge orig_best and b_element together and replace original with merged
2760       if (ref $orig_best ne 'HASH') {
2761         $orig->[$best_candidate->{position}] = $import_element;
2762       } elsif (ref $import_element eq 'HASH') {
2763         my ($key) = keys %{$orig_best};
2764         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2765       }
2766     }
2767     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2768   }
2769
2770   return $orig;
2771 }
2772
2773 sub result_source {
2774     my $self = shift;
2775
2776     if (@_) {
2777         $self->_source_handle($_[0]->handle);
2778     } else {
2779         $self->_source_handle->resolve;
2780     }
2781 }
2782
2783 =head2 throw_exception
2784
2785 See L<DBIx::Class::Schema/throw_exception> for details.
2786
2787 =cut
2788
2789 sub throw_exception {
2790   my $self=shift;
2791   if (ref $self && $self->_source_handle->schema) {
2792     $self->_source_handle->schema->throw_exception(@_)
2793   } else {
2794     croak(@_);
2795   }
2796
2797 }
2798
2799 # XXX: FIXME: Attributes docs need clearing up
2800
2801 =head1 ATTRIBUTES
2802
2803 Attributes are used to refine a ResultSet in various ways when
2804 searching for data. They can be passed to any method which takes an
2805 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2806 L</count>.
2807
2808 These are in no particular order:
2809
2810 =head2 order_by
2811
2812 =over 4
2813
2814 =item Value: ( $order_by | \@order_by | \%order_by )
2815
2816 =back
2817
2818 Which column(s) to order the results by. If a single column name, or
2819 an arrayref of names is supplied, the argument is passed through
2820 directly to SQL. The hashref syntax allows for connection-agnostic
2821 specification of ordering direction:
2822
2823  For descending order:
2824
2825   order_by => { -desc => [qw/col1 col2 col3/] }
2826
2827  For explicit ascending order:
2828
2829   order_by => { -asc => 'col' }
2830
2831 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2832 supported, although you are strongly encouraged to use the hashref
2833 syntax as outlined above.
2834
2835 =head2 columns
2836
2837 =over 4
2838
2839 =item Value: \@columns
2840
2841 =back
2842
2843 Shortcut to request a particular set of columns to be retrieved. Each
2844 column spec may be a string (a table column name), or a hash (in which
2845 case the key is the C<as> value, and the value is used as the C<select>
2846 expression). Adds C<me.> onto the start of any column without a C<.> in
2847 it and sets C<select> from that, then auto-populates C<as> from
2848 C<select> as normal. (You may also use the C<cols> attribute, as in
2849 earlier versions of DBIC.)
2850
2851 =head2 +columns
2852
2853 =over 4
2854
2855 =item Value: \@columns
2856
2857 =back
2858
2859 Indicates additional columns to be selected from storage. Works the same
2860 as L</columns> but adds columns to the selection. (You may also use the
2861 C<include_columns> attribute, as in earlier versions of DBIC). For
2862 example:-
2863
2864   $schema->resultset('CD')->search(undef, {
2865     '+columns' => ['artist.name'],
2866     join => ['artist']
2867   });
2868
2869 would return all CDs and include a 'name' column to the information
2870 passed to object inflation. Note that the 'artist' is the name of the
2871 column (or relationship) accessor, and 'name' is the name of the column
2872 accessor in the related table.
2873
2874 =head2 include_columns
2875
2876 =over 4
2877
2878 =item Value: \@columns
2879
2880 =back
2881
2882 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2883
2884 =head2 select
2885
2886 =over 4
2887
2888 =item Value: \@select_columns
2889
2890 =back
2891
2892 Indicates which columns should be selected from the storage. You can use
2893 column names, or in the case of RDBMS back ends, function or stored procedure
2894 names:
2895
2896   $rs = $schema->resultset('Employee')->search(undef, {
2897     select => [
2898       'name',
2899       { count => 'employeeid' },
2900       { sum => 'salary' }
2901     ]
2902   });
2903
2904 When you use function/stored procedure names and do not supply an C<as>
2905 attribute, the column names returned are storage-dependent. E.g. MySQL would
2906 return a column named C<count(employeeid)> in the above example.
2907
2908 =head2 +select
2909
2910 =over 4
2911
2912 Indicates additional columns to be selected from storage.  Works the same as
2913 L</select> but adds columns to the selection.
2914
2915 =back
2916
2917 =head2 +as
2918
2919 =over 4
2920
2921 Indicates additional column names for those added via L</+select>. See L</as>.
2922
2923 =back
2924
2925 =head2 as
2926
2927 =over 4
2928
2929 =item Value: \@inflation_names
2930
2931 =back
2932
2933 Indicates column names for object inflation. That is, C<as>
2934 indicates the name that the column can be accessed as via the
2935 C<get_column> method (or via the object accessor, B<if one already
2936 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2937
2938 The C<as> attribute is used in conjunction with C<select>,
2939 usually when C<select> contains one or more function or stored
2940 procedure names:
2941
2942   $rs = $schema->resultset('Employee')->search(undef, {
2943     select => [
2944       'name',
2945       { count => 'employeeid' }
2946     ],
2947     as => ['name', 'employee_count'],
2948   });
2949
2950   my $employee = $rs->first(); # get the first Employee
2951
2952 If the object against which the search is performed already has an accessor
2953 matching a column name specified in C<as>, the value can be retrieved using
2954 the accessor as normal:
2955
2956   my $name = $employee->name();
2957
2958 If on the other hand an accessor does not exist in the object, you need to
2959 use C<get_column> instead:
2960
2961   my $employee_count = $employee->get_column('employee_count');
2962
2963 You can create your own accessors if required - see
2964 L<DBIx::Class::Manual::Cookbook> for details.
2965
2966 Please note: This will NOT insert an C<AS employee_count> into the SQL
2967 statement produced, it is used for internal access only. Thus
2968 attempting to use the accessor in an C<order_by> clause or similar
2969 will fail miserably.
2970
2971 To get around this limitation, you can supply literal SQL to your
2972 C<select> attibute that contains the C<AS alias> text, eg:
2973
2974   select => [\'myfield AS alias']
2975
2976 =head2 join
2977
2978 =over 4
2979
2980 =item Value: ($rel_name | \@rel_names | \%rel_names)
2981
2982 =back
2983
2984 Contains a list of relationships that should be joined for this query.  For
2985 example:
2986
2987   # Get CDs by Nine Inch Nails
2988   my $rs = $schema->resultset('CD')->search(
2989     { 'artist.name' => 'Nine Inch Nails' },
2990     { join => 'artist' }
2991   );
2992
2993 Can also contain a hash reference to refer to the other relation's relations.
2994 For example:
2995
2996   package MyApp::Schema::Track;
2997   use base qw/DBIx::Class/;
2998   __PACKAGE__->table('track');
2999   __PACKAGE__->add_columns(qw/trackid cd position title/);
3000   __PACKAGE__->set_primary_key('trackid');
3001   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3002   1;
3003
3004   # In your application
3005   my $rs = $schema->resultset('Artist')->search(
3006     { 'track.title' => 'Teardrop' },
3007     {
3008       join     => { cd => 'track' },
3009       order_by => 'artist.name',
3010     }
3011   );
3012
3013 You need to use the relationship (not the table) name in  conditions,
3014 because they are aliased as such. The current table is aliased as "me", so
3015 you need to use me.column_name in order to avoid ambiguity. For example:
3016
3017   # Get CDs from 1984 with a 'Foo' track
3018   my $rs = $schema->resultset('CD')->search(
3019     {
3020       'me.year' => 1984,
3021       'tracks.name' => 'Foo'
3022     },
3023     { join => 'tracks' }
3024   );
3025
3026 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3027 similarly for a third time). For e.g.
3028
3029   my $rs = $schema->resultset('Artist')->search({
3030     'cds.title'   => 'Down to Earth',
3031     'cds_2.title' => 'Popular',
3032   }, {
3033     join => [ qw/cds cds/ ],
3034   });
3035
3036 will return a set of all artists that have both a cd with title 'Down
3037 to Earth' and a cd with title 'Popular'.
3038
3039 If you want to fetch related objects from other tables as well, see C<prefetch>
3040 below.
3041
3042 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3043
3044 =head2 prefetch
3045
3046 =over 4
3047
3048 =item Value: ($rel_name | \@rel_names | \%rel_names)
3049
3050 =back
3051
3052 Contains one or more relationships that should be fetched along with
3053 the main query (when they are accessed afterwards the data will
3054 already be available, without extra queries to the database).  This is
3055 useful for when you know you will need the related objects, because it
3056 saves at least one query:
3057
3058   my $rs = $schema->resultset('Tag')->search(
3059     undef,
3060     {
3061       prefetch => {
3062         cd => 'artist'
3063       }
3064     }
3065   );
3066
3067 The initial search results in SQL like the following:
3068
3069   SELECT tag.*, cd.*, artist.* FROM tag
3070   JOIN cd ON tag.cd = cd.cdid
3071   JOIN artist ON cd.artist = artist.artistid
3072
3073 L<DBIx::Class> has no need to go back to the database when we access the
3074 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3075 case.
3076
3077 Simple prefetches will be joined automatically, so there is no need
3078 for a C<join> attribute in the above search.
3079
3080 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3081 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3082 with an accessor type of 'single' or 'filter'). A more complex example that
3083 prefetches an artists cds, the tracks on those cds, and the tags associted
3084 with that artist is given below (assuming many-to-many from artists to tags):
3085
3086  my $rs = $schema->resultset('Artist')->search(
3087    undef,
3088    {
3089      prefetch => [
3090        { cds => 'tracks' },
3091        { artist_tags => 'tags' }
3092      ]
3093    }
3094  );
3095
3096
3097 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3098 attributes will be ignored.
3099
3100 =head2 page
3101
3102 =over 4
3103
3104 =item Value: $page
3105
3106 =back
3107
3108 Makes the resultset paged and specifies the page to retrieve. Effectively
3109 identical to creating a non-pages resultset and then calling ->page($page)
3110 on it.
3111
3112 If L<rows> attribute is not specified it defualts to 10 rows per page.
3113
3114 When you have a paged resultset, L</count> will only return the number
3115 of rows in the page. To get the total, use the L</pager> and call
3116 C<total_entries> on it.
3117
3118 =head2 rows
3119
3120 =over 4
3121
3122 =item Value: $rows
3123
3124 =back
3125
3126 Specifes the maximum number of rows for direct retrieval or the number of
3127 rows per page if the page attribute or method is used.
3128
3129 =head2 offset
3130
3131 =over 4
3132
3133 =item Value: $offset
3134
3135 =back
3136
3137 Specifies the (zero-based) row number for the  first row to be returned, or the
3138 of the first row of the first page if paging is used.
3139
3140 =head2 group_by
3141
3142 =over 4
3143
3144 =item Value: \@columns
3145
3146 =back
3147
3148 A arrayref of columns to group by. Can include columns of joined tables.
3149
3150   group_by => [qw/ column1 column2 ... /]
3151
3152 =head2 having
3153
3154 =over 4
3155
3156 =item Value: $condition
3157
3158 =back
3159
3160 HAVING is a select statement attribute that is applied between GROUP BY and
3161 ORDER BY. It is applied to the after the grouping calculations have been
3162 done.
3163
3164   having => { 'count(employee)' => { '>=', 100 } }
3165
3166 =head2 distinct
3167
3168 =over 4
3169
3170 =item Value: (0 | 1)
3171
3172 =back
3173
3174 Set to 1 to group by all columns.
3175
3176 =head2 where
3177
3178 =over 4
3179
3180 Adds to the WHERE clause.
3181
3182   # only return rows WHERE deleted IS NULL for all searches
3183   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3184
3185 Can be overridden by passing C<{ where => undef }> as an attribute
3186 to a resulset.
3187
3188 =back
3189
3190 =head2 cache
3191
3192 Set to 1 to cache search results. This prevents extra SQL queries if you
3193 revisit rows in your ResultSet:
3194
3195   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3196
3197   while( my $artist = $resultset->next ) {
3198     ... do stuff ...
3199   }
3200
3201   $rs->first; # without cache, this would issue a query
3202
3203 By default, searches are not cached.
3204
3205 For more examples of using these attributes, see
3206 L<DBIx::Class::Manual::Cookbook>.
3207
3208 =head2 from
3209
3210 =over 4
3211
3212 =item Value: \@from_clause
3213
3214 =back
3215
3216 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3217 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3218 clauses.
3219
3220 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3221
3222 C<join> will usually do what you need and it is strongly recommended that you
3223 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3224 And we really do mean "cannot", not just tried and failed. Attempting to use
3225 this because you're having problems with C<join> is like trying to use x86
3226 ASM because you've got a syntax error in your C. Trust us on this.
3227
3228 Now, if you're still really, really sure you need to use this (and if you're
3229 not 100% sure, ask the mailing list first), here's an explanation of how this
3230 works.
3231
3232 The syntax is as follows -
3233
3234   [
3235     { <alias1> => <table1> },
3236     [
3237       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3238       [], # nested JOIN (optional)
3239       { <table1.column1> => <table2.column2>, ... (more conditions) },
3240     ],
3241     # More of the above [ ] may follow for additional joins
3242   ]
3243
3244   <table1> <alias1>
3245   JOIN
3246     <table2> <alias2>
3247     [JOIN ...]
3248   ON <table1.column1> = <table2.column2>
3249   <more joins may follow>
3250
3251 An easy way to follow the examples below is to remember the following:
3252
3253     Anything inside "[]" is a JOIN
3254     Anything inside "{}" is a condition for the enclosing JOIN
3255
3256 The following examples utilize a "person" table in a family tree application.
3257 In order to express parent->child relationships, this table is self-joined:
3258
3259     # Person->belongs_to('father' => 'Person');
3260     # Person->belongs_to('mother' => 'Person');
3261
3262 C<from> can be used to nest joins. Here we return all children with a father,
3263 then search against all mothers of those children:
3264
3265   $rs = $schema->resultset('Person')->search(
3266       undef,
3267       {
3268           alias => 'mother', # alias columns in accordance with "from"
3269           from => [
3270               { mother => 'person' },
3271               [
3272                   [
3273                       { child => 'person' },
3274                       [
3275                           { father => 'person' },
3276                           { 'father.person_id' => 'child.father_id' }
3277                       ]
3278                   ],
3279                   { 'mother.person_id' => 'child.mother_id' }
3280               ],
3281           ]
3282       },
3283   );
3284
3285   # Equivalent SQL:
3286   # SELECT mother.* FROM person mother
3287   # JOIN (
3288   #   person child
3289   #   JOIN person father
3290   #   ON ( father.person_id = child.father_id )
3291   # )
3292   # ON ( mother.person_id = child.mother_id )
3293
3294 The type of any join can be controlled manually. To search against only people
3295 with a father in the person table, we could explicitly use C<INNER JOIN>:
3296
3297     $rs = $schema->resultset('Person')->search(
3298         undef,
3299         {
3300             alias => 'child', # alias columns in accordance with "from"
3301             from => [
3302                 { child => 'person' },
3303                 [
3304                     { father => 'person', -join_type => 'inner' },
3305                     { 'father.id' => 'child.father_id' }
3306                 ],
3307             ]
3308         },
3309     );
3310
3311     # Equivalent SQL:
3312     # SELECT child.* FROM person child
3313     # INNER JOIN person father ON child.father_id = father.id
3314
3315 If you need to express really complex joins or you need a subselect, you
3316 can supply literal SQL to C<from> via a scalar reference. In this case
3317 the contents of the scalar will replace the table name asscoiated with the
3318 resultsource.
3319
3320 WARNING: This technique might very well not work as expected on chained
3321 searches - you have been warned.
3322
3323     # Assuming the Event resultsource is defined as:
3324
3325         MySchema::Event->add_columns (
3326             sequence => {
3327                 data_type => 'INT',
3328                 is_auto_increment => 1,
3329             },
3330             location => {
3331                 data_type => 'INT',
3332             },
3333             type => {
3334                 data_type => 'INT',
3335             },
3336         );
3337         MySchema::Event->set_primary_key ('sequence');
3338
3339     # This will get back the latest event for every location. The column
3340     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3341     # combo to limit the resultset
3342
3343     $rs = $schema->resultset('Event');
3344     $table = $rs->result_source->name;
3345     $latest = $rs->search (
3346         undef,
3347         { from => \ "
3348             (SELECT e1.* FROM $table e1
3349                 JOIN $table e2
3350                     ON e1.location = e2.location
3351                     AND e1.sequence < e2.sequence
3352                 WHERE e2.sequence is NULL
3353             ) me",
3354         },
3355     );
3356
3357     # Equivalent SQL (with the DBIC chunks added):
3358
3359     SELECT me.sequence, me.location, me.type FROM
3360        (SELECT e1.* FROM events e1
3361            JOIN events e2
3362                ON e1.location = e2.location
3363                AND e1.sequence < e2.sequence
3364            WHERE e2.sequence is NULL
3365        ) me;
3366
3367 =head2 for
3368
3369 =over 4
3370
3371 =item Value: ( 'update' | 'shared' )
3372
3373 =back
3374
3375 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3376 ... FOR SHARED.
3377
3378 =cut
3379
3380 1;