lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  10
  11 =head1 SYNOPSIS
  12
  13 Load this component and then declare one or more
  14 columns to be of the datetime, timestamp or date datatype.
  15
  16   package Event;
  17   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  18   __PACKAGE__->add_columns(
  19     starts_when => { data_type => 'datetime' }
  20   );
  21
  22 Then you can treat the specified column as a L<DateTime> object.
  23
  24   print "This event starts the month of ".
  25     $event->starts_when->month_name();
  26
  27 If you want to set a specific timezone for that field, use:
  28
  29   __PACKAGE__->add_columns(
  30     starts_when => { data_type => 'datetime', extra => { timezone => "America/Chicago" } }
  31   );
  32
  33 =head1 DESCRIPTION
  34
  35 This module figures out the type of DateTime::Format::* class to
  36 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  37 that you are using.  If you switch from one database to a different
  38 one your code should continue to work without modification (though note
  39 that this feature is new as of 0.07, so it may not be perfect yet - bug
  40 reports to the list very much welcome).
  41
  42 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  43
  44 =cut
  45
  46 __PACKAGE__->load_components(qw/InflateColumn/);
  47
  48 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  49
  50 =head2 register_column
  51
  52 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  53 up datetime columns appropriately.  This would not normally be
  54 directly called by end users.
  55
  56 =cut
  57
  58 sub register_column {
  59   my ($self, $column, $info, @rest) = @_;
  60   $self->next::method($column, $info, @rest);
  61   return unless defined($info->{data_type});
  62   my $type = lc($info->{data_type});
  63   $type = 'datetime' if ($type =~ /^timestamp/);
  64   my $timezone;
  65   if ( exists $info->{extra} and exists $info->{extra}{timezone} and defined $info->{extra}{timezone} ) {
  66     $timezone = $info->{extra}{timezone};
  67   }
  68
  69   if ($type eq 'datetime' || $type eq 'date') {
  70     my ($parse, $format) = ("parse_${type}", "format_${type}");
  71     $self->inflate_column(
  72       $column =>
  73         {
  74           inflate => sub {
  75             my ($value, $obj) = @_;
  76             my $dt = $obj->_datetime_parser->$parse($value);
  77             $dt->set_time_zone($timezone) if $timezone;
  78             return $dt;
  79           },
  80           deflate => sub {
  81             my ($value, $obj) = @_;
  82             $value->set_time_zone($timezone) if $timezone;
  83             $obj->_datetime_parser->$format($value);
  84           },
  85         }
  86     );
  87   }
  88 }
  89
  90 sub _datetime_parser {
  91   my $self = shift;
  92   if (my $parser = $self->__datetime_parser) {
  93     return $parser;
  94   }
  95   my $parser = $self->result_source->storage->datetime_parser(@_);
  96   return $self->__datetime_parser($parser);
  97 }
  98
  99 1;
 100 __END__
 101
 102 =head1 SEE ALSO
 103
 104 =over 4
 105
 106 =item More information about the add_columns method, and column metadata,
 107       can be found in the documentation for L<DBIx::Class::ResultSource>.
 108
 109 =back
 110
 111 =head1 AUTHOR
 112
 113 Matt S. Trout <mst@shadowcatsystems.co.uk>
 114
 115 =head1 CONTRIBUTORS
 116
 117 Aran Deltac <bluefeet@cpan.org>
 118
 119 =head1 LICENSE
 120
 121 You may distribute this code under the same terms as Perl itself.
 122