lib/DBIx/Class/Relationship/HasOne.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::HasOne;
   3
   4 use strict;
   5 use warnings;
   6
   7 sub might_have {
   8   shift->_has_one('LEFT' => @_);
   9 }
  10
  11 sub has_one {
  12   shift->_has_one(undef() => @_);
  13 }
  14
  15 sub _has_one {
  16   my ($class, $join_type, $rel, $f_class, $cond, $attrs) = @_;
  17   unless (ref $cond) {
  18     $class->ensure_class_loaded($f_class);
  19     my ($pri, $too_many) = $class->primary_columns;
  20
  21     $class->throw_exception(
  22       "might_have/has_one can only infer join for a single primary key; ".
  23       "${class} has more"
  24     ) if $too_many;
  25
  26     $class->throw_exception(
  27       "might_have/has_one needs a primary key  to infer a join; ".
  28       "${class} has none"
  29     ) if !defined $pri && (!defined $cond || !length $cond);
  30
  31     my $f_class_loaded = eval { $f_class->columns };
  32     my ($f_key,$guess);
  33     if (defined $cond && length $cond) {
  34       $f_key = $cond;
  35       $guess = "caller specified foreign key '$f_key'";
  36     } elsif ($f_class_loaded && $f_class->has_column($rel)) {
  37       $f_key = $rel;
  38       $guess = "using given relationship '$rel' for foreign key";
  39     } else {
  40       ($f_key, $too_many) = $f_class->primary_columns;
  41       $class->throw_exception(
  42         "might_have/has_one can only infer join for a single primary key; ".
  43         "${f_class} has more"
  44       ) if $too_many;
  45       $guess = "using primary key of foreign class for foreign key";
  46     }
  47     $class->throw_exception(
  48       "No such column ${f_key} on foreign class ${f_class} ($guess)"
  49     ) if $f_class_loaded && !$f_class->has_column($f_key);
  50     $cond = { "foreign.${f_key}" => "self.${pri}" };
  51   }
  52   $class->add_relationship($rel, $f_class,
  53    $cond,
  54    { accessor => 'single',
  55      cascade_update => 1, cascade_delete => 1,
  56      ($join_type ? ('join_type' => $join_type) : ()),
  57      %{$attrs || {}} });
  58   1;
  59 }
  60
  61 1;