lib/DBIx/Class/Relationship/HasOne.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::HasOne;
   3
   4 use strict;
   5 use warnings;
   6 use DBIx::Class::Carp;
   7 use Try::Tiny;
   8 use namespace::clean;
   9
  10 our %_pod_inherit_config =
  11   (
  12    class_map => { 'DBIx::Class::Relationship::HasOne' => 'DBIx::Class::Relationship' }
  13   );
  14
  15 sub might_have {
  16   shift->_has_one('LEFT' => @_);
  17 }
  18
  19 sub has_one {
  20   shift->_has_one(undef() => @_);
  21 }
  22
  23 sub _has_one {
  24   my ($class, $join_type, $rel, $f_class, $cond, $attrs) = @_;
  25   unless (ref $cond) {
  26     my $pri = $class->result_source_instance->_single_pri_col_or_die;
  27
  28     my ($f_key,$guess,$f_rsrc);
  29     if (defined $cond && length $cond) {
  30       $f_key = $cond;
  31       $guess = "caller specified foreign key '$f_key'";
  32     }
  33     else {
  34       # at this point we need to load the foreigner, expensive or not
  35       $class->ensure_class_loaded($f_class);
  36
  37       $f_rsrc = try {
  38         $f_class->result_source_instance;
  39       }
  40       catch {
  41         $class->throw_exception(
  42           "Foreign class '$f_class' does not seem to be a Result class "
  43         . "(or it simply did not load entirely due to a circular relation chain)"
  44         );
  45       };
  46
  47       if ($f_rsrc->has_column($rel)) {
  48         $f_key = $rel;
  49         $guess = "using given relationship name '$rel' as foreign key column name";
  50       }
  51       else {
  52         $f_key = $f_rsrc->_single_pri_col_or_die;
  53         $guess = "using primary key of foreign class for foreign key";
  54       }
  55     }
  56
  57     # only perform checks if the far side was not preloaded above *AND*
  58     # appears to have been loaded by something else (has a rsrc_instance)
  59     if (! $f_rsrc and $f_rsrc = try { $f_class->result_source_instance }) {
  60       $class->throw_exception(
  61         "No such column '$f_key' on foreign class ${f_class} ($guess)"
  62       ) if !$f_rsrc->has_column($f_key);
  63     }
  64
  65     $cond = { "foreign.${f_key}" => "self.${pri}" };
  66   }
  67   $class->_validate_has_one_condition($cond);
  68
  69   my $default_cascade = ref $cond eq 'CODE' ? 0 : 1;
  70
  71   $class->add_relationship($rel, $f_class,
  72    $cond,
  73    { accessor => 'single',
  74      cascade_update => $default_cascade,
  75      cascade_delete => $default_cascade,
  76      ($join_type ? ('join_type' => $join_type) : ()),
  77      %{$attrs || {}} });
  78   1;
  79 }
  80
  81 sub _validate_has_one_condition {
  82   my ($class, $cond )  = @_;
  83
  84   return if $ENV{DBIC_DONT_VALIDATE_RELS};
  85   return unless 'HASH' eq ref $cond;
  86   foreach my $foreign_id ( keys %$cond ) {
  87     my $self_id = $cond->{$foreign_id};
  88
  89     # we can ignore a bad $self_id because add_relationship handles this
  90     # warning
  91     return unless $self_id =~ /^self\.(.*)$/;
  92     my $key = $1;
  93     $class->throw_exception("Defining rel on ${class} that includes '$key' but no such column defined here yet")
  94         unless $class->has_column($key);
  95     my $column_info = $class->column_info($key);
  96     if ( $column_info->{is_nullable} ) {
  97       carp(qq'"might_have/has_one" must not be on columns with is_nullable set to true ($class/$key). This might indicate an incorrect use of those relationship helpers instead of belongs_to.');
  98     }
  99   }
 100 }
 101
 102 1;