lib/DBIx/Class/InflateColumn.pm

   1 package DBIx::Class::InflateColumn;
   2
   3 use strict;
   4 use warnings;
   5 use Scalar::Util qw/blessed/;
   6
   7 use base qw/DBIx::Class::Row/;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::InflateColumn - Automatically create references from column data
  12
  13 =head1 SYNOPSIS
  14
  15     # In your table classes
  16     __PACKAGE__->inflate_column('column_name', {
  17         inflate => sub { ... },
  18         deflate => sub { ... },
  19     });
  20
  21 =head1 DESCRIPTION
  22
  23 This component translates column data into references, i.e. "inflating"
  24 the column data. It also "deflates" references into an appropriate format
  25 for the database.
  26
  27 It can be used, for example, to automatically convert to and from
  28 L<DateTime> objects for your date and time fields.
  29
  30 It will accept arrayrefs, hashrefs and blessed references (objects),
  31 but not scalarrefs. Scalar references are passed through to the
  32 database to deal with, to allow such settings as C< \'year + 1'> and
  33 C< \'DEFAULT' > to work.
  34
  35 =head1 METHODS
  36
  37 =head2 inflate_column
  38
  39 Instruct L<DBIx::Class> to inflate the given column.
  40
  41 In addition to the column name, you must provide C<inflate> and
  42 C<deflate> methods. The C<inflate> method is called when you access
  43 the field, while the C<deflate> method is called when the field needs
  44 to used by the database.
  45
  46 For example, if you have a table C<events> with a timestamp field
  47 named C<insert_time>, you could inflate the column in the
  48 corresponding table class using something like:
  49
  50     __PACKAGE__->inflate_column('insert_time', {
  51         inflate => sub { DateTime::Format::Pg->parse_datetime(shift); },
  52         deflate => sub { DateTime::Format::Pg->format_datetime(shift); },
  53     });
  54
  55 (Replace L<DateTime::Format::Pg> with the appropriate module for your
  56 database, or consider L<DateTime::Format::DBI>.)
  57
  58 The coderefs you set for inflate and deflate are called with two parameters,
  59 the first is the value of the column to be inflated/deflated, the second is the
  60 row object itself. Thus you can call C<< ->result_source->schema->storage->dbh >> on
  61 it, to feed to L<DateTime::Format::DBI>.
  62
  63 In this example, calls to an event's C<insert_time> accessor return a
  64 L<DateTime> object. This L<DateTime> object is later "deflated" when
  65 used in the database layer.
  66
  67 =cut
  68
  69 sub inflate_column {
  70   my ($self, $col, $attrs) = @_;
  71   $self->throw_exception("No such column $col to inflate")
  72     unless $self->has_column($col);
  73   $self->throw_exception("inflate_column needs attr hashref")
  74     unless ref $attrs eq 'HASH';
  75   $self->column_info($col)->{_inflate_info} = $attrs;
  76   $self->mk_group_accessors('inflated_column' => $col);
  77   return 1;
  78 }
  79
  80 sub _inflated_column {
  81   my ($self, $col, $value) = @_;
  82   return $value unless defined $value; # NULL is NULL is NULL
  83   my $info = $self->column_info($col)
  84     or $self->throw_exception("No column info for $col");
  85   return $value unless exists $info->{_inflate_info};
  86   my $inflate = $info->{_inflate_info}{inflate};
  87   $self->throw_exception("No inflator for $col") unless defined $inflate;
  88   return $inflate->($value, $self);
  89 }
  90
  91 sub _deflated_column {
  92   my ($self, $col, $value) = @_;
  93 #  return $value unless ref $value && blessed($value); # If it's not an object, don't touch it
  94   ## Leave scalar refs (ala SQL::Abstract literal SQL), untouched, deflate all other refs
  95   return $value unless (ref $value && ref($value) ne 'SCALAR');
  96   my $info = $self->column_info($col) or
  97     $self->throw_exception("No column info for $col");
  98   return $value unless exists $info->{_inflate_info};
  99   my $deflate = $info->{_inflate_info}{deflate};
 100   $self->throw_exception("No deflator for $col") unless defined $deflate;
 101   return $deflate->($value, $self);
 102 }
 103
 104 =head2 get_inflated_column
 105
 106   my $val = $obj->get_inflated_column($col);
 107
 108 Fetch a column value in its inflated state.  This is directly
 109 analogous to L<DBIx::Class::Row/get_column> in that it only fetches a
 110 column already retreived from the database, and then inflates it.
 111 Throws an exception if the column requested is not an inflated column.
 112
 113 =cut
 114
 115 sub get_inflated_column {
 116   my ($self, $col) = @_;
 117   $self->throw_exception("$col is not an inflated column")
 118     unless exists $self->column_info($col)->{_inflate_info};
 119   return $self->{_inflated_column}{$col}
 120     if exists $self->{_inflated_column}{$col};
 121   return $self->{_inflated_column}{$col} =
 122            $self->_inflated_column($col, $self->get_column($col));
 123 }
 124
 125 =head2 set_inflated_column
 126
 127   my $copy = $obj->set_inflated_column($col => $val);
 128
 129 Sets a column value from an inflated value.  This is directly
 130 analogous to L<DBIx::Class::Row/set_column>.
 131
 132 =cut
 133
 134 sub set_inflated_column {
 135   my ($self, $col, $inflated) = @_;
 136   $self->set_column($col, $self->_deflated_column($col, $inflated));
 137 #  if (blessed $inflated) {
 138   if (ref $inflated && ref($inflated) ne 'SCALAR') {
 139     $self->{_inflated_column}{$col} = $inflated;
 140   } else {
 141     delete $self->{_inflated_column}{$col};
 142   }
 143   return $inflated;
 144 }
 145
 146 =head2 store_inflated_column
 147
 148   my $copy = $obj->store_inflated_column($col => $val);
 149
 150 Sets a column value from an inflated value without marking the column
 151 as dirty. This is directly analogous to L<DBIx::Class::Row/store_column>.
 152
 153 =cut
 154
 155 sub store_inflated_column {
 156   my ($self, $col, $inflated) = @_;
 157 #  unless (blessed $inflated) {
 158   unless (ref $inflated && ref($inflated) ne 'SCALAR') {
 159       delete $self->{_inflated_column}{$col};
 160       $self->store_column($col => $inflated);
 161       return $inflated;
 162   }
 163   delete $self->{_column_data}{$col};
 164   return $self->{_inflated_column}{$col} = $inflated;
 165 }
 166
 167 =head2 get_column
 168
 169 Gets a column value in the same way as L<DBIx::Class::Row/get_column>. If there
 170 is an inflated value stored that has not yet been deflated, it is deflated
 171 when the method is invoked.
 172
 173 =cut
 174
 175 sub get_column {
 176   my ($self, $col) = @_;
 177   if (exists $self->{_inflated_column}{$col}
 178         && !exists $self->{_column_data}{$col}) {
 179     $self->store_column($col, $self->_deflated_column($col, $self->{_inflated_column}{$col}));
 180   }
 181   return $self->next::method($col);
 182 }
 183
 184 =head2 get_columns
 185
 186 Returns the get_column info for all columns as a hash,
 187 just like L<DBIx::Class::Row/get_columns>.  Handles inflation just
 188 like L</get_column>.
 189
 190 =cut
 191
 192 sub get_columns {
 193   my $self = shift;
 194   if (exists $self->{_inflated_column}) {
 195     foreach my $col (keys %{$self->{_inflated_column}}) {
 196       $self->store_column($col, $self->_deflated_column($col, $self->{_inflated_column}{$col}))
 197        unless exists $self->{_column_data}{$col};
 198     }
 199   }
 200   return $self->next::method;
 201 }
 202
 203 =head2 has_column_loaded
 204
 205 Like L<DBIx::Class::Row/has_column_loaded>, but also returns true if there
 206 is an inflated value stored.
 207
 208 =cut
 209
 210 sub has_column_loaded {
 211   my ($self, $col) = @_;
 212   return 1 if exists $self->{_inflated_column}{$col};
 213   return $self->next::method($col);
 214 }
 215
 216 =head2 update
 217
 218 Updates a row in the same way as L<DBIx::Class::Row/update>, handling
 219 inflation and deflation of columns appropriately.
 220
 221 =cut
 222
 223 sub update {
 224   my ($class, $attrs, @rest) = @_;
 225   foreach my $key (keys %{$attrs||{}}) {
 226     if (ref $attrs->{$key} && $class->has_column($key)
 227           && exists $class->column_info($key)->{_inflate_info}) {
 228       $class->set_inflated_column($key, delete $attrs->{$key});
 229     }
 230   }
 231   return $class->next::method($attrs, @rest);
 232 }
 233
 234 =head2 new
 235
 236 Creates a row in the same way as L<DBIx::Class::Row/new>, handling
 237 inflation and deflation of columns appropriately.
 238
 239 =cut
 240
 241 sub new {
 242   my ($class, $attrs, @rest) = @_;
 243   my $inflated;
 244   foreach my $key (keys %{$attrs||{}}) {
 245     $inflated->{$key} = delete $attrs->{$key}
 246       if ref $attrs->{$key} && $class->has_column($key)
 247          && exists $class->column_info($key)->{_inflate_info};
 248   }
 249   my $obj = $class->next::method($attrs, @rest);
 250   $obj->{_inflated_column} = $inflated if $inflated;
 251   return $obj;
 252 }
 253
 254 =head1 SEE ALSO
 255
 256 =over 4
 257
 258 =item L<DBIx::Class::Core> - This component is loaded as part of the
 259       "core" L<DBIx::Class> components; generally there is no need to
 260       load it directly
 261
 262 =back
 263
 264 =head1 AUTHOR
 265
 266 Matt S. Trout <mst@shadowcatsystems.co.uk>
 267
 268 =head1 CONTRIBUTORS
 269
 270 Daniel Westermann-Clark <danieltwc@cpan.org> (documentation)
 271
 272 Jess Robinson <cpan@desert-island.demon.co.uk>
 273
 274 =head1 LICENSE
 275
 276 You may distribute this code under the same terms as Perl itself.
 277
 278 =cut
 279
 280 1;