lib/DBIx/Class/Relationship.pm

   1 package DBIx::Class::Relationship;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class/;
   7
   8 __PACKAGE__->load_own_components(qw/
   9   Helpers
  10   Accessor
  11   CascadeActions
  12   ProxyMethods
  13   Base
  14 /);
  15
  16 =head1 NAME
  17
  18 DBIx::Class::Relationship - Inter-table relationships
  19
  20 =head1 SYNOPSIS
  21
  22   MyDB::Schema::Actor->has_many('actorroles' => 'MyDB::Schema::ActorRole',
  23                                 'actor');
  24   MyDB::Schema::Role->has_many('actorroles' => 'MyDB::Schema::ActorRole',
  25                                 'role');
  26   MyDB::Schema::ActorRole->belongs_to('role' => 'MyDB::Schema::Role');
  27   MyDB::Schema::ActorRole->belongs_to('actor' => 'MyDB::Schema::Actor');
  28
  29   MyDB::Schema::Role->many_to_many('actors' => 'actorroles', 'actor');
  30   MyDB::Schema::Actor->many_to_many('roles' => 'actorroles', 'role');
  31
  32   $schema->resultset('Actor')->roles();
  33   $schema->resultset('Role')->search_related('actors', { Name => 'Fred' });
  34   $schema->resultset('ActorRole')->add_to_roles({ Name => 'Sherlock Holmes'});
  35
  36 See L<DBIx::Class::Manual::Cookbook> for more.
  37
  38 =head1 DESCRIPTION
  39
  40 This class provides methods to set up relationships between the tables
  41 in your database model. Relationships are the most useful and powerful
  42 technique that L<DBIx::Class> provides. To create efficient database queries,
  43 create relationships between any and all tables that have something in
  44 common, for example if you have a table Authors:
  45
  46   ID  | Name | Age
  47  ------------------
  48    1  | Fred | 30
  49    2  | Joe  | 32
  50
  51 and a table Books:
  52
  53   ID  | Author | Name
  54  --------------------
  55    1  |      1 | Rulers of the universe
  56    2  |      1 | Rulers of the galaxy
  57
  58 Then without relationships, the method of getting all books by Fred goes like
  59 this:
  60
  61  my $fred = $schema->resultset('Author')->find({ Name => 'Fred' });
  62  my $fredsbooks = $schema->resultset('Book')->search({ Author => $fred->ID });
  63 With a has_many relationship called "books" on Author (see below for details),
  64 we can do this instead:
  65
  66  my $fredsbooks = $schema->resultset('Author')->find({ Name => 'Fred' })->books;
  67
  68 Each relationship sets up an accessor method on the
  69 L<DBIx::Class::Manual::Glossary/"Row"> objects that represent the items
  70 of your table. From L<DBIx::Class::Manual::Glossary/"ResultSet"> objects,
  71 the relationships can be searched using the "search_related" method.
  72 In list context, each returns a list of Row objects for the related class,
  73 in scalar context, a new ResultSet representing the joined tables is
  74 returned. Thus, the calls can be chained to produce complex queries.
  75 Since the database is not actually queried until you attempt to retrieve
  76 the data for an actual item, no time is wasted producing them.
  77
  78  my $cheapfredbooks = $schema->resultset('Author')->find({
  79    Name => 'Fred',
  80  })->books->search_related('prices', {
  81    Price => { '<=' => '5.00' },
  82  });
  83
  84 will produce a query something like:
  85
  86  SELECT * FROM Author me
  87  LEFT JOIN Books books ON books.author = me.id
  88  LEFT JOIN Prices prices ON prices.book = books.id
  89  WHERE prices.Price <= 5.00
  90
  91 all without needing multiple fetches.
  92
  93 Only the helper methods for setting up standard relationship types
  94 are documented here. For the basic, lower-level methods, and a description
  95 of all the useful *_related methods that you get for free, see
  96 L<DBIx::Class::Relationship::Base>.
  97
  98 =head1 METHODS
  99
 100 All helper methods take the following arguments:
 101
 102   __PACKAGE__>$method_name('relname', 'Foreign::Class', $cond, $attrs);
 103
 104 Both C<$cond> and C<$attrs> are optional. Pass C<undef> for C<$cond> if
 105 you want to use the default value for it, but still want to set C<$attrs>.
 106
 107 See L<DBIx::Class::Relationship::Base> for a list of valid attributes and valid
 108 relationship attributes.
 109
 110 =head2 belongs_to
 111
 112 =over 4
 113
 114 =item Arguments: $accessor_name, $related_class, $foreign_key_column|$cond?, $attr?
 115
 116 =back
 117
 118   # in a Book class (where Author has many Books)
 119   My::DBIC::Schema::Book->belongs_to( author => 'My::DBIC::Schema::Author' );
 120
 121   my $author_obj = $obj->author; # get author object
 122   $obj->author( $new_author_obj ); # set author object
 123
 124 The above belongs_to relationship could also have been specified as,
 125
 126   My::DBIC::Schema::Book->belongs_to( author,
 127                                       'My::DBIC::Schema::Author',
 128                                       { 'self.author' => 'foreign.author' } );
 129
 130 Creates a relationship where the calling class stores the foreign class's
 131 primary key in one (or more) of its columns. This relationship defaults to
 132 using C<$accessor_name> as the foreign key in C<$related_class> to resolve the
 133 join, unless C<$foreign_key_column> specifies the foreign key column in
 134 C<$related_class> or C<$cond> specifies a reference to a join condition hash.
 135
 136 If the relationship is optional -- i.e. the column containing the foreign key
 137 can be NULL -- then the belongs_to relationship does the right thing. Thus, in
 138 the example above C<$obj-E<gt>author> would return C<undef>.  However in this
 139 case you would probably want to set the C<join_type> attribute so that a C<LEFT
 140 JOIN> is done, which makes complex resultsets involving C<join> or C<prefetch>
 141 operations work correctly.  The modified declaration is shown below:
 142
 143   # in a Book class (where Author has_many Books)
 144   __PACKAGE__->belongs_to(author => 'My::DBIC::Schema::Author',
 145                           'author', {join_type => 'left'});
 146
 147
 148 Cascading deletes are off by default on a C<belongs_to>
 149 relationship. To turn them on, pass C<< cascade_delete => 1 >>
 150 in the $attr hashref.
 151
 152 NOTE: If you are used to L<Class::DBI> relationships, this is the equivalent
 153 of C<has_a>.
 154
 155 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 156 methods and valid relationship attributes.
 157
 158 =head2 has_many
 159
 160 =over 4
 161
 162 =item Arguments: $accessor_name, $related_class, $foreign_key_column|$cond?, $attr?
 163
 164 =back
 165
 166   # in an Author class (where Author has_many Books)
 167   My::DBIC::Schema::Author->has_many(books => 'My::DBIC::Schema::Book', 'author');
 168
 169   my $booklist = $obj->books;
 170   my $booklist = $obj->books({
 171     name => { LIKE => '%macaroni%' },
 172     { prefetch => [qw/book/],
 173   });
 174   my @book_objs = $obj->books;
 175   my $books_rs = $obj->books;
 176   ( $books_rs ) = $obj->books_rs;
 177
 178   $obj->add_to_books(\%col_data);
 179
 180 The above C<has_many> relationship could also have been specified with an
 181 explicit join condition:
 182
 183   My::DBIC::Schema::Author->has_many( books => 'My::DBIC::Schema::Book', {
 184     'foreign.author' => 'self.author',
 185   });
 186
 187 Creates a one-to-many relationship, where the corresponding elements of the
 188 foreign class store the calling class's primary key in one (or more) of its
 189 columns. This relationship defaults to using C<$accessor_name> as the foreign
 190 key in C<$related_class> to resolve the join, unless C<$foreign_key_column>
 191 specifies the foreign key column in C<$related_class> or C<$cond> specifies a
 192 reference to a join condition hash.
 193
 194 Three methods are created when you create a has_many relationship.  The first
 195 method is the expected accessor method, C<$accessor_name()>.  The second is
 196 almost exactly the same as the accessor method but "_rs" is added to the end of
 197 the method name.  This method works just like the normal accessor, except that
 198 it returns a resultset no matter what, even in list context. The third method,
 199 named C<< add_to_$relname >>, will also be added to your Row items; this
 200 allows you to insert new related items, using the same mechanism as in
 201 L<DBIx::Class::Relationship::Base/"create_related">.
 202
 203 If you delete an object in a class with a C<has_many> relationship, all
 204 the related objects will be deleted as well.  To turn this behaviour off,
 205 pass C<< cascade_delete => 0 >> in the C<$attr> hashref. However, any
 206 database-level cascade or restrict will take precedence over a
 207 DBIx-Class-based cascading delete.
 208
 209 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 210 methods and valid relationship attributes.
 211
 212 =head2 might_have
 213
 214 =over 4
 215
 216 =item Arguments: $accessor_name, $related_class, $foreign_key_column|$cond?, $attr?
 217
 218 =back
 219
 220   My::DBIC::Schema::Author->might_have( pseudonym =>
 221                                         'My::DBIC::Schema::Pseudonym' );
 222
 223   my $pname = $obj->pseudonym; # to get the Pseudonym object
 224
 225 The above might_have relationship could have been specified as:
 226
 227   My::DBIC::Schema::Author->might_have( pseudonym =>
 228                                         'My::DBIC::Schema::Pseudonym',
 229                                         'author' );
 230
 231 Or even:
 232
 233   My::DBIC::Schema::Author->might_have( pseudonym =>
 234                                         'My::DBIC::Schema::Pseudonym',
 235                                         { 'foreign.author' => 'self.author' } );
 236
 237 Assuming the Pseudonym table has
 238
 239 Creates an optional one-to-one relationship with a class. This relationship
 240 defaults to using C<$accessor_name> as the foreign key in C<$related_class> to
 241 resolve the join, unless C<$foreign_key_column> specifies the foreign key
 242 column in C<$related_class> or C<$cond> specifies a reference to a join
 243 condition hash.
 244
 245 If you update or delete an object in a class with a C<might_have>
 246 relationship, the related object will be updated or deleted as well. To
 247 turn off this behavior, add C<< cascade_delete => 0 >> to the C<$attr>
 248 hashref. Any database-level update or delete constraints will override
 249 this behavior.
 250
 251 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 252 methods and valid relationship attributes.
 253
 254 =head2 has_one
 255
 256 =over 4
 257
 258 =item Arguments: $accessor_name, $related_class_name, $join_condition?, $attr?
 259
 260 =back
 261
 262   My::DBIC::Schema::Book->has_one(isbn => 'My::DBIC::Schema::ISBN');
 263
 264   my $isbn_obj = $obj->isbn; # to get the ISBN object
 265
 266 Creates a one-to-one relationship with another class. This is just like
 267 C<might_have>, except the implication is that the other object is always
 268 present. The only difference between C<has_one> and C<might_have> is that
 269 C<has_one> uses an (ordinary) inner join, whereas C<might_have> uses a
 270 left join.
 271
 272 The has_one relationship should be used when a row in the table has exactly one
 273 related row in another table. If the related row might not exist in the foreign
 274 table, use the L<DBIx::Class::Relationship/might_have> relationship.
 275
 276 In the above example, each Book in the database is associated with exactly one
 277 ISBN object.
 278
 279 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 280 methods and valid relationship attributes.
 281
 282 =head2 many_to_many
 283
 284 =over 4
 285
 286 =item Arguments: $accessor_name, $link_rel_name, $foreign_rel_name, $attr?
 287
 288 =back
 289
 290 To create a many_to_many relationship from Actor to Role:
 291
 292   My::DBIC::Schema::Actor->has_many( actor_roles =>
 293                                      'My::DBIC::Schema::ActorRoles',
 294                                      'actor' );
 295   My::DBIC::Schema::ActorRoles->belongs_to( role =>
 296                                             'My::DBIC::Schema::Role' );
 297   My::DBIC::Schema::ActorRoles->belongs_to( actor =>
 298                                             'My::DBIC::Schema::Actor' );
 299
 300   My::DBIC::Schema::Actor->many_to_many( roles => 'actor_roles',
 301                                          'role' );
 302
 303 And, for the reverse relationship, from Role to Actor:
 304
 305   My::DBIC::Schema::Role->has_many( actor_roles =>
 306                                     'My::DBIC::Schema::ActorRoles',
 307                                     'role' );
 308
 309   My::DBIC::Schema::Role->many_to_many( actors => 'actor_roles', 'actor' );
 310
 311 Creates accessors bridging two relationships; not strictly a relationship in
 312 its own right, although the accessor will return a resultset or collection of
 313 objects just as a has_many would.
 314
 315 In the above example, ActorRoles is the link table class, and Role is the
 316 foreign class. The C<$link_rel_name> parameter is the name of the accessor for
 317 the has_many relationship from this table to the link table, and the
 318 C<$foreign_rel_name> parameter is the accessor for the belongs_to relationship
 319 from the link table to the foreign table.
 320
 321 To use many_to_many, existing relationships from the original table to the link
 322 table, and from the link table to the end table must already exist, these
 323 relation names are then used in the many_to_many call.
 324
 325 In the above example, the Actor class will have 3 many_to_many accessor methods
 326 set: C<$roles>, C<$add_to_roles>, C<$set_roles>, and similarly named accessors
 327 will be created for the Role class for the C<actors> many_to_many
 328 relationship.
 329
 330 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 331 methods and valid relationship attributes.
 332
 333 =cut
 334
 335 1;
 336
 337 =head1 AUTHORS
 338
 339 Matt S. Trout <mst@shadowcatsystems.co.uk>
 340
 341 =head1 LICENSE
 342
 343 You may distribute this code under the same terms as Perl itself.
 344
 345 =cut
 346