lib/DBIx/Class/DeploymentHandler.pm

   1 package DBIx::Class::DeploymentHandler;
   2
   3 use Moose;
   4 use Method::Signatures::Simple;
   5 require DBIx::Class::Schema;    # loaded for type constraint
   6 require DBIx::Class::Storage;   # loaded for type constraint
   7 require DBIx::Class::ResultSet; # loaded for type constraint
   8 use Carp::Clan '^DBIx::Class::DeploymentHandler';
   9 use SQL::Translator;
  10
  11 BEGIN {
  12   use Moose::Util::TypeConstraints;
  13   subtype 'DBIx::Class::DeploymentHandler::Databases'
  14     => as 'ArrayRef[Str]';
  15
  16   coerce 'DBIx::Class::DeploymentHandler::Databases'
  17     => from 'Str'
  18     => via { [$_] };
  19   no Moose::Util::TypeConstraints;
  20 }
  21
  22 has schema => (
  23   isa      => 'DBIx::Class::Schema',
  24   is       => 'ro',
  25   required => 1,
  26   handles => [qw( ddl_filename schema_version )],
  27 );
  28
  29 has upgrade_directory => (
  30   isa      => 'Str',
  31   is       => 'ro',
  32   required => 1,
  33   default  => 'sql',
  34 );
  35
  36 has backup_directory => (
  37   isa => 'Str',
  38   is  => 'ro',
  39 );
  40
  41 has storage => (
  42   isa        => 'DBIx::Class::Storage',
  43   is         => 'ro',
  44   lazy_build => 1,
  45 );
  46
  47 method _build_storage {
  48   my $s = $self->schema->storage;
  49   $s->_determine_driver;
  50   $s
  51 }
  52
  53 has _filedata => (
  54   isa => 'ArrayRef[Str]',
  55   is  => 'rw',
  56 );
  57
  58 has do_backup => (
  59   isa     => 'Bool',
  60   is      => 'ro',
  61   default => undef,
  62 );
  63
  64 has do_diff_on_init => (
  65   isa     => 'Bool',
  66   is      => 'ro',
  67   default => undef,
  68 );
  69
  70 has version_rs => (
  71   isa        => 'DBIx::Class::ResultSet',
  72   is         => 'ro',
  73   lazy_build => 1,
  74   handles    => [qw( is_installed db_version )],
  75 );
  76
  77 has databases => (
  78   coerce  => 1,
  79   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  80   is      => 'ro',
  81   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  82 );
  83
  84 has sqltargs => (
  85   isa => 'HashRef',
  86   is  => 'ro',
  87   default => sub { {} },
  88 );
  89
  90 method _build_version_rs {
  91    $self->schema->set_us_up_the_bomb;
  92    $self->schema->resultset('__VERSION')
  93 }
  94
  95 method backup { $self->storage->backup($self->backup_directory) }
  96
  97 method install($new_version) {
  98   carp 'Install not possible as versions table already exists in database'
  99     if $self->is_installed;
 100
 101   $new_version ||= $self->schema_version;
 102
 103   if ($new_version) {
 104     $self->schema->deploy;
 105
 106     $self->version_rs->create({
 107       version     => $new_version,
 108       # ddl         => $ddl,
 109       # upgrade_sql => $upgrade_sql,
 110     });
 111   }
 112 }
 113
 114 method create_upgrade_path { }
 115
 116 method ordered_schema_versions { undef }
 117
 118 method upgrade {
 119   my $db_version     = $self->db_version;
 120   my $schema_version = $self->schema_version;
 121
 122   unless ($db_version) {
 123     # croak?
 124     carp 'Upgrade not possible as database is unversioned. Please call install first.';
 125     return;
 126   }
 127
 128   if ( $db_version eq $schema_version ) {
 129     # croak?
 130     carp "Upgrade not necessary\n";
 131     return;
 132   }
 133
 134   my @version_list = $self->ordered_schema_versions ||
 135     ( $db_version, $schema_version );
 136
 137   # remove all versions in list above the required version
 138   while ( @version_list && ( $version_list[-1] ne $schema_version ) ) {
 139     pop @version_list;
 140   }
 141
 142   # remove all versions in list below the current version
 143   while ( @version_list && ( $version_list[0] ne $db_version ) ) {
 144     shift @version_list;
 145   }
 146
 147   # check we have an appropriate list of versions
 148   die if @version_list < 2;
 149
 150   # do sets of upgrade
 151   while ( @version_list >= 2 ) {
 152     $self->upgrade_single_step( $version_list[0], $version_list[1] );
 153     shift @version_list;
 154   }
 155 }
 156
 157 method upgrade_single_step($db_version, $target_version) {
 158   if ($db_version eq $target_version) {
 159     # croak?
 160     carp "Upgrade not necessary\n";
 161     return;
 162   }
 163
 164   my $upgrade_file = $self->ddl_filename(
 165     $self->storage->sqlt_type,
 166     $target_version,
 167     $self->upgrade_directory,
 168     $db_version,
 169   );
 170
 171   $self->create_upgrade_path({ upgrade_file => $upgrade_file });
 172
 173   unless (-f $upgrade_file) {
 174     # croak?
 175     carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 176     return;
 177   }
 178
 179   carp "DB version ($db_version) is lower than the schema version (".$self->schema_version."). Attempting upgrade.\n";
 180
 181   $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 182   $self->backup if $self->do_backup;
 183   $self->schema->txn_do(sub { $self->do_upgrade });
 184
 185   $self->version_rs->create({
 186     version     => $target_version,
 187     # ddl         => $ddl,
 188     # upgrade_sql => $upgrade_sql,
 189   });
 190 }
 191
 192 method create_ddl_dir($version, $preversion) {
 193   my $schema    = $self->schema;
 194   my $databases = $self->databases;
 195   my $dir       = $self->upgrade_directory;
 196   my $sqltargs  = $self->sqltargs;
 197   unless( -d $dir ) {
 198     carp "Upgrade directory $dir does not exist, using ./\n";
 199     $dir = "./";
 200   }
 201
 202   my $schema_version = $schema->schema_version || '1.x';
 203   $version ||= $schema_version;
 204
 205   $sqltargs = {
 206     add_drop_table => 1,
 207     ignore_constraint_names => 1,
 208     ignore_index_names => 1,
 209     %{$sqltargs || {}}
 210   };
 211
 212   my $sqlt = SQL::Translator->new( $sqltargs );
 213
 214   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 215   my $sqlt_schema = $sqlt->translate({ data => $schema })
 216     or $self->throw_exception ($sqlt->error);
 217
 218   foreach my $db (@$databases) {
 219     $sqlt->reset;
 220     $sqlt->{schema} = $sqlt_schema;
 221     $sqlt->producer($db);
 222
 223     my $filename = $self->ddl_filename($db, $version, $dir);
 224     if (-e $filename && ($version eq $schema_version )) {
 225       # if we are dumping the current version, overwrite the DDL
 226       carp "Overwriting existing DDL file - $filename";
 227       unlink $filename;
 228     }
 229
 230     my $output = $sqlt->translate;
 231     if(!$output) {
 232       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 233       next;
 234     }
 235     my $file;
 236     unless( open $file, q(>), $filename ) {
 237       $self->throw_exception("Can't open $filename for writing ($!)");
 238       next;
 239     }
 240     print {$file} $output;
 241     close $file;
 242
 243     next unless $preversion;
 244
 245     require SQL::Translator::Diff;
 246
 247     my $prefilename = $self->ddl_filename($db, $preversion, $dir);
 248     unless(-e $prefilename) {
 249       carp("No previous schema file found ($prefilename)");
 250       next;
 251     }
 252
 253     my $diff_file = $self->ddl_filename($db, $version, $dir, $preversion);
 254     if(-e $diff_file) {
 255       carp("Overwriting existing diff file - $diff_file");
 256       unlink $diff_file;
 257     }
 258
 259     my $source_schema;
 260     {
 261       my $t = SQL::Translator->new({
 262          %{$sqltargs},
 263          debug => 0,
 264          trace => 0,
 265       });
 266
 267       $t->parser( $db ) # could this really throw an exception?
 268         or $self->throw_exception ($t->error);
 269
 270       my $out = $t->translate( $prefilename )
 271         or $self->throw_exception ($t->error);
 272
 273       $source_schema = $t->schema;
 274
 275       $source_schema->name( $prefilename )
 276         unless  $source_schema->name;
 277     }
 278
 279     # The "new" style of producers have sane normalization and can support
 280     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 281     # And we have to diff parsed SQL against parsed SQL.
 282     my $dest_schema = $sqlt_schema;
 283
 284     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 285       my $t = SQL::Translator->new({
 286          %{$sqltargs},
 287          debug => 0,
 288          trace => 0,
 289       });
 290
 291       $t->parser( $db ) # could this really throw an exception?
 292         or $self->throw_exception ($t->error);
 293
 294       my $out = $t->translate( $filename )
 295         or $self->throw_exception ($t->error);
 296
 297       $dest_schema = $t->schema;
 298
 299       $dest_schema->name( $filename )
 300         unless $dest_schema->name;
 301     }
 302
 303     my $diff = SQL::Translator::Diff::schema_diff(
 304        $source_schema, $db,
 305        $dest_schema,   $db,
 306        $sqltargs
 307     );
 308     unless(open $file, q(>), $diff_file) {
 309       $self->throw_exception("Can't write to $diff_file ($!)");
 310       next;
 311     }
 312     print {$file} $diff;
 313     close $file;
 314   }
 315 }
 316
 317 method do_upgrade { $self->run_upgrade(qr/.*?/) }
 318
 319 method run_upgrade($stm) {
 320   return unless $self->_filedata;
 321   my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 322
 323   for (@statements) {
 324     $self->storage->debugobj->query_start($_) if $self->storage->debug;
 325     $self->apply_statement($_);
 326     $self->storage->debugobj->query_end($_) if $self->storage->debug;
 327   }
 328 }
 329
 330 method apply_statement($statement) {
 331   # croak?
 332   $self->storage->dbh->do($_) or carp "SQL was: $_"
 333 }
 334
 335 method _read_sql_file($file) {
 336   return unless $file;
 337
 338   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 339   my @data = split /\n/, join '', <$fh>;
 340   close $fh;
 341
 342   @data = grep {
 343     $_ &&
 344     !/^--/ &&
 345     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/m
 346   } split /;/,
 347     join '', @data;
 348
 349   return \@data;
 350 }
 351
 352 1;
 353
 354 __END__
 355
 356 vim: ts=2,sw=2,expandtab