lib/DBIx/Class/DeploymentHandler.pm

   1 package DBIx::Class::DeploymentHandler;
   2
   3 use Moose;
   4 use Method::Signatures::Simple;
   5 require DBIx::Class::Schema;    # loaded for type constraint
   6 require DBIx::Class::Storage;   # loaded for type constraint
   7 require DBIx::Class::ResultSet; # loaded for type constraint
   8 use Carp::Clan '^DBIx::Class::DeploymentHandler';
   9 use SQL::Translator;
  10 require SQL::Translator::Diff;
  11 use Try::Tiny;
  12
  13 with 'DBIx::Class::DeploymentHandler::WithSqltDeployMethod';
  14
  15 BEGIN {
  16   use Moose::Util::TypeConstraints;
  17   subtype 'DBIx::Class::DeploymentHandler::Databases'
  18     => as 'ArrayRef[Str]';
  19
  20   coerce 'DBIx::Class::DeploymentHandler::Databases'
  21     => from 'Str'
  22     => via { [$_] };
  23   no Moose::Util::TypeConstraints;
  24 }
  25
  26 has schema => (
  27   isa      => 'DBIx::Class::Schema',
  28   is       => 'ro',
  29   required => 1,
  30   handles => [qw( ddl_filename schema_version )],
  31 );
  32
  33 has upgrade_directory => (
  34   isa      => 'Str',
  35   is       => 'ro',
  36   required => 1,
  37   default  => 'sql',
  38 );
  39
  40 has backup_directory => (
  41   isa => 'Str',
  42   is  => 'ro',
  43   predicate  => 'has_backup_directory',
  44 );
  45
  46 has storage => (
  47   isa        => 'DBIx::Class::Storage',
  48   is         => 'ro',
  49   lazy_build => 1,
  50 );
  51
  52 method _build_storage {
  53   my $s = $self->schema->storage;
  54   $s->_determine_driver;
  55   $s
  56 }
  57
  58 has do_backup => (
  59   isa     => 'Bool',
  60   is      => 'ro',
  61   default => undef,
  62 );
  63
  64 has do_diff_on_init => (
  65   isa     => 'Bool',
  66   is      => 'ro',
  67   default => undef,
  68 );
  69
  70 has version_rs => (
  71   isa        => 'DBIx::Class::ResultSet',
  72   is         => 'ro',
  73   lazy_build => 1,
  74   handles    => [qw( is_installed db_version )],
  75 );
  76
  77 method _build_version_rs {
  78    $self->schema->set_us_up_the_bomb;
  79    $self->schema->resultset('__VERSION')
  80 }
  81
  82 has databases => (
  83   coerce  => 1,
  84   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  85   is      => 'ro',
  86   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  87 );
  88
  89 has sqltargs => (
  90   isa => 'HashRef',
  91   is  => 'ro',
  92   default => sub { {} },
  93 );
  94
  95 method deploy {
  96   my $storage  = $self->storage;
  97
  98   my $deploy = sub {
  99     my $line = shift;
 100     return if(!$line || $line =~ /^--|^BEGIN TRANSACTION|^COMMIT|^\s+$/);
 101     $storage->_query_start($line);
 102     try {
 103       # do a dbh_do cycle here, as we need some error checking in
 104       # place (even though we will ignore errors)
 105       $storage->dbh_do (sub { $_[1]->do($line) });
 106     }
 107     catch {
 108       carp "$_ (running '${line}')"
 109     }
 110     $storage->_query_end($line);
 111   };
 112   my @statements = $self->deployment_statements();
 113   if (@statements > 1) {
 114     foreach my $statement (@statements) {
 115       $deploy->( $statement );
 116     }
 117   }
 118   elsif (@statements == 1) {
 119     foreach my $line ( split(";\n", $statements[0])) {
 120       $deploy->( $line );
 121     }
 122   }
 123 }
 124
 125 method install($new_version) {
 126   carp 'Install not possible as versions table already exists in database'
 127     if $self->is_installed;
 128
 129   $new_version ||= $self->schema_version;
 130
 131   if ($new_version) {
 132     $self->deploy();
 133
 134     $self->version_rs->create({
 135       version     => $new_version,
 136       # ddl         => $ddl,
 137       # upgrade_sql => $upgrade_sql,
 138     });
 139   }
 140 }
 141
 142 method ordered_schema_versions { undef }
 143
 144 method upgrade {
 145   my $db_version     = $self->db_version;
 146   my $schema_version = $self->schema_version;
 147
 148   unless ($db_version) {
 149     # croak?
 150     carp 'Upgrade not possible as database is unversioned. Please call install first.';
 151     return;
 152   }
 153
 154   if ( $db_version eq $schema_version ) {
 155     # croak?
 156     carp "Upgrade not necessary\n";
 157     return;
 158   }
 159
 160   my @version_list = $self->ordered_schema_versions ||
 161     ( $db_version, $schema_version );
 162
 163   # remove all versions in list above the required version
 164   while ( @version_list && ( $version_list[-1] ne $schema_version ) ) {
 165     pop @version_list;
 166   }
 167
 168   # remove all versions in list below the current version
 169   while ( @version_list && ( $version_list[0] ne $db_version ) ) {
 170     shift @version_list;
 171   }
 172
 173   # check we have an appropriate list of versions
 174   die if @version_list < 2;
 175
 176   # do sets of upgrade
 177   while ( @version_list >= 2 ) {
 178     $self->upgrade_single_step( $version_list[0], $version_list[1] );
 179     shift @version_list;
 180   }
 181 }
 182
 183 __PACKAGE__->meta->make_immutable;
 184
 185 1;
 186
 187 __END__
 188
 189 vim: ts=2,sw=2,expandtab