lib/DBIx/Class/InflateColumn.pm

   1 package DBIx::Class::InflateColumn;
   2
   3 use strict;
   4 use warnings;
   5 use Scalar::Util qw/blessed/;
   6
   7 use base qw/DBIx::Class::Row/;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::InflateColumn - Automatically create objects from column data
  12
  13 =head1 SYNOPSIS
  14
  15     # In your table classes
  16     __PACKAGE__->inflate_column('column_name', {
  17         inflate => sub { ... },
  18         deflate => sub { ... },
  19     });
  20
  21 =head1 DESCRIPTION
  22
  23 This component translates column data into objects, i.e. "inflating"
  24 the column data. It also "deflates" objects into an appropriate format
  25 for the database.
  26
  27 It can be used, for example, to automatically convert to and from
  28 L<DateTime> objects for your date and time fields.
  29
  30 =head1 METHODS
  31
  32 =head2 inflate_column
  33
  34 Instruct L<DBIx::Class> to inflate the given column.
  35
  36 In addition to the column name, you must provide C<inflate> and
  37 C<deflate> methods. The C<inflate> method is called when you access
  38 the field, while the C<deflate> method is called when the field needs
  39 to used by the database.
  40
  41 For example, if you have a table C<events> with a timestamp field
  42 named C<insert_time>, you could inflate the column in the
  43 corresponding table class using something like:
  44
  45     __PACKAGE__->inflate_column('insert_time', {
  46         inflate => sub { DateTime::Format::Pg->parse_datetime(shift); },
  47         deflate => sub { DateTime::Format::Pg->format_datetime(shift); },
  48     });
  49
  50 (Replace L<DateTime::Format::Pg> with the appropriate module for your
  51 database, or consider L<DateTime::Format::DBI>.)
  52
  53 The coderefs you set for inflate and deflate are called with two parameters,
  54 the first is the value of the column to be inflated/deflated, the second is the
  55 row object itself. Thus you can call C<< ->result_source->schema->storage->dbh >> on
  56 it, to feed to L<DateTime::Format::DBI>.
  57
  58 In this example, calls to an event's C<insert_time> accessor return a
  59 L<DateTime> object. This L<DateTime> object is later "deflated" when
  60 used in the database layer.
  61
  62 =cut
  63
  64 sub inflate_column {
  65   my ($self, $col, $attrs) = @_;
  66   $self->throw_exception("No such column $col to inflate")
  67     unless $self->has_column($col);
  68   $self->throw_exception("inflate_column needs attr hashref")
  69     unless ref $attrs eq 'HASH';
  70   $self->column_info($col)->{_inflate_info} = $attrs;
  71   $self->mk_group_accessors('inflated_column' => $col);
  72   return 1;
  73 }
  74
  75 sub _inflated_column {
  76   my ($self, $col, $value) = @_;
  77   return $value unless defined $value; # NULL is NULL is NULL
  78   my $info = $self->column_info($col)
  79     or $self->throw_exception("No column info for $col");
  80   return $value unless exists $info->{_inflate_info};
  81   my $inflate = $info->{_inflate_info}{inflate};
  82   $self->throw_exception("No inflator for $col") unless defined $inflate;
  83   return $inflate->($value, $self);
  84 }
  85
  86 sub _deflated_column {
  87   my ($self, $col, $value) = @_;
  88   return $value unless ref $value; # If it's not an object, don't touch it
  89   my $info = $self->column_info($col) or
  90     $self->throw_exception("No column info for $col");
  91   return $value unless exists $info->{_inflate_info};
  92   my $deflate = $info->{_inflate_info}{deflate};
  93   $self->throw_exception("No deflator for $col") unless defined $deflate;
  94   return $deflate->($value, $self);
  95 }
  96
  97 =head2 get_inflated_column
  98
  99   my $val = $obj->get_inflated_column($col);
 100
 101 Fetch a column value in its inflated state.  This is directly
 102 analogous to L<DBIx::Class::Row/get_column> in that it only fetches a
 103 column already retreived from the database, and then inflates it.
 104 Throws an exception if the column requested is not an inflated column.
 105
 106 =cut
 107
 108 sub get_inflated_column {
 109   my ($self, $col) = @_;
 110   $self->throw_exception("$col is not an inflated column")
 111     unless exists $self->column_info($col)->{_inflate_info};
 112   return $self->{_inflated_column}{$col}
 113     if exists $self->{_inflated_column}{$col};
 114   return $self->{_inflated_column}{$col} =
 115            $self->_inflated_column($col, $self->get_column($col));
 116 }
 117
 118 =head2 set_inflated_column
 119
 120   my $copy = $obj->set_inflated_column($col => $val);
 121
 122 Sets a column value from an inflated value.  This is directly
 123 analogous to L<DBIx::Class::Row/set_column>.
 124
 125 =cut
 126
 127 sub set_inflated_column {
 128   my ($self, $col, $obj) = @_;
 129   $self->set_column($col, $self->_deflated_column($col, $obj));
 130   if (blessed $obj) {
 131     $self->{_inflated_column}{$col} = $obj;
 132   } else {
 133     delete $self->{_inflated_column}{$col};
 134   }
 135   return $obj;
 136 }
 137
 138 =head2 store_inflated_column
 139
 140   my $copy = $obj->store_inflated_column($col => $val);
 141
 142 Sets a column value from an inflated value without marking the column
 143 as dirty. This is directly analogous to L<DBIx::Class::Row/store_column>.
 144
 145 =cut
 146
 147 sub store_inflated_column {
 148   my ($self, $col, $obj) = @_;
 149   unless (blessed $obj) {
 150       delete $self->{_inflated_column}{$col};
 151       $self->store_column($col => $obj);
 152       return $obj;
 153   }
 154   delete $self->{_column_data}{$col};
 155   return $self->{_inflated_column}{$col} = $obj;
 156 }
 157
 158 =head2 get_column
 159
 160 Gets a column value in the same way as L<DBIx::Class::Row/get_column>. If there
 161 is an inflated value stored that has not yet been deflated, it is deflated
 162 when the method is invoked.
 163
 164 =cut
 165
 166 sub get_column {
 167   my ($self, $col) = @_;
 168   if (exists $self->{_inflated_column}{$col}
 169         && !exists $self->{_column_data}{$col}) {
 170     $self->store_column($col, $self->_deflated_column($col, $self->{_inflated_column}{$col}));
 171   }
 172   return $self->next::method($col);
 173 }
 174
 175 =head2 get_columns
 176
 177 Returns the get_column info for all columns as a hash,
 178 just like L<DBIx::Class::Row/get_columns>.  Handles inflation just
 179 like L</get_column>.
 180
 181 =cut
 182
 183 sub get_columns {
 184   my $self = shift;
 185   if (exists $self->{_inflated_column}) {
 186     foreach my $col (keys %{$self->{_inflated_column}}) {
 187       $self->store_column($col, $self->_deflated_column($col, $self->{_inflated_column}{$col}))
 188        unless exists $self->{_column_data}{$col};
 189     }
 190   }
 191   return $self->next::method;
 192 }
 193
 194 =head2 has_column_loaded
 195
 196 Like L<DBIx::Class::Row/has_column_loaded>, but also returns true if there
 197 is an inflated value stored.
 198
 199 =cut
 200
 201 sub has_column_loaded {
 202   my ($self, $col) = @_;
 203   return 1 if exists $self->{_inflated_column}{$col};
 204   return $self->next::method($col);
 205 }
 206
 207 =head2 update
 208
 209 Updates a row in the same way as L<DBIx::Class::Row/update>, handling
 210 inflation and deflation of columns appropriately.
 211
 212 =cut
 213
 214 sub update {
 215   my ($class, $attrs, @rest) = @_;
 216   foreach my $key (keys %{$attrs||{}}) {
 217     if (ref $attrs->{$key}
 218           && exists $class->column_info($key)->{_inflate_info}) {
 219       $class->set_inflated_column($key, delete $attrs->{$key});
 220     }
 221   }
 222   return $class->next::method($attrs, @rest);
 223 }
 224
 225 =head2 new
 226
 227 Creates a row in the same way as L<DBIx::Class::Row/new>, handling
 228 inflation and deflation of columns appropriately.
 229
 230 =cut
 231
 232 sub new {
 233   my ($class, $attrs, @rest) = @_;
 234   my $inflated;
 235   foreach my $key (keys %{$attrs||{}}) {
 236     $inflated->{$key} = delete $attrs->{$key}
 237       if ref $attrs->{$key} && exists $class->column_info($key)->{_inflate_info};
 238   }
 239   my $obj = $class->next::method($attrs, @rest);
 240   $obj->{_inflated_column} = $inflated if $inflated;
 241   return $obj;
 242 }
 243
 244 =head1 SEE ALSO
 245
 246 =over 4
 247
 248 =item L<DBIx::Class::Core> - This component is loaded as part of the
 249       "core" L<DBIx::Class> components; generally there is no need to
 250       load it directly
 251
 252 =back
 253
 254 =head1 AUTHOR
 255
 256 Matt S. Trout <mst@shadowcatsystems.co.uk>
 257
 258 =head1 CONTRIBUTORS
 259
 260 Daniel Westermann-Clark <danieltwc@cpan.org> (documentation)
 261
 262 =head1 LICENSE
 263
 264 You may distribute this code under the same terms as Perl itself.
 265
 266 =cut
 267
 268 1;