lib/DBIx/Class/Manual/Example.pod

   1 =head1 NAME
   2
   3 DBIx::Class::Manual::Example - Simple CD database example
   4
   5 =head1 DESCRIPTION
   6
   7 This tutorial will guide you through the process of setting up and
   8 testing a very basic CD database using SQLite, with DBIx::Class::Schema
   9 as the database frontend.
  10
  11 The database consists of the following:
  12
  13   table 'artist' with columns:  artistid, name
  14   table 'cd'     with columns:  cdid, artist, title
  15   table 'track'  with columns:  trackid, cd, title
  16
  17
  18 And these rules exists:
  19
  20   one artist can have many cds
  21   one cd belongs to one artist
  22   one cd can have many tracks
  23   one track belongs to one cd
  24
  25
  26 =head2 Installation
  27
  28 Install DBIx::Class via CPAN should be sufficient.
  29
  30 =head3 Create the database/tables
  31
  32 First make and change the directory:
  33
  34   mkdir app
  35   cd app
  36   mkdir db
  37   cd db
  38
  39 This example uses SQLite which is a dependency of DBIx::Class, so you
  40 shouldn't have to install extra software.
  41
  42 Save the following into a example.sql in the directory db
  43
  44   CREATE TABLE artist (
  45     artistid INTEGER PRIMARY KEY,
  46     name TEXT NOT NULL
  47   );
  48
  49   CREATE TABLE cd (
  50     cdid INTEGER PRIMARY KEY,
  51     artist INTEGER NOT NULL REFERENCES artist(artistid),
  52     title TEXT NOT NULL
  53   );
  54
  55   CREATE TABLE track (
  56     trackid INTEGER PRIMARY KEY,
  57     cd INTEGER NOT NULL REFERENCES cd(cdid),
  58     title TEXT NOT NULL
  59   );
  60
  61 and create the SQLite database file:
  62
  63   sqlite3 example.db < example.sql
  64
  65 =head3 Set up DBIx::Class::Schema
  66
  67 Change directory back from db to the directory app:
  68
  69   cd ../
  70
  71 Now create some more directories:
  72
  73   mkdir MyDatabase
  74   mkdir MyDatabase/Main
  75   mkdir MyDatabase/Main/Result
  76   mkdir MyDatabase/Main/ResultSet
  77
  78 Then, create the following DBIx::Class::Schema classes:
  79
  80 MyDatabase/Main.pm:
  81
  82   package MyDatabase::Main;
  83   use base qw/DBIx::Class::Schema/;
  84   __PACKAGE__->load_namespaces;
  85
  86   1;
  87
  88
  89 MyDatabase/Main/Result/Artist.pm:
  90
  91   package MyDatabase::Main::Result::Artist;
  92   use base qw/DBIx::Class::Core/;
  93   __PACKAGE__->table('artist');
  94   __PACKAGE__->add_columns(qw/ artistid name /);
  95   __PACKAGE__->set_primary_key('artistid');
  96   __PACKAGE__->has_many('cds' => 'MyDatabase::Main::Result::Cd');
  97
  98   1;
  99
 100
 101 MyDatabase/Main/Result/Cd.pm:
 102
 103   package MyDatabase::Main::Result::Cd;
 104   use base qw/DBIx::Class::Core/;
 105   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
 106   __PACKAGE__->table('cd');
 107   __PACKAGE__->add_columns(qw/ cdid artist title/);
 108   __PACKAGE__->set_primary_key('cdid');
 109   __PACKAGE__->belongs_to('artist' => 'MyDatabase::Main::Result::Artist');
 110   __PACKAGE__->has_many('tracks' => 'MyDatabase::Main::Result::Track');
 111
 112   1;
 113
 114
 115 MyDatabase/Main/Result/Track.pm:
 116
 117   package MyDatabase::Main::Result::Track;
 118   use base qw/DBIx::Class::Core/;
 119   __PACKAGE__->table('track');
 120   __PACKAGE__->add_columns(qw/ trackid cd title /);
 121   __PACKAGE__->set_primary_key('trackid');
 122   __PACKAGE__->belongs_to('cd' => 'MyDatabase::Main::Result::Cd');
 123
 124   1;
 125
 126
 127 =head3 Write a script to insert some records
 128
 129 insertdb.pl
 130
 131   #!/usr/bin/perl
 132
 133   use strict;
 134   use warnings;
 135
 136   use MyDatabase::Main;
 137
 138   my $schema = MyDatabase::Main->connect('dbi:SQLite:db/example.db');
 139
 140   #  here's some of the SQL that is going to be generated by the schema
 141   #  INSERT INTO artist VALUES (NULL,'Michael Jackson');
 142   #  INSERT INTO artist VALUES (NULL,'Eminem');
 143
 144   my @artists = (['Michael Jackson'], ['Eminem']);
 145   $schema->populate('Artist', [
 146      [qw/name/],
 147      @artists,
 148   ]);
 149
 150   my %albums = (
 151     'Thriller' => 'Michael Jackson',
 152     'Bad' => 'Michael Jackson',
 153     'The Marshall Mathers LP' => 'Eminem',
 154   );
 155
 156   my @cds;
 157   foreach my $lp (keys %albums) {
 158     my $artist = $schema->resultset('Artist')->find({
 159       name => $albums{$lp}
 160     });
 161     push @cds, [$lp, $artist->id];
 162   }
 163
 164   $schema->populate('Cd', [
 165     [qw/title artist/],
 166     @cds,
 167   ]);
 168
 169
 170   my %tracks = (
 171     'Beat It'         => 'Thriller',
 172     'Billie Jean'     => 'Thriller',
 173     'Dirty Diana'     => 'Bad',
 174     'Smooth Criminal' => 'Bad',
 175     'Leave Me Alone'  => 'Bad',
 176     'Stan'            => 'The Marshall Mathers LP',
 177     'The Way I Am'    => 'The Marshall Mathers LP',
 178   );
 179
 180   my @tracks;
 181   foreach my $track (keys %tracks) {
 182     my $cdname = $schema->resultset('Cd')->find({
 183       title => $tracks{$track},
 184     });
 185     push @tracks, [$cdname->id, $track];
 186   }
 187
 188   $schema->populate('Track',[
 189     [qw/cd title/],
 190     @tracks,
 191   ]);
 192
 193 =head3 Create and run the test scripts
 194
 195 testdb.pl:
 196
 197   #!/usr/bin/perl
 198
 199   use strict;
 200   use warnings;
 201
 202   use MyDatabase::Main;
 203
 204   my $schema = MyDatabase::Main->connect('dbi:SQLite:db/example.db');
 205   # for other DSNs, e.g. MySQL, see the perldoc for the relevant dbd
 206   # driver, e.g perldoc L<DBD::mysql>.
 207
 208   get_tracks_by_cd('Bad');
 209   get_tracks_by_artist('Michael Jackson');
 210
 211   get_cd_by_track('Stan');
 212   get_cds_by_artist('Michael Jackson');
 213
 214   get_artist_by_track('Dirty Diana');
 215   get_artist_by_cd('The Marshall Mathers LP');
 216
 217
 218   sub get_tracks_by_cd {
 219     my $cdtitle = shift;
 220     print "get_tracks_by_cd($cdtitle):\n";
 221     my $rs = $schema->resultset('Track')->search(
 222       {
 223         'cd.title' => $cdtitle
 224       },
 225       {
 226         join     => [qw/ cd /],
 227       }
 228     );
 229     while (my $track = $rs->next) {
 230       print $track->title . "\n";
 231     }
 232     print "\n";
 233   }
 234
 235   sub get_tracks_by_artist {
 236     my $artistname = shift;
 237     print "get_tracks_by_artist($artistname):\n";
 238     my $rs = $schema->resultset('Track')->search(
 239       {
 240         'artist.name' => $artistname
 241       },
 242       {
 243         join => {
 244           'cd' => 'artist'
 245         },
 246       }
 247     );
 248     while (my $track = $rs->next) {
 249       print $track->title . "\n";
 250     }
 251     print "\n";
 252   }
 253
 254
 255   sub get_cd_by_track {
 256     my $tracktitle = shift;
 257     print "get_cd_by_track($tracktitle):\n";
 258     my $rs = $schema->resultset('Cd')->search(
 259       {
 260         'tracks.title' => $tracktitle
 261       },
 262       {
 263         join     => [qw/ tracks /],
 264       }
 265     );
 266     my $cd = $rs->first;
 267     print $cd->title . "\n\n";
 268   }
 269
 270   sub get_cds_by_artist {
 271     my $artistname = shift;
 272     print "get_cds_by_artist($artistname):\n";
 273     my $rs = $schema->resultset('Cd')->search(
 274       {
 275         'artist.name' => $artistname
 276       },
 277       {
 278         join     => [qw/ artist /],
 279       }
 280     );
 281     while (my $cd = $rs->next) {
 282       print $cd->title . "\n";
 283     }
 284     print "\n";
 285   }
 286
 287
 288
 289   sub get_artist_by_track {
 290     my $tracktitle = shift;
 291     print "get_artist_by_track($tracktitle):\n";
 292     my $rs = $schema->resultset('Artist')->search(
 293       {
 294         'tracks.title' => $tracktitle
 295       },
 296       {
 297         join => {
 298           'cds' => 'tracks'
 299         }
 300       }
 301     );
 302     my $artist = $rs->first;
 303     print $artist->name . "\n\n";
 304   }
 305
 306   sub get_artist_by_cd {
 307     my $cdtitle = shift;
 308     print "get_artist_by_cd($cdtitle):\n";
 309     my $rs = $schema->resultset('Artist')->search(
 310       {
 311         'cds.title' => $cdtitle
 312       },
 313       {
 314         join     => [qw/ cds /],
 315       }
 316     );
 317     my $artist = $rs->first;
 318     print $artist->name . "\n\n";
 319   }
 320
 321
 322
 323 It should output:
 324
 325   get_tracks_by_cd(Bad):
 326   Dirty Diana
 327   Smooth Criminal
 328   Leave Me Alone
 329
 330   get_tracks_by_artist(Michael Jackson):
 331   Beat it
 332   Billie Jean
 333   Dirty Diana
 334   Smooth Criminal
 335   Leave Me Alone
 336
 337   get_cd_by_track(Stan):
 338   The Marshall Mathers LP
 339
 340   get_cds_by_artist(Michael Jackson):
 341   Thriller
 342   Bad
 343
 344   get_artist_by_track(Dirty Diana):
 345   Michael Jackson
 346
 347   get_artist_by_cd(The Marshall Mathers LP):
 348   Eminem
 349
 350 =head1 Notes
 351
 352 A reference implementation of the database and scripts in this example
 353 are available in the main distribution for DBIx::Class under the
 354 directory F<t/examples/Schema>.
 355
 356 With these scripts we're relying on @INC looking in the current
 357 working directory.  You may want to add the MyDatabase namespaces to
 358 @INC in a different way when it comes to deployment.
 359
 360 The F<testdb.pl> script is an excellent start for testing your database
 361 model.
 362
 363 This example uses L<DBIx::Class::Schema/load_namespaces> to load in the
 364 appropriate L<Row|DBIx::Class::Row> classes from the MyDatabase::Main::Result namespace,
 365 and any required resultset classes from the MyDatabase::Main::ResultSet
 366 namespace (although we created the directory in the directions above we
 367 did not add, or need to add, any resultset classes).
 368
 369 =head1 TODO
 370
 371 =head1 AUTHOR
 372
 373   sc_ from irc.perl.org#dbix-class
 374   Kieren Diment <kd@totaldatasolution.com>
 375   Nigel Metheringham <nigelm@cpan.org>
 376
 377 =cut