lib/DBIx/Class/Relationship/HasMany.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::HasMany;
   3
   4 use strict;
   5 use warnings;
   6
   7 our %_pod_inherit_config =
   8   (
   9    class_map => { 'DBIx::Class::Relationship::HasMany' => 'DBIx::Class::Relationship' }
  10   );
  11
  12 sub has_many {
  13   my ($class, $rel, $f_class, $cond, $attrs) = @_;
  14
  15   unless (ref $cond) {
  16     $class->ensure_class_loaded($f_class);
  17     my ($pri, $too_many) = eval { $class->_pri_cols };
  18     $class->throw_exception(
  19       "Can't infer join condition for ${rel} on ${class}: $@"
  20     ) if $@;
  21
  22     $class->throw_exception(
  23       "has_many can only infer join for a single primary key; ".
  24       "${class} has more"
  25     ) if $too_many;
  26
  27     $class->throw_exception(
  28       "has_many needs a primary key to infer a join; ".
  29       "${class} has none"
  30     ) if !defined $pri && (!defined $cond || !length $cond);
  31
  32     my ($f_key,$guess);
  33     if (defined $cond && length $cond) {
  34       $f_key = $cond;
  35       $guess = "caller specified foreign key '$f_key'";
  36     } else {
  37       $class =~ /([^\:]+)$/;
  38       $f_key = lc $1; # go ahead and guess; best we can do
  39       $guess = "using our class name '$class' as foreign key";
  40     }
  41
  42     my $f_class_loaded = eval { $f_class->columns };
  43     $class->throw_exception(
  44       "No such column ${f_key} on foreign class ${f_class} ($guess)"
  45     ) if $f_class_loaded && !$f_class->has_column($f_key);
  46
  47     $cond = { "foreign.${f_key}" => "self.${pri}" };
  48   }
  49
  50   $class->add_relationship($rel, $f_class, $cond, {
  51     accessor => 'multi',
  52     join_type => 'LEFT',
  53     cascade_delete => 1,
  54     cascade_copy => 1,
  55     %{$attrs||{}}
  56   });
  57 }
  58
  59 1;